hlmod.hu :: Nézô Lista

hlmod.hu https://hlmod.hu/

Nézô Lista https://hlmod.hu/viewtopic.php?f=101&t=12020	Oldal: 1 / 2

Szerző:

CheeseDave [ 2008.03.02. 23:00 ]

Hozzászólás témája:

Nézô Lista

Plugin Neve:	Nézô Lista	Plugint készitette:	FatalisDK
Játék:	Mind	Kategória:	Statisztikai
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

Kiírja a jobb felsô sarokba hogy ki néz téged.

#include <amxmodx>
#include <fakemeta>

#pragma semicolon 1

#define RED 64
#define GREEN 64
#define BLUE 64
#define UPDATEINTERVAL 1.0

// Comment below if you do not want /speclist showing up on chat
#define ECHOCMD

// Admin flag used for immunity
#define FLAG ADMIN_KICK

new const PLUGIN[] = "SpecList";
new const VERSION[] = "1.2";
new const AUTHOR[] = "FatalisDK";

new gMaxPlayers;
new gCvarOn;
new gCvarImmunity;
new bool:gOnOff[33] = { true, ... };

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	
	register_cvar(PLUGIN, VERSION, FCVAR_SERVER, 0.0);
	gCvarOn = register_cvar("amx_speclist", "1", 0, 0.0);
	gCvarImmunity = register_cvar("amx_speclist_immunity", "1", 0, 0.0);
	
	register_clcmd("say /speclist", "cmdSpecList", -1, "");
	
	gMaxPlayers = get_maxplayers();
	
	set_task(UPDATEINTERVAL, "tskShowSpec", 123094, "", 0, "b", 0);
}

public cmdSpecList(id)
{
	if( gOnOff[id] )
	{
		client_print(id, print_chat, "[AMXX] Mostmar nem fogod latni ki nez teged.");
		gOnOff[id] = false;
	}
	else
	{
		client_print(id, print_chat, "[AMXX] Mostmar latni fogod ki nez teged.");
		gOnOff[id] = true;
	}
	
	#if defined ECHOCMD
	return PLUGIN_CONTINUE;
	#else
	return PLUGIN_HANDLED;
	#endif
}

public tskShowSpec()
{
	if( !get_pcvar_num(gCvarOn) )
	{
		return PLUGIN_CONTINUE;
	}
	
	static szHud[1102];//32*33+45
	static szName[34];
	static bool:send;
	
	// FRUITLOOOOOOOOOOOOPS!
	for( new alive = 1; alive <= gMaxPlayers; alive++ )
	{
		new bool:sendTo[33];
		send = false;
		
		if( !is_user_alive(alive) )
		{
			continue;
		}
		
		sendTo[alive] = true;
		
		get_user_name(alive, szName, 32);
		format(szHud, 45, "%s nezoi:^n", szName);
		
		for( new dead = 1; dead <= gMaxPlayers; dead++ )
		{
			if( is_user_connected(dead) )
			{
				if( is_user_alive(dead)
				|| is_user_bot(dead) )
				{
					continue;
				}
				
				if( pev(dead, pev_iuser2) == alive )
				{
					if( !(get_pcvar_num(gCvarImmunity)&&get_user_flags(dead, 0)&FLAG) )
					{
						get_user_name(dead, szName, 32);
						add(szName, 33, "^n", 0);
						add(szHud, 1101, szName, 0);
						send = true;
					}

sendTo[dead] = true;
					
				}
			}
		}
		
		if( send == true )
		{
			for( new i = 1; i <= gMaxPlayers; i++ )
			{
				if( sendTo[i] == true
				&& gOnOff[i] == true )
				{
					set_hudmessage(RED, GREEN, BLUE,
						0.75, 0.12, 0, 0.0, 1.1, 0.0, 0.0, 1);
					
					show_hudmessage(i, szHud);
				}
			}
		}
	}
	
	return PLUGIN_CONTINUE;
}

public client_connect(id)
{
	gOnOff[id] = true;
}

public client_disconnect(id)
{
	gOnOff[id] = true;
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	Jostyi [ 2013.03.04. 19:10 ]
Hozzászólás témája:	Re: Nézô Lista \| Mind \| Statisztikai
Dave tudnál nekem segíteni plugint szerkeszteni?

Szerző:	Silent [ 2013.03.05. 15:04 ]
Hozzászólás témája:	Re: Nézô Lista \| Mind \| Statisztikai
www.hlmod.hu

Szerző:	DeR0iD [ 2014.01.20. 19:22 ]
Hozzászólás témája:	Re: Nézô Lista
színeket berakom randomba nagyon tutkon néznek ki:D

Szerző:	norbee.16 [ 2014.01.20. 19:27 ]
Hozzászólás témája:	Re: Nézô Lista
Értjük! De ezt legközelebb ne ide írd mert olyan off felé szaga van :S

Szerző:	Beckx [ 2014.01.20. 19:43 ]
Hozzászólás témája:	Re: Nézô Lista
Valaki nem segít hogy lehet színezni?:o

Szerző:	norbee.16 [ 2014.01.20. 19:47 ]
Hozzászólás témája:	Re: Nézô Lista
Beckx írta: Valaki nem segít hogy lehet színezni?:o SMA Forráskód: [ Mindet kijelol ] 121. set_hudmessage(RED, GREEN, BLUE, 122. piros, zöld, kék, 0.0, 1.1, 0.0, 0.0, 1 Ahol vannak a színek írva ott állíthaó a szín [255-ig]

Szerző:	Beckx [ 2014.01.20. 19:48 ]
Hozzászólás témája:	Re: Nézô Lista
és az nem lehet hogy folyamatosan váltogat minden szint?

Szerző:	*GrafitY* [ 2016.07.18. 18:57 ]
Hozzászólás témája:	Re: Nézô Lista
norbee.16 írta: Beckx írta: Valaki nem segít hogy lehet színezni?:o [sma] 121. set_hudmessage(RED, GREEN, BLUE, 122. piros, zöld, kék, 0.0, 1.1, 0.0, 0.0, 1[/sma] Ahol vannak a színek írva ott állíthaó a szín [255-ig] Az előző hozzászólás szerűen kellene nekem is..azt hogy lehet? Leírná valaki a forráskódot?

Szerző:	norbee.16 [ 2016.07.18. 19:00 ]
Hozzászólás témája:	Re: Nézô Lista
Új téma pls. Sma-t csatold easy feladat.

Oldal: 1 / 2	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/