hlmod.hu ::Lődd ki a gránátot

hlmod.hu https://hlmod.hu/

Lődd ki a gránátot https://hlmod.hu/viewtopic.php?f=101&t=12057	Oldal: 1 / 1

Szerző:

bliq [2010.12.10. 23:48 ]

Hozzászólás témája:

Lődd ki a gránátot

Plugin Neve:	Lődd ki a gránátot	Plugint készitette:	joaquimandrade
Játék:	Counter-Strike	Kategória:	Technikai/Fejlesztő
Eredeti link:	Nincs megadva	Jóváhagyó:	kiki

Egy érdekes plugin, és egyúttal mondhatom realisztikusnak is.
Bármelyik gránátra rálősz + a c4re is az felrobban (módját megtartva)

Cvar:

shoot_c4 0 - ki , 1 - ct nem tudja kilőni 2 - t ki tudja lőni
shoot_smoke 0 - ki , 1 - be
shoot_flash 0 - ki , 1 - be
shoot_he 0 - ki , 1 - be
shoot_c4 0 - ki , 1 - be

Kellemes játékot.

#include <amxmodx>

#include <fakemeta>
#include <engine>
#include <hamsandwich>

#include <cstrike>

#include <xs>

new const Plugin[] = "Shoot Grenades"
new const Author[] = "joaquimandrade"
new const Version[] = "1.1"

enum Grenade
{
	Flashbang,
	He,
	Smoke,
	C4
}

new Cvars[Grenade]

new CvarsNames[Grenade][] =
{
	"flash",
	"he",
	"smoke",
	"c4"
}

// Arkshine
const m_flC4Blow = 100

new Trie:RegisteredClasses

public plugin_precache()
{
	RegisteredClasses = TrieCreate()
	
	register_forward(FM_Spawn,"spawn")
}

public spawn(id)
{
	if(pev_valid(id))
	{
		static classname[32]
		pev(id,pev_classname,classname,charsmax(classname))
		
		if(!TrieKeyExists(RegisteredClasses,classname))
		{
			RegisterHam(Ham_TraceAttack,classname,"globalTraceAttack")
			TrieSetCell(RegisteredClasses,classname,true)
		}
	}
}

public plugin_init()
{
	register_plugin(Plugin,Version,Author)
	
	RegisterHam(Ham_TraceAttack,"worldspawn","globalTraceAttack")
	RegisterHam(Ham_TraceAttack,"player","globalTraceAttack")
	
	register_cvar("shootGrenades_version",Version,FCVAR_SERVER|FCVAR_SPONLY)
}

public plugin_cfg()
{
	new cvarName[15]
	
	for(new Grenade:i=Grenade:0;i<Grenade;i++)
	{
		formatex(cvarName,charsmax(cvarName),"shoot_%s",CvarsNames[i])
		Cvars[i] = register_cvar(cvarName,"1")
	}		
}

public globalTraceAttack(this,attackerID,Float:damage,Float:direction[3],tracehandle,damagebits)
{
	if(1 <= attackerID <= 32)
	{
		static Float:origin[3]
		pev(attackerID,pev_origin,origin)
		
		static Float:viewOfs[3]
		pev(attackerID,pev_view_ofs,viewOfs)
		
		xs_vec_add(origin,viewOfs,origin)
		
		static Float:end[3]
		get_tr2(tracehandle,TR_vecEndPos,end)
		
		new trace = create_tr2()
		
		new grenade = -1
		
		while((grenade = find_ent_by_class(grenade,"grenade")))
		{
			engfunc(EngFunc_TraceModel,origin,end,HULL_POINT,grenade,trace)
			
			if(get_tr2(trace,TR_pHit) == grenade)
			{
				new Grenade:id = fm_cs_get_grenade_type_myid(grenade)
				
				if(id == C4)
				{
					new cvarValue = get_pcvar_num(Cvars[C4])
						
					if((cvarValue == 2) || (cvarValue && (cs_get_user_team(attackerID) == CS_TEAM_CT)))
					{
						set_pdata_float(grenade,m_flC4Blow,0.0)
						dllfunc(DLLFunc_Think,grenade)
					}
				}
				else
				{
					if(get_pcvar_num(Cvars[id]))
					{
						if(id == Smoke)
							set_pev(grenade,pev_flags,pev(grenade,pev_flags) | FL_ONGROUND)
						
						// Connor
						set_pev(grenade,pev_dmgtime,0.0)
						dllfunc(DLLFunc_Think,grenade)
					}
				}
			}
		}
		
		free_tr2(trace)
	}
}

// VEN
Grenade:fm_cs_get_grenade_type_myid(index) 
{
	if(get_pdata_int(index, 96) & (1<<8))
	{
		return C4
	}	
	
	return Grenade:(get_pdata_int(index, 114) & 3)
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	sajt97 [2011.04.07. 18:07 ]
Hozzászólás témája:	Re: Lődd ki a gránátot \| Mind \| Ismeretlen
Hello! Nemrég foglalkozom amx-el hogy kell feltenni a játékba? A plugins mappába beraktam az amxx et a scripting be az smat, aztán a plugins inibe beirtam a nevét a pluginnak amxx-el elinditom a játékot de vmiért nem mükszik mi a baj? Help

Szerző:	suN.sh!n3 [2011.06.18. 16:58 ]
Hozzászólás témája:	Re: Lődd ki a gránátot \| Mind \| Ismeretlen
Nem tom nekem se megy.. -.-

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/