#include <amxmodx>
#include <csstats>
 
#define PLUGIN "Simply Connect Messages"
#define VERSION "1.0"
#define AUTHOR "mforce"
 
// Ha szeretnéd chat helyett HUD-ra iratni a szöveget, akkor vedd ki a //-t a # elől.
//#define HUD
 
#if !defined HUD
    new const PREFIX[] = "ElTaX~"
#endif
 
// Ha hangot is szeretnél lejátszani, akkor vedd ki a //-t a # elől.
//#define CONNECT_SOUND
 
#if defined CONNECT_SOUND
    new const soundfile[] = "buttons/blip1.wav"; // Hangfájl beállítása (.wav)
 
    public plugin_precache() {
        precache_sound(soundfile)
    }
#endif
 
#if defined HUD
    new connectsyncmsg
#endif
public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    #if defined HUD
    connectsyncmsg = CreateHudSyncObj()
    #endif
}
 
public client_putinserver(id) {
    set_task(2.0, "csatlakozott", id)
}
 
public csatlakozott(id) {
    if(!is_user_bot(id)) {
        new name[32];
        get_user_name(id, name, charsmax(name))
        new izStats[8], izBody[8], iRankPos
        iRankPos = get_user_stats(id, izStats, izBody)
        #if defined HUD
            set_hudmessage(70, 55, 100, 0.10, 0.55, 0, 6.0, 6.0, 0.5, 0.15, 3)
            ShowSyncHudMsg(0, connectsyncmsg, "%s Csatlakozott a Szerverre.^nRank: %i^nJo Jatekot!", name, iRankPos)
        #else
            ChatColor(0, "^4[%s]^3 %s ^1csatlakozott a szerverre,^3 Rank: %i", PREFIX, name, iRankPos)
        #endif
        #if defined CONNECT_SOUND
            client_cmd(0, "spk ^"%s^"", soundfile)
        #endif
    }
}
 
public client_disconnect(id) {
    if(!is_user_bot(id)) {
    new name[32];
    get_user_name(id, name, charsmax(name))
    #if defined HUD
        set_hudmessage(255, 0, 255, 0.10, 0.55, 0, 6.0, 6.0, 0.5, 0.15, 3)
        ShowSyncHudMsg(0, connectsyncmsg, "%s lelepett a szerverrol.", name)
    #else
        ChatColor(0, "^4[%s]^3 %s ^1lelepett a szerverrol.", PREFIX, name)
    #endif
    }
}
 
stock ChatColor(const id, const szMessage[], any:...) {
        static pnum, players[32], szMsg[190], IdMsg;
        vformat(szMsg, charsmax(szMsg), szMessage, 3);
       
        if(!IdMsg) IdMsg = get_user_msgid("SayText");
       
        if(id) {
                if(!is_user_connected(id)) return;
                players[0] = id;
                pnum = 1;
        }
        else get_players(players, pnum, "ch");
       
        for(new i; i < pnum; i++) {
                message_begin(MSG_ONE, IdMsg, .player = players[i]);
                write_byte(players[i]);
                write_string(szMsg);
                message_end();
        }
}