﻿block config
{
   es_xset as_spawn_command "!aspawn" // Parancsa az újraéledésnek (Alap: "!aspawn")
   es_xset as_buy_command "!buyspawn" // Parancsa az újraéledés vásárlásnak (Alap: "!buyspawn")
   es_xset as_max_lives 3 // Max újraéledés (Alap: 3)
   es_xset as_life_cost 5000 // Az ára (Alap: 5000)
   es_xset as_starting_respawns 1 // Újraéledések, hogy egy új játékos ingyen éledjen újra (Alap: 1)
}

// ---------------- EGYÉB INFORMÁCIÓ!! ---------------- \\
// A-Spawn by Appl3 - fordítás SmaCk
// Version: 0.9.5
// Parancsok: "!aspawn" az újraéledés és "!buyspawn" az újraéledés vásárlása (mindkét változtatható)
// Megjegyzés: Teszt kiadás, a hibákat jelezzétek.
// ------------------- EGYÉB INFORMÁCIÓ!! --- \\

block load
{
    es_cexec_all play admin_plugin/activated.wav
	es_msg #multi #green[BuyReSpawn] #defaultBekapcsolva!
	es_xset as_exists 0
	es_xset as_user 0
	es_xset as_respawns 0
	es_xset as_cash 0
	es_xset as_dead 0
	es_xset as_temp 0

	es_setinfo aspawn_version 0.9.5
	es_makepublic aspawn_version
	
	es_doblock aspawn/config

	es_exists as_exists command server_var(as_spawn_command)
	ifx false(as_exists) do
	{
		es_regsaycmd server_var(as_spawn_command) aspawn/spawnplayer "Írd be aspawn az újraéledéshez."
	}
	es_exists as_exists command server_var(as_buy_command)
	ifx false(as_exists) do
	{
		es_regsaycmd server_var(as_buy_command) aspawn/buyspawn "Írd be buyspawn a vásárláshoz."
	}

	es_xkeygroupdelete aspawn
	es_xkeygroupload aspawn |aspawn
}

event es_map_start
{
downloadable "sound/admin_plugin/activated.wav"
downloadable "sound/admin_plugin/deactivated.wav"
}

event player_activate
{
	es est_GetSteam as_user event_var(userid)
	if (server_var(as_user) != "BOT") do
	{
		es_exists as_exists key aspawn server_var(as_user)
		ifx false(as_exists) do
		{
			es_keycreate aspawn server_var(as_user)
			es_keysetvalue aspawn server_var(as_user) Respawns server_var(as_starting_respawns)
			es_xkeygroupsave aspawn |aspawn
		}
	}

}

event round_start
{
es_msg #multi #green[BuyReSpawn] #defaultÚjraélesztés vásárlása: #green!buyspawn #defaulthasználata: #green!aspawn
}

event player_spawn
{
	es est_GetSteam as_user event_var(userid)
	if (server_var(as_user) != "BOT") do
	{
		es_exists as_exists key aspawn server_var(as_user)
		ifx false(as_exists) do
		{
			es_keycreate aspawn server_var(as_user)
			es_keysetvalue aspawn server_var(as_user) Respawns server_var(as_starting_respawns)
			es_xkeygroupsave aspawn |aspawn
		}
	}

}

event round_end
{
   es_xkeygroupsave aspawn |aspawn
}

block buyspawn
{
	es_getcmduserid as_temp
	es est_GetSteam as_user server_var(as_temp)

	es playerget cash as_cash server_var(as_user)
	if (server_var(as_cash) >= server_var(as_life_cost)) do
	{
		es_keygetvalue as_respawns aspawn server_var(as_user) Respawns
		if (server_var(as_respawns) < server_var(as_max_lives)) do
		{
			es_math as_respawns + 1
			es_keysetvalue aspawn server_var(as_user) Respawns server_var(as_respawns)
			es_tell server_var(as_temp) #multi #green[BuyReSpawn] #defaultVettél egy újraélesztést! Most már #green server_var(as_respawns) #defaultújraélesztésed van.
			es_math as_cash - server_var(as_life_cost)
			es playerset cash server_var(as_user) server_var(as_cash)
		}
		else do
		{
			es_tell server_var(as_temp) #multi #green[BusReSpawn] #defaultEléted a maximálisan vehető újraélesztések számát!.
		}
	}
   else do
	{
		es_tell server_var(as_temp) #multi #green[BuyReSpawn] #defaultNincs elég pénzed!#green server_var(as_life_cost)$ #defaultkell, hogy vegyél egy újraélesztést.
	}
}

block spawnplayer
{
	es_getcmduserid as_temp
	es est_GetSteam as_user server_var(as_temp)

	es playerget isdead as_dead server_var(as_user)
	ifx true(as_dead) do
	{
		es_keygetvalue as_respawns aspawn server_var(as_user) Respawns
		ifx true(as_respawns) do
		{
			es_math as_respawns - 1
			es_keysetvalue aspawn server_var(as_user) Respawns server_var(as_respawns)
			es est_spawn server_var(as_user)
			es_tell server_var(as_temp) #multi #green[BuyReSpawn] #lightgreen server_var(as_respawns) #defaultÚjraélesztésed maradt!
		}
		else do
		{
			es_tell server_var(as_temp) #multi #green[BuyReSpawn] #defaultNincs felhasználható újraélesztésed!
		}
	}
	else do
	{
		es_tell server_var(as_temp) #multi #green[BuyReSpawn] #defaultHalotnak kell lenned az újraélesztéshez!
	}
}

block unload
{
es_msg #multi #green[BuyReSpawn] #defaultKikapcsolva!
es_cexec_all play admin_plugin/deactivated.wav
}
