#define PLUGIN_NAME "No Name Change"
#define PLUGIN_VERSION "0.1.1"
#define PLUGIN_AUTHOR "VEN"

#include <amxmodx>
#include <fakemeta>

new const g_reason[] = "[NNC] Sajnos a név váltás ezen a szerveren tiltott."
new const g_clcmd_template[] = "name ^"%s^"; setinfo name ^"%s^""
new const g_name[] = "name"

public plugin_init() {
	register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
	register_forward(FM_ClientUserInfoChanged, "fwClientUserInfoChanged")
}

public fwClientUserInfoChanged(id, buffer) {
	if (!is_user_connected(id))
		return FMRES_IGNORED

	static name[32], val[32]
	get_user_name(id, name, sizeof name - 1)
	engfunc(EngFunc_InfoKeyValue, buffer, g_name, val, sizeof val - 1)
	if (equal(val, name))
		return FMRES_IGNORED

	engfunc(EngFunc_SetClientKeyValue, id, buffer, g_name, name)
	client_cmd(id, g_clcmd_template, name, name)
	console_print(id, "%s", g_reason)
	client_print(id, print_chat, "%s", g_reason)

	return FMRES_SUPERCEDE
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1038\\ f0\\ fs16 \n\\ par }
*/