#include <amxmodx>
#include <fakemeta>
#include <zombieplague>
 
new Hands[33], MaxPlayers
 
new const MODELS[3][] =
{
	"",
	"models/zombie_plague/zombie_win.mdl",
	"models/zombie_plague/human_win.mdl"
};
 
new const MODELS_FLIP[3][] =
{
	"",
	"models/zombie_plague/zombie_win-f.mdl",
	"models/zombie_plague/human_win-f.mdl"
};
 
 
new g_iModelIndex[3], g_iWinTeam, g_iModelIndexFlip[3];
 
public plugin_init()
{
	register_plugin("[ZP] Sub-Plugin: New Win Messages", "1.3", "pro100stas" );
	register_event("HLTV", "EventRoundStart", "a", "1=0", "2=0" );
	register_event("CurWeapon", "EventCurWeapon", "be", "1=1");
 
	MaxPlayers = get_maxplayers();
 
	register_cvar("Shidla", "[ZP] New Win Messages v.1.3", FCVAR_SERVER|FCVAR_SPONLY);
	register_cvar("zp_new_win_messages", "[ZP] New Win Messages v.1.3", FCVAR_SERVER|FCVAR_SPONLY);
}
 
public plugin_precache()
{
	for (new i = WIN_ZOMBIES; i <= WIN_HUMANS; i++)
	{
		precache_model(MODELS[i]);
		g_iModelIndex[i] = engfunc(EngFunc_AllocString, MODELS[i]);
		precache_model(MODELS_FLIP[i]);
		g_iModelIndexFlip[i] = engfunc(EngFunc_AllocString, MODELS_FLIP[i]);
	}
}
 
public client_connect(id)
{
	if(!is_user_bot(id))
		query_client_cvar(id , "cl_righthand" , "Hands_CVAR_Value");
}
 
public Hands_CVAR_Value(id, const cvar[], const value[])
{
	if(1 <= id <= MaxPlayers)	// Hiba fix
		Hands[id] = str_to_num(value)
}
 
public client_disconnect(id)
{
	Hands[id] = 0
}
 
public zp_round_ended(iTeam)
{
	if (iTeam == WIN_NO_ONE)
		return;
	g_iWinTeam = iTeam;
	new iPlayers[32], iNum;
	get_players(iPlayers, iNum, "ch");
	for (new i; i < iNum; i++)
	{
		client_cmd(iPlayers[i], "cl_righthand ^"1^"");
		zp_set_user_nightvision(iPlayers[i], 1);
 
		if (get_user_weapon(iPlayers[i]) != CSW_KNIFE)
			set_pev(iPlayers[i], pev_viewmodel, g_iModelIndexFlip[iTeam]);
		else
			set_pev(iPlayers[i], pev_viewmodel, g_iModelIndex[iTeam]);
	}
}
 
public EventRoundStart()
{
	g_iWinTeam = WIN_NO_ONE;
 
	for (new i = 1; i <= MaxPlayers; i++)
	{
		if(!is_user_connected(i))
			continue;		// xPaw fix)))
 
		client_cmd(i, "cl_righthand ^"%d^"", Hands[i]);
		//client_print(i,print_chat,"[DEBUG] Значение данных '%d'***", Hands[i]);
	}
}
 
public EventCurWeapon(const id)
{
	if (g_iWinTeam > WIN_NO_ONE)
	{
		client_cmd(id, "cl_righthand ^"1^"");
 
		if (get_user_weapon(id) != CSW_KNIFE)
			set_pev(id, pev_viewmodel, g_iModelIndexFlip[g_iWinTeam]);
		else
			set_pev(id, pev_viewmodel, g_iModelIndex[g_iWinTeam]);
	}
}