#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <fakemeta_util>
#include <fun>
#include <hamsandwich>
#include <xs>
#include <cstrike>

#define ZPS

#if defined ZPS
	#include <zombie_plague_special>
#else
	#include <zombieplague>
#endif
//#include <dhudmessage>

#define ENG_NULLENT			-1
#define EV_INT_WEAPONKEY	EV_INT_impulse
#define plasma_WEAPONKEY 	2815
#define MAX_PLAYERS  		32
#define IsValidUser(%1) (1 <= %1 <= g_MaxPlayers)

const USE_STOPPED = 0
const OFFSET_ACTIVE_ITEM = 373
const OFFSET_WEAPONOWNER = 41
const OFFSET_LINUX = 5
const OFFSET_LINUX_WEAPONS = 4

#define WEAP_LINUX_XTRA_OFF		4
#define m_fKnown					44
#define m_flNextPrimaryAttack 		46
#define m_flNextSecondaryAttack		47
#define m_flTimeWeaponIdle			48
#define m_iClip					51
#define m_fInReload				54
#define PLAYER_LINUX_XTRA_OFF	5
#define m_flNextAttack				83
#define plasma_SPINDOWN_TIME	0.5
#define plasma_SPINUP_TIME	2.0
#define plasma_RELOAD_TIME	3.0
#define plasma_DRAW_TIME 	1.1
#define plasma_SHOOT1		5
#define plasma_SHOOT2		7
#define plasma_RELOAD		9
#define plasma_DRAW			10
#define plasma_FIRE_READY	3
#define plasma_FIRE_AFTER	2
new const TRUNCATEDPLASMAID[] = "famas"
new const PLASMAID[] = "weapon_famas"
#define CSW_WPN CSW_FAMAS


#define write_coord_f(%1)	engfunc(EngFunc_WriteCoord,%1)

new const Fire_Sounds[][] = { "weapons/plasma/plasma_fire1.wav","weapons/plasma/plasma_fire2.wav" }
new const Hit_Sounds[][] = { "weapons/plasma/plasma_hit.wav" }
new const g_shellent [] = "plasma_shell"

new const spr_beam[] = "sprites/weapons/plasma/plasma_beam.spr"
new const spr_exp[] = "sprites/weapons/plasma/plasma_exp.spr"
new plasma_V_MODEL[64] = "models/weapons/plasma/v_plasma.mdl"
new plasma_P_MODEL[64] = "models/weapons/plasma/p_plasma.mdl"
new plasma_W_MODEL[64] = "models/weapons/plasma/w_plasma.mdl"
	
new const GUNSHOT_DECALS[] = { 41, 42, 43, 44, 45 }

new g_itemid_plasma
new g_sprBeam,g_sprExp
new g_msgDamage, g_msgScreenFade, g_msgScreenShake
new cvar_dmg_plasma, cvar_recoil_plasma,  cvar_clip_plasma ,cvar_oneround_plasma,cvar_punch_plasma
new cvar_spd_plasma, cvar_ammo_plasma, cvar_speedrun_plasma, cvar_speedrunfire_plasma
new g_MaxPlayers, g_orig_event_plasma, g_IsInPrimaryAttack
new Float:cl_pushangle[MAX_PLAYERS + 1][3], m_iBlood[2]
new g_has_plasma[33], g_clip_ammo[33], g_plasma_TmpClip[33], oldweap[33], g_can[33], g_afterreload[33]
new cvar_shells_plasma, cvar_shellshealth_plasma
new gmsgWeaponList, shell_mode, shell_mode2
new bool:g_startround = false
const PRIMARY_WEAPONS_BIT_SUM = 
(1<<CSW_SCOUT)|(1<<CSW_XM1014)|(1<<CSW_MAC10)|(1<<CSW_AUG)|(1<<CSW_UMP45)|(1<<CSW_SG550)|(1<<CSW_GALIL)|(1<<CSW_FAMAS)|(1<<CSW_AWP)|(1<<
CSW_MP5NAVY)|(1<<CSW_M249)|(1<<CSW_M3)|(1<<CSW_M4A1)|(1<<CSW_TMP)|(1<<CSW_G3SG1)|(1<<CSW_SG552)|(1<<CSW_AK47)|(1<<CSW_P90)
new const WEAPONENTNAMES[][] = { "", "weapon_p228", "", "weapon_scout", "weapon_hegrenade", "weapon_xm1014", "weapon_c4", "weapon_mac10",
			"weapon_aug", "weapon_smokegrenade", "weapon_elite", "weapon_fiveseven", "weapon_ump45", "weapon_sg550",
			"weapon_galil", "weapon_famas", "weapon_usp", "weapon_glock18", "weapon_awp", "weapon_mp5navy", "weapon_m249",
			"weapon_m3", "weapon_m4a1", "weapon_tmp", "weapon_g3sg1", "weapon_flashbang", "weapon_deagle", "weapon_sg552",
			"weapon_ak47", "weapon_knife", "weapon_p90" }

public plugin_init()
{
	register_plugin("[ZP] Extra: Plasma Gun", "1.0", "LARS-DAY[BR]EAKER/Furion")
	register_message(get_user_msgid("DeathMsg"), "message_DeathMsg")
	register_event("CurWeapon","CurrentWeapon","be","1=1")
	RegisterHam(Ham_Item_AddToPlayer, PLASMAID, "fw_plasma_AddToPlayer")
	RegisterHam(Ham_Use, "func_tank", "fw_UseStationary_Post", 1)
	RegisterHam(Ham_Use, "func_tankmortar", "fw_UseStationary_Post", 1)
	RegisterHam(Ham_Use, "func_tankrocket", "fw_UseStationary_Post", 1)
	RegisterHam(Ham_Use, "func_tanklaser", "fw_UseStationary_Post", 1)
	for (new i = 1; i < sizeof WEAPONENTNAMES; i++)
	if (WEAPONENTNAMES[i][0]) RegisterHam(Ham_Item_Deploy, WEAPONENTNAMES[i], "fw_Item_Deploy_Post", 1)
	RegisterHam(Ham_Weapon_PrimaryAttack, PLASMAID, "fw_plasma_PrimaryAttack")
	RegisterHam(Ham_Weapon_PrimaryAttack, PLASMAID, "fw_plasma_PrimaryAttack_Post", 1)
	RegisterHam(Ham_Weapon_SecondaryAttack, PLASMAID, "fw_plasma_PrimaryAttack")
	RegisterHam(Ham_Weapon_SecondaryAttack, PLASMAID, "fw_plasma_PrimaryAttack_Post", 1)
	RegisterHam(Ham_Item_PostFrame, PLASMAID, "plasma_ItemPostFrame")
	RegisterHam(Ham_Weapon_Reload, PLASMAID, "plasma_Reload")
	RegisterHam(Ham_Weapon_Reload, PLASMAID, "plasma_Reload_Post", 1)
	RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
	register_forward(FM_SetModel, "fw_SetModel")
	register_forward(FM_UpdateClientData, "fw_UpdateClientData_Post", 1)
	register_forward(FM_PlaybackEvent, "fwPlaybackEvent")
	register_forward(FM_CmdStart, "fw_CmdStart")
	register_forward(FM_PlayerPreThink, "fw_PlayerPreThink")
	register_think(g_shellent,"think_shell")
	
	RegisterHam(Ham_Spawn, "player", "fwHamPlayerSpawnPost", 1)	
	RegisterHam(Ham_TraceAttack, "worldspawn", "fw_TraceAttack", 1)
	RegisterHam(Ham_TraceAttack, "func_breakable", "fw_TraceAttack", 1)
	RegisterHam(Ham_TraceAttack, "func_wall", "fw_TraceAttack", 1)
	RegisterHam(Ham_TraceAttack, "func_door", "fw_TraceAttack", 1)
	RegisterHam(Ham_TraceAttack, "func_door_rotating", "fw_TraceAttack", 1)
	RegisterHam(Ham_TraceAttack, "func_plat", "fw_TraceAttack", 1)
	RegisterHam(Ham_TraceAttack, "func_rotating", "fw_TraceAttack", 1)
	
	gmsgWeaponList = get_user_msgid("WeaponList")
	cvar_oneround_plasma = register_cvar("zp_plasma_oneround", "1")
	cvar_dmg_plasma = register_cvar("zp_plasma_dmg", "6.0")
	cvar_punch_plasma = register_cvar("zp_plasma_push", "0.7")
	cvar_recoil_plasma = register_cvar("zp_plasma_recoil", "2.5")
	cvar_clip_plasma = register_cvar("zp_plasma_clip", "100")
	cvar_spd_plasma = register_cvar("zp_plasma_spd", "1.0")
	cvar_ammo_plasma = register_cvar("zp_plasma_ammo", "100")
	cvar_speedrunfire_plasma= register_cvar("zp_plasma_speedrunfire", "150.0")
	cvar_speedrun_plasma = register_cvar("zp_plasma_speedrun", "200.0")
	cvar_shells_plasma = register_cvar("zp_plasma_shells", "1")
	cvar_shellshealth_plasma = register_cvar("zp_plasma_shellslife", "2.0")

	g_msgDamage = get_user_msgid("Damage")
	g_msgScreenFade = get_user_msgid("ScreenFade")
	g_msgScreenShake = get_user_msgid("ScreenShake")

	
	g_itemid_plasma = zp_register_extra_item("[Plasma] Gun", 61, ZP_TEAM_HUMAN)
	g_MaxPlayers = get_maxplayers()
}

public plugin_precache()
{
	
	precache_model(plasma_V_MODEL)
	precache_model(plasma_P_MODEL)
	precache_model(plasma_W_MODEL)
	for(new i = 0; i < sizeof Fire_Sounds; i++)
	precache_sound(Fire_Sounds[i])	
	for(new j = 0; j < sizeof Hit_Sounds; j++)
	precache_sound(Hit_Sounds[j])	
	precache_sound("weapons/plasma/plasma_clipoff.wav")
	precache_sound("weapons/plasma/plasma_clipon.wav")
	precache_sound("weapons/plasma/plasma_pinpull.wav")
  	precache_sound("weapons/plasma/plasma_spindown.wav") 
  	precache_sound("weapons/plasma/plasma_spinup.wav") 
	shell_mode = precache_model("models/rshell.mdl")
	shell_mode2 = precache_model("models/rshell_big.mdl")
	precache_generic("sprites/weapons/plasma/weapon_plasma_bc.txt")
	precache_generic("sprites/weapons/plasma/640hud3_plasma.spr")
	precache_generic("sprites/weapons/plasma/640hud91_plasma.spr")

	m_iBlood[0] = precache_model("sprites/blood.spr")
	m_iBlood[1] = precache_model("sprites/bloodspray.spr")
	
	g_sprBeam = precache_model(spr_beam)
	g_sprExp = precache_model(spr_exp)
	register_clcmd("weapon_plasma_bc", "weapon_hook")
	register_forward(FM_PrecacheEvent, "fwPrecacheEvent_Post", 1)
}

public zp_round_started()
{
	g_startround = true
}
public zp_round_ended(winteam)
{
	
	g_startround = false
}

public zp_extra_item_selected_pre(id, itemid)
{

	if (itemid == g_itemid_plasma)
	{
		if (/*zp_is_multi_round() ||zp_is_swarm_round()||*/g_startround == false  ) return ZP_PLUGIN_SUPERCEDE

	}	

	return PLUGIN_CONTINUE
}

public zp_extra_item_selected(id, itemid)
{
	if(itemid == g_itemid_plasma)
	{
		if (/*zp_is_multi_round() ||zp_is_swarm_round()||*/g_startround == false) return ZP_PLUGIN_HANDLED
		give_plasma(id)
	}

	
	return PLUGIN_HANDLED
}

public weapon_hook(id) engclient_cmd(id, PLASMAID)

public fw_TraceAttack(iEnt, iAttacker, Float:flDamage, Float:fDir[3], ptr, iDamageType)
{
	if(!is_user_alive(iAttacker))
		return

	new g_currentweapon = get_user_weapon(iAttacker)

	if(g_currentweapon != CSW_WPN) return
	
	if(!g_has_plasma[iAttacker]) return

	static Float:flEnd[3]
	get_tr2(ptr, TR_vecEndPos, flEnd)
	
	if(iEnt)
	{
		message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
		write_byte(TE_DECAL)
		write_coord_f(flEnd[0])
		write_coord_f(flEnd[1])
		write_coord_f(flEnd[2])
		write_byte(GUNSHOT_DECALS[random_num (0, sizeof GUNSHOT_DECALS -1)])
		write_short(iEnt)
		message_end()
	}
	else
	{
		message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
		write_byte(TE_WORLDDECAL)
		write_coord_f(flEnd[0])
		write_coord_f(flEnd[1])
		write_coord_f(flEnd[2])
		write_byte(GUNSHOT_DECALS[random_num (0, sizeof GUNSHOT_DECALS -1)])
		message_end()
	}
	message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
	write_byte(TE_GUNSHOTDECAL)
	write_coord_f(flEnd[0])
	write_coord_f(flEnd[1])
	write_coord_f(flEnd[2])
	write_short(iAttacker)
	write_byte(GUNSHOT_DECALS[random_num (0, sizeof GUNSHOT_DECALS -1)])
	message_end()
}

public zp_user_humanized_post(id)
{
	g_has_plasma[id] = false

}


public fwHamPlayerSpawnPost(id)
{

	if (g_has_plasma[id])
	{

		g_has_plasma[id] = false
		if(get_pcvar_num(cvar_oneround_plasma))	remove_plasmaweapon(id)
			
	}

}

// remove gun and save all guns
public remove_plasmaweapon(id) { 
	new wpnList[32] 
	new number
	get_user_weapons(id,wpnList,number) 
	for (new i = 0;i < number ;i++) { 
		if (wpnList[i] == CSW_WPN) {
			fm_strip_user_gun(id, wpnList[i])
		}
	}
} 


public plugin_natives ()
{
	register_native("give_weapon_plasma", "native_give_weapon_add", 1)
}
public native_give_weapon_add(id)
{
	give_plasma(id)
}

public fwPrecacheEvent_Post(type, const name[])
{
	if (equal("events/famas.sc", name))
	{
		g_orig_event_plasma = get_orig_retval()
		return FMRES_HANDLED
	}
	return FMRES_IGNORED
}

public client_connect(id)
{
	g_has_plasma[id] = false

}

public client_disconnected(id)
{
	g_has_plasma[id] = false

}

public zp_user_infected_post(id)
{
	if (zp_get_user_zombie(id))
	{
		g_has_plasma[id] = false
	}

}

public user_can(id) 
{
	g_can[id] = 2
}

public user_can2(id) 
{
	g_can[id] = 0
	

}

public fw_SetModel(entity, model[])
{
	if(!is_valid_ent(entity))
		return FMRES_IGNORED
	
	static szClassName[33]
	entity_get_string(entity, EV_SZ_classname, szClassName, charsmax(szClassName))
		
	if(!equal(szClassName, "weaponbox"))
		return FMRES_IGNORED
	
	static iOwner
	
	iOwner = entity_get_edict(entity, EV_ENT_owner)
	
	if(equal(model, "models/w_famas.mdl"))
	{
		static iStoredFamasID
		
		iStoredFamasID = find_ent_by_owner(ENG_NULLENT, "weapon_famas", entity)
	
		if(!is_valid_ent(iStoredFamasID))
			return FMRES_IGNORED
	
		if(g_has_plasma[iOwner])
		{
			entity_set_int(iStoredFamasID, EV_INT_WEAPONKEY, plasma_WEAPONKEY)
			
			g_has_plasma[iOwner] = false
			
			entity_set_model(entity, plasma_W_MODEL)
			
			return FMRES_SUPERCEDE
		}
	}
	return FMRES_IGNORED
}

public give_plasma(id)
{
	drop_weapons(id, 1)
	new iWep2 = give_item(id,"weapon_famas")
	if( iWep2 > 0 )
	{
		cs_set_weapon_ammo(iWep2, get_pcvar_num(cvar_clip_plasma))
		cs_set_user_bpammo (id, CSW_WPN, get_pcvar_num(cvar_ammo_plasma))	
		UTIL_PlayWeaponAnimation(id, plasma_DRAW)
		set_pdata_float(id, m_flNextAttack, plasma_DRAW_TIME, PLAYER_LINUX_XTRA_OFF)
		set_pdata_float(id, m_flNextPrimaryAttack, plasma_DRAW_TIME, PLAYER_LINUX_XTRA_OFF)
		set_pdata_float(id, m_flNextSecondaryAttack, plasma_DRAW_TIME, PLAYER_LINUX_XTRA_OFF)
		
		
		
		
	}
	g_has_plasma[id] = true

	message_begin(MSG_ONE, gmsgWeaponList, _, id)
	{
		write_string("weapon_plasma_bc")
		write_byte(3)
		write_byte(200)
		write_byte(-1)
		write_byte(-1)
		write_byte(0)
		write_byte(4)
		write_byte(CSW_WPN)
	}
	message_end()
}




public fw_plasma_AddToPlayer(plasma, id)
{
	if(!is_valid_ent(plasma) || !is_user_connected(id))
		return HAM_IGNORED
	
	if(entity_get_int(plasma, EV_INT_WEAPONKEY) == plasma_WEAPONKEY)
	{
		g_has_plasma[id] = true
		entity_set_int(plasma, EV_INT_WEAPONKEY, 0)
		message_begin(MSG_ONE, gmsgWeaponList, {0,0,0}, id)
		write_string("weapon_plasma_bc")
		write_byte(5)
		write_byte(32)
		write_byte(-1)
		write_byte(-1)
		write_byte(0)
		write_byte(5)
		write_byte(CSW_WPN)
		message_end()		
		
		return HAM_HANDLED
	}
	else
	{
		message_begin(MSG_ONE, gmsgWeaponList, {0,0,0}, id)
		write_string("weapon_famas")
		write_byte(5)
		write_byte(32)
		write_byte(-1)
		write_byte(-1)
		write_byte(0)
		write_byte(5)
		write_byte(CSW_WPN)
		message_end()
	}
	return HAM_IGNORED
}

public fw_UseStationary_Post(entity, caller, activator, use_type)
{
	if (use_type == USE_STOPPED && is_user_connected(caller))
		replace_weapon_models(caller, get_user_weapon(caller))
}

public fw_Item_Deploy_Post(weapon_ent)
{
	static owner
	owner = fm_cs_get_weapon_ent_owner(weapon_ent)
	
	static weaponid
	weaponid = cs_get_weapon_id(weapon_ent)
	replace_weapon_models(owner, weaponid)
}

public CurrentWeapon(id)
{
     replace_weapon_models(id, read_data(2))

     if(read_data(2) != CSW_WPN || !g_has_plasma[id])
          return
     
     static Float:iSpeed
     if(g_has_plasma[id])
          iSpeed = get_pcvar_float(cvar_spd_plasma)
     
     static weapon[32],Ent
     get_weaponname(read_data(2),weapon,31)
     Ent = find_ent_by_owner(-1,weapon,id)
     if(Ent)
     {
          static Float:Delay
          Delay = get_pdata_float( Ent, 46, 4) * iSpeed
          if (Delay > 0.0)
          {
               set_pdata_float(Ent, 46, Delay, 4)
               set_pdata_float(Ent, 47, Delay, 4)
          }
     }
}

replace_weapon_models(id, weaponid)
{
	switch (weaponid)
	{
		case CSW_WPN:
		{
			if (zp_get_user_zombie(id))
				return
			
			if(g_has_plasma[id])
			{
				
				set_pev(id, pev_viewmodel2, plasma_V_MODEL)

				set_pev(id, pev_weaponmodel2, plasma_P_MODEL)
	
				message_begin(MSG_ONE, get_user_msgid("CurWeapon"), {0,0,0}, id) 
				write_byte(1) 
				write_byte(CSW_KNIFE) 
				write_byte(0) 
				message_end()

				if(oldweap[id] != CSW_WPN) 
				{
					UTIL_PlayWeaponAnimation(id, plasma_DRAW)
					set_pdata_float(id, m_flNextAttack, plasma_DRAW_TIME, PLAYER_LINUX_XTRA_OFF)
					set_pdata_float(id, m_flNextPrimaryAttack,plasma_DRAW_TIME, PLAYER_LINUX_XTRA_OFF)
					set_pdata_float(id, m_flNextSecondaryAttack,plasma_DRAW_TIME, PLAYER_LINUX_XTRA_OFF)
					message_begin(MSG_ONE, gmsgWeaponList, _, id)
					{
						write_string("weapon_plasma_bc")
						write_byte(3)
						write_byte(200)
						write_byte(-1)
						write_byte(-1)
						write_byte(0)
						write_byte(4)
						write_byte(CSW_WPN)
					}
					message_end()
				
				}
			}
		}
	}
	if(weaponid != CSW_WPN)
	{
		remove_task(id)
		g_can[id] = 0
		g_afterreload[id] = 0
		if(oldweap[id] == CSW_WPN && g_has_plasma[id]) 
		{
			message_begin(MSG_ONE, get_user_msgid("CurWeapon"), {0,0,0}, id) 
			write_byte(1) 
			write_byte(CSW_KNIFE) 
			write_byte(0) 
			message_end()
		}
	}
	oldweap[id] = weaponid
}

public fw_UpdateClientData_Post(Player, SendWeapons, CD_Handle)
{
	if(!is_user_alive(Player) || (get_user_weapon(Player) != CSW_WPN || !g_has_plasma[Player]))
		return FMRES_IGNORED
	
	set_cd(CD_Handle, CD_flNextAttack, halflife_time () + 0.001)
	return FMRES_HANDLED
}

public fw_CmdStart(id, uc_handle, seed)
{
	if(!is_user_alive(id) || zp_get_user_zombie(id) || get_user_weapon(id) != CSW_WPN || !g_has_plasma[id]) 
		return PLUGIN_HANDLED

	new Float:flNextAttack = get_pdata_float(id, m_flNextAttack, PLAYER_LINUX_XTRA_OFF)

	if(flNextAttack > 0.0)
		return PLUGIN_HANDLED

	new szClip, szAmmo
	get_user_weapon(id, szClip, szAmmo)

	if(szClip <= 0)
	{
	//	emit_sound(id, CHAN_WEAPON, "weapons/plasma/plasma_pinpull.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
		return PLUGIN_HANDLED	
	}
	
	

	if(!(pev(id, pev_oldbuttons) & IN_ATTACK))
	{
		remove_task(id)
		set_pdata_float(id, m_flNextAttack, 0.0, PLAYER_LINUX_XTRA_OFF)
		set_pdata_float(id, m_flNextPrimaryAttack, 0.0, PLAYER_LINUX_XTRA_OFF)
		set_pdata_float(id, m_flNextSecondaryAttack, 0.0, PLAYER_LINUX_XTRA_OFF)
		

		
		
		g_can[id] = 0
	}
	if((pev(id, pev_oldbuttons) & IN_ATTACK) && !(get_uc(uc_handle, UC_Buttons) & IN_ATTACK))
	{
		remove_task(id)
		set_task(1.0,"user_can2",id)
		g_can[id] = 3
		set_pdata_float(id, m_flNextAttack, plasma_SPINUP_TIME, PLAYER_LINUX_XTRA_OFF)
		set_pdata_float(id, m_flNextPrimaryAttack,plasma_SPINUP_TIME, PLAYER_LINUX_XTRA_OFF)
		set_pdata_float(id, m_flNextSecondaryAttack,plasma_SPINUP_TIME, PLAYER_LINUX_XTRA_OFF)
		UTIL_PlayWeaponAnimation(id,plasma_FIRE_AFTER)
		g_can[id] = 0
	}

	return PLUGIN_HANDLED
}






public fw_plasma_PrimaryAttack(Weapon)
{
	new Player = get_pdata_cbase(Weapon, 41, 4)
	
	if (!g_has_plasma[Player])
		return HAM_IGNORED

	g_IsInPrimaryAttack = 1

	if(g_afterreload[Player])
	{
		g_afterreload[Player] = 0
		return HAM_SUPERCEDE
	}
	new Float:flNextAttack = get_pdata_float(Player, m_flNextAttack, PLAYER_LINUX_XTRA_OFF)

	if(flNextAttack > 0.0)
		return HAM_IGNORED

	new szClip, szAmmo
	get_user_weapon(Player, szClip, szAmmo)

	if(!g_can[Player] || g_can[Player] == 3)
	{
		if(szClip <= 0)
		{
			UTIL_PlayWeaponAnimation(Player,plasma_FIRE_AFTER)
			//emit_sound(Player, CHAN_WEAPON, "weapons/plasma/plasma_pinpull.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM)

			set_pdata_float(Player, m_flNextAttack, get_pcvar_float(cvar_spd_plasma ), PLAYER_LINUX_XTRA_OFF)
			set_pdata_float(Player, m_flNextPrimaryAttack,get_pcvar_float(cvar_spd_plasma ), PLAYER_LINUX_XTRA_OFF)
			set_pdata_float(Player, m_flNextSecondaryAttack,get_pcvar_float(cvar_spd_plasma ), PLAYER_LINUX_XTRA_OFF)
			return HAM_SUPERCEDE
		}
		else
		{
		
			set_task(1.0,"user_can",Player)
			g_can[Player] = 1
			set_pdata_float(Player, m_flNextAttack, plasma_SPINUP_TIME, PLAYER_LINUX_XTRA_OFF)
			set_pdata_float(Player, m_flNextPrimaryAttack,plasma_SPINUP_TIME, PLAYER_LINUX_XTRA_OFF)
			set_pdata_float(Player, m_flNextSecondaryAttack,plasma_SPINUP_TIME, PLAYER_LINUX_XTRA_OFF)

			UTIL_PlayWeaponAnimation(Player,plasma_FIRE_READY)
			emit_sound(Player, CHAN_WEAPON, "weapons/plasma/plasma_spinup.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
			
			return HAM_SUPERCEDE
		}

		//return HAM_SUPERCEDE
	}
	pev(Player,pev_punchangle,cl_pushangle[Player])
	
	g_clip_ammo[Player] = cs_get_weapon_ammo(Weapon)

	return HAM_IGNORED
}

public fwPlaybackEvent(flags, invoker, eventid, Float:delay, Float:origin[3], Float:angles[3], Float:fparam1, Float:fparam2, iParam1, iParam2, bParam1, bParam2)
{
	if ((eventid != g_orig_event_plasma) || !g_IsInPrimaryAttack)
		return FMRES_IGNORED
	if (!(1 <= invoker <= g_MaxPlayers))
    return FMRES_IGNORED

	playback_event(flags | FEV_HOSTONLY, invoker, eventid, delay, origin, angles, fparam1, fparam2, iParam1, iParam2, bParam1, bParam2)
	return FMRES_SUPERCEDE
}

public fw_plasma_PrimaryAttack_Post(Weapon)
{
	g_IsInPrimaryAttack = 0
	new Player = get_pdata_cbase(Weapon, 41, 4)
	
	if(!is_user_alive(Player))
		return

	new szClip, szAmmo
	get_user_weapon(Player, szClip, szAmmo)

	if(g_has_plasma[Player])
	{
		if(g_can[Player] != 2)
			return

		if(szClip <= 0)
		{
			UTIL_PlayWeaponAnimation(Player,plasma_FIRE_AFTER)
			emit_sound(Player, CHAN_WEAPON, "weapons/plasma/plasma_pinpull.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM)

			set_pdata_float(Player, m_flNextAttack, get_pcvar_float(cvar_spd_plasma ), PLAYER_LINUX_XTRA_OFF)
			set_pdata_float(Player, m_flNextPrimaryAttack,get_pcvar_float(cvar_spd_plasma ), PLAYER_LINUX_XTRA_OFF)
			set_pdata_float(Player, m_flNextSecondaryAttack,get_pcvar_float(cvar_spd_plasma ), PLAYER_LINUX_XTRA_OFF)

		}

		if (!g_clip_ammo[Player])
			return
		
		static Float:g_punchangle[3]
		g_punchangle[0] = -1 * get_pcvar_float(cvar_recoil_plasma)
		set_pev(Player, pev_punchangle, g_punchangle); 
		remove_task(Player+93200)
		UTIL_PlayWeaponAnimation(Player, random_num(plasma_SHOOT1,plasma_SHOOT2))
		set_pdata_float(Player, m_flNextAttack, get_pcvar_float(cvar_spd_plasma ), PLAYER_LINUX_XTRA_OFF)
		set_pdata_float(Player, m_flNextPrimaryAttack,get_pcvar_float(cvar_spd_plasma ), PLAYER_LINUX_XTRA_OFF)
		set_pdata_float(Player, m_flNextSecondaryAttack,get_pcvar_float(cvar_spd_plasma ), PLAYER_LINUX_XTRA_OFF)

		set_pdata_float(Weapon, m_flTimeWeaponIdle, 0.5, WEAP_LINUX_XTRA_OFF)
		
		
		
		make_punch(Player, 50)
		
		//new sprites
		static iTarget, iBody,iEndOrigin[3], iStartOrigin[3]
		get_user_origin(Player, iStartOrigin, 1) 
		get_user_origin(Player, iEndOrigin, 3)
		fire_effects(iStartOrigin, iEndOrigin)
		get_user_aiming(Player, iTarget, iBody)

		

		new iEnt = create_entity("info_target")
		static Float:flOrigin[3]
		IVecFVec(iEndOrigin, flOrigin)
		entity_set_origin(iEnt, flOrigin)
		remove_entity(iEnt)		
		if(is_user_alive(iTarget))
		{	
			if(get_pcvar_float(cvar_punch_plasma) > 0.0)
			{
				static Float:flVelocity[3]
				get_user_velocity(iTarget, flVelocity)
				xs_vec_mul_scalar(flVelocity, get_pcvar_float(cvar_punch_plasma), flVelocity)
				set_user_velocity(iTarget, flVelocity)	
			}
			if(zp_get_user_zombie(iTarget) )
			{
			
				damage_effects(iTarget)
			}
			
			emit_sound(Player, CHAN_WEAPON, Hit_Sounds[0], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)

		}
		else
		{
		
			emit_sound(Player, CHAN_WEAPON, Fire_Sounds[0], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)

		}

		set_task(get_pcvar_float(cvar_spd_plasma ) + 0.1,"spindownsound",Player+93200)
		
		//sprites end
		
		
		if(get_pcvar_num(cvar_shells_plasma)) make_shell(Player)
	}
}


public spindownsound(taskid)
{
	new id = taskid - 93200
	emit_sound(id, CHAN_WEAPON, "weapons/plasma/plasma_spindown.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM)	


}


public fw_TakeDamage(victim, inflictor, attacker, Float:damage)
{
	if (victim != attacker && is_user_connected(attacker))
	{
		if(get_user_weapon(attacker) == CSW_WPN)
		{
			if(g_has_plasma[attacker])
			{
				
				SetHamParamFloat(4, damage * get_pcvar_float(cvar_dmg_plasma))
				
				
				
				
				
				
				
				
				
				
				
				
			}
		}
	}
}

public message_DeathMsg(msg_id, msg_dest, id)
{
	static szTruncatedWeapon[33], iAttacker, iVictim
	
	get_msg_arg_string(4, szTruncatedWeapon, charsmax(szTruncatedWeapon))
	
	iAttacker = get_msg_arg_int(1)
	iVictim = get_msg_arg_int(2)
	
	if(!is_user_connected(iAttacker) || iAttacker == iVictim)
		return PLUGIN_CONTINUE
	
	if(equal(szTruncatedWeapon, TRUNCATEDPLASMAID) && get_user_weapon(iAttacker) == CSW_WPN)
	{
		if(g_has_plasma[iAttacker])
			set_msg_arg_string(4, TRUNCATEDPLASMAID)
	}
	return PLUGIN_CONTINUE
}

stock fm_cs_get_current_weapon_ent(id)
{
	return get_pdata_cbase(id, OFFSET_ACTIVE_ITEM, OFFSET_LINUX)
}

stock fm_cs_get_weapon_ent_owner(ent)
{
	return get_pdata_cbase(ent, OFFSET_WEAPONOWNER, OFFSET_LINUX_WEAPONS)
}

stock UTIL_PlayWeaponAnimation(const Player, const Sequence)
{
	set_pev(Player, pev_weaponanim, Sequence)
	
	message_begin(MSG_ONE_UNRELIABLE, SVC_WEAPONANIM, .player = Player)
	write_byte(Sequence)
	write_byte(pev(Player, pev_body))
	message_end()
}

public plasma_ItemPostFrame(weapon_entity) 
{
     new id = pev(weapon_entity, pev_owner)
     if (!is_user_connected(id))
          return HAM_IGNORED

     if (!g_has_plasma[id])
          return HAM_IGNORED

     new Float:flNextAttack = get_pdata_float(id, m_flNextAttack, PLAYER_LINUX_XTRA_OFF)

     new iBpAmmo = cs_get_user_bpammo(id, CSW_WPN)
     new iClip = get_pdata_int(weapon_entity, m_iClip, WEAP_LINUX_XTRA_OFF)

     new fInReload = get_pdata_int(weapon_entity, m_fInReload, WEAP_LINUX_XTRA_OFF) 

     if( fInReload && flNextAttack <= 0.0 )
     {
	     new j = min(get_pcvar_num(cvar_clip_plasma) - iClip, iBpAmmo)
	
	     set_pdata_int(weapon_entity, m_iClip, iClip + j, WEAP_LINUX_XTRA_OFF)
	     cs_set_user_bpammo(id, CSW_WPN, iBpAmmo-j)
		
	     set_pdata_int(weapon_entity, m_fInReload, 0, WEAP_LINUX_XTRA_OFF)
	     fInReload = 0
	     g_can[id] = 0
     }
     return HAM_IGNORED
}

public plasma_Reload(weapon_entity) 
{
     new id = pev(weapon_entity, pev_owner)
     if (!is_user_connected(id))
          return HAM_IGNORED

     if (!g_has_plasma[id])
          return HAM_IGNORED

     g_plasma_TmpClip[id] = -1

     new iBpAmmo = cs_get_user_bpammo(id, CSW_WPN)
     new iClip = get_pdata_int(weapon_entity, m_iClip, WEAP_LINUX_XTRA_OFF)

     if (iBpAmmo <= 0)
          return HAM_SUPERCEDE

     if (iClip >= get_pcvar_num(cvar_clip_plasma))
          return HAM_SUPERCEDE

     g_plasma_TmpClip[id] = iClip
   //  emit_sound(id, CHAN_WEAPON, "weapons/plasma/plasma_clipoff.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM)

     return HAM_IGNORED
}

public plasma_Reload_Post(weapon_entity) 
{
	new id = pev(weapon_entity, pev_owner)
	if (!is_user_connected(id))
		return HAM_IGNORED

	if (!g_has_plasma[id])
		return HAM_IGNORED

	new szClip, szAmmo
	get_user_weapon(id, szClip, szAmmo)

	if (szClip == get_pcvar_num(cvar_clip_plasma))
		return HAM_IGNORED

	if (szAmmo <= 0)
		return HAM_IGNORED

	if (g_plasma_TmpClip[id] == -1)
		return HAM_IGNORED

	set_pdata_int(weapon_entity, m_iClip, g_plasma_TmpClip[id], WEAP_LINUX_XTRA_OFF)

	set_pdata_float(weapon_entity, m_flTimeWeaponIdle, plasma_RELOAD_TIME, WEAP_LINUX_XTRA_OFF)

	set_pdata_float(id, m_flNextAttack, plasma_RELOAD_TIME, PLAYER_LINUX_XTRA_OFF)
	set_pdata_float(id, m_flNextPrimaryAttack,plasma_RELOAD_TIME, PLAYER_LINUX_XTRA_OFF)
	set_pdata_float(id, m_flNextSecondaryAttack,plasma_RELOAD_TIME, PLAYER_LINUX_XTRA_OFF)

	set_pdata_int(weapon_entity, m_fInReload, 1, WEAP_LINUX_XTRA_OFF)

	UTIL_PlayWeaponAnimation(id, plasma_RELOAD)
	emit_sound(id, CHAN_WEAPON, "weapons/plasma/plasma_reload.wav", VOL_NORM, ATTN_NORM, 0, PITCH_NORM)

	remove_task(id)
	g_can[id] = 0
	g_afterreload[id] = 1

	return HAM_IGNORED
}

public make_shell(id)
{
	static Float:origin[3], Float:origin2[3],  Float:vSrc[3], Float:angles[3], Float:v_forward[3], Float:v_right[3], Float:v_up[3], Float:gun_position[3], Float:player_origin[3], Float:player_view_offset[3]
	static Float:OriginX[3]
	pev(id, pev_v_angle, angles)
	pev(id, pev_origin, OriginX)
	engfunc(EngFunc_MakeVectors, angles)

	static Float:v_forward2[3], Float:v_right2[3], Float:v_up2[3], Float:vSrc2[3]

	global_get(glb_v_forward, v_forward)
	global_get(glb_v_right, v_right)
	global_get(glb_v_up, v_up)

	global_get(glb_v_forward, v_forward2)
	global_get(glb_v_right, v_right2)
	global_get(glb_v_up, v_up2)

	//m_pPlayer->GetGunPosition( ) = pev->origin + pev->view_ofs
	pev(id, pev_origin, player_origin)
	pev(id, pev_view_ofs, player_view_offset)
	xs_vec_add(player_origin, player_view_offset, gun_position)

	xs_vec_mul_scalar(v_forward, 10.0, v_forward)
	xs_vec_mul_scalar(v_right, 3.0, v_right)
	xs_vec_mul_scalar(v_up, -8.0, v_up)

	xs_vec_mul_scalar(v_forward2, random_float(0.01, 10.0), v_forward2)
	xs_vec_mul_scalar(v_right2, random_float(0.0, -2.5), v_right2)
	xs_vec_mul_scalar(v_up2,-30.0, v_up2)

	xs_vec_add(gun_position, v_forward, origin)
	xs_vec_add(origin, v_right, origin)
	xs_vec_add(origin, v_up, origin)

	xs_vec_add(gun_position, v_forward2, origin2)
	xs_vec_add(origin2, v_right2, origin2)
	xs_vec_add(origin2, v_up2, origin2)

	vSrc[0] = origin[0]
	vSrc[1] = origin[1]
	vSrc[2] = origin[2]

	vSrc2[0] = origin2[0]
	vSrc2[1] = origin2[1]
	vSrc2[2] = origin2[2]

	new ent = create_entity("info_target")
	set_pev(ent, pev_classname, g_shellent)

	engfunc(EngFunc_SetModel,ent, "models/rshell.mdl")

	set_pev(ent,pev_mins,Float:{-1.0,-1.0,0.0})
	set_pev(ent,pev_maxs,Float:{1.0,1.0,1.0})
	set_pev(ent,pev_size,Float:{-1.0,-1.0,0.0,1.0,1.0,1.0})
	engfunc(EngFunc_SetSize,ent,Float:{-1.0,-1.0,0.0},Float:{1.0,1.0,1.0})

	//set_pev(ent,pev_solid,SOLID_BBOX)
	//set_pev(ent,pev_movetype,MOVETYPE_TOSS)

	set_pev(ent, pev_origin, vSrc)

	static Float:newangles[3]
	pev(id,pev_angles,newangles)
	set_pev(ent,pev_angles, newangles)

	static Float:flVelocity [ 3 ]
	get_speed_vector ( vSrc2, vSrc, random_float(100.0,150.0), flVelocity )
	set_pev(ent,pev_velocity,flVelocity)

	entity_set_float(ent, EV_FL_health, get_pcvar_float(cvar_shellshealth_plasma))

	entity_set_float(ent, EV_FL_nextthink, get_gametime() + 0.01) 
	
	new angle = random_num(0,360)
	
	message_begin(MSG_ONE_UNRELIABLE, SVC_TEMPENTITY,_,id)
	write_byte(TE_MODEL)
	write_coord_f(OriginX[0])
	write_coord_f(OriginX[1])
	write_coord_f(OriginX[2])
	write_coord_f(flVelocity[0])
	write_coord_f(flVelocity[1])
	write_coord_f(flVelocity[2])
	write_angle(angle)
	write_short(shell_mode)
	write_byte(1)
	write_byte(get_pcvar_num(cvar_shellshealth_plasma) * 10)
	message_end()

	make_shell2(id)
}

public make_shell2(id)
{
	static Float:origin[3], Float:origin2[3],  Float:vSrc[3], Float:angles[3], Float:v_forward[3], Float:v_right[3], Float:v_up[3], Float:gun_position[3], Float:player_origin[3], Float:player_view_offset[3]
	static Float:OriginX[3]
	pev(id, pev_v_angle, angles)
	pev(id, pev_origin, OriginX)
	engfunc(EngFunc_MakeVectors, angles)

	static Float:v_forward2[3] , Float:v_right2[3],  Float:v_up2[3] , Float:vSrc2[3]

	global_get(glb_v_forward, v_forward)
	global_get(glb_v_right, v_right)
	global_get(glb_v_up, v_up)

	global_get(glb_v_forward, v_forward2)
	global_get(glb_v_right, v_right2)
	global_get(glb_v_up, v_up2)

	//m_pPlayer->GetGunPosition( ) = pev->origin + pev->view_ofs
	pev(id, pev_origin, player_origin)
	pev(id, pev_view_ofs, player_view_offset)
	xs_vec_add(player_origin, player_view_offset, gun_position)

	xs_vec_mul_scalar(v_forward, 13.0, v_forward);
	xs_vec_mul_scalar(v_right, random_float(-4.5,-6.0), v_right);
	xs_vec_mul_scalar(v_up, -5.0, v_up); // -3.0

	xs_vec_mul_scalar(v_forward2, 0.0, v_forward2);
	xs_vec_mul_scalar(v_right2, 0.0, v_right2);
	xs_vec_mul_scalar(v_up2, 0.0, v_up2);

	xs_vec_add(gun_position, v_forward, origin)
	xs_vec_add(origin, v_right, origin)
	xs_vec_add(origin, v_up, origin)

	xs_vec_add(gun_position, v_forward2, origin2)
	xs_vec_add(origin2, v_right2, origin2)
	xs_vec_add(origin2, v_up2, origin2)

	vSrc[0] = origin[0]
	vSrc[1] = origin[1]
	vSrc[2] = origin[2]

	vSrc2[0] = origin2[0]
	vSrc2[1] = origin2[1]
	vSrc2[2] = origin2[2]

	new ent = create_entity("info_target")
	set_pev(ent, pev_classname, g_shellent)

	engfunc(EngFunc_SetModel,ent, "models/rshell_big.mdl")

	set_pev(ent,pev_mins,Float:{-1.0,-1.0,0.0})
	set_pev(ent,pev_maxs,Float:{1.0,1.0,1.0})
	set_pev(ent,pev_size,Float:{-1.0,-1.0,0.0,1.0,1.0,1.0})
	engfunc(EngFunc_SetSize,ent,Float:{-1.0,-1.0,0.0},Float:{1.0,1.0,1.0})

	//set_pev(ent,pev_solid, SOLID_TRIGGER)
	//set_pev(ent,pev_movetype, MOVETYPE_TOSS)
	
	new angle = random_num(0,360)

	set_pev(ent, pev_origin, vSrc)

	static Float:newangles[3]
	pev(id,pev_angles,newangles)
	set_pev(ent,pev_angles, newangles)

	static Float:flVelocity [ 3 ]
	get_speed_vector ( vSrc2, vSrc, random_float(100.0, 200.0), flVelocity )
	set_pev(ent,pev_velocity,flVelocity)
	
	message_begin(MSG_ONE_UNRELIABLE, SVC_TEMPENTITY,_,id)
	write_byte(TE_MODEL)
	write_coord_f(OriginX[0])
	write_coord_f(OriginX[1])
	write_coord_f(OriginX[2])
	write_coord_f(flVelocity[0])
	write_coord_f(flVelocity[1])
	write_coord_f(flVelocity[2])
	write_angle(angle)
	write_short(shell_mode2)
	write_byte(1)
	write_byte(get_pcvar_num(cvar_shellshealth_plasma) * 10)
	message_end()

	entity_set_float(ent, EV_FL_health, get_pcvar_float(cvar_shellshealth_plasma))

	entity_set_float(ent, EV_FL_nextthink, get_gametime() + 0.01) 
}

public think_shell(ent) 
{
	if(!pev_valid(ent))
		return
		
	if(!(pev(ent,pev_flags) & FL_ONGROUND))
	{
		new Float:oldangles[3],Float:angles[3]
		pev(ent,pev_angles,oldangles)
		angles[0] = oldangles[0] + random_float(10.0,20.0)
		angles[1] = oldangles[1] + random_float(10.0,20.0)
		angles[2] = oldangles[2] + random_float(10.0,20.0)
		set_pev(ent,pev_angles,angles)
	}
	entity_set_float(ent, EV_FL_health, entity_get_float(ent,EV_FL_health) - 10.0) 
	entity_set_float(ent, EV_FL_nextthink, get_gametime() + 0.01) 
	if(entity_get_float(ent,EV_FL_health) <= 0) remove_entity(ent)
}

stock get_speed_vector(const Float:origin1[3],const Float:origin2[3],Float:speed, Float:new_velocity[3])
{
	new_velocity[0] = origin2[0] - origin1[0]
	new_velocity[1] = origin2[1] - origin1[1]
	new_velocity[2] = origin2[2] - origin1[2]
	new Float:num = floatsqroot(speed*speed / (new_velocity[0]*new_velocity[0] + new_velocity[1]*new_velocity[1] + new_velocity[2]*new_velocity[2]))
	new_velocity[0] *= num
	new_velocity[1] *= num
	new_velocity[2] *= num
       
	return 1
} 

public client_PreThink(id)
{
	if(!is_user_alive(id) || zp_get_user_zombie(id) || !g_has_plasma[id] || get_user_weapon(id) != CSW_WPN)
		return

	new szClip, szAmmo
	get_user_weapon(id, szClip, szAmmo)

	if(szClip <= 0 && szAmmo <= 0)
		g_can[id] = 0

	set_dhudmessage(200, 80, 0, 0.9, 1.0, 0, 0.002, 0.1, 0.0, 0.0)
	show_dhudmessage(id, "%d | %d ", szClip, szAmmo) 
}

public fw_PlayerPreThink(id)
{
	if(!is_user_alive(id) || zp_get_user_zombie(id) || !g_has_plasma[id] || get_user_weapon(id) != CSW_WPN)
		return

	new szClip
	get_user_weapon(id, szClip)

	if(g_can[id]) set_pev(id, pev_maxspeed, get_pcvar_float(cvar_speedrunfire_plasma))
	if(!g_can[id] || szClip <= 0) set_pev(id, pev_maxspeed, get_pcvar_float(cvar_speedrun_plasma))
}

stock drop_weapons(id, dropwhat)
{
     static weapons[32], num, i, weaponid
     num = 0
     get_user_weapons(id, weapons, num)
     
     for (i = 0; i < num; i++)
     {
          weaponid = weapons[i]
          
          if (dropwhat == 1 && ((1<<weaponid) & PRIMARY_WEAPONS_BIT_SUM))
          {
               static wname[32]
               get_weaponname(weaponid, wname, sizeof wname - 1)
               engclient_cmd(id, "drop", wname)
          }
     }
}


//new effect


stock fire_effects(iStartOrigin[3], iEndOrigin[3])
{
	message_begin(MSG_BROADCAST,SVC_TEMPENTITY)
	write_byte(0)    
	write_coord(iStartOrigin[0])
	write_coord(iStartOrigin[1])
	write_coord(iStartOrigin[2])
	write_coord(iEndOrigin[0])
	write_coord(iEndOrigin[1])
	write_coord(iEndOrigin[2])
	write_short(g_sprBeam)
	write_byte(1) 
	write_byte(5) 
	write_byte(10) 
	write_byte(25) 
	write_byte(0) 
	write_byte(0)     
	write_byte(255)      
	write_byte(0)      
	write_byte(100) 
	write_byte(0) 
	message_end()
	
	
	message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
	write_byte(3)
	write_coord(iEndOrigin[0])
	write_coord(iEndOrigin[1])
	write_coord(iEndOrigin[2])
	write_short(g_sprExp)
	write_byte(10)
	write_byte(15)
	write_byte(4)
	message_end()	
}

stock make_punch(id, velamount) 
{
	static Float:flNewVelocity[3], Float:flCurrentVelocity[3]
	velocity_by_aim(id, -velamount, flNewVelocity)
	get_user_velocity(id, flCurrentVelocity)
	xs_vec_add(flNewVelocity, flCurrentVelocity, flNewVelocity)
	set_user_velocity(id, flNewVelocity)	
}

stock damage_effects(id)
{
	message_begin(MSG_ONE_UNRELIABLE, g_msgDamage, _, id)
	write_byte(0)
	write_byte(0)
	write_long(DMG_NERVEGAS)
	write_coord(0) 
	write_coord(0)
	write_coord(0)
	message_end()
	
	message_begin(MSG_ONE_UNRELIABLE, g_msgScreenFade, {0,0,0}, id)
	write_short(1<<13)
	write_short(1<<14)
	write_short(0x0000)
	write_byte(0)
	write_byte(255)
	write_byte(0)
	write_byte(100) 
	message_end()
		
	message_begin(MSG_ONE, g_msgScreenShake, {0,0,0}, id)
	write_short(0xFFFF)
	write_short(1<<13)
	write_short(0xFFFF) 
	message_end()

}