#include < amxmodx >
#include < engine >
 
// 31 nap
#define VIPTIME 31 * 86400
#define VIPFLAG ADMIN_LEVEL_H
 
new const g_sPrefix[ ] = "VIP Rendszer";
 
new const g_sVipsFile[ ] = "addons/amxmodx/configs/vips.ini";
enum _: eVipInfos { sVipAuthId[ 32 ], iVipTime };
 
new Array: g_daVips, g_iVip[ eVipInfos ], g_iVipsNum, g_iVipCheckEntity;
new g_sAuthId[ 33 ][ 32 ], g_iTime[ 33 ];
 
public plugin_init( )
{
    register_plugin( "VIP Rendszer", "1.0", "Demon" );
 
    register_clcmd( "say /vipvasarlas", "CmdBuyVip" );
    register_clcmd( "say /info", "CmdVipInfo" );
 
    CreateVipCheckEntity( );
}
 
public CmdVipInfo( iId )
{
    if ( !( get_user_flags( iId ) & VIPFLAG ) )
    {
        ChatColor( iId, "Te nem vagy VIP tag." );
        return;
    }
 
    static iTime;
    iTime = g_iTime[ iId ] - get_systime( );
 
    if ( iTime <= 0 ) ChatColor( iId, "VIP tagsagod lejart." );
    else ChatColor( iId, "VIP tagsagod lejar: %d ora %02d perc %02d mp mulva.", iTime / 3600, ( iTime / 60 ) % 60, iTime % 60 );
}
 
public CmdBuyVip( iId )
{
	if ( get_user_flags( iId ) & VIPFLAG )
	{
		ChatColor( iId, "Te VIP tag vagy, nem vasarolhatsz ujra VIP tagsagot." );
		return;
	}
 
	g_iVip[ iVipTime ] = get_systime( ) + VIPTIME;
	copy( g_iVip[ sVipAuthId ], charsmax( g_sAuthId[ ] ), g_sAuthId[ iId ] );
 
	ArrayPushArray( g_daVips, g_iVip );
	g_iVipsNum = ArraySize( g_daVips );
	g_iTime[ iId ] = g_iVip[ iVipTime ];
	set_user_flags( iId, get_user_flags( iId ) | VIPFLAG );
 
	ChatColor( iId, "Sikeresen vasaroltal VIP tagsagot." );
}
 
public plugin_precache( )
{
    g_daVips = ArrayCreate( eVipInfos );
 
    new pFile  = fopen( g_sVipsFile, "rt" );
 
    if ( pFile )
    {
        new sLine[ 64 ];
 
        new sData[ 2 ][ 32 ];
        while ( !feof( pFile ) )
        {
            fgets( pFile, sLine, charsmax( sLine ) );
 
            if ( sLine[ 0 ] == ';' || strlen( sLine ) < 10 ) continue;
 
            parse( sLine, sData[ 0 ], 31, sData[ 1 ], 31 );
 
            g_iVip[ iVipTime ] = str_to_num( sData[ 1 ] );
 
            if ( g_iVip[ iVipTime ] < get_systime( ) ) continue;
 
            copy( g_iVip[ sVipAuthId ], charsmax( sData[ ] ), sData[ 0 ] );
 
            ArrayPushArray( g_daVips, g_iVip );
        }
 
        g_iVipsNum = ArraySize( g_daVips );
 
        fclose( pFile );
    }
    else Save( );
}
 
public CreateVipCheckEntity( )
{
    g_iVipCheckEntity = create_entity( "info_target" );
 
    if ( !is_valid_ent( g_iVipCheckEntity ) ) return;
 
    entity_set_string( g_iVipCheckEntity, EV_SZ_classname, "vipcheck_entity" );
    entity_set_float( g_iVipCheckEntity, EV_FL_nextthink, get_gametime( ) + 1.0 );
 
    register_think( "vipcheck_entity", "FwdThink" );
}
 
public FwdThink( iEntity )
{
    if ( iEntity != g_iVipCheckEntity || g_iVipsNum == 0 ) return;
 
    static iCurSysTime;
 
    iCurSysTime = get_systime( );
 
    for ( new i; i < g_iVipsNum; ++i )
    {
        ArrayGetArray( g_daVips, i, g_iVip );
 
        if ( g_iVip[ iVipTime ] < iCurSysTime ){
            ArrayDeleteItem( g_daVips, i );
            g_iVipsNum = ArraySize( g_daVips );
		}
    }
 
    entity_set_float( g_iVipCheckEntity, EV_FL_nextthink, get_gametime( ) + 5.0 );
}
 
public client_putinserver( iId )
{
    if ( is_user_bot( iId ) || is_user_hltv( iId ) ) return;
 
    get_user_authid( iId, g_sAuthId[ iId ], charsmax( g_sAuthId[ ] ) );
 
    Check( iId );
}
 
public Check( iId )
{
    for ( new i; i < g_iVipsNum; ++i )
    {
        ArrayGetArray( g_daVips, i, g_iVip );
 
        if ( equal( g_iVip[ sVipAuthId ], g_sAuthId[ iId ] ) )
        {
            set_user_flags( iId, get_user_flags( iId ) | ADMIN_LEVEL_H );
 
            g_iTime[ iId ] =  g_iVip[ iVipTime ];
 
            break;
        }
    }
}
 
public Save( )
{
    if ( file_exists( g_sVipsFile ) ) delete_file( g_sVipsFile );
 
    new pFile  = fopen( g_sVipsFile, "wt" );
    if ( pFile )
    {
        new sLine[ 64 ];
 
        for ( new i; i < g_iVipsNum; ++i )
        {
            ArrayGetArray( g_daVips, i, g_iVip );
 
            if(g_iVip[ iVipTime ] < get_systime( ))
			    continue;
 
            formatex( sLine, charsmax( sLine ), "^"%s^" ^"%d^"", g_iVip[ sVipAuthId ], g_iVip[ iVipTime ] );
 
            fputs( pFile, sLine);
        }
 
        fclose( pFile );
	}
}
 
public plugin_end( ) { Save( ); }
 
stock ChatColor( iId, const sMessage[ ], any:... )
{
    static iPlrNum, iPlayers[ 32 ], sMsg[ 256 ], iIdMsg, iMsgLen = charsmax( sMsg );
 
    vformat( sMsg, iMsgLen, sMessage, 3 );
    format( sMsg, iMsgLen, "!g[%s]!y %s", g_sPrefix, sMsg );
 
    replace_all( sMsg, iMsgLen, "!g", "^4" );
    replace_all( sMsg, iMsgLen, "!y", "^1" );
    replace_all( sMsg, iMsgLen, "!t", "^3" );
 
    if ( !iIdMsg ) iIdMsg = get_user_msgid( "SayText" );
 
    if ( iId )
    {
        iPlayers[ 0 ] = iId;
        iPlrNum = 1;
    }
    else get_players( iPlayers, iPlrNum, "ch" );
 
    for ( new i, iPId; i < iPlrNum; ++i )
    {
        iPId = iPlayers[ i ];
 
        if ( !is_user_connected( iPId ) ) continue;
 
        message_begin( MSG_ONE, iIdMsg, _, iPId );
        write_byte( iPId );
        write_string( sMsg );
        message_end( );
    }
}