HLMOD.HU Forrás Megtekintés - www.hlmod.hu
  1. /*
  2.    Fordította: BBk - Death of Legend
  3. */
  4.  
  5. #include <amxmodx>
  6. #include <cstrike>
  7. #include <hamsandwich>
  8.  
  9. #define NAME "show teammate's money"
  10. #define VERSION "1.3.1"
  11. #define AUTHOR "K.K.Lv"
  12.  
  13. new g_max_players, g_sync_creat_statustext, g_sync_creat_list
  14.  
  15. new bool:g_teammate[33]
  16.  
  17. new cvar_plugin_on
  18. new cvar_status_on
  19.  
  20. public plugin_init()
  21. {
  22. 	register_plugin(NAME, VERSION, AUTHOR)
  23.  
  24. 	RegisterHam(Ham_Spawn, "player", "player_spawn", 1)
  25.  
  26. 	register_clcmd("say /money", "clcmd_money")
  27.  
  28. 	register_event("StatusValue", "show_teammate_money", "be", "1=2", "2!0")
  29. 	register_event("StatusValue", "set_team", "be", "1=1")
  30.  
  31. 	cvar_plugin_on = register_cvar("stm_on", "1")
  32. 	cvar_status_on = register_cvar("stm_st_on", "1")
  33.  
  34. 	g_max_players = get_maxplayers()
  35. 	g_sync_creat_statustext = CreateHudSyncObj()
  36. 	g_sync_creat_list = CreateHudSyncObj()
  37. }
  38.  
  39. public clcmd_money(client)
  40. {
  41. 	if (!get_pcvar_num(cvar_plugin_on))
  42. 	{
  43. 		client_print(client, print_chat, "[AMXX]: Csapatok penzenek mutatasa ki volt kapcsolva.")
  44. 		return PLUGIN_HANDLED
  45. 	}
  46. 	show_money(client)
  47. 	return PLUGIN_CONTINUE
  48. }
  49.  
  50. public player_spawn(client)
  51. {
  52. 	remove_task(client)
  53. 	if (is_user_alive(client) && get_pcvar_num(cvar_plugin_on))
  54. 	{
  55. 		set_task(1.0, "show_money", client)
  56. 	}
  57. }
  58.  
  59. public show_money(client)
  60. {
  61. 	static message[1024];
  62. 	static name[32];
  63.  
  64. 	new money, id, len;
  65.  
  66. 	len = format(message, charsmax(message), "A csapatok penze:^n");
  67. 	for (id = 1; id <= g_max_players; id++)
  68. 	{
  69. 		if (id != client && is_user_connected(id) && cs_get_user_team(id) == cs_get_user_team(client))
  70. 		{
  71. 			money = cs_get_user_money(id);
  72. 			get_user_name(id, name, 31);
  73. 			len += format(message[len], charsmax(message) - len, "%-22.22s: %d^n", name, money);
  74. 		}
  75. 	}
  76. 	set_hudmessage(100, 200, 0, 0.05, 0.35, 0, 0.02, 5.0, 0.1, 0.2, 2);
  77. 	ShowSyncHudMsg(client, g_sync_creat_list, message);
  78. }
  79.  
  80. public set_team(id)
  81. 	g_teammate[id] = bool:(read_data(2) == 1);
  82.  
  83. public show_teammate_money(id)
  84. {
  85. 	if (!get_pcvar_num(cvar_plugin_on))
  86. 		return PLUGIN_HANDLED
  87. 	if(!is_user_bot(id) && is_user_connected(id) && get_pcvar_num(cvar_status_on))
  88. 	{
  89. 		static name[32]
  90.  
  91. 		new pid = read_data(2)
  92. 		new red = 0, blue = 0
  93.  
  94. 		if (cs_get_user_team(pid) == CS_TEAM_T)
  95. 			red = 255
  96. 		else if(cs_get_user_team(pid) == CS_TEAM_CT)
  97. 			blue = 255
  98.  
  99. 		get_user_name(pid, name, charsmax(name))
  100. 		new money = cs_get_user_money(pid)
  101. 		if (g_teammate[id])
  102. 		{
  103. 			set_hudmessage(red, 50, blue, -1.0, 0.60, 1, 0.01, 0.6, 0.01, 0.01, 8)
  104. 			ShowSyncHudMsg(id, g_sync_creat_statustext, "Barat:%s -- Penz:%d", name, money)
  105. 		}
  106. 		else {
  107. 			set_hudmessage(red, 50, blue, -1.0, 0.60, 1, 0.01, 0.6, 0.01, 0.01, 8)
  108. 			ShowSyncHudMsg(id, g_sync_creat_statustext, "Ellenseg:%s", name)
  109. 		}
  110. 	}
  111. 	return PLUGIN_CONTINUE
  112. }
  113.  
  114. public client_disconnect(client)
  115. {
  116. 	remove_task(client)
  117. }
  118.