hlmod.hu ::Weaponbox modellek HLDMből

hlmod.hu https://hlmod.hu/

Weaponbox modellek HLDMből https://hlmod.hu/viewtopic.php?f=101&t=11833	Oldal: 1 / 1

Szerző:

kiki [2013.11.14. 13:58 ]

Hozzászólás témája:

Weaponbox modellek HLDMből

Plugin Neve:	Weaponbox modellek HLDMből	Plugint készitette:	KORD_12.7
Játék:	Half-Life	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

Támogatott játékok:
HLDM / HLTDM / AG mini - (valve)
Adrenaline Gamer - (ag)
Opposing Force - (gearbox)

Szükséges modulok:
Fakemeta
HamSandWich

Leírás:
A plugin lecseréli a weaponbox modelt, az adott fegyver w_ modelljére, így a földön az lesz látható.

Változók (cvarok):
wpnbox_models "1" (1 - plugin bekapcsolása, 0 - plugin kikapcsolása)
wpnbox_render "1" (1 - burok engedélyezése, 0 - burok tiltása)
wpnbox_render_color "random vagy rgb szín" - burok színe (alap random)

Kép:
Kép

Egyéb:
Készítő: KORD_12.7
Eredeti link: http://forums.alliedmods.net/showthread.php?t=117916

#include <amxmodx>
#include <fakemeta_util>
#include <hamsandwich>

#define PLUGIN "Weaponbox Models for HLDM"
#define VERSION "0.4"
#define AUTHOR "KORD_12.7"

#define IsPlayer(%1)  (1 <= %1 <= g_MaxPlayers)

#define HLW_DISPLACER	20
#define HLW_KNIFE	25

new 
g_CvarEnable,
g_CvarRendEnable,
g_CvarRendColor, 
g_CvarRendMode,
g_MaxPlayers,
g_XV11382,
g_RGB[3]

new const g_wpn_models[][] = 
{
	"models/w_weaponbox.mdl",
	"models/w_crowbar.mdl",
	"models/w_9mmhandgun.mdl",
	"models/w_357.mdl",
	"models/w_9mmAR.mdl",
	"models/w_weaponbox.mdl",
	"models/w_crossbow.mdl",
	"models/w_shotgun.mdl",
	"models/w_rpg.mdl",
	"models/w_gauss.mdl",
	"models/w_egon.mdl",
	"models/w_hgun.mdl",
	"models/w_grenade.mdl",
	"models/v_tripmine.mdl",
	"models/w_satchel.mdl",
	"models/w_sqknest.mdl",
	"models/w_bgrap.mdl",
	"models/w_desert_eagle.mdl",
	"models/w_pipe_wrench.mdl",
	"models/w_saw.mdl",
	"models/w_displacer.mdl",
	"models/w_weaponbox.mdl",
	"models/w_shock_rifle.mdl",
	"models/w_spore_launcher.mdl",
	"models/w_m40a1.mdl",
	"models/w_knife.mdl"
}

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_cvar("wpnbox_version", VERSION, FCVAR_SPONLY | FCVAR_SERVER | FCVAR_UNLOGGED)
	
	RegisterHam(Ham_Spawn, "weaponbox", "fw_WpnboxSpawnPost", 1)
	
	g_CvarEnable = register_cvar("wpnbox_models", "1")
	g_CvarRendEnable = register_cvar("wpnbox_render", "1")
	g_CvarRendColor = register_cvar("wpnbox_render_color", "random")
	
	g_MaxPlayers = get_maxplayers()
}

public plugin_cfg()
{
	new color[32]
	get_pcvar_string(g_CvarRendColor, color, charsmax(color))
	trim(color)
	
	if (equali(color, "random"))
		g_CvarRendMode = 0
	else
	{
		new r[4], g[4], b[4]
		parse(color, r, charsmax(r), g, charsmax(g), b, charsmax(b))
		
		g_RGB[0] = str_to_num(r)
		g_RGB[1] = str_to_num(g)
		g_RGB[2] = str_to_num(b)
		
		g_CvarRendMode = 1
	}
	
	if (get_cvar_pointer("displacer_version"))
		g_XV11382 = 1
}

public fw_WpnboxSpawnPost(ent)
{
	if (get_pcvar_num(g_CvarEnable) && pev_valid(ent))
	{
		new id = pev(ent, pev_owner)
		
		if (IsPlayer(id))
		{
			new wpn_id = get_user_weapon(id)
			
			if (g_XV11382 && wpn_id == HLW_EGON)
				wpn_id = HLW_DISPLACER
			
			if (HLW_CROWBAR <= wpn_id <= HLW_KNIFE)
			{
				engfunc(EngFunc_SetModel, ent, g_wpn_models[wpn_id])
	
				if (wpn_id == HLW_TRIPMINE)
				{
					set_pev(ent, pev_body, 3)
					set_pev(ent, pev_sequence, 8)
				}
				
				if (get_pcvar_num(g_CvarRendEnable))
				{
					switch(g_CvarRendMode)
					{
						case 1: fm_set_rendering(ent, kRenderFxGlowShell, g_RGB[0], g_RGB[1], g_RGB[2], kRenderNormal, 16)
						case 0: fm_set_rendering(ent, kRenderFxGlowShell, random_num(1, 255), random_num(1, 255), random_num(1, 255), kRenderNormal, 16)
					}
				}
			}
		}
	}
	
	return HAM_IGNORED
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/