[ZP] Sawn-Off Shotgun

Megválaszolatlan témák | Aktív témák

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Navigáció

Főmenü

Kezdőlap

Fórum

Kapcsolat

Képfeltöltő Amx Mod X

Letöltések

Pluginok

Fordító (Compiler) SourceMod

Letöltések

Pluginok

Fordító (Compiler) EventScript

Letöltések

Magyar scriptek Pályák

Half-Life

Half-Life 2

Jelenlévő felhasználók

Jelenleg 309 felhasználó van jelen :: 1 regisztrált, 0 rejtett és 308 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: Bing [Bot] az elmúlt 5 percben aktív felhasználók alapján

[ Ki van itt ]

Utoljára aktív

Kereső

[ZP] Sawn-Off Shotgun

Moderátor: Fórum Moderátor

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 1

[ 5 hozzászólás ]

Nyomtatóbarát verzió | Barát értesítése e-mailben

Előző téma | Következő téma

Szerző

Üzenet

johnny

Hozzászólás témája: [ZP] Sawn-Off Shotgun

HozzászólásElküldve: 2013.11.13. 21:04

Offline

Csatlakozott: 2013.10.02. 16:50
Hozzászólások: 116
Megköszönt másnak: 5 alkalommal
Megköszönték neki: 78 alkalommal

Plugin Neve:	[ZP] Sawn-Off Shotgun	Plugint készitette:	meTaLiCroSS
Játék:	Counter-Strike	Kategória:	Játékmenet
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

Bemutatnám a "Sawn-Off Shotgun" nevezetű Extra Fegyvert.
Se a fórumon se a web-en nem volt erről még szó!

A Plugin helyen : [mozgo]forums.alliedmods.net/showthread.php?t=99312[/mozgo]

[kozep]//cvar\\[/kozep]

zp_sawnoff_enable '1' - Plugin Ki/Be kapcsolasa (1=Bekapcsolva | 0=Kikapcsolva)
zp_sawnoff_unlimited_clip '1' - Végtelen töltény
zp_sawnoff_damage_mult '4.0' - Sebzés szorzó
zp_sawnoff_oneround '0' - Új körben elveszi a fegyver.
zp_sawnoff_knockback '1' - Legyen-e visszalökése a fegyvernek.
zp_sawnoff_kbackpower '10.0' - Visszalökési szorzó

/*================================================================================

[ZP] Extra Item: Sawn-Off Shotgun
Copyright (C) 2009 by meTaLiCroSS
Request maded by Clear

This program is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or
(at your option) any later version.

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program.  If not, see <http://www.gnu.org/licenses/>.

In addition, as a special exception, the author gives permission to
link the code of this program with the Half-Life Game Engine ("HL
Engine") and Modified Game Libraries ("MODs") developed by Valve,
L.L.C ("Valve"). You must obey the GNU General Public License in all
respects for all of the code used other than the HL Engine and MODs
from Valve. If you modify this file, you may extend this exception
to your version of the file, but you are not obligated to do so. If
you do not wish to do so, delete this exception statement from your
version.

=================================================================================*/

#include <amxmodx>
#include <fakemeta>
#include <engine>
#include <hamsandwich>
#include <xs>
#if defined _zombieplague_included
  #endinput
#endif
#define _zombieplague_included

#define ZP_TEAM_ZOMBIE (1<<0)
#define ZP_TEAM_HUMAN (1<<1)
#define ZP_TEAM_NEMESIS (1<<2)
#define ZP_TEAM_SURVIVOR (1<<3)

enum
{
	MODE_INFECTION = 1,
	MODE_NEMESIS,
	MODE_SURVIVOR,
	MODE_SWARM,
	MODE_MULTI,
	MODE_PLAGUE
}

enum
{
	WIN_NO_ONE = 0,
	WIN_ZOMBIES,
	WIN_HUMANS
}

#define ZP_PLUGIN_HANDLED 97

native zp_get_user_zombie(id)
native zp_get_user_nemesis(id)
native zp_get_user_survivor(id)
native zp_get_user_first_zombie(id)
native zp_get_user_last_zombie(id)
native zp_get_user_last_human(id)
native zp_get_user_zombie_class(id)
native zp_get_user_next_class(id)
native zp_set_user_zombie_class(id, classid)
native zp_get_user_ammo_packs(id)
native zp_set_user_ammo_packs(id, amount)
native zp_get_zombie_maxhealth(id)
native zp_get_user_batteries(id)
native zp_set_user_batteries(id, charge)
native zp_get_user_nightvision(id)
native zp_set_user_nightvision(id, set)
native zp_infect_user(id, infector = 0, silent = 0, rewards = 0)
native zp_disinfect_user(id, silent = 0)
native zp_make_user_nemesis(id)
native zp_make_user_survivor(id)
native zp_respawn_user(id, team)
native zp_force_buy_extra_item(id, itemid, ignorecost = 0)
native zp_override_user_model(id, const newmodel[], modelindex = 0)
native zp_has_round_started()
native zp_is_nemesis_round()
native zp_is_survivor_round()
native zp_is_swarm_round()
native zp_is_plague_round()
native zp_get_zombie_count()
native zp_get_human_count()
native zp_get_nemesis_count()
native zp_get_survivor_count()
native zp_register_extra_item(const name[], cost, teams)
native zp_register_zombie_class(const name[], const info[], const model[], const clawmodel[], hp, speed, Float:gravity, Float:knockback)
native zp_get_extra_item_id(const name[])
native zp_get_zombie_class_id(const name[])
native zp_get_zombie_class_info(classid, info[], len)
forward zp_round_started(gamemode, id)
forward zp_round_ended(winteam)
forward zp_user_infected_pre(id, infector, nemesis)
forward zp_user_infected_post(id, infector, nemesis)
forward zp_user_humanized_pre(id, survivor)
forward zp_user_humanized_post(id, survivor)
forward zp_user_infect_attempt(id, infector, nemesis)
forward zp_user_humanize_attempt(id, survivor)
forward zp_extra_item_selected(id, itemid)
forward zp_user_unfrozen(id)
forward zp_user_last_zombie(id)
forward zp_user_last_human(id)

#define ZP_TEAM_ANY 0
#define ZP_TEAM_NO_ONE 0

/*================================================================================
[Customization]
=================================================================================*/

// Item Cost
new const g_SawnOff_Cost = 30

// Models
new const sawnoff_model_v[] = "models/v_sawn_off_shotgun.mdl"
new const sawnoff_model_p[] = "models/p_sawn_off_shotgun.mdl"
new const sawnoff_model_w[] = "models/w_sawn_off_shotgun.mdl"

// ---------------------------------------------------------------
// ------------------ Customization ends here!! ------------------
// ---------------------------------------------------------------

// Offsets
#if cellbits == 32
const OFFSET_CLIPAMMO = 51
#else
const OFFSET_CLIPAMMO = 65
#endif
const OFFSET_LINUX = 5
const OFFSET_LINUX_WEAPONS = 4
const OFFSET_LASTPRIMARYITEM = 368

// Version
#define VERSION "0.4.5"

// Arrays
new g_sawnoff_shotgun[33], g_currentweapon[33]

// Variables
new g_SawnOff, g_MaxPlayers

// Cvar Pointers
new cvar_enable, cvar_oneround, cvar_knockback, cvar_knockbackpower, cvar_uclip, cvar_damage

/*================================================================================
[Init and Precache]
=================================================================================*/

public plugin_init() 
{
	// Plugin Info
	register_plugin("[ZP] Extra Item: Sawn-Off Shotgun", VERSION, "meTaLiCroSS")
	
	// Ham Forwards
	RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
	RegisterHam(Ham_TraceAttack, "player", "fw_TraceAttack")
	RegisterHam(Ham_Killed, "player", "fw_PlayerKilled")
	
	// Fakemeta Forwards
	register_forward(FM_SetModel, "fw_SetModel")
	
	// Event: Round Start
	register_event("HLTV", "event_round_start", "a", "1=0", "2=0")
	
	// Message: Cur Weapon
	register_message(get_user_msgid("CurWeapon"), "message_cur_weapon")
	
	// CVARS
	register_cvar("zp_extra_sawnoff", VERSION, FCVAR_SERVER|FCVAR_SPONLY)
	cvar_enable = register_cvar("zp_sawnoff_enable", "1")
	cvar_uclip = register_cvar("zp_sawnoff_unlimited_clip", "1")
	cvar_damage = register_cvar("zp_sawnoff_damage_mult", "4.0")
	cvar_oneround = register_cvar("zp_sawnoff_oneround", "0")
	cvar_knockback = register_cvar("zp_sawnoff_knockback", "1")
	cvar_knockbackpower = register_cvar("zp_sawnoff_kbackpower", "10.0")
	
	// Variables
	g_MaxPlayers = get_maxplayers()
	g_SawnOff = zp_register_extra_item("Sawn-Off Shotgun", g_SawnOff_Cost, ZP_TEAM_HUMAN)
	
}

public plugin_precache()
{
	// Precaching models
	precache_model(sawnoff_model_v)
	precache_model(sawnoff_model_p)
	precache_model(sawnoff_model_w)
}

/*================================================================================
[Main Functions]
=================================================================================*/

// Round Start Event
public event_round_start()
{
	// Get all the players
	for(new id = 1; id <= g_MaxPlayers; id++)
	{
		// Check
		if(get_pcvar_num(cvar_oneround) || !get_pcvar_num(cvar_enable))
		{
			// Striping Sawn Off
			if(g_sawnoff_shotgun[id])
			{
				g_sawnoff_shotgun[id] = false;
				ham_strip_weapon(id, "weapon_m3")
			}
		}
	}
}

// Message Current Weapon
public message_cur_weapon(msg_id, msg_dest, id)
{
	// Doesn't have a Sawn Off
	if (!g_sawnoff_shotgun[id])
		return PLUGIN_CONTINUE
	
	// Isn't alive / not active weapon
	if (!is_user_alive(id) || get_msg_arg_int(1) != 1)
		return PLUGIN_CONTINUE
	
	// Get Weapon Clip
	new clip = get_msg_arg_int(3)
	
	// Update Weapon Array
	g_currentweapon[id] = get_msg_arg_int(2) // get weapon ID
	
	// Weapon isn't M3
	if(g_currentweapon[id] != CSW_M3)
		return PLUGIN_CONTINUE;
	
	// Replace Models
	entity_set_string(id, EV_SZ_viewmodel, sawnoff_model_v)
	entity_set_string(id, EV_SZ_weaponmodel, sawnoff_model_p)
	
	// Check cvar
	if(get_pcvar_num(cvar_uclip))
	{	
		// Set Ammo HUD in 8
		set_msg_arg_int(3, get_msg_argtype(3), 8)
		
		// Check clip if more than 2
		if (clip < 2)
		{
			// Update weapon ammo
			fm_set_weapon_ammo(find_ent_by_owner(-1, "weapon_m3", id), 8)
		}
	}
	
	return PLUGIN_CONTINUE;
}

// Touch fix (when user drop the Sawn off, already has the Sawn off.
public touch_fix(id)
{
	if(g_sawnoff_shotgun[id])
		g_sawnoff_shotgun[id] = false;
}

/*================================================================================
[Main Forwards]
=================================================================================*/

public fw_PlayerKilled(victim, attacker, shouldgib)
{
	// Victim has a Sawn off
	if(g_sawnoff_shotgun[victim])
		g_sawnoff_shotgun[victim] = false;
}

public fw_SetModel(entity, model[])
{
	// Entity is not valid
	if(!is_valid_ent(entity))
		return FMRES_IGNORED;
	
	// Entity model is not a M3
	if(!equali(model, "models/w_m3.mdl")) 
		return FMRES_IGNORED;
	
	// Get owner and entity classname
	new owner = entity_get_edict(entity, EV_ENT_owner)
	new classname[33]
	entity_get_string(entity, EV_SZ_classname, classname, charsmax(classname))
	
	// Entity classname is a weaponbox
	if(equal(classname, "weaponbox"))
	{
		// The weapon owner has a Sawn Off
		if(g_sawnoff_shotgun[owner])
		{
			// Striping Sawn off and set New Model
			g_sawnoff_shotgun[owner] = false;
			entity_set_model(entity, sawnoff_model_w)
			set_task(0.1, "touch_fix", owner)
			
			return FMRES_SUPERCEDE
		}
	}
	
	return FMRES_IGNORED
	
}

public fw_TakeDamage(victim, inflictor, attacker, Float:damage, damage_type)
{
	// Attacker isn't a Player (1 in 32)
	if(!(1 <= attacker <= g_MaxPlayers))
		return HAM_IGNORED;
	
	// Attacker's weapon isn't a M3
	if(g_currentweapon[attacker] != CSW_M3)
		return HAM_IGNORED;
	
	// User doesn't have a Sawn Off
	if(!g_sawnoff_shotgun[attacker])
		return HAM_IGNORED;
	
	SetHamParamFloat(4, damage * get_pcvar_float(cvar_damage) )
	
	return HAM_IGNORED;
}

public fw_TraceAttack(victim, attacker, Float:damage, Float:direction[3], tracehandle, damage_type)
{
	// Player is allowed to make a Knockback
	if(!allowed_knockback(victim, attacker))
		return HAM_IGNORED;
	
	// Check damage type
	if(!(damage_type & DMG_BULLET))
		return HAM_IGNORED;
	
	// Make Knockback...
	new Float:velocity[3]; pev(victim, pev_velocity, velocity)
	xs_vec_mul_scalar(direction, get_pcvar_float(cvar_knockbackpower), direction)
	xs_vec_add(velocity, direction, direction)
	entity_set_vector(victim, EV_VEC_velocity, direction)
	
	return HAM_IGNORED;
	
}

public pfn_touch(entity, toucher)
{
	new model[33], toucherclass[33], entityclass[33]
	
	// Get toucher Classname
	if((toucher > 0) && is_valid_ent(toucher)) entity_get_string(toucher, EV_SZ_classname, toucherclass, charsmax(toucherclass))
	
	// Get entity Classname
	if((entity > 0) && is_valid_ent(entity)) entity_get_string(entity, EV_SZ_classname, entityclass, charsmax(entityclass))
	
	// Now check if is a Weapon and is a Player
	if(equali(toucherclass, "player") && equali(entityclass, "weaponbox"))
	{
		// Get Model
		entity_get_string(entity, EV_SZ_model, model, charsmax(model))
		
		// Check Model
		if(equali(model, sawnoff_model_w))
			if(allowed_touch(toucher)) // Player is allowed to pickup the weapon
			g_sawnoff_shotgun[toucher] = true // Set Weapon
	}
}

/*================================================================================
[Internal Functions]
=================================================================================*/

allowed_knockback(victim, attacker)
{
// Obviously, doesn't is allowed to be Knockbacked (WTF)
if(!g_sawnoff_shotgun[attacker] || !get_pcvar_num(cvar_knockback) || g_currentweapon[attacker] != CSW_M3 || !zp_get_user_zombie(victim))
	return false;
	
	return true;
}

allowed_touch(toucher)
{
// Can't touch the Weapon
if(zp_get_user_survivor(toucher) || zp_get_user_zombie(toucher) || fm_get_user_lastprimaryitem(toucher) || g_sawnoff_shotgun[toucher])
	return false;
	
	return true;
}

/*================================================================================
[Zombie Plague Forwards]
=================================================================================*/

public zp_extra_item_selected(id, itemid)
{
	// Item is the Sawn-Off
	if(itemid == g_SawnOff)
	{
		if(!get_pcvar_num(cvar_enable))
		{
			zp_set_user_ammo_packs(id, zp_get_user_ammo_packs(id) + g_SawnOff_Cost)
			client_print(id, print_chat, "[ZP] A Sawn-Off Shotgun tiltva van!")
			
			return;
		}
		
		// Already has an M3
		if(g_sawnoff_shotgun[id] && user_has_weapon(id, CSW_M3))
		{
			zp_set_user_ammo_packs(id, zp_get_user_ammo_packs(id) + g_SawnOff_Cost)
			client_print(id, print_chat, "[ZP] Neked mar van Sawn-Off Shotgunod!")
			
			return;
		}
		
		// Array
		g_sawnoff_shotgun[id] = true
		
		// Weapon
		ham_give_weapon(id, "weapon_m3")
		
		// Message
		client_print(id, print_chat, "[ZP] Vettel egy Sawn-Off Shotgun-t!")
		
	}
}

public zp_user_infected_post(infected, infector)
{
	// Infected has a M3
	if(g_sawnoff_shotgun[infected])
		g_sawnoff_shotgun[infected] = false;
}

public zp_user_humanized_post(player)
{
	// Is Survivor
	if(zp_get_user_survivor(player) && g_sawnoff_shotgun[player])
		g_sawnoff_shotgun[player] = false;
}

/*================================================================================
[Stocks]
=================================================================================*/

stock ham_give_weapon(id, weapon[])
{
	if(!equal(weapon,"weapon_",7)) 
		return 0
	
	new wEnt = create_entity(weapon)
	
	if(!is_valid_ent(wEnt)) 
		return 0
	
	entity_set_int(wEnt, EV_INT_spawnflags, SF_NORESPAWN)
	DispatchSpawn(wEnt)
	
	if(!ExecuteHamB(Ham_AddPlayerItem,id,wEnt))
	{
		if(is_valid_ent(wEnt)) entity_set_int(wEnt, EV_INT_flags, entity_get_int(wEnt, EV_INT_flags) | FL_KILLME)
		return 0
	}
	
	ExecuteHamB(Ham_Item_AttachToPlayer,wEnt,id)
	return 1
}

stock ham_strip_weapon(id, weapon[])
{
	if(!equal(weapon,"weapon_",7)) 
		return 0
	
	new wId = get_weaponid(weapon)
	
	if(!wId) return 0
	
	new wEnt
	
	while((wEnt = find_ent_by_class(wEnt, weapon)) && entity_get_edict(wEnt, EV_ENT_owner) != id) {}
	
	if(!wEnt) return 0
	
	if(get_user_weapon(id) == wId) 
		ExecuteHamB(Ham_Weapon_RetireWeapon,wEnt);
	
	if(!ExecuteHamB(Ham_RemovePlayerItem,id,wEnt)) 
		return 0
	
	ExecuteHamB(Ham_Item_Kill, wEnt)
	
	entity_set_int(id, EV_INT_weapons, entity_get_int(id, EV_INT_weapons) & ~(1<<wId))
	
	return 1
}

stock fm_set_weapon_ammo(entity, amount)
{
	set_pdata_int(entity, OFFSET_CLIPAMMO, amount, OFFSET_LINUX_WEAPONS);
}

stock fm_get_user_lastprimaryitem(id) // Thanks to joaquimandrade
{
	if(get_pdata_cbase(id, OFFSET_LASTPRIMARYITEM) != -1)
		return 1;
	
	return 0;
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1038\\ f0\\ fs16 \n\\ par }
*/

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

Ők köszönték meg johnny nek ezt a hozzászólást: mldpapa (2015.07.18. 02:26)

Népszerűség: 2.27%

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

ultraibolya

Hozzászólás témája: Re: [ZP] Sawn-Off Shotgun | Counter-Strike | Játékmenet

HozzászólásElküldve: 2013.11.13. 21:16

Offline

Csatlakozott: 2012.03.22. 18:22
Hozzászólások: 2978
Megköszönt másnak: 115 alkalommal
Megköszönték neki: 368 alkalommal

Nem elég csak a cvarokat leírni.

_________________
Blasenkampfwagen

https://discord.gg/uBYnNnZP
GTA:PURSUIT MTA

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

IrOn

Hozzászólás témája: Re: [ZP] Sawn-Off Shotgun | Counter-Strike | Játékmenet

HozzászólásElküldve: 2013.11.13. 22:06

Offline

Csatlakozott: 2010.02.04. 19:12
Hozzászólások: 3528
Megköszönt másnak: 26 alkalommal
Megköszönték neki: 180 alkalommal

meg azt a pár sort magyarosítsd le

_________________
http://www.ebateam.eu/

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

ultraibolya

Hozzászólás témája: Re: [ZP] Sawn-Off Shotgun | Counter-Strike | Játékmenet

HozzászólásElküldve: 2013.11.22. 18:44

Offline

Csatlakozott: 2012.03.22. 18:22
Hozzászólások: 2978
Megköszönt másnak: 115 alkalommal
Megköszönték neki: 368 alkalommal

Magyarosítottam!Máskor figyelj a cvarokra meg a nyelvre!

_________________
Blasenkampfwagen

https://discord.gg/uBYnNnZP
GTA:PURSUIT MTA

Ők köszönték meg ultraibolya nek ezt a hozzászólást: norbee.16 (2013.12.04. 21:43)

Népszerűség: 2.27%

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

johnny

Hozzászólás témája: Re: [ZP] Sawn-Off Shotgun | Counter-Strike | Játékmenet

HozzászólásElküldve: 2013.12.04. 17:41

Offline

Csatlakozott: 2013.10.02. 16:50
Hozzászólások: 116
Megköszönt másnak: 5 alkalommal
Megköszönték neki: 78 alkalommal

Jóvan már ultra!:D

Ők köszönték meg johnny nek ezt a hozzászólást: mldpapa (2015.07.18. 02:26)

Népszerűség: 2.27%

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Hozzászólások megjelenítése: Rendezés

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 1

[ 5 hozzászólás ]

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 19 vendég

Nem nyithatsz témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Ugrás:

hlmod.hu

[ZP] Sawn-Off Shotgun

Ki van itt