﻿//fordította motomoto

block load
{
//ON-CONNECT MESSAGE INFORMING PLAYER OF COMMANDS. 1=on 0=off
	es_xset cf_onconnectmsg 1
//###########################################################
	es_xset kgroup 0
	es_xexists kgroup keygroup cf
	ifx false(kgroup) do
	{
		es_xkeygroupload cf "|colourflash"
	}
	else do
	{
		es_xkeygroupdelete cf
		es_xkeygroupload cf "|colourflash"
	}
	es_msg #multi #green[ColourFlash] #defaultBekapcsolva!
//Popups with menu/helpmenu
	es popup create cfmenu
	es popup addline cfmenu "ColourFlash"
	es popup addline cfmenu "Menü -"
	es popup addline cfmenu "-> 1. Fény színe"
	es popup addline cfmenu "-> 2. ColourFlash segítség"
	es popup addline cfmenu "0. Bezár"
	es popup submenu cfmenu 2 cfhelp
	es popup select cfmenu 1 colourflash/sendpopup
	es popup timeout cfmenu send 3
	
	es popup create cfpick
	es popup addline cfpick "ColourFlash"
	es popup addline cfpick "Válaszd ki a fény színét"
	es popup addline cfpick "-> 1. Piros"
	es popup addline cfpick "-> 2. Zöld"
	es popup addline cfpick "-> 3. Kék"
	es popup addline cfpick "-> 4. Citromsárga"
	es popup addline cfpick "-> 5. Rózsaszín"
	es popup addline cfpick "-> 6. Narancssárga"
	es popup addline cfpick "-> 7. Lila"
	es popup addline cfpick "-> 8. Fehér/alap"
	es popup addline cfpick "-> 9. Vissza"
	es popup addline cfpick "0. Bezár"
	es popup select cfpick 1 colourflash/flashred
	es popup select cfpick 2 colourflash/flashgreen
	es popup select cfpick 3 colourflash/flashblue
	es popup select cfpick 4 colourflash/flashyellow
	es popup select cfpick 5 colourflash/flashpink
	es popup select cfpick 6 colourflash/flashorange
	es popup select cfpick 7 colourflash/flashpurple
	es popup select cfpick 8 colourflash/flashwhite
	
	es popup create cfhelp
	es popup addline cfhelp "ColourFlash"
	es popup addline cfhelp "Útmutató"
	es popup addline cfhelp " "
	es popup addline cfhelp "ColourFlash egy olyan mod megy megváltoztatja"
	es popup addline cfhelp "a fény színét mikor flashbang-et dobnak rád."
	es popup addline cfhelp "Betudod állítani a saját színed"
	es popup addline cfhelp "amelyikkel játszani szeretnél."
	es popup addline cfhelp " "
	es popup addline cfhelp "Hogy megváltoztasd a színt írd a chatbe"
	es popup addline cfhelp "hogy !cflash"
	es popup addline cfhelp "Abból a menüből elérhetőlesz ismét ez a segítség"
	es popup addline cfhelp "Ha megakarod tudni a fény színed"
        es popup addline cfhelp "írd a chat-be, hogy !cfnow."
        es popup addline cfhelp "Boldog flashelgetést."
}
block unload
{
	es_xkeygroupdelete cf
	es popup delete cfmenu
	es popup delete cfpick
	es popup delete cfhelp
	es_msg #multi #green[ColourFlash] #defaultKikapcsolva
}
block flashred
{
	es_keysetvalue cf event_var(es_steamid) flashcolour "Piros"
	es_keysetvalue cf event_var(es_steamid) flashred "255"
	es_keysetvalue cf event_var(es_steamid) flashgreen "0"
	es_keysetvalue cf event_var(es_steamid) flashblue "0"
	es_tell event_var(userid) #multi #green[ColourFlash] #defaultA te színed most: #greenPiros
}
block flashgreen
{
	es_keysetvalue cf event_var(es_steamid) flashcolour "Zöld"
	es_keysetvalue cf event_var(es_steamid) flashred "0"
	es_keysetvalue cf event_var(es_steamid) flashgreen "255"
	es_keysetvalue cf event_var(es_steamid) flashblue "0"
	es_tell event_var(userid) #multi #green[ColourFlash] #defaultA te színed most: #greenZöld
}
block flashblue
{
	es_keysetvalue cf event_var(es_steamid) flashcolour "Kék"
	es_keysetvalue cf event_var(es_steamid) flashred "0"
	es_keysetvalue cf event_var(es_steamid) flashgreen "0"
	es_keysetvalue cf event_var(es_steamid) flashblue "255"
	es_tell event_var(userid) #multi #green[ColourFlash] #defaultA te színed most: #greenKék
}
block flashyellow
{
	es_keysetvalue cf event_var(es_steamid) flashcolour "Citromsárga"
	es_keysetvalue cf event_var(es_steamid) flashred "255"
	es_keysetvalue cf event_var(es_steamid) flashgreen "255"
	es_keysetvalue cf event_var(es_steamid) flashblue "0"
	es_tell event_var(userid) #multi #green[ColourFlash] #defaultA te színed most: #greenCitromsárga
}
block flashpink
{
	es_keysetvalue cf event_var(es_steamid) flashcolour "Rózsaszín"
	es_keysetvalue cf event_var(es_steamid) flashred "255"
	es_keysetvalue cf event_var(es_steamid) flashgreen "0"
	es_keysetvalue cf event_var(es_steamid) flashblue "255"
	es_tell event_var(userid) #multi #green[ColourFlash] #defaultA te színed most: #greenRózsaszín
}
block flashorange
{
	es_keysetvalue cf event_var(es_steamid) flashcolour "Narancssárga"
	es_keysetvalue cf event_var(es_steamid) flashred "255"
	es_keysetvalue cf event_var(es_steamid) flashgreen "155"
	es_keysetvalue cf event_var(es_steamid) flashblue "0"
	es_tell event_var(userid) #multi #green[ColourFlash]#defaultA te színed most: #greenNarancssárga
}
block flashpurple
{
	es_keysetvalue cf event_var(es_steamid) flashcolour "Lila"
	es_keysetvalue cf event_var(es_steamid) flashred "155"
	es_keysetvalue cf event_var(es_steamid) flashgreen "0"
	es_keysetvalue cf event_var(es_steamid) flashblue "155"
	es_tell event_var(userid) #multi #green[ColourFlash] #defaultA te színed most: #greenLila
}
block flashwhite
{
	es_keysetvalue cf event_var(es_steamid) flashcolour "Fehér/Alap"
	es_keysetvalue cf event_var(es_steamid) flashred "255"
	es_keysetvalue cf event_var(es_steamid) flashgreen "255"
	es_keysetvalue cf event_var(es_steamid) flashblue "255"
	es_tell event_var(userid) #multi #green[ColourFlash] #defaultA te színed most: #greenFehér/alap
}
block sendpopup
{
	es_xset thesteam 0
	es_getplayersteamid thesteam event_var(_popup_userid)
	es popup send cfpick event_var(userid)
}
event player_activate
{
	if (server_var(cf_onconnectmsg) > 0) do
	{
		es popup send cfhelp event_var(userid)
	}
	es_xset inkeygroup 0
	es_exists inkeygroup key cf event_var(es_steamid)
	ifx false(inkeygroup) do
	{
		es_keycreate cf event_var(es_steamid)
		es_keysetvalue cf event_var(es_steamid) flashcolour "white (default)"
		es_keysetvalue cf event_var(es_steamid) flashred "255"
		es_keysetvalue cf event_var(es_steamid) flashgreen "255"
		es_keysetvalue cf event_var(es_steamid) flashblue "255"
	}
}
event player_say
{
	if (event_var(text) == "!cfnow") do
	{
		es_xset curflashcolour 0
		es_keygetvalue curflashcolour cf event_var(es_steamid) flashcolour
		es_tell event_var(userid) #multi #green[ColourFlash] #defaultA te színed most:#green server_var(curflashcolour)
	}
	if (event_var(text) == "!cflash") do
	{
		es popup send cfmenu event_var(userid)
	}
}
event player_blind
{
	es_xset tempred 0
	es_xset tempgreen 0
	es_xset tempblue 0
	es_xset tempalpha 255
	es_keygetvalue tempred cf event_var(es_steamid) flashred
	es_keygetvalue tempgreen cf event_var(es_steamid) flashgreen
	es_keygetvalue tempblue cf event_var(es_steamid) flashblue
	es_getplayerprop tempalpha event_var(userid) "CCSPlayer.m_flFlashDuration"
	es_setplayerprop event_var(userid) "CCSPlayer.m_flFlashMaxAplha" 0
	es_setplayerprop event_var(userid) "CCSPlayer.m_flFlashDuration" 0
	es_xusermsg create cf_flash Fade
	es_xusermsg write short cf_flash 1000
	es_usermsg write short cf_flash server_var(tempalpha)
	es_xusermsg write short cf_flash 1
	es_usermsg write byte cf_flash server_var(tempred)
	es_usermsg write byte cf_flash server_var(tempgreen)
	es_usermsg write byte cf_flash server_var(tempblue)
	es_xusermsg write byte cf_flash 255
	es_usermsg send cf_flash event_var(userid) 0
	es_xusermsg delete cf_flash
}
event round_end
{
	es_xkeygroupsave cf "|colourflash"
}
