hlmod.hu
https://hlmod.hu/

Deathrun semiclip átírás...
https://hlmod.hu/viewtopic.php?f=10&t=5372		 Oldal: 1 / 1
Szerző:  tson_ [2012.07.23. 00:08 ]
Hozzászólás témája:  Deathrun semiclip átírás...
Át kéne írni, hogy ne blokkolják egymást a játékosok de ne is változzanak átlátszóvá ha közel mennek egymáshoz...rendesen látszódjon a textura ha 2 player közel is van egymáshoz de ne blokkolják egymást.
Kód:
  1. /***

  2.  * Link to the plugin

  3.  *


  5.  */

  6.  

  7. #include < amxmodx >

  8. #include < engine >

  9. #include < cstrike >

  10. #include < fun >

  11. #include < fakemeta >

  12. #include < hamsandwich >

  13.  

  14. #pragma semicolon 1

  15.  

  16. // Comment this line if you do not want to have fake player !

  17. #define FAKE_PLAYER

  18.  

  19. // Bot name

  20. #if defined FAKE_PLAYER

  21.         new const g_szBotName[ ] = "DRM Fake Player";

  22. #endif

  23.  

  24. // Messages prefix

  25. new const g_szPrefix[ ] = "[ Deathrun ]";

  26.  

  27. // Global Variables

  28. new bool:g_bHauntedHouse, bool:g_bGamerFun, bool:g_bRandromized, bool:g_bStarting, bool:g_bFirstRound;

  29. new bool:g_bEnabled, bool:g_bRestart, bool:g_bConnected[ 33 ];

  30.  

  31. new g_pRemoveBuyZone, g_pHideHuds, g_pBlockMoney, g_pLifeSystem, g_pSvRestart, g_pAutoBalance, g_pLimitTeams;

  32. new g_pNoFallDmg, g_pGameName, g_pToggle, g_pBlockSpray, g_pBlockRadio, g_pSemiclip, g_pGiveUsp, g_pBlockKill;

  33.  

  34. new g_iMsgHideWeapon, g_iMsgCrosshair, g_iMsgMoney, g_iMsgTeamInfo, g_iMsgSayText;

  35. new g_iMaxplayers, g_iHudSync, g_iHudSync2, g_iLastTerr, g_iThinker;

  36. new g_iSemiClip[ 33 ], g_Lifes[ 33 ];

  37.  

  38. #if defined FAKE_PLAYER

  39.         new g_iFakeplayer;

  40. #endif

  41.  

  42. // Macros

  43. #if cellbits == 32

  44.         #define OFFSET_BZ 235

  45. #else

  46.         #define OFFSET_BZ 268

  47. #endif

  48.  

  49. // Colorchat

  50. enum Color {

  51.         NORMAL = 1,

  52.         GREEN,

  53.         RED,

  54.         BLUE

  55. };

  56.  

  57. new TeamName[ ][ ] = {

  58.         "",

  59.         "TERRORIST",

  60.         "CT",

  61.         "SPECTATOR"

  62. };

  63.  

  64. // =======================================================================================

  65.  

  66. public plugin_init( ) {

  67.         new const VERSION[ ] = "3.0.3";

  68.         

  69.         register_plugin( "Deathrun Manager", VERSION, "xPaw" );

  70.         

  71.         g_pToggle        = register_cvar( "deathrun_toggle",     "1" );

  72.         g_pBlockSpray    = register_cvar( "deathrun_spray",      "1" );

  73.         g_pBlockRadio    = register_cvar( "deathrun_radio",      "1" );

  74.         g_pBlockKill     = register_cvar( "deathrun_blockkill",  "1" );

  75.         g_pBlockMoney    = register_cvar( "deathrun_blockmoney", "1" );

  76.         g_pSemiclip      = register_cvar( "deathrun_semiclip",   "1" );

  77.         g_pGiveUsp       = register_cvar( "deathrun_giveusp",    "1" );

  78.         g_pHideHuds      = register_cvar( "deathrun_hidehud",    "1" );

  79.         g_pLifeSystem    = register_cvar( "deathrun_lifesystem", "1" );

  80.         g_pGameName      = register_cvar( "deathrun_gamename",   "1" );

  81.         g_pNoFallDmg     = register_cvar( "deathrun_terrnfd",    "1" );

  82.         g_pRemoveBuyZone = register_cvar( "deathrun_removebz",   "1" );

  83.         

  84.         // Lets get map name...

  85.         new szMapName[ 64 ];

  86.         get_mapname( szMapName, 63 );

  87.         

  88.         if( contain( szMapName, "deathrun_" ) != -1 ) {

  89.                 set_pcvar_num( g_pToggle, 1 );

  90.                 

  91.                 if( contain( szMapName, "hauntedhouse" ) != -1 )

  92.                         g_bHauntedHouse = true;

  93.                 else {

  94.                         g_bHauntedHouse = false;

  95.                         

  96.                         if( equal( szMapName, "deathrun_gamerfun" ) )

  97.                                 g_bGamerFun = true;

  98.                         else

  99.                                 g_bGamerFun = false;

  100.                 }

  101.         } else

  102.                 set_pcvar_num( g_pToggle, 0 );

  103.         

  104.         g_pSvRestart   = get_cvar_pointer( "sv_restart" );

  105.         g_pAutoBalance = get_cvar_pointer( "mp_autoteambalance" );

  106.         g_pLimitTeams  = get_cvar_pointer( "mp_limitteams" );

  107.         

  108.         register_cvar( "deathrun_version", VERSION, FCVAR_SERVER | FCVAR_SPONLY );

  109.         set_cvar_string( "deathrun_version", VERSION );

  110.         

  111.         // Registering Language file

  112.         register_dictionary( "deathrun.txt" );

  113.         

  114.         // Logging Events

  115.         register_logevent( "EventRoundStart", 2, "1=Round_Start" );

  116.         register_logevent( "EventRandromize", 2, "1=Round_End" );

  117.         register_event( "SendAudio", "EventTerrsWin",   "a", "2&%!MRAD_terwin" );

  118.         register_event( "TextMsg",       "EventRandromize", "a", "2&#Game_w" );

  119.         register_event( "DeathMsg",      "EventDeath",      "a");

  120.         register_event( "Money",         "EventMoney",      "b" );

  121.         register_event( "ResetHUD",      "EventResetHud",   "be" );

  122.         

  123.         g_bFirstRound    = true;

  124.         g_iMaxplayers    = get_maxplayers( );

  125.         g_iMsgHideWeapon = get_user_msgid( "HideWeapon" );

  126.         g_iMsgCrosshair  = get_user_msgid( "Crosshair" );

  127.         g_iMsgMoney      = get_user_msgid( "Money" );

  128.         g_iMsgSayText    = get_user_msgid( "SayText" );

  129.         g_iMsgTeamInfo   = get_user_msgid( "TeamInfo" );

  130.         

  131.         g_iHudSync       = CreateHudSyncObj( );

  132.         g_iHudSync2      = CreateHudSyncObj( );

  133.         

  134.         if( get_pcvar_num( g_pToggle ) ) {

  135.                 RegisterHam( Ham_TakeDamage, "player", "FwdHamPlayerDamage" );

  136.                 RegisterHam( Ham_Spawn,      "player", "FwdHamPlayerSpawn", 1 );

  137.                 register_forward( FM_ClientKill,       "FwdClientKill" );

  138.                 register_impulse( 201, "FwdImpulse_201" );

  139.                 

  140.                 if( get_pcvar_num( g_pGameName ) )

  141.                         register_forward( FM_GetGameDescription, "FwdGameDesc" );

  142.                 

  143.                 register_clcmd( "say /lifes", "CmdShowlifes" );

  144.                 register_clcmd( "say /lives", "CmdShowlifes" );

  145.                 

  146.                 register_clcmd( "radio1", "CmdRadio" );

  147.                 register_clcmd( "radio2", "CmdRadio" );

  148.                 register_clcmd( "radio3", "CmdRadio" );

  149.                 

  150.                 // Terrorist Check

  151.                 g_iThinker= create_entity( "info_target" );

  152.                 

  153.                 if( is_valid_ent( g_iThinker ) ) {

  154.                         entity_set_string( g_iThinker, EV_SZ_classname, "DeathrunThinker" );

  155.                         entity_set_float( g_iThinker, EV_FL_nextthink, get_gametime( ) + 20.0 );

  156.                         

  157.                         g_bRestart = true;

  158.                         

  159.                         // First think will happen in 20.0, Restart will be done there.

  160.                         

  161.                         register_think( "DeathrunThinker", "FwdThinker" );

  162.                 } else {

  163.                         set_task( 15.0, "CheckTerrorists", _, _, _, "b" );

  164.                         

  165.                         // Lets make restart after 20 seconds from map start.

  166.                         set_task( 20.0, "RestartRound" );

  167.                 }

  168.                 

  169.                 if( get_pcvar_num( g_pRemoveBuyZone ) ) {

  170.                         register_message( get_user_msgid( "StatusIcon" ), "MsgStatusIcon" ); // BuyZone Icon

  171.                         

  172.                         // Remove buyzone on map

  173.                         remove_entity_name( "info_map_parameters" );

  174.                         remove_entity_name( "func_buyzone" );

  175.                         

  176.                         // Create own entity to block buying

  177.                         new iEntity = create_entity( "info_map_parameters" );

  178.                         

  179.                         DispatchKeyValue( iEntity, "buying", "3" );

  180.                         DispatchSpawn( iEntity );

  181.                 }

  182.                 

  183.                 if( get_pcvar_num( g_pSemiclip ) ) {

  184.                         register_forward( FM_StartFrame,        "FwdStartFrame", 0 );

  185.                         register_forward( FM_AddToFullPack,     "FwdFullPack",   1 );

  186.                 }

  187.                 

  188.                 g_bEnabled = true;

  189.                 

  190.         #if defined FAKE_PLAYER

  191.                 new iEntity, iCount;

  192.                 

  193.                 while( ( iEntity = find_ent_by_class( iEntity, "info_player_deathmatch" ) ) > 0 )

  194.                         if( iCount++ > 1 )

  195.                                 break;

  196.                 

  197.                 if( iCount <= 1 )

  198.                         g_iFakeplayer = -1;

  199.                 

  200.                 set_task( 5.0, "UpdateBot" );

  201.                 

  202.                 register_message( get_user_msgid( "DeathMsg" ), "MsgDeathMsg" );

  203.         #endif

  204.         } else

  205.                 g_bEnabled = false;

  206. }

  207.  

  208. // FAKEPLAYER

  209. ///////////////////////////////////////////

  210. #if defined FAKE_PLAYER

  211.         public UpdateBot( ) {

  212.                 if( g_iFakeplayer == -1 )

  213.                         return;

  214.                 

  215.                 new id = find_player( "i" );

  216.                 

  217.                 if( !id ) {

  218.                         id = engfunc( EngFunc_CreateFakeClient, g_szBotName );

  219.                         if( pev_valid( id ) ) {

  220.                                 engfunc( EngFunc_FreeEntPrivateData, id );

  221.                                 dllfunc( MetaFunc_CallGameEntity, "player", id );

  222.                                 set_user_info( id, "rate", "3500" );

  223.                                 set_user_info( id, "cl_updaterate", "25" );

  224.                                 set_user_info( id, "cl_lw", "1" );

  225.                                 set_user_info( id, "cl_lc", "1" );

  226.                                 set_user_info( id, "cl_dlmax", "128" );

  227.                                 set_user_info( id, "cl_righthand", "1" );

  228.                                 set_user_info( id, "_vgui_menus", "0" );

  229.                                 set_user_info( id, "_ah", "0" );

  230.                                 set_user_info( id, "dm", "0" );

  231.                                 set_user_info( id, "tracker", "0" );

  232.                                 set_user_info( id, "friends", "0" );

  233.                                 set_user_info( id, "*bot", "1" );

  234.                                 set_pev( id, pev_flags, pev( id, pev_flags ) | FL_FAKECLIENT );

  235.                                 set_pev( id, pev_colormap, id );

  236.                                 

  237.                                 new szMsg[ 128 ];

  238.                                 dllfunc( DLLFunc_ClientConnect, id, g_szBotName, "127.0.0.1", szMsg );

  239.                                 dllfunc( DLLFunc_ClientPutInServer, id );

  240.                                 

  241.                                 cs_set_user_team( id, CS_TEAM_T );

  242.                                 ExecuteHamB( Ham_CS_RoundRespawn, id );

  243.                                 

  244.                                 set_pev( id, pev_effects, pev( id, pev_effects ) | EF_NODRAW );

  245.                                 set_pev( id, pev_solid, SOLID_NOT );

  246.                                 dllfunc( DLLFunc_Think, id );

  247.                                 

  248.                                 g_iFakeplayer = id;

  249.                         }

  250.                 }

  251.         }

  252.         

  253.         public MsgDeathMsg( const iMsgId, const iMsgDest, const id ) {

  254.                 if( get_msg_arg_int( 2 ) == g_iFakeplayer )

  255.                         return PLUGIN_HANDLED;

  256.                 

  257.                 return PLUGIN_CONTINUE;

  258.         }

  259. #endif

  260.  

  261. // NEW TERRORIST

  262. ///////////////////////////////////////////

  263. public EventRandromize( ) {

  264.         if( !g_bEnabled || g_bFirstRound || g_bRandromized )

  265.                 return PLUGIN_CONTINUE;

  266.         

  267.         g_bRandromized = true;

  268.         

  269.         new i, iPlayers[ 32 ], iNum, iPlayer;

  270.         get_players( iPlayers, iNum, "c" );

  271.         

  272.         if( iNum <= 1 )

  273.                 return PLUGIN_CONTINUE;

  274.         

  275.         for( i = 0; i < iNum; i++ ) {

  276.                 iPlayer = iPlayers[ i ];

  277.                 

  278.                 if( cs_get_user_team( iPlayer ) == CS_TEAM_T )

  279.                         cs_set_user_team( iPlayer, CS_TEAM_CT );

  280.         }

  281.         

  282.         new iRandomPlayer, CsTeams:iTeam;

  283.         

  284.         while( ( iRandomPlayer = iPlayers[ random_num( 0, iNum - 1 ) ] ) == g_iLastTerr ) { }

  285.         

  286.         g_iLastTerr = iRandomPlayer;

  287.         

  288.         iTeam = cs_get_user_team( iRandomPlayer );

  289.         

  290.         if( iTeam == CS_TEAM_T || iTeam == CS_TEAM_CT ) {

  291.                 cs_set_user_team(iRandomPlayer, CS_TEAM_T);

  292.                 

  293.                 new szName[ 32 ];

  294.                 get_user_name( iRandomPlayer, szName, 31 );

  295.                 

  296.                 for( i = 0; i < iNum; i++ )

  297.                         ColorChat(iPlayers[ i ], RED, "%s^4 %L", g_szPrefix, iPlayers[ i ], "DR_NOW_TERR", szName);

  298.                 

  299.                 if( !g_bRestart && is_valid_ent( g_iThinker ) )

  300.                         entity_set_float( g_iThinker, EV_FL_nextthink, get_gametime( ) + 15.0 );

  301.         } else {

  302.                 g_bRandromized = false;

  303.                 EventRandromize( );

  304.         }

  305.         

  306.         return PLUGIN_CONTINUE;

  307. }

  308.  

  309. // NEW ROUND

  310. ///////////////////////////////////////////

  311. public EventRoundStart( ) {

  312.         if( !g_bEnabled )

  313.                 return PLUGIN_CONTINUE;

  314.         

  315.         g_bRandromized  = false;

  316.         g_bStarting     = false;

  317.         

  318.         new i, iPlayers[ 32 ], iNum, iRealPlayers, CsTeams:iTeam;

  319.         get_players( iPlayers, iNum, "c" );

  320.         

  321.         if( iNum <= 1 )

  322.                 return PLUGIN_CONTINUE;

  323.         

  324.         for( i = 0; i < iNum; i++ ) {

  325.                 iTeam = cs_get_user_team( iPlayers[ i ] );

  326.                 

  327.                 if( iTeam == CS_TEAM_T || iTeam == CS_TEAM_CT )

  328.                         iRealPlayers++;

  329.         }

  330.         

  331.         if( iRealPlayers <= 1 ) {

  332.                 set_hudmessage( 0, 128, 0, -1.0, 0.1, 0, 4.0, 4.0, 0.5, 0.5, 4 );

  333.                 

  334.                 for( i = 0; i < iNum; i++ )

  335.                         ShowSyncHudMsg( iPlayers[ i ], g_iHudSync, "%L", iPlayers[ i ], "DR_NOT_ENOUGH" );

  336.                 

  337.                 return PLUGIN_CONTINUE;

  338.         }

  339.         

  340.         set_pcvar_num( g_pAutoBalance, 0 );

  341.         set_pcvar_num( g_pLimitTeams, 0 );

  342.         

  343.         if( g_bFirstRound ) {

  344.                 set_hudmessage( 0, 128, 0, -1.0, 0.1, 0, 4.0, 4.0, 0.5, 0.5, 4 );

  345.                 

  346.                 for( i = 0; i < iNum; i++ ) {

  347.                         ShowSyncHudMsg( iPlayers[ i ], g_iHudSync, "%L", iPlayers[ i ], "DR_STARTING" );

  348.                         

  349.                         ColorChat( iPlayers[ i ], RED, "%s^1 %L", g_szPrefix, iPlayers[ i ], "DR_STARTING_CC" );

  350.                 }

  351.                 

  352.                 if( is_valid_ent( g_iThinker ) ) {

  353.                         g_bRestart = true;

  354.                         

  355.                         entity_set_float( g_iThinker, EV_FL_nextthink, get_gametime( ) + 9.0 );

  356.                 } else

  357.                         set_task( 9.0, "RestartRound" );

  358.                 

  359.                 g_bStarting = true;

  360.                 g_bFirstRound = false;

  361.         }

  362.         

  363.         return PLUGIN_CONTINUE;

  364. }

  365.  

  366. // CHECK TERRORIST

  367. ///////////////////////////////////////////

  368. public FwdThinker( iEntity ) {

  369.         if( g_bRestart ) {

  370.                 g_bRestart = false;

  371.                 

  372.                 RestartRound( );

  373.         } else

  374.                 CheckTerrorists( );

  375.         

  376.         entity_set_float( iEntity, EV_FL_nextthink, get_gametime( ) + 15.0 );

  377. }

  378.  

  379. public CheckTerrorists( ) {

  380.         if( !g_bEnabled || g_bFirstRound || g_bStarting )

  381.                 return PLUGIN_CONTINUE;

  382.         

  383.         new i, iPlayers[ 32 ], iTerrors, iNum, iRealPlayers, CsTeams:iTeam;

  384.         get_players( iPlayers, iNum, "c" );

  385.         

  386.         if( iNum <= 1 )

  387.                 return PLUGIN_CONTINUE;

  388.         

  389.         for( i = 0; i < iNum; i++ ) {

  390.                 iTeam = cs_get_user_team( iPlayers[ i ] );

  391.                 

  392.                 if( iTeam == CS_TEAM_T )

  393.                         iTerrors++;

  394.                 

  395.                 if( iTeam == CS_TEAM_T || iTeam == CS_TEAM_CT )

  396.                         iRealPlayers++;

  397.         }

  398.         

  399.         if( iRealPlayers <= 1 ) {

  400.                 set_hudmessage( 0, 128, 0, -1.0, 0.1, 0, 4.0, 4.0, 0.5, 0.5, 4 );

  401.                 

  402.                 for( i = 0; i < iNum; i++ )

  403.                         ShowSyncHudMsg( iPlayers[ i ], g_iHudSync, "%L", iPlayers[ i ], "DR_NOT_ENOUGH" );

  404.                 

  405.                 return PLUGIN_CONTINUE;

  406.         }

  407.         

  408.         if( iTerrors == 0 ) {

  409.                 for( i = 0; i < iNum; i++ ) {

  410.                         ColorChat(iPlayers[ i ], RED, "%s^1 %L", g_szPrefix, iPlayers[ i ], "DR_NO_DETECT");

  411.                         

  412.                         if( is_user_alive( iPlayers[ i ] ) && cs_get_user_team( iPlayers[ i ] ) == CS_TEAM_CT )

  413.                                 user_silentkill( iPlayers[ i ] );

  414.                 }

  415.                 

  416.                 set_task( 0.5, "EventRandromize" );

  417.         }

  418.         

  419.         return PLUGIN_CONTINUE;

  420. }

  421.  

  422. // LIFE SYSTEM

  423. ///////////////////////////////////////////

  424. public EventTerrsWin( ) {

  425.         if( !g_bEnabled || g_bFirstRound )

  426.                 return PLUGIN_CONTINUE;

  427.         

  428.         new iPlayers[ 32 ], iNum, iPlayer;

  429.         get_players( iPlayers, iNum, "c" );

  430.         

  431.         if( iNum <= 1 )

  432.                 return PLUGIN_CONTINUE;

  433.         

  434.         new iLifeCvar = get_pcvar_num( g_pLifeSystem );

  435.         

  436.         for( new i = 0; i < iNum; i++ ) {

  437.                 iPlayer = iPlayers[ i ];

  438.                 

  439.                 if( cs_get_user_team( iPlayer ) == CS_TEAM_T ) {

  440.                         set_user_frags( iPlayer, get_user_frags( iPlayer ) + 3 );

  441.                         

  442.                         if( iLifeCvar == 2 )

  443.                                 g_Lifes[ iPlayer ]++;

  444.                 }

  445.         }

  446.         

  447.         return PLUGIN_CONTINUE;

  448. }

  449.  

  450. public EventDeath( ) {

  451.         if( !g_bEnabled )

  452.                 return PLUGIN_CONTINUE;

  453.         

  454. #if defined FAKE_PLAYER

  455.         new iVictim = read_data( 2 );

  456.         new iTeam = get_user_team( iVictim );

  457.         

  458.         if( iTeam == 1 && is_user_alive( g_iFakeplayer ) )

  459.                 fakedamage( g_iFakeplayer, "worldspawn", 100.0, DMG_GENERIC );

  460.         

  461.         if( !get_pcvar_num( g_pLifeSystem ) )

  462.                 return PLUGIN_CONTINUE;

  463. #else

  464.         if( !get_pcvar_num( g_pLifeSystem ) )

  465.                 return PLUGIN_CONTINUE;

  466.         

  467.         new iVictim = read_data( 2 );

  468.         new iTeam = get_user_team( iVictim );

  469. #endif

  470.         

  471.         new iKiller = read_data( 1 );

  472.         

  473.         if( iKiller != iVictim && get_user_team(iKiller) != iTeam )

  474.                 g_Lifes[iKiller]++;

  475.         

  476.         if( cs_get_user_team( iVictim ) == CS_TEAM_CT && g_Lifes[ iVictim ] > 0 ) {

  477.                 new iCTcount;

  478.                 for( new i = 1; i <= g_iMaxplayers; i++ ) {

  479.                         if( is_user_alive( i ) && cs_get_user_team( i ) == CS_TEAM_CT )

  480.                                 iCTcount++;

  481.                 }

  482.                 

  483.                 if( iCTcount > 1 ) {

  484.                         set_task(3.2, "fnRevivePlayer", iVictim);

  485.                         

  486.                         ColorChat( iVictim, RED, "%s^1 %L", g_szPrefix, iVictim, "DR_LIFE_RESPAWN" );

  487.                 }

  488.                 /*else

  489.                         ColorChat( iVictim, RED, "%s^1 %L", g_szPrefix, iVictim, "DR_LIFE_CANT" );*/

  490.         }

  491.         

  492.         return PLUGIN_CONTINUE;

  493. }

  494.  

  495. public fnRevivePlayer( id ) {

  496.         if( g_bConnected[ id ] ) {

  497.                 if( cs_get_user_team( id ) == CS_TEAM_CT ) {

  498.                         new iCTcount;

  499.                         for( new i = 1; i <= g_iMaxplayers; i++ )

  500.                                 if( is_user_alive( i ) && cs_get_user_team( i ) == CS_TEAM_CT )

  501.                                         iCTcount++;

  502.                         

  503.                         if( iCTcount > 1 ) {

  504.                                 ExecuteHamB( Ham_CS_RoundRespawn, id );

  505.                                 

  506.                                 g_Lifes[ id ]--;

  507.                         }

  508.                 }

  509.         }

  510. }

  511.  

  512. public CmdShowlifes( id ) {

  513.         if( get_pcvar_num( g_pLifeSystem ) == 0 ) {

  514.                 ColorChat( id, RED, "%s^1 %L", g_szPrefix, id, "DR_LIFE_DISABLE" );

  515.                 return PLUGIN_HANDLED;

  516.         }

  517.         

  518.         if( g_Lifes[ id ] > 0 )

  519.                 ColorChat( id, RED, "%s^1 %L", g_szPrefix, id, "DR_LIFE_CC_COUNT", g_Lifes[ id ] );

  520.         else

  521.                 ColorChat( id, RED, "%s^1 %L", g_szPrefix, id, "DR_LIFE_CC_NO" );

  522.         

  523.         return PLUGIN_HANDLED;

  524. }

  525.  

  526. public Showlifes( id ) {

  527.         set_hudmessage( 0, 128, 0, 0.04, 0.71, 0, 2.5, 2.5, 0.5, 0.5, 3 );

  528.         

  529.         if( g_Lifes[ id ] > 0 )

  530.                 ShowSyncHudMsg( id, g_iHudSync2, "%L", id, "DR_LIFE_COUNT", g_Lifes[ id ] );

  531.         else

  532.                 ShowSyncHudMsg( id, g_iHudSync2, "%L", id, "DR_LIFE_NO" );

  533. }

  534.  

  535. // EVENTS

  536. ///////////////////////////////////////////

  537. public EventResetHud( id ) {

  538.         if( g_bEnabled && get_pcvar_num( g_pHideHuds ) && !is_user_bot( id ) ) {

  539.                 message_begin( MSG_ONE_UNRELIABLE, g_iMsgHideWeapon, _, id );

  540.                 write_byte( ( 1<<4 | 1<<5 ) );

  541.                 message_end( );

  542.                 

  543.                 message_begin( MSG_ONE_UNRELIABLE, g_iMsgCrosshair, _, id );

  544.                 write_byte( 0 );

  545.                 message_end( );

  546.         }

  547. }

  548.  

  549. public EventMoney( id ) {

  550.         if( g_bEnabled && get_pcvar_num( g_pBlockMoney ) ) {

  551.                 set_pdata_int( id, 115, 0 );

  552.                 

  553.                 message_begin( MSG_ONE_UNRELIABLE, g_iMsgMoney, _, id );

  554.                 write_long ( 0 );

  555.                 write_byte ( 1 );

  556.                 message_end( );

  557.         }

  558. }

  559.  

  560. public client_putinserver( id )

  561.         g_bConnected[ id ] = true;

  562.  

  563. public client_disconnect( id ) {

  564.         g_bConnected[ id ] = false;

  565.         CheckTerrorists( );

  566.         

  567.         if( !g_bRestart && is_valid_ent( g_iThinker ) )

  568.                 entity_set_float( g_iThinker, EV_FL_nextthink, get_gametime( ) + 15.0 );

  569.         

  570. #if defined FAKE_PLAYER

  571.         if( g_iFakeplayer == id ) {

  572.                 set_task( 1.5, "UpdateBot" );

  573.                 

  574.                 g_iFakeplayer = 0;

  575.         }

  576. #endif

  577. }

  578.  

  579. // SEMICLIP

  580. ///////////////////////////////////////////

  581. public FwdFullPack( es, e, ent, host, flags, player, pSet ) {

  582.         if( !g_bEnabled )

  583.                 return FMRES_IGNORED;

  584.         

  585.         if( player && g_iSemiClip[ ent ] && g_iSemiClip[ host ] ) {

  586.                 set_es( es, ES_Solid, SOLID_NOT );

  587.                 set_es( es, ES_RenderMode, kRenderTransAlpha );

  588.                 set_es( es, ES_RenderAmt, 85 );

  589.         }

  590.         

  591.         return FMRES_IGNORED;

  592. }

  593.  

  594. public FwdStartFrame( ) {

  595.         if( !g_bEnabled )

  596.                 return FMRES_IGNORED;

  597.         

  598.         static iPlayers[ 32 ], iNum, iPlayer, iPlayer2, i, j;

  599.         get_players( iPlayers, iNum, "ache", "CT" );

  600.         

  601.         arrayset( g_iSemiClip, 0, 32 );

  602.         

  603.         if( iNum <= 1 )

  604.                 return FMRES_IGNORED;

  605.         

  606.         for( i = 0; i < iNum; i++ ) {

  607.                 iPlayer = iPlayers[ i ];

  608.                 

  609.                 for( j = 0; j < iNum; j++ ) {

  610.                         iPlayer2 = iPlayers[ j ];

  611.                         

  612.                         if( iPlayer == iPlayer2 )

  613.                                 continue;

  614.                         

  615.                         if( g_iSemiClip[ iPlayer ] && g_iSemiClip[ iPlayer2 ] )

  616.                                 continue;

  617.                         

  618.                         if( entity_range( iPlayer, iPlayer2 ) < 128 ) {

  619.                                 g_iSemiClip[ iPlayer ]  = true;

  620.                                 g_iSemiClip[ iPlayer2 ] = true;

  621.                         }

  622.                 }

  623.         }

  624.         

  625.         for( i = 0; i < iNum; i++ ) {

  626.                 iPlayer = iPlayers[ i ];

  627.                 

  628.                 set_pev( iPlayer, pev_solid, g_iSemiClip[ iPlayer ] ? SOLID_NOT : SOLID_SLIDEBOX );

  629.         }

  630.         

  631.         return FMRES_IGNORED;

  632. }

  633.  

  634. // FORWARDS

  635. ///////////////////////////////////////////

  636. public FwdHamPlayerSpawn( id ) {

  637.         if( !g_bEnabled || !is_user_alive( id ) )

  638.                 return HAM_IGNORED;

  639.         

  640.         if( get_pcvar_num( g_pBlockRadio ) ) // thanks to ConnorMcLeod for this good way :)

  641.                 set_pdata_int( id, 192, 0 );

  642.         

  643. #if defined FAKE_PLAYER

  644.         if( g_iFakeplayer == id ) {

  645.                 set_pev( id, pev_frags, -1000.0 );

  646.                 cs_set_user_deaths( id, -1000 );

  647.                 

  648.                 set_pev( id, pev_effects, pev( id, pev_effects ) | EF_NODRAW );

  649.                 set_pev( id, pev_solid, SOLID_NOT );

  650.                 entity_set_origin( id, Float:{ 999999.0, 999999.0, 999999.0 } );

  651.                 dllfunc( DLLFunc_Think, id );

  652.         } else {

  653. #endif

  654.                 new CsTeams:iTeam = cs_get_user_team( id );

  655.                 

  656.                 // An small delay for message

  657.                 if( get_pcvar_num( g_pLifeSystem ) != 0 && iTeam == CS_TEAM_CT )

  658.                         set_task( 0.8, "Showlifes", id );

  659.                 

  660.                 strip_user_weapons( id );

  661.                 give_item( id, "weapon_knife" );

  662.                 

  663.                 set_pdata_int( id, 116, 0 ); // Pickup fix by ConnorMcLeod

  664.                 

  665.                 if( g_bGamerFun && iTeam == CS_TEAM_CT )

  666.                         give_item( id, "weapon_smokegrenade" );

  667.                 

  668.                 if( get_pcvar_num( g_pGiveUsp ) && iTeam == CS_TEAM_CT && !g_bHauntedHouse )

  669.                         set_task( 1.0, "GiveUsp", id );

  670.  

  671. #if defined FAKE_PLAYER

  672.         }

  673. #endif

  674.         

  675.         return HAM_IGNORED;

  676. }

  677.  

  678. public GiveUsp( const id ) {

  679.         if( is_user_alive( id ) ) {

  680.                 give_item( id, "weapon_usp" );

  681.                 cs_set_user_bpammo( id, CSW_USP, 100 );

  682.         }

  683. }

  684.  

  685. public FwdGameDesc( ) {

  686.         static const GameName[ ] = "Deathrun v3.0";

  687.         

  688.         forward_return( FMV_STRING, GameName );

  689.         

  690.         return FMRES_SUPERCEDE;

  691. }

  692.  

  693. public FwdClientKill( const id ) {

  694.         if( !g_bEnabled || !is_user_alive(id) )

  695.                 return FMRES_IGNORED;

  696.         

  697.         if( get_pcvar_num( g_pBlockKill ) || cs_get_user_team( id ) == CS_TEAM_T ) {

  698.                 client_print( id, print_center, "%L", id, "DR_BLOCK_KILL" );

  699.                 client_print( id, print_console, "%L", id, "DR_BLOCK_KILL" );

  700.                 

  701.                 return FMRES_SUPERCEDE;

  702.         }

  703.         

  704.         return FMRES_IGNORED;

  705. }

  706.  

  707. public FwdImpulse_201( const id ) {

  708.         if( g_bEnabled && get_pcvar_num( g_pBlockSpray ) ) {

  709.                 if( is_user_alive( id ) )

  710.                         client_print( id, print_center, "%L", id, "DR_BLOCK_SPRAY" );

  711.                 

  712.                 return PLUGIN_HANDLED_MAIN;

  713.         }

  714.         

  715.         return PLUGIN_CONTINUE;

  716. }

  717.  

  718. public FwdHamPlayerDamage( id, idInflictor, idAttacker, Float:flDamage, iDamageBits ) {

  719.         if( get_pcvar_num( g_pNoFallDmg ) )

  720.                 if( iDamageBits & DMG_FALL )

  721.                         if( get_user_team( id ) == 1 )

  722.                                 return HAM_SUPERCEDE;

  723.         

  724.         return HAM_IGNORED;

  725. }

  726.  

  727. public MsgStatusIcon( msg_id, msg_dest, id ) {

  728.         new szIcon[ 8 ];

  729.         get_msg_arg_string( 2, szIcon, 7 );

  730.         

  731.         static const BuyZone[ ] = "buyzone";

  732.         

  733.         if( equal( szIcon, BuyZone ) ) {

  734.                 set_pdata_int( id, OFFSET_BZ, get_pdata_int( id, OFFSET_BZ, 5 ) & ~( 1 << 0 ), 5 );

  735.                 

  736.                 return PLUGIN_HANDLED;

  737.         }

  738.         

  739.         return PLUGIN_CONTINUE;

  740. }

  741.  

  742. public CmdRadio( id ) {

  743.         if( get_pcvar_num( g_pBlockRadio ) )

  744.                 return PLUGIN_HANDLED_MAIN;

  745.         

  746.         return PLUGIN_CONTINUE;

  747. }

  748.  

  749. public RestartRound( )

  750.         set_pcvar_num( g_pSvRestart, 1 );

  751.  

  752. // COLORCHAT

  753. /////////////////////////////////////////////

  754. ColorChat( id, Color:type, const szMessage[], {Float,Sql,Result,_}:... ) {

  755.         if( !get_playersnum( ) ) return;

  756.         

  757.         new message[ 256 ];

  758.         

  759.         switch( type ) {

  760.                 case NORMAL: message[0] = 0x01;

  761.                 case GREEN: message[0] = 0x04;

  762.                 default: message[0] = 0x03;

  763.         }

  764.         

  765.         vformat( message[ 1 ], 251, szMessage, 4 );

  766.         

  767.         message[ 192 ] = '^0';

  768.         

  769.         replace_all( message, 191, "\YEL", "^1" );

  770.         replace_all( message, 191, "\GRN", "^4" );

  771.         replace_all( message, 191, "\TEM", "^3" );

  772.         

  773.         new iTeam, ColorChange, index, MSG_Type;

  774.         

  775.         if( id ) {

  776.                 MSG_Type = MSG_ONE_UNRELIABLE;

  777.                 index = id;

  778.         } else {

  779.                 index = CC_FindPlayer();

  780.                 MSG_Type = MSG_BROADCAST;

  781.         }

  782.         

  783.         iTeam = get_user_team( index );

  784.         ColorChange = CC_ColorSelection(index, MSG_Type, type);

  785.  

  786.         CC_ShowColorMessage(index, MSG_Type, message);

  787.         

  788.         if( ColorChange )

  789.                 CC_Team_Info(index, MSG_Type, TeamName[iTeam]);

  790. }

  791.  

  792. CC_ShowColorMessage( id, type, message[] ) {

  793.         message_begin( type, g_iMsgSayText, _, id );

  794.         write_byte( id );       

  795.         write_string( message );

  796.         message_end( ); 

  797. }

  798.  

  799. CC_Team_Info( id, type, team[] ) {

  800.         message_begin( type, g_iMsgTeamInfo, _, id );

  801.         write_byte( id );

  802.         write_string( team );

  803.         message_end( );

  804.         

  805.         return 1;

  806. }

  807.  

  808. CC_ColorSelection( index, type, Color:Type ) {

  809.         switch( Type ) {

  810.                 case RED: return CC_Team_Info( index, type, TeamName[ 1 ] );

  811.                 case BLUE: return CC_Team_Info( index, type, TeamName[ 2 ] );

  812.         }

  813.         

  814.         return 0;

  815. }

  816.  

  817. CC_FindPlayer( ) {

  818.         for( new i = 1; i <= g_iMaxplayers; i++ )

  819.                 if( g_bConnected[ i ] )

  820.                         return i;

  821.         

  822.         return -1;

  823. }


Virtual aztmondta írjam át ezt:
Kód:
  1.                 set_es( es, ES_RenderAmt, 85 );

erre:
Kód:
  1.                 set_es( es, ES_RenderAmt, 0 );

DE sajnos így sem akar működni...
Szerző:  kiki [2012.07.24. 20:36 ]
Hozzászólás témája:  Re: Deathrun semiclip átírás...
set_es( es, ES_RenderMode, kRenderTransAlpha );
set_es( es, ES_RenderAmt, 85 );

->

//set_es( es, ES_RenderMode, kRenderTransAlpha );
// set_es( es, ES_RenderAmt, 85 );
Szerző:  eroscsavo [2012.07.27. 14:43 ]
Hozzászólás témája:  Re: Deathrun semiclip átírás...
De van erre kulon plugin csak nem tudom mi a neve pontosan.A plugin azt tartalmazza hogya játékosok át mehetnek 1máson zm szervereken gyakran látom.
Szerző:  kiki [2012.07.27. 14:47 ]
Hozzászólás témája:  Re: Deathrun semiclip átírás...
eroscsavo írta:
De van erre kulon plugin csak nem tudom mi a neve pontosan.A plugin azt tartalmazza hogya játékosok át mehetnek 1máson zm szervereken gyakran látom.


Már megválaszoltam és működik, nem kell az off!
Szerző:  eroscsavo [2012.07.27. 14:49 ]
Hozzászólás témája:  Re: Deathrun semiclip átírás...
NEM off segiteni akartam bocs
Szerző:  kiki [2012.07.27. 14:52 ]
Hozzászólás témája:  Re: Deathrun semiclip átírás...
Mint látod ebbe is benne van, ő a rendering értéket akarta leszedni...
Szerző:  eroscsavo [2012.07.27. 15:48 ]
Hozzászólás témája:  Re: Deathrun semiclip átírás...
:)) ez nekem magas haggyuk is mondtam h bocs és az a lényeg hogy sikerült megoldani
Oldal: 1 / 1 Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited
https://www.phpbb.com/