Kés Rendszer 1.0.0 -hlmod.hu

Megválaszolatlan témák | Aktív témák

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Navigáció

Főmenü

Kezdőlap

Fórum

Kapcsolat

Képfeltöltő Amx Mod X

Letöltések

Pluginok

Fordító (Compiler) SourceMod

Letöltések

Pluginok

Fordító (Compiler) EventScript

Letöltések

Magyar scriptek Pályák

Half-Life

Half-Life 2

Jelenlévő felhasználók

Jelenleg 272 felhasználó van jelen :: 2 regisztrált, 0 rejtett és 270 vendég

A legtöbb felhasználó (2883 fő) 2025.07.30. 16:00-kor tartózkodott itt.

Regisztrált felhasználók: Bing [Bot], Google [Bot]az elmúlt 5 percben aktív felhasználók alapján

[ Ki van itt ]

Utoljára aktív

Kereső

Kés Rendszer 1.0.0

Moderátor:Fórum Moderátor

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 1

[10 hozzászólás ]

Nyomtatóbarát verzió |Barát értesítése e-mailben

Előző téma | Következő téma

Szerző

Üzenet

Akosch:.

Hozzászólás témája: Kés Rendszer 1.0.0

HozzászólásElküldve:2015.08.01. 02:13

Offline

Csatlakozott:2015.04.10. 19:49
Hozzászólások:610
Megköszönt másnak: 53 alkalommal
Megköszönték neki: 147 alkalommal

Plugin Neve:	Kés Rendszer 1.0.0	Plugint készitette:	Akosch:.
Játék:	Counter-Strike	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	mforce

[kozep]Kés Rendszer[/kozep]
[kozep]v1.0.0 by Akosch:.[/kozep]

Mire jó a plugin? Miért használjam?
Egyszerűen kezelhető, szerkeszthető, egy késes szerver alapjaként szolgálhat, több képességet is hozzá tudunk adni a késeinkhez, testre szabhatjuk a fejlődés nehézségét is, majdnem minden szerkeszthető anélkül, hogy hozzáérnénk az sma-hoz

Használat, beállítások:
A kések egy külső fájlból lesznek/vannak beolvasva, ez alapból a "knives.txt" fájlból történik, későbbiekben leírom, hogy ez hol változtatható.
Kések megadási formátuma a fájlban:

"név" "model" "szintlimit" "sebesség" "gravitáció" "sebzés" "visszalökés" "élet" "átlátszóság"

Név: Ide írjuk a kés nevét amit szeretnénk a menüben látni.

Model: Ide írjuk model elérési útját a "models" mappától. pl.: alap kés: models/v_knife.mdl

Szintlimit: Ide írjuk, hogy hányas szinttől legyen elérhető az adott kés.

Sebesség: Itt adjuk meg, hogy milyen gyorsan tudjunk mozogni a késünkkel, nagyobb érték esetén szükséges lehet állítani az "sv_maxspeed" cvaron. Alap sebesség késsel: 250.0 .(float értékben kell megadni!)

Gravitáció: Itt adjuk meg, hogy az alap(800) gravitáció hányszorosát, hányad részét akarjuk adni a játékosnak. pl: ha 0.5-t írunk ide akkor dupla akkorát fogunk ugrani mint alapból, ahogy néztem 0.3 - 0.4-től lehetnek gondok pl 35hp_2-n spawnolásnál egyből meghal. (float értékben kell megadni!)

Sebzés: Itt adjuk meg, hogy az alap sebzés hányszorosát, hányad részét akarjuk adni a játékosnak. Alap sebzés * itt megadott érték = új sebzés(float értékben kell megadni!)

Visszalökés: Itt adjuk meg, hogy legyen-e visszalökése a késnek és, ha igen akkor mekkora. Az ellökés mértéke több dologtól is függ, érdemes óvatosan bánni az értékkel.

Élet: Itt adhatjuk meg, hogy spawnolásnál mennyi plusz hp-t kapjon a játékos. pl.: ha ide 30 -t írunk, akkor az azt jelenti, hogy 35hp -s mapon 65hp -val kezdesz. (100 -nál nagyobb hp-t valamiért nem akart engedni spawnolásnál nekem.)

Átlátszóság: Itt adhatjuk meg, hogy mennyire legyen átlátszó a játékos. ( 0 - láthatatlan, 255 - alap )

Kések megadásáról röviden, tömören ennyit.

A fejlődés nehézségét is teljesen be tudjuk állítani a cvarok és a levels.txt(Ezt is később leírom, hogyan módosítható.) segítségével.

Levels.txt -ről:
A fájlban lefelé haladva kell megadni, hogy egyes szintekhez mennyi xp-t kelljen szedni.
pl:

Kód:

"10" - 10xp kell az 1. szinthez.
"142" - 142xp kell a 2. szinthez.
"167" - 167xp kell a 3. szinthez.
"342" - 342xp kell a 4. szinthez.
"764" - 764xp kell az 5. szinthez.
"967" - 967xp kell a 6. szinthez...

Cvarok:
kill_messages( 0 - ki, 1 -be ) - A gyilkosnak adjon-e üzenetet chaten arról, hogy kit ölt meg, és hogy mit kapott ezért.
kill_xp( 0 - felfelé ) - Mennyi xp járjon egy sima ölés után.
kill_point( 0 - felfelé ) - Mennyi pont járjon egy sima ölésért.
hs_xp( 0 - felfelé ) - Mennyi xp járjon egy hs után.
hs_point( 0 - felfelé ) - Mennyi pont járjon egy hs után.
hp_prise( 0 - felfelé ) - Mennyibe kerüljön 50hp a boltban.
armor_prise( 0 - felfelé ) - Mennyibe kerüljön 50ap a boltban.
xp_prise( 0 - felfelé ) - Mennyibe kerüljön az xp a boltban.
gambling_prise( 0 - felfelé ) - Mennyibe kerüljön a szerencsejáték a boltban.

És amikor ezekkel meglennénk akkor ajánlanám beállítani a preprocesszorokat:

SMA Forráskód: [ Mindet kijelol ]

#pragma semicolon 1			//Kérjen e sorvégi ";" zárókaraktert.
#define SLOT 32				//Hány slotos a szervered.
#define MAXLEVEL 50			//Hányas legyen a maximum szint, ez ugyebár függ a levels.txt-ben megadottaktól is.
#define KNIVES 10			//Mennyi kés legyen a menüben, ez meg a knives.txt-ben beállítottaktól függ.
#define ADDFLAG ADMIN_CVAR	//Milyen joggal lehessen addolni pontot.
#define XPMIN 10			//Xp vásárlásnál mi legyen a minimum amit kaphat.
#define XPMAX 20			//Xp vásárlásnál mi legyen a maximum amit kaphat.

Utóbbiak miatt ajánlanám először átgondolni mit akarunk, azt megírni a fájlokban, majd beállítani a preprocesszorokat és lefordítani az sma-t.

Mentés:
Ini kiterjesztésű fájlokba ment alapból(ServerDatas.ini és PlayerDatas.ini), ezeknek a fájloknak a nevét, kiterjesztését az sma -ban tudjuk állítani mégpedig itt:

SMA Forráskód: [ Mindet kijelol ]

stock const g_sServerSaveFile[] = {"ServerDatas.ini"};
stock const g_sPlayerSaveFile[] = {"PlayerDatas.ini"};

Sokakat érdekelt, hogy hogyan lehetne menteni, hogy hányszor volt megnyitva egy menü... Most láthatjátok itt a ServerDatas.ini-be menti.

PlayerDatas.ini -ben lefelé haladva láthatjuk a játékosok neveit, adatait. ("név" szint xp pont kés)
pl:

Kód:

"Jóska" 10 1250 500 1
"Pista" 50 10000 2500 8

->
Jóska nevű játékosunk 10-es szintű, 1250xp-vel rendelkezik, van 500 pontja, és utoljára az 1-es számú(menüben 2.) késsel játszott.
Pista nevű játékosunk 50-es szintű, 10.000xp-vel rendelkezik, van 2500 pontja, és utoljára a 8-as számú(menüben 9.) késsel játszott.

Egyebek:
Ha a zöld "[Információ]" felirat helyett mást szeretnénk látni a chatben az üzeneteknél(szintlépés, ölés...), akkor az sma -ban itt módosítható:

SMA Forráskód: [ Mindet kijelol ]

stock const g_sServerPrefix[] = {"[Információ]"};

levels.txt és knives.txt nevének, kiterjesztésének átírása:
plugin_precache() -en belül található 2 ilyen sor(külön - külön):

SMA Forráskód: [ Mindet kijelol ]

format(sFile, charsmax(sFile), "%s/knives.txt", sFile);
format(sFile, charsmax(sFile), "%s/levels.txt", sFile);

Itt írhatjuk át őket, pl.:

SMA Forráskód: [ Mindet kijelol ]

format(sFile, charsmax(sFile), "%s/kesek.txt", sFile);
format(sFile, charsmax(sFile), "%s/szintek.ini", sFile);

Fontos, hogy a format -t ne írjuk át formatex -re, direkt van úgy.

Menük átszínezésére most nem térnék ki, aki tudja hogy kell csinálja kedvére, aki nem az pedig nézzen utána a fórumon, volt több téma is ezzel kapcsolatban.

A plugin rendelkezik egy ajándékozás menüvel is, ahol pontot lehet küldeni a jelenleg online játékosoknak, ennek több értelme lehet, ha valaki kiegészíti a boltot.

Információk!
1. Ajánlanám az UTF8 -as karakterkódolást minden fájlnál, ha ékezetet szeretnénk használni.
2. A fájlok létrehozzák magukat, ha nem írjuk meg őket előre.
3. Colorchat.inc szükséges a pluginhoz, vagy át kell írni az üzenetes részeket.
4. ZIP -et direkt nem mellékeltem, mindenki készítse el magának az egyedi kés rendszerét, nem véletlen csináltam ilyenre amilyen.

Welcome to the AMX Mod X 1.8.1-300 Compiler.
Copyright (c) 1997-2013 ITB CompuPhase, AMX Mod X Team

Header size: 2300 bytes
Code size: 30388 bytes
Data size: 15584 bytes
Stack/heap size: 16384 bytes; max. usage is unknown, due to recursion
Total requirements: 64656 bytes
Done.

Pár kép a menüről stb(nagyobb méretért katt a képre):

1.

10.

Tesztelési lehetőségért külön köszönet DecToR -nak.
Mi nem találtunk hibákat / bugokat, ha valaki észlelne írjon és megpróbálom orvosolni.
Ha lenne ötlet fejlesztésre, kiegészítésre azt is szívesen fogadom.

#include <amxmodx>
#include <amxmisc>
enum Color
{
	NORMAL = 1, // clients scr_concolor cvar color
	GREEN, // Green Color
	TEAM_COLOR, // Red, grey, blue
	GREY, // grey
	RED, // Red
	BLUE, // Blue
}

new TeamName[][] = 
{
	"",
	"TERRORIST",
	"CT",
	"SPECTATOR"
}

ColorChat(id, Color:type, const msg[], {Float,Sql,Result,_}:...)
{
	static message[256];

switch(type)
	{
		case NORMAL: // clients scr_concolor cvar color
		{
			message[0] = 0x01;
		}
		case GREEN: // Green
		{
			message[0] = 0x04;
		}
		default: // White, Red, Blue
		{
			message[0] = 0x03;
		}
	}

vformat(message[1], 251, msg, 4);
	message[192] = '^0';

static team, ColorChange, index, MSG_Type;
	
	if(id)
	{
		MSG_Type = MSG_ONE;
		index = id;
	} else {
		index = FindPlayer();
		MSG_Type = MSG_ALL;
	}
	
	team = get_user_team(index);
	ColorChange = ColorSelection(index, MSG_Type, type);

ShowColorMessage(index, MSG_Type, message);
		
	if(ColorChange)
	{
		Team_Info(index, MSG_Type, TeamName[team]);
	}
}

ShowColorMessage(id, type, message[])
{
	message_begin(type, get_user_msgid("SayText"), _, id);
	write_byte(id)		
	write_string(message);
	message_end();	
}

Team_Info(id, type, team[])
{
	message_begin(type, get_user_msgid("TeamInfo"), _, id);
	write_byte(id);
	write_string(team);
	message_end();

return 1;
}

ColorSelection(index, type, Color:Type)
{
	switch(Type)
	{
		case RED:
		{
			return Team_Info(index, type, TeamName[1]);
		}
		case BLUE:
		{
			return Team_Info(index, type, TeamName[2]);
		}
		case GREY:
		{
			return Team_Info(index, type, TeamName[0]);
		}
	}

return 0;
}

FindPlayer()
{
	static i;
	i = -1;

while(i <= get_maxplayers())
	{
		if(is_user_connected(++i))
		{
			return i;
		}
	}

return -1;
}

#include <fakemeta>
#include <fun>
#include <hamsandwich>

#pragma semicolon 1

#define PLUGIN "KnifeSystem"
#define VERSION "1.0.0"
#define AUTHOR "Akosch:."

#define SLOT 32
#define MAXLEVEL 50
#define KNIVES 10
#define ADDFLAG ADMIN_CVAR
#define XPMIN 10
#define XPMAX 20

enum _:eKnifeDatas
{
	mName[32],
	mModel[32],
	mLevel,
	Float:mSpeed,
	Float:mGravity,
	Float:mDamage,
	mKnockback,
	mHealth,
	mVisibly
};

enum _:ePlayerInfo
{
	mPlayerLevel,
	mPlayerXp,
	mPlayerPoints
};

new g_eKnives[KNIVES][eKnifeDatas], g_ePlayerInfo[SLOT + 1][ePlayerInfo];
new g_iLevels[MAXLEVEL], g_iSelected[SLOT + 1], g_iTarget[SLOT + 1], g_pCvar[9], g_iOpening;

stock const g_sServerPrefix[] = {"[Információ]"};
stock const g_sServerSaveFile[] = {"ServerDatas.ini"};
stock const g_sPlayerSaveFile[] = {"PlayerDatas.ini"};

public plugin_init()
{
	RegisterHam(Ham_Spawn, "player", "fwdSpawnPost", 1);
	RegisterHam(Ham_TakeDamage, "player", "fwdDamagePre", 0);
	RegisterHam(Ham_Killed, "player", "fwdDeathPost", 1);
	
	register_event("CurWeapon", "eWeapon", "be", "1=1");
	
	register_clcmd("drop", "MainMenu");
	register_clcmd("say /menu", "MainMenu");
	register_clcmd("POINT", "Give");
	register_clcmd("POINT_ADD", "Add");
	
	g_pCvar[0] = register_cvar("kill_messages", "0");
	g_pCvar[1] = register_cvar("kill_xp", "1");
	g_pCvar[2] = register_cvar("kill_point", "2");
	g_pCvar[3] = register_cvar("hs_xp", "3");
	g_pCvar[4] = register_cvar("hs_point", "4");
	g_pCvar[5] = register_cvar("hp_prise", "100");
	g_pCvar[6] = register_cvar("armor_prise", "75");
	g_pCvar[7] = register_cvar("xp_prise", "150");
	g_pCvar[8] = register_cvar("gambling_prise", "125");

register_plugin(PLUGIN, VERSION, AUTHOR);
	LoadServerDatas();
}

public plugin_end()
{
	SaveServerDatas();
}

public plugin_precache()
{
	new sData[10][32], sBuffer[256], sFile[64], pFile, i;

get_configsdir(sFile, charsmax(sFile));
	format(sFile, charsmax(sFile), "%s/knives.txt", sFile);

pFile = fopen(sFile, "rt");

if(pFile)
	{		
		while(!feof(pFile))
		{
			fgets(pFile, sBuffer, charsmax(sBuffer));

parse(sBuffer, sData[0], 31, sData[1], 31, sData[2], 31, sData[3], 31, sData[4], 31, sData[5], 31, sData[6], 31, sData[7], 31, sData[8], 31);

copy(g_eKnives[i][mName], 31, sData[0]);

if(ValidMdl(sData[1]))
			{
				copy(g_eKnives[i][mModel], 31, sData[1]);
				precache_model(g_eKnives[i][mModel]);
			}
			else
				copy(g_eKnives[i][mModel], 31, "models/v_knife.mdl");

g_eKnives[i][mLevel] = str_to_num(sData[2]);
			g_eKnives[i][mSpeed] = _:str_to_float(sData[3]);
			g_eKnives[i][mGravity] = _:str_to_float(sData[4]);
			g_eKnives[i][mDamage] = _:str_to_float(sData[5]);
			g_eKnives[i][mKnockback] = str_to_num(sData[6]);
			g_eKnives[i][mHealth] = str_to_num(sData[7]);
			g_eKnives[i][mVisibly] = str_to_num(sData[8]);
			
			i++;
		}
		fclose(pFile);
	}
	else
		write_file(sFile, "^"Default^" ^"models/v_knife.mdl^" ^"0^" ^"250.0^" ^"1.0^" ^"1.0^" ^"0^" ^"0^" ^"255^"");
	
	get_configsdir(sFile, charsmax(sFile));
	format(sFile, charsmax(sFile), "%s/levels.txt", sFile);

pFile = fopen(sFile, "rt");

if(pFile)
	{
		i = 0;
		while(!feof(pFile))
		{
			fgets(pFile, sBuffer, charsmax(sBuffer));
			
			g_iLevels[i] = str_to_num(sBuffer);
			i++;
		}
		fclose(pFile);
	}
	else
		write_file(sFile, "1");
}

public client_connect(id)
{
	LoadPlayerDatas(id);
}

public client_disconnect(id)
{
	SavePlayerDatas(id);
}

public fwdDamagePre(victim, inflictor, attacker, Float:damage)
{
	if(is_user_alive(attacker) && is_user_alive(victim))
	{
		SetHamParamFloat(4, damage * g_eKnives[g_iSelected[attacker]][mDamage]);
		if(g_eKnives[g_iSelected[attacker]][mKnockback] > 0.0 && get_user_team(attacker) != get_user_team(victim))
		{
			new Float:fVec[3];
			new Float:fOldVelo[3];
			pev(victim, pev_velocity, fOldVelo);
			create_velocity_vector(victim, attacker, fVec);
			fVec[0] += fOldVelo[0];
			fVec[1] += fOldVelo[1];
			set_pev(victim, pev_velocity,fVec);
		}
	}
}

public fwdSpawnPost(id)
{
	set_user_health(id, get_user_health(id) + g_eKnives[g_iSelected[id]][mHealth]);

set_user_rendering(id, kRenderFxGlowShell, 0, 0, 0, kRenderTransAlpha, g_eKnives[g_iSelected[id]][mVisibly]);

set_pev(id, pev_gravity, g_eKnives[g_iSelected[id]][mGravity]);
}

public fwdDeathPost(iVictim, iKiller)
{
	new sName[32];
	get_user_name(iVictim, sName, charsmax(sName));
	
	if(get_pdata_int(iVictim, 75) == HIT_HEAD)
	{
		g_ePlayerInfo[iKiller][mPlayerXp] += get_pcvar_num(g_pCvar[3]);
		g_ePlayerInfo[iKiller][mPlayerPoints] += get_pcvar_num(g_pCvar[4]);
		if(get_pcvar_num(g_pCvar[0]) == 1)
			ColorChat(iKiller, GREEN, "%s ^3%i ^1xp-t és ^3%i ^1pontot kaptál ^3%s fejbelövéséért^4!", g_sServerPrefix, get_pcvar_num(g_pCvar[3]), get_pcvar_num(g_pCvar[4]), sName);
	}
	else if(iKiller != iVictim && get_user_team(iKiller) != get_user_team(iVictim))
	{
		g_ePlayerInfo[iKiller][mPlayerXp] += get_pcvar_num(g_pCvar[1]);
		g_ePlayerInfo[iKiller][mPlayerPoints] += get_pcvar_num(g_pCvar[2]);
		if(get_pcvar_num(g_pCvar[0]) == 1)
			ColorChat(iKiller, GREEN, "%s ^3%i ^1xp-t és ^3%i ^1pontot kaptál ^3%s megöléséért^4!", g_sServerPrefix, get_pcvar_num(g_pCvar[1]), get_pcvar_num(g_pCvar[2]), sName);
	}

LevelUp(iKiller);
}

public eWeapon(id)
{
	set_pev(id, pev_gravity, g_eKnives[g_iSelected[id]][mGravity]);
	
	set_user_maxspeed(id, g_eKnives[g_iSelected[id]][mSpeed]);
	
	if(get_user_weapon(id) == CSW_KNIFE)
		set_pev(id, pev_viewmodel2, g_eKnives[g_iSelected[id]][mModel]);
}

public MainMenu(id)
{
	g_iOpening++;
	new sMenu[64], pMenu;
	formatex(sMenu, charsmax(sMenu), "Főmenü \r[\wMegnyitások: %i\r]", g_iOpening);
	pMenu = menu_create(sMenu, "MainHandler");
	
	menu_additem(pMenu, "Kések", "");
	menu_additem(pMenu, "Bolt", "");
	menu_additem(pMenu, "Ajándékozás", "");
	menu_additem(pMenu, "Játékosok", "");
	if(access(id, ADDFLAG))
		menu_additem(pMenu, "Addolás", "");

menu_setprop(pMenu, MPROP_EXIT, MEXIT_ALL);
	menu_setprop(pMenu, MPROP_BACKNAME, "Vissza");
	menu_setprop(pMenu, MPROP_NEXTNAME, "Tovább");
	menu_setprop(pMenu, MPROP_EXITNAME, "Kilépés");
	
	menu_display(id, pMenu, 0);
	
	return PLUGIN_HANDLED;
}

public MainHandler(id, menu, item)
{
	if(item == MENU_EXIT)
	{
		menu_destroy(menu);
		
		return PLUGIN_HANDLED;
	}
	
	switch(item)
	{
		case 0: KnifeMenu(id);
		case 1: ShopMenu(id);
		case 2: GiftMenu(id);
		case 3: PlayersMenu(id);
		case 4: AddMenu(id);
	}
	
	menu_destroy(menu);
	
	return PLUGIN_HANDLED;
}

public KnifeMenu(id)
{
	new sMenu[128], pMenu;
	formatex(sMenu, charsmax(sMenu), "Válaszd ki a késed!^n Szinted: %i | Tapasztalatod: %i / %i", g_ePlayerInfo[id][mPlayerLevel], g_ePlayerInfo[id][mPlayerXp], g_iLevels[g_ePlayerInfo[id][mPlayerLevel]]);
	pMenu = menu_create(sMenu, "KnifeHandler");
	
	for(new i; i < KNIVES; i++)
	{
		formatex(sMenu, charsmax(sMenu), "%s \r[\w%i\r]", g_eKnives[i][mName], g_eKnives[i][mLevel]);
		menu_additem(pMenu, sMenu, "");
	}
	
	menu_setprop(pMenu, MPROP_EXIT, MEXIT_ALL);
	menu_setprop(pMenu, MPROP_BACKNAME, "Vissza");
	menu_setprop(pMenu, MPROP_NEXTNAME, "Tovább");
	menu_setprop(pMenu, MPROP_EXITNAME, "Kilépés");
	
	menu_display(id, pMenu, 0);
	
	return PLUGIN_HANDLED;
}

public KnifeHandler(id, menu, item)
{
	if(item == MENU_EXIT)
	{
		menu_destroy(menu);
		
		return PLUGIN_HANDLED;
	}
	
	if(g_ePlayerInfo[id][mPlayerLevel] < g_eKnives[item][mLevel])
	{
		ColorChat(id, GREEN, "%s ^1Sajnos nincs elég szinted ehhez a késhez^4!", g_sServerPrefix);
		
		menu_display(id, menu, 0);
	}
	else
	{
		g_iSelected[id] = item;
		strip_user_weapons(id);
		give_item(id, "weapon_knife");
		ColorChat(id, GREEN, "%s ^3%s ^1kiválasztva, sok sikert^4!", g_sServerPrefix, g_eKnives[item][mName]);
		
		menu_destroy(menu);
	}
	
	return PLUGIN_HANDLED;
}

public ShopMenu(id)
{
	new sMenu[64], pMenu;
	formatex(sMenu, charsmax(sMenu), "Bolt^nPontjaid: %i", g_ePlayerInfo[id][mPlayerPoints]);
	pMenu = menu_create(sMenu, "ShopHandler");
	
	formatex(sMenu, charsmax(sMenu), "+50hp \r[\w%i\r]", get_pcvar_num(g_pCvar[5]));
	menu_additem(pMenu, sMenu, "");
	formatex(sMenu, charsmax(sMenu), "+50ap \r[\w%i\r]", get_pcvar_num(g_pCvar[6]));
	menu_additem(pMenu, sMenu, "");
	formatex(sMenu, charsmax(sMenu), "Random xp bónusz \r[\w%i\r]", get_pcvar_num(g_pCvar[7]));
	menu_additem(pMenu, sMenu, "");
	formatex(sMenu, charsmax(sMenu), "Szerencsejáték \r[\w%i\r]", get_pcvar_num(g_pCvar[8]));
	menu_additem(pMenu, sMenu, "");
	
	menu_setprop(pMenu, MPROP_EXIT, MEXIT_ALL);
	menu_setprop(pMenu, MPROP_BACKNAME, "Vissza");
	menu_setprop(pMenu, MPROP_NEXTNAME, "Tovább");
	menu_setprop(pMenu, MPROP_EXITNAME, "Kilépés");
	
	menu_display(id, pMenu, 0);
	
	return PLUGIN_HANDLED;
}

public ShopHandler(id, menu, item)
{
	if(item == MENU_EXIT)
	{
		menu_destroy(menu);
		
		return PLUGIN_HANDLED;
	}
	
	if(g_ePlayerInfo[id][mPlayerPoints] < get_pcvar_num(g_pCvar[item + 5]))
	{
		ColorChat(id, GREEN, "%s ^1 Sajnos nincs elég pénzed erre^4!", g_sServerPrefix);
		
		menu_display(id, menu, 0);
		
		return PLUGIN_HANDLED;
	}
	
	switch(item)
	{
		case 0: 
		{
			ColorChat(id, GREEN, "%s ^1Sikeres vásárlás, kaptál +50hp-t^4!", g_sServerPrefix);
			set_user_health(id, get_user_health(id) + 50);
		}
		case 1: 
		{
			ColorChat(id, GREEN, "%s ^1Sikeres vásárlás, kaptál +50ap-t^4!", g_sServerPrefix);
			set_user_armor(id, get_user_armor(id) + 50);
		}
		case 2: 
		{
			new random_xp = random_num(XPMIN, XPMAX);
			ColorChat(id, GREEN, "%s ^1Sikeres vásárlás, kaptál %ixp-t^4!", g_sServerPrefix, random_xp);
			g_ePlayerInfo[id][mPlayerXp] += random_xp;
		}
		case 3: 
		{
			switch(random(5))
			{
				case 0: 
				{
					new random_hp = random_num(25, 75);
					ColorChat(id, GREEN, "%s ^1Sikeres vásárlás, kaptál %ihp-t^4!", g_sServerPrefix, random_hp);
					set_user_health(id, get_user_health(id) + random_hp);
				}
				case 1: 
				{
					new random_ap = random_num(25, 75);
					ColorChat(id, GREEN, "%s ^1Sikeres vásárlás, kaptál %iap-t^4!", g_sServerPrefix, random_ap);
					set_user_armor(id, get_user_armor(id) + random_ap);
				}
				case 2: 
				{
					new random_xp = random_num(XPMIN, XPMAX);
					ColorChat(id, GREEN, "%s ^1Sikeres vásárlás, kaptál %ixp-t^4!", g_sServerPrefix, random_xp);
					g_ePlayerInfo[id][mPlayerXp] += random_xp;
				}
				case 3: 
				{
					new random_points = random_num(50,250);
					ColorChat(id, GREEN, "%s ^1Sikeres vásárlás, kaptál %iPontot^4!", g_sServerPrefix, random_points);
					g_ePlayerInfo[id][mPlayerPoints] += random_points;
				}
				case 4: 
				{
					ColorChat(id, GREEN, "%s ^1Sajnos nem kaptál semmit^4!", g_sServerPrefix);
				}
				case 5: 
				{
					ColorChat(id, GREEN, "%s ^1Sikeres vásárlás, kaptál +1 szintet ^4!", g_sServerPrefix);
					g_ePlayerInfo[id][mPlayerLevel] ++;
					g_ePlayerInfo[id][mPlayerXp] = 0;
				}
			}
		}
	}
	g_ePlayerInfo[id][mPlayerPoints] -= get_pcvar_num(g_pCvar[item + 5]);
	
	menu_destroy(menu);
	
	return PLUGIN_HANDLED;
}

public GiftMenu(id)
{
	new sMenu[64], sInfo[8], pMenu, iUser;
	formatex(sMenu, charsmax(sMenu), "Válaszd ki kinek akarsz pontot küldeni!^n Pontjaid: \r%i", g_ePlayerInfo[id][mPlayerPoints]);
	pMenu = menu_create(sMenu, "GiftHandler");

while(++iUser <= SLOT)
	{
		if(!is_user_connected(iUser))
			continue;

formatex(sMenu, charsmax(sMenu), "%s", get_player_name(iUser));
		num_to_str(iUser, sInfo, charsmax(sInfo));
		menu_additem(pMenu, sMenu, sInfo);
	}

menu_setprop(pMenu, MPROP_EXIT, MEXIT_ALL);
	menu_setprop(pMenu, MPROP_BACKNAME, "Vissza");
	menu_setprop(pMenu, MPROP_NEXTNAME, "Tovább");
	menu_setprop(pMenu, MPROP_EXITNAME, "Kilépés");

menu_display(id, pMenu, 0);

return PLUGIN_HANDLED;
}

public GiftHandler(id, menu, item)
{
	if(item == MENU_EXIT)
	{
		menu_destroy(menu);
		
		return PLUGIN_HANDLED;
	}
	
	new access, info[8], name[64], callback;
	menu_item_getinfo(menu, item, access, info, charsmax(info), name, charsmax(name), callback);

g_iTarget[id] = str_to_num(info);
	
	if(!is_user_connected(g_iTarget[id]))
	{
		ColorChat(id, GREEN, "%s ^1Sajnos lecsatlakozott a kiválasztott játékos^4!", g_sServerPrefix);
		
		menu_display(id, menu, 0);
		
		return PLUGIN_HANDLED;
	}
	
	client_cmd(id, "messagemode POINT");
	
	menu_destroy(menu);
	
	return PLUGIN_HANDLED;
}

public PlayersMenu(id)
{
	new sMenu[128], sInfo[8], pMenu, iUser;
	pMenu = menu_create("Itt láthatod a többiek szintjét stb.", "PlayersHandler");
	
	while(++iUser <= SLOT)
	{
		if(!is_user_connected(iUser))
			continue;

formatex(sMenu, charsmax(sMenu), "%s \r[\wSzint: %i\r] \r[\wKés: %s\r]", get_player_name(iUser), g_ePlayerInfo[iUser][mPlayerLevel], g_eKnives[g_iSelected[iUser]][mName]);
		num_to_str(iUser, sInfo, charsmax(sInfo));
		menu_additem(pMenu, sMenu, sInfo);
	}
	
	menu_setprop(pMenu, MPROP_EXIT, MEXIT_ALL);
	menu_setprop(pMenu, MPROP_BACKNAME, "Vissza");
	menu_setprop(pMenu, MPROP_NEXTNAME, "Tovább");
	menu_setprop(pMenu, MPROP_EXITNAME, "Kilépés");
	
	menu_display(id, pMenu, 0);
	
	return PLUGIN_HANDLED;
}

public PlayersHandler(id, menu, item)
{
	if(item == MENU_EXIT)
	{
		menu_destroy(menu);
		
		return PLUGIN_HANDLED;
	}
	
	new access, info[8], name[64], callback, key;
	menu_item_getinfo(menu, item, access, info, charsmax(info), name, charsmax(name), callback);

key = str_to_num(info);
	
	if(!is_user_connected(key))
	{
		ColorChat(id, GREEN, "%s ^1Sajnos lecsatlakozott a kiválasztott játékos^4!", g_sServerPrefix);
		
		menu_display(id, menu, 0);
		
		return PLUGIN_HANDLED;
	}
	
	ColorChat(id, GREEN, "%s ^1Név: ^4%s ^1Kés: ^3%s ^1Szint: ^3%i ^1Élet: ^3%i", g_sServerPrefix, get_player_name(key), g_eKnives[g_iSelected[key]][mName], g_ePlayerInfo[key][mPlayerLevel], pev(key, pev_health));
	
	menu_destroy(menu);
	
	return PLUGIN_HANDLED;
}

public AddMenu(id)
{
	new sMenu[64], sInfo[8], pMenu, iUser;
	formatex(sMenu, charsmax(sMenu), "Válaszd ki kinek akarsz pontot adni!", g_ePlayerInfo[id][mPlayerPoints]);
	pMenu = menu_create(sMenu, "AddHandler");
	
	while(++iUser <= SLOT)
	{
		if(!is_user_connected(iUser))
			continue;

formatex(sMenu, charsmax(sMenu), "%s", get_player_name(iUser));
		num_to_str(iUser, sInfo, charsmax(sInfo));
		menu_additem(pMenu, sMenu, sInfo);
	}
	
	menu_setprop(pMenu, MPROP_EXIT, MEXIT_ALL);
	menu_setprop(pMenu, MPROP_BACKNAME, "Vissza");
	menu_setprop(pMenu, MPROP_NEXTNAME, "Tovább");
	menu_setprop(pMenu, MPROP_EXITNAME, "Kilépés");
	
	menu_display(id, pMenu, 0);
	
	return PLUGIN_HANDLED;
}

public AddHandler(id, menu, item)
{
	if(item == MENU_EXIT)
	{
		menu_destroy(menu);
		
		return PLUGIN_HANDLED;
	}
	
	new access, info[8], name[64], callback;
	menu_item_getinfo(menu, item, access, info, charsmax(info), name, charsmax(name), callback);

g_iTarget[id] = str_to_num(info);
	
	if(!is_user_connected(g_iTarget[id]))
	{
		ColorChat(id, GREEN, "%s ^1Sajnos lecsatlakozott a kiválasztott játékos^4!", g_sServerPrefix);
		
		menu_display(id, menu, 0);
		
		return PLUGIN_HANDLED;
	}
	
	client_cmd(id, "messagemode POINT_ADD");
	
	menu_destroy(menu);
	
	return PLUGIN_HANDLED;
}

public Give(id)
{
	new sData[192], num;
	read_args(sData, charsmax(sData));
	remove_quotes(sData);
	
	if(is_str_num(sData))
	{
		num = str_to_num(sData);
		if(g_ePlayerInfo[id][mPlayerPoints] > num)
		{
			g_ePlayerInfo[id][mPlayerPoints] -= num;
			g_ePlayerInfo[g_iTarget[id]][mPlayerPoints] += num;
			new sName[32];
			get_user_name(g_iTarget[id], sName, charsmax(sName));
			ColorChat(id, GREEN, "%s ^1Sikeres ajándékozás, ^3%i ^1pont elküdve ^3%s ^1-nak^4!", g_sServerPrefix, num, sName);
			ColorChat(g_iTarget[id], GREEN, "%s ^1Kaptál %i pontot %s-tól!", g_sServerPrefix, get_player_name(id));
		}
		else
			ColorChat(id, GREEN, "%s ^1Nincs elég pontod, hogy ennyit küldj^4!", g_sServerPrefix);
	}
	else
		ColorChat(id, GREEN, "%s ^1Nem csak számok szerepelnek a beírt szövegben^4!", g_sServerPrefix);
	
	return PLUGIN_HANDLED;
}

public Add(id)
{
	new sData[192], num;
	read_args(sData, charsmax(sData));
	remove_quotes(sData);
	
	if(is_str_num(sData))
	{
		num = str_to_num(sData);
		if(num)
		{
			g_ePlayerInfo[g_iTarget[id]][mPlayerPoints] += num;
			new sName[32];
			get_user_name(g_iTarget[id], sName, charsmax(sName));
			ColorChat(id, GREEN, "%s ^1Sikeres addolás! %i pont elküdve %s -nak.", g_sServerPrefix, num, sName);
			ColorChat(g_iTarget[id], GREEN, "%s ^1Kaptál %i pontot %s-tól!", g_sServerPrefix, get_player_name(id));
		}
		else
			ColorChat(id, GREEN, "%s ^1 0 pontot fölösleges küldeni^4!", g_sServerPrefix);
	}
	else
		ColorChat(id, GREEN, "%s ^1Nem csak számok szerepelnek a beírt szövegben^4!", g_sServerPrefix);
	
	return PLUGIN_HANDLED;
}

public LevelUp(id)
{
	if(!is_user_connected(id))
		return PLUGIN_HANDLED;

if(g_ePlayerInfo[id][mPlayerLevel] < MAXLEVEL)
		while(g_ePlayerInfo[id][mPlayerXp] > g_iLevels[g_ePlayerInfo[id][mPlayerLevel]])
		{
			g_ePlayerInfo[id][mPlayerLevel]++;
			if(g_ePlayerInfo[id][mPlayerLevel] == MAXLEVEL)
			{
				new sName[32];
				get_user_name(id, sName, charsmax(sName));
				ColorChat(0, GREEN, "%s ^3%s ^1elérte a maximum szintet^4!", g_sServerPrefix, sName);
				break;
			}
			else
				ColorChat(id, GREEN, "%s ^1Gratulálunk szintet léptél, jelenlegi szinted: %i^4!", g_sServerPrefix, g_ePlayerInfo[id][mPlayerLevel]);
		}

return PLUGIN_CONTINUE;
}

public SaveServerDatas()
{
	new sFile[128], pFile;
	get_configsdir(sFile, charsmax(sFile));
	format(sFile, charsmax(sFile), "%s/%s", sFile, g_sServerSaveFile);

pFile = fopen(sFile, "wt");

if(pFile)
	{
		fprintf(pFile, "%i", g_iOpening);
		fclose(pFile);
	}
	
	return PLUGIN_CONTINUE;
}

public LoadServerDatas()
{
	new sLine[192], sFile[128], pFile;
	get_configsdir(sFile, charsmax(sFile));
	format(sFile, charsmax(sFile), "%s/%s", sFile, g_sServerSaveFile);

pFile = fopen(sFile, "rt");

if(pFile)
	{
		fgets(pFile, sLine, charsmax(sLine));
		
		g_iOpening = str_to_num(sLine);
	}
	else
	{
		formatex(sLine, charsmax(sLine), "%i", g_iOpening);
		write_file(sFile, sLine);
	}

return PLUGIN_CONTINUE;
}

public SavePlayerDatas(id)
{
	if(!is_user_connected(id))
		return PLUGIN_HANDLED;

new sFile[64], pFile;
	get_configsdir(sFile, charsmax(sFile));
	format(sFile, charsmax(sFile), "%s/%s", sFile, g_sPlayerSaveFile);
	
	pFile = fopen(sFile, "rt");
	
	if(pFile)
	{
		new sLine[128], sSaveLine[128], sName[32], sLineName[32], LineNum, bool:bFound;
		get_user_name(id, sName, charsmax(sName));
		
		while(!feof(pFile))
		{
			fgets(pFile, sLine, charsmax(sLine));
			
			parse(sLine, sLineName, charsmax(sLineName));
			
			if(equal(sLineName, sName))
			{
				formatex(sSaveLine, charsmax(sSaveLine), "^"%s^" %i %i %i %i", sName, g_ePlayerInfo[id][mPlayerLevel], g_ePlayerInfo[id][mPlayerXp], g_ePlayerInfo[id][mPlayerPoints], g_iSelected[id]);
				write_file(sFile, sSaveLine, LineNum);
				bFound = true;
				return PLUGIN_HANDLED;
			}
			
			LineNum++;
		}
		
		if(!bFound)
		{
			formatex(sSaveLine, charsmax(sSaveLine), "^"%s^" %i %i %i %i", sName, g_ePlayerInfo[id][mPlayerLevel], g_ePlayerInfo[id][mPlayerXp], g_ePlayerInfo[id][mPlayerPoints], g_iSelected[id]);
			write_file(sFile, sSaveLine);
			return PLUGIN_HANDLED;
		}
		fclose(pFile);
	}
	return PLUGIN_CONTINUE;
}

public LoadPlayerDatas(id)
{

new sFile[64], pFile;
	get_configsdir(sFile, charsmax(sFile));
	format(sFile, charsmax(sFile), "%s/%s", sFile, g_sPlayerSaveFile);
	
	pFile = fopen(sFile, "rt");
	
	if(pFile)
	{
		new sLine[128],sData[5][32], sName[32], sLineName[32];
		get_user_name(id, sName, charsmax(sName));
		
		while(!feof(pFile))
		{
			fgets(pFile, sLine, charsmax(sLine));
			
			parse(sLine, sLineName, charsmax(sLineName));
			
			remove_quotes(sLineName);
			
			if(equal(sLineName, sName))
			{
				parse(sLine, sData[0], 31, sData[1], 31, sData[2], 31, sData[3], 31, sData[4], 31);
				
				g_ePlayerInfo[id][mPlayerLevel] = str_to_num(sData[1]);
				g_ePlayerInfo[id][mPlayerXp] = str_to_num(sData[2]);
				g_ePlayerInfo[id][mPlayerPoints] = str_to_num(sData[3]);
				g_iSelected[id] = str_to_num(sData[4]);
				
				return PLUGIN_HANDLED;
			}
		}
		fclose(pFile);
	}
	else
		write_file(sFile, "");

return PLUGIN_CONTINUE;
}

stock get_player_name(index)
{
	new sName[32];
	get_user_name(index, sName, charsmax(sName));
	return sName;
}

stock bool:ValidMdl(Mdl[])
	return (containi(Mdl, ".mdl") != -1);

stock create_velocity_vector(victim,attacker,Float:velocity[3])
{
	if(!is_user_alive(victim) || !is_user_alive(attacker))
		return 0;

new Float:vicorigin[3];
	new Float:attorigin[3];
	pev(victim, pev_origin, vicorigin);
	pev(attacker, pev_origin, attorigin);
	
	new Float:origin2[3];
	origin2[0] = vicorigin[0] - attorigin[0];
	origin2[1] = vicorigin[1] - attorigin[1];

new Float:largestnum = 0.0;

if(floatabs(origin2[0])>largestnum) largestnum = floatabs(origin2[0]);
	if(floatabs(origin2[1])>largestnum) largestnum = floatabs(origin2[1]);

origin2[0] /= largestnum;
	origin2[1] /= largestnum;

velocity[0] = ( origin2[0] * (g_eKnives[g_iSelected[attacker]][mKnockback] * 3000) ) / get_distance_f(vicorigin, attorigin);
	velocity[1] = ( origin2[1] * (g_eKnives[g_iSelected[attacker]][mKnockback] * 3000) ) / get_distance_f(vicorigin, attorigin);
	if(velocity[0] <= 20.0 || velocity[1] <= 20.0)
		velocity[2] = random_float(200.0 , 275.0);

return 1;
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

_________________
Néha itt, de többször nem.

Ők köszönték meg Akosch:. nek ezt a hozzászólást (összesen 4):Applee (2015.08.01. 09:13) • LyleChriss (2015.08.01. 11:50) • joxxa4cfg (2015.08.02. 14:44) • alfaanero (2015.12.04. 19:07)

Népszerűség: 9.09%

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Applee

Hozzászólás témája: Re: Kés Rendszer 1.0.0

HozzászólásElküldve:2015.08.01. 09:13

Offline

Csatlakozott:2012.09.23. 09:50
Hozzászólások:569
Megköszönt másnak: 76 alkalommal
Megköszönték neki: 37 alkalommal

Gratula

_________________

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

LyleChriss

Hozzászólás témája: Re: Kés Rendszer 1.0.0

HozzászólásElküldve:2015.08.01. 11:50

Offline

Csatlakozott:2014.08.24. 18:28
Hozzászólások:584
Megköszönt másnak: 122 alkalommal
Megköszönték neki: 120 alkalommal

Nekem tetszik, szép igényes, jó.

Köszi.

Szerintem pedig ő írta, de mindegy, ez mindenkinek az egyéni véleménye.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

6almasok

Hozzászólás témája: Re: Kés Rendszer 1.0.0

HozzászólásElküldve:2015.08.01. 16:43

Offline

Csatlakozott:2014.11.16. 12:37
Hozzászólások:686
Megköszönt másnak: 32 alkalommal
Megköszönték neki: 131 alkalommal

Akosch látom feltöltötted

_________________
Kép

"I wouldn't hold my breath if I was you
Cause I'll forget but I'll never forgive you
Don't you know, don't you know?
True friends stab you in the front."

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Akosch:.

Hozzászólás témája: Re: Kés Rendszer 1.0.0

HozzászólásElküldve:2015.08.01. 16:46

Offline

Csatlakozott:2015.04.10. 19:49
Hozzászólások:610
Megköszönt másnak: 53 alkalommal
Megköszönték neki: 147 alkalommal

Fel-fel, tegnap lőttük az utolsó tesztet este

_________________
Néha itt, de többször nem.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

'HoTDoG'

Hozzászólás témája: Re: Kés Rendszer 1.0.0

HozzászólásElküldve:2015.08.01. 18:02

Offline

Csatlakozott:2015.02.26. 16:24
Hozzászólások:57
Megköszönt másnak: 75 alkalommal

Nagyon jó.
Praktikus

Gratula.

_________________
Fegyver Skin menüm: 90%
Rólam:
Játébeli nevem: 'HoTDoG'
Már több mint 2 éve configolok.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

alfaanero

Hozzászólás témája: Re: Kés Rendszer 1.0.0

HozzászólásElküldve:2015.08.01. 22:30

Offline

Csatlakozott:2014.04.10. 15:32
Hozzászólások:776
Megköszönt másnak: 122 alkalommal
Megköszönték neki: 60 alkalommal

Szép,kiváló,igényes munka. Sok mindenkinek jól fog jönni ,a felől pedig ne aggódjatok ,hogy nem ő írta.Biztos vagyok benne ,hogy ő írta.

_________________

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

joxxa4cfg

Hozzászólás témája: Re: Kés Rendszer 1.0.0

HozzászólásElküldve:2015.08.02. 14:44

Offline

Csatlakozott:2014.06.08. 10:25
Hozzászólások:164
Megköszönt másnak: 38 alkalommal
Megköszönték neki: 19 alkalommal

Na ez komoly leírás, gratula, szép munka!

_________________

87.229.77.40:27020

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Zolika_36

Hozzászólás témája: Re: Kés Rendszer 1.0.0

HozzászólásElküldve:2021.04.22. 13:25

Offline

Csatlakozott:2020.12.01. 15:42
Hozzászólások:113
Megköszönt másnak: 15 alkalommal
Megköszönték neki: 3 alkalommal

Sziasztok!
Valaki tudna nekem segíteni?
Beletettem a szerverbe ezt a plugint és leáll a szerver és ezt irja:

FATAL ERROR (shutting down): Mod_LoadModel: models/v_knife.mdl not found

A szerverben alapból benne van ez az alap kés, de én utánna még megpróbáltam kicserélni is, de úgy sem jó

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

kajlakaki01

Hozzászólás témája: Re: Kés Rendszer 1.0.0

HozzászólásElküldve:2021.04.24. 05:59

Offline

Csatlakozott:2021.01.08. 18:25
Hozzászólások:273
Megköszönt másnak: 26 alkalommal
Megköszönték neki: 20 alkalommal

Zolika_36 írta:

Kód: [Egész kijelölése] [Mutatás/Eltüntetés]

else
                copy(g_eKnives[i][mModel], 31, "models/v_knife.mdl");

Cseréld le..
Pl: models/v_knife2.mdl

_________________

FÓRUM

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Hozzászólások megjelenítése: Rendezés

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 1

[10 hozzászólás ]

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 3 vendég

Nem nyithatsz témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Ugrás: