hlmod.hu :: HE gránát felrobbant gránátokat

hlmod.hu https://hlmod.hu/

HE gránát felrobbant gránátokat https://hlmod.hu/viewtopic.php?f=101&t=11845	Oldal: 1 / 1

Szerző:

IrOn [ 2013.11.14. 22:36 ]

Hozzászólás témája:

HE gránát felrobbant gránátokat

Plugin Neve:	HE gránát felrobbant gránátokat	Plugint készitette:	beast
Játék:	Counter-Strike	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

Plugin verzió: 1.0
Készítő: BeasT

Leírás:
Ha egy HE gránát felrobban a közelében repülő gránátok is felrobbannak.

Videó:
[ablak][youtube]VG96m52Ffkg[/youtube][/ablak]

Cvarok:

Kód:

hdg_affect_radius          // Mennyi legyen a robbanás sugara, ahol felrobbanjon a többi gránát is. Alap: 350.
hdg_survival_chance      // Mennyi legyen az esély, hogy ne robbanjon fel a gránát a közelben. Alap 3(%). Tedd 0-ra, hogy ki legyen kapcsolva.

#include <amxmodx>
#include <fakemeta>
#include <engine>

#define FL_EXPLODED		FL_IMMUNE_SLIME

#define m_usEvent		114
#define XO_WEAPON		4

#define HEGRENADE		(1<<0)
#define SMOKENADE		(1<<1)

new cvar_AffectRadius, cvar_SurvivalChance

public plugin_init()
{
	register_plugin("HEs destroy grenades", "1.0", "beast")
	
	register_think("grenade", "ThinkGrenade")
	
	cvar_AffectRadius = register_cvar("hdg_affect_radius", "350")
	cvar_SurvivalChance = register_cvar("hdg_survival_chance", "3")
}

public ThinkGrenade(he)
{
	// ent not valid or not a HE
	if(!pev_valid(he) || ~get_pdata_int(he, m_usEvent, XO_WEAPON) & HEGRENADE)
		return PLUGIN_CONTINUE
		
	static flags
	
	flags = pev(he, pev_flags)
	
	// grenade has exploded
	if(flags & FL_EXPLODED)
		return PLUGIN_CONTINUE
	
	static Float:dmgTime
	
	pev(he, pev_dmgtime, dmgTime)
	
	// not ready to explode yet
	if(dmgTime > get_gametime())
		return PLUGIN_CONTINUE
	
	// marking the grenade as exploded 
	set_pev(he, pev_flags, flags | FL_EXPLODED)
	
	static nearbyNades[32], count, nearbyNade, Float:affectRadius, survivalChance, 
	Float:originHe[3], Float:originNearbyNade[3]
	
	affectRadius = get_pcvar_float(cvar_AffectRadius)
	survivalChance = get_pcvar_num(cvar_SurvivalChance)
	
	pev(he, pev_origin, originHe)
	
	// finding nearby grenades
	count = find_sphere_class(he, "grenade", affectRadius, nearbyNades, charsmax(nearbyNades))

for(new i = 0; i < count; i++)
	{
		nearbyNade = nearbyNades[i]
		
		if(nearbyNade == he)
			continue

if(survivalChance)
		{
			pev(nearbyNade, pev_origin, originNearbyNade)
			
			// grenade has a chance to survive
			if(random_float(0.0, 100.0) <= survivalChance + // some distance randomness
			get_distance_f(originHe, originNearbyNade) * random_float(0.0, 5.0) / affectRadius)
				continue
		}
		
		// detonating he and flashbang
		set_pev(nearbyNade, pev_dmgtime, 0.0)

// detonating smokenade
		if(get_pdata_int(nearbyNade, m_usEvent, XO_WEAPON) & SMOKENADE)
		{
			set_pev(nearbyNade, pev_flags, pev(nearbyNade, pev_flags) | FL_ONGROUND)
			dllfunc(DLLFunc_Think, nearbyNade)
		}
	}
	
	return PLUGIN_CONTINUE
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1063\\ f0\\ fs16 \n\\ par }
*/

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	davke1 [ 2013.11.15. 07:32 ]
Hozzászólás témája:	Re: HE gránát felrobbant gránátokat \| Mind \| Szórakoztató
A játékot cs-re tenném. Tudtommal csak abban vannak ilyen gránátok.

Szerző:	IrOn [ 2013.11.15. 08:03 ]
Hozzászólás témája:	Re: HE gránát felrobbant gránátokat \| Mind \| Szórakoztató
davke1 írta: A játékot cs-re tenném. Tudtommal csak abban vannak ilyen gránátok. elvileg elfut a többi játékban is, bár nem néztem, de nem szükséges hozzá cstrike modul, így elvileg kell mennie attól függ, a többi játékban milyen neve van a gránát entitynek, de szerintem ugyan úgy grenade mint itt

Szerző:	kiki [ 2013.11.15. 13:43 ]
Hozzászólás témája:	Re: HE gránát felrobbant gránátokat \| Mind \| Szórakoztató
Csak CZbe és CSbe van, valamelyik játékba fegyver sincs

Szerző:	theglorious [ 2013.11.15. 20:36 ]
Hozzászólás témája:	Re: HE gránát felrobbant gránátokat \| Counter-Strike \| Szórakoztató
csak én nem tudom letőlteni? Vagy valamit elnéztem?

Szerző:	IrOn [ 2013.11.15. 21:08 ]
Hozzászólás témája:	Re: HE gránát felrobbant gránátokat \| Counter-Strike \| Szórakoztató
theglorious írta: csak én nem tudom letőlteni? Vagy valamit elnéztem? nekem letölti

Szerző:	theglorious [ 2013.11.15. 21:39 ]
Hozzászólás témája:	Re: HE gránát felrobbant gránátokat \| Counter-Strike \| Szórakoztató
IrOn123 írta: theglorious írta: csak én nem tudom letőlteni? Vagy valamit elnéztem? nekem letölti Mobil ról ki se rakja az sma-t :s csak néha Nálam lehet a gond!

Szerző:	davke1 [ 2013.11.16. 07:20 ]
Hozzászólás témája:	Re: HE gránát felrobbant gránátokat \| Counter-Strike \| Szórakoztató
Ne a letöltésre menj, hanem a megtekintésre.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/