hlmod.hu :: [ZP] Kiegészítő: Gránát Státusz

hlmod.hu https://hlmod.hu/

[ZP] Kiegészítő: Gránát Státusz https://hlmod.hu/viewtopic.php?f=101&t=13005	Oldal: 1 / 1

Szerző:

norbee.16 [ 2013.11.30. 21:49 ]

Hozzászólás témája:

[ZP] Kiegészítő: Gránát Státusz

Plugin Neve:	[ZP] Kiegészítő: Gránát Státusz	Plugint készitette:	rapara13
Játék:	Counter-Strike	Kategória:	Szerver kezelés
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

[kozep][ZP] Kiegészítő: Gránát Státusz[/kozep]

Leírás:
Minden gránátnál más fajta és színű ikont rak a bal oldalra. Gránátok Státusza: Tűz, Fagyasztó, Fény és Fertőző.

Cvarok:

Kód:

// Gránát Státusz Cvars
 zp_nadestatus_icon "1" // [0 - Elrejtés | 1 - Mutatás | 2 - Vaku (Ne legyen piros szín)]

// Tűz Gránát Cvars
 zp_firenade_icon "1" // [0 - Kikapcsolás | 1 - Bekapcsolás]
 zp_firenade_color "255 0 0" // Tűz gránát ikon színe RGB 

// Fagyasztó Gránát Cvars
 zp_frostnade_icon "1" // [0 - Kikapcsolás | 1 - Bekapcsolás]
 zp_frostnade_color "100 149 237" // Fagyasztó gránát ikon színe RGB 

// Fény Gránát Cvars
 zp_flarenade_icon "1" // [0 - Kikapcsolás | 1 - Bekapcsolás]
 zp_flarenade_color "255 255 255" // Fény gránát ikon színe RGB 

// Fertőző Gránát Cvars
 zp_infectnade_icon "1" // [0 - Kikapcsolás | 1 - Bekapcsolás]
 zp_infectnade_color "0 255 0" // Fertőző gránát ikon színe RGB

Képek:
Tűz Gránát:
Kép

Fagyasztó Gránát:
Kép

Fény Gránát:
Kép

Fertőző Gránát:
Kép

Eredeti készítő: rapara13
Plugin verzió: 1.2
Eredeti plugin: http://forums.alliedmods.net/showthread.php?t=113711

/*********************************************************
*                         Made by                      
*
*  RRRRR   AAA   PPPPP   AAA   RRRRR   AAA      1 33333
*  R   R  A   A  P   P  A   A  R   R  A   A    11     3
*  RRRRR  A   A  PPPPP  A   A  RRRRR  A   A   1 1     3
*  RR     AaaaA  P      AaaaA  RR     AaaaA     1  3333
*  R R    A   A  P      A   A  R R    A   A     1     3
*  R  R   A   A  P      A   A  R  R   A   A     1 33333
*
**********************************************************
*                   AMX MOD X script.                    *
* You can modify the code, but DO NOT modify the author! *
**********************************************************
*
*  Special Tanks to:
*  =================
*  DaRk_StyLe - Idea for set grenade status colors by cvars
*********************************************************/

#include <amxmodx>
#if defined _zombieplague_included
  #endinput
#endif
#define _zombieplague_included

#define ZP_TEAM_ZOMBIE (1<<0)
#define ZP_TEAM_HUMAN (1<<1)
#define ZP_TEAM_NEMESIS (1<<2)
#define ZP_TEAM_SURVIVOR (1<<3)

enum
{
	MODE_INFECTION = 1,
	MODE_NEMESIS,
	MODE_SURVIVOR,
	MODE_SWARM,
	MODE_MULTI,
	MODE_PLAGUE
}

enum
{
	WIN_NO_ONE = 0,
	WIN_ZOMBIES,
	WIN_HUMANS
}

#define ZP_PLUGIN_HANDLED 97

native zp_get_user_zombie(id)
native zp_get_user_nemesis(id)
native zp_get_user_survivor(id)
native zp_get_user_first_zombie(id)
native zp_get_user_last_zombie(id)
native zp_get_user_last_human(id)
native zp_get_user_zombie_class(id)
native zp_get_user_next_class(id)
native zp_set_user_zombie_class(id, classid)
native zp_get_user_ammo_packs(id)
native zp_set_user_ammo_packs(id, amount)
native zp_get_zombie_maxhealth(id)
native zp_get_user_batteries(id)
native zp_set_user_batteries(id, charge)
native zp_get_user_nightvision(id)
native zp_set_user_nightvision(id, set)
native zp_infect_user(id, infector = 0, silent = 0, rewards = 0)
native zp_disinfect_user(id, silent = 0)
native zp_make_user_nemesis(id)
native zp_make_user_survivor(id)
native zp_respawn_user(id, team)
native zp_force_buy_extra_item(id, itemid, ignorecost = 0)
native zp_override_user_model(id, const newmodel[], modelindex = 0)
native zp_has_round_started()
native zp_is_nemesis_round()
native zp_is_survivor_round()
native zp_is_swarm_round()
native zp_is_plague_round()
native zp_get_zombie_count()
native zp_get_human_count()
native zp_get_nemesis_count()
native zp_get_survivor_count()
native zp_register_extra_item(const name[], cost, teams)
native zp_register_zombie_class(const name[], const info[], const model[], const clawmodel[], hp, speed, Float:gravity, Float:knockback)
native zp_get_extra_item_id(const name[])
native zp_get_zombie_class_id(const name[])
native zp_get_zombie_class_info(classid, info[], len)
forward zp_round_started(gamemode, id)
forward zp_round_ended(winteam)
forward zp_user_infected_pre(id, infector, nemesis)
forward zp_user_infected_post(id, infector, nemesis)
forward zp_user_humanized_pre(id, survivor)
forward zp_user_humanized_post(id, survivor)
forward zp_user_infect_attempt(id, infector, nemesis)
forward zp_user_humanize_attempt(id, survivor)
forward zp_extra_item_selected(id, itemid)
forward zp_user_unfrozen(id)
forward zp_user_last_zombie(id)
forward zp_user_last_human(id)

#define ZP_TEAM_ANY 0
#define ZP_TEAM_NO_ONE 0

#define VERSION "1.2"

new cvar_status, cvar_fire_icon, cvar_fire_color, cvar_frost_icon, cvar_frost_color, cvar_flare_icon, cvar_flare_color,
cvar_infect_icon, cvar_infect_color

new g_StatusIcon
new g_GrenadeIcon[33][32]

public plugin_init()  {
	register_plugin("[ZP] Addon: Grenade Status", VERSION, "rapara13")
	register_cvar("zp_grenade_status", VERSION, FCVAR_SERVER|FCVAR_SPONLY)
	
	// Nade Status Cvar
	cvar_status = register_cvar("zp_nadestatus_icon","1") // [0=Hide | 1=Show | 2=Flash (Don't work with red color)]
	
	// Fire Grenade Cvars
	cvar_fire_icon = register_cvar("zp_firenade_icon","1") // [0=Disable | 1=Enable]
	cvar_fire_color = register_cvar("zp_firenade_color","255 0 0") // Color of Fire Nade in RGB
	
	// Frost Grenade Cvars
	cvar_frost_icon = register_cvar("zp_frostnade_icon","1") // [0=Disable | 1=Enable]
	cvar_frost_color = register_cvar("zp_frostnade_color","100 149 237") // Color of Frost Nade in RGB
	
	// Flare Grenade Cvars
	cvar_flare_icon = register_cvar("zp_flarenade_icon","1") // [0=Disable | 1=Enable]
	cvar_flare_color = register_cvar("zp_flarenade_color","255 255 255") // Color of Flare Nade in RGB
	
	// Infect Grenade Cvars
	cvar_infect_icon = register_cvar("zp_infectnade_icon","1") // [0=Disable | 1=Enable]
	cvar_infect_color = register_cvar("zp_infectnade_color","0 255 0") // Color of Infect Nade in RGB
	
	register_event("CurWeapon", "GrenadeIcon", "be", "1=1")
	register_event("DeathMsg", "DeathEvent", "a")
	
	g_StatusIcon = get_user_msgid("StatusIcon")
}

public GrenadeIcon(id) {
	RemoveGrenadeIcon(id)
		
	if(is_user_bot(id))
		return
		
	static NadeType, GrenadeSprite[16], Color[17], Red[5], Green[5], Blue[5]
	NadeType = get_user_weapon(id)
	
	switch(NadeType) {
		case CSW_HEGRENADE: // Fire Nade / Infect Nade
		{
			if(!zp_get_user_zombie(id)) {
				if(!get_pcvar_num(cvar_fire_icon))
					return
				
				GrenadeSprite = "dmg_heat"
				get_pcvar_string(cvar_fire_color, Color, charsmax(Color))
				
			} else {
				if(!get_pcvar_num(cvar_infect_icon))
					return
					
				GrenadeSprite = "dmg_bio"
				get_pcvar_string(cvar_infect_color, Color, charsmax(Color))
			}
		}
		case CSW_FLASHBANG: // Frost Nade
		{
			if(!get_pcvar_num(cvar_frost_icon))
					return
			
			GrenadeSprite = "dmg_cold"
			get_pcvar_string(cvar_frost_color, Color, charsmax(Color))
		}
		case CSW_SMOKEGRENADE: // Flare Nade
		{
			if(!get_pcvar_num(cvar_flare_icon))
					return
			
			GrenadeSprite = "dmg_shock"
			get_pcvar_string(cvar_flare_color, Color, charsmax(Color))
		}
		default: 
		return
	}
	parse(Color,Red,charsmax(Red),Green,charsmax(Green),Blue,charsmax(Blue))
	g_GrenadeIcon[id] = GrenadeSprite
	
	// Show Grenade Icons
	message_begin(MSG_ONE,g_StatusIcon,{0,0,0},id)
	write_byte(get_pcvar_num(cvar_status)) // Status [0=Hide, 1=Show, 2=Flash]
	write_string(g_GrenadeIcon[id]) // Sprite Name
	write_byte(str_to_num(Red)) // Red
	write_byte(str_to_num(Green)) // Green
	write_byte(str_to_num(Blue)) // Blue
	message_end()
	
	return
}

public RemoveGrenadeIcon(id) {
	// Remove Grenade Icons
	message_begin(MSG_ONE,g_StatusIcon,{0,0,0},id)
	write_byte(0) // Status [0=Hide, 1=Show, 2=Flash]
	write_string(g_GrenadeIcon[id]) // Sprite Name
	message_end()
}

public DeathEvent() {
	new id = read_data(2)
	
	if(is_user_bot(id))
	RemoveGrenadeIcon(id)
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/