hlmod.hu ::Valódi Élet kijelző

hlmod.hu https://hlmod.hu/

Valódi Élet kijelző https://hlmod.hu/viewtopic.php?f=101&t=12153	Oldal: 1 / 1

Szerző:

Gosser [2010.05.30. 07:36 ]

Hozzászólás témája:

Valódi Élet kijelző

Plugin Neve:	Valódi Élet kijelző	Plugint készitette:	Exolent
Játék:	Counter-Strike	Kategória:	Általános célú
Eredeti link:	Nincs megadva	Jóváhagyó:	kiki

GosseR - gosser@luxhosting.hu

Ez a plugin inkább kz/surf/zm , de pub/fun szervereken is ajánlatos.

A plugin magában annyit tesz hogyha beirjuk a chatba hogy :
/health akkor megjeleníti nekünk fehér számokkal a valódi életünket.
Persze ennek így nincs nagy értelme , de kaptunk hozzá effekteket.

Screenshot:
http://img443.imageshack.us/img443/229/ ... 000mi6.png

Parancsok:[Cvarok]
health_on ~ alap:1 ~ a plugin ki/be kapcsolása.
health_time ~ alap:15 ~ hogy meddig jelezze ki az adott ember életét.
health_color ~ alap:1 ~ a szöveg szine(a következö parancsnál állitható)
health_custom ~ RRGGBB ~ szinekben állítható.
health_effects ~ alap:1 ~ 0-nicns effekt 1-van effekt,szöveg 2-nincs szöveg.
health_always ~alap:1 1:mindig mutassa az életet. 2.csak akkor mutassa az életet ha az megváltozik.

Szerintem ennyi lenne

A felrakás a megszokott módon :]~

#include <amxmodx>
#include <amxmisc>

#define PLUGIN_NAME	"Health Display"
#define PLUGIN_VERSION	"11.1"
#define PLUGIN_AUTHOR	"Exolent"

#pragma semicolon 1

new bool:g_player_didnt_spawn[33];

new health_on;
new health_time;
new health_color;
new health_custom;
new health_effects;
new health_always;

public plugin_init()
{
	register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR);
	register_cvar("health_display", PLUGIN_VERSION, FCVAR_SPONLY);
	
	register_clcmd("say /health", "CmdHealth");
	register_clcmd("say_team /health", "CmdHealth");
	register_clcmd("fullupdate", "CmdFullupdate");
	
	register_event("Health", "EventHealth", "be", "1>0");
	register_event("ResetHUD", "EventResetHud", "be");
	register_event("TextMsg", "EventRestartAttempt", "a", "2&#Game_w");
	register_event("DeathMsg", "EventDeathMsg", "a");
	
	health_on = register_cvar("health_on", "1");
	health_time = register_cvar("health_time", "12");
	health_color = register_cvar("health_color", "1");
	health_custom = register_cvar("health_custom", "255 255 0");
	health_effects = register_cvar("health_effects", "1");
	health_always = register_cvar("health_always", "0");
}

public client_disconnect(client)
{
	remove_task(client);
}

public CmdHealth(client)
{
	if( !get_pcvar_num(health_on) )
	{
		client_print(client, print_chat, "Az �let kijelz� most nem l�that�.");
	}
	else if( is_user_alive(client) )
	{
		ShowHealth(client);
	}
	
	return PLUGIN_HANDLED;
}

public CmdFullupdate(client)
{
	return PLUGIN_HANDLED_MAIN;
}

public EventHealth(client)
{
	if( get_pcvar_num(health_on) )
	{
		ShowHealth(client);
	}
}

public EventResetHud(client)
{
	if( g_player_didnt_spawn[client] )
	{
		g_player_didnt_spawn[client] = false;
	}
	else if( is_user_alive(client) && get_pcvar_num(health_always) )
	{
		set_task(0.1, "ShowHealth", client);
	}
}

public EventRestartAttempt()
{
	new players[32], pnum;
	get_players(players, pnum, "a");
	
	for( new i = 0; i < pnum; i++ )
	{
		g_player_didnt_spawn[players[i]] = true;
	}
}

public EventDeathMsg()
{
	new client = read_data(2);
	
	remove_task(client);
	
	set_hudmessage(_, _, _, _, _, _, _, _, _, _, 3);
	show_hudmessage(client, "");
}

public ShowHealth(client)
{
	remove_task(client);
	
	new hud_red, hud_green, hud_blue;
	switch( get_pcvar_num(health_color) )
	{
		case 0:
		{
			hud_red = 255;
			hud_green = 255;
			hud_blue = 255;
		}
		case 1:
		{
			new color[16], red[4], green[4], blue[4];
			get_pcvar_string(health_custom, color, 15);
			parse(color, red, 3, green, 3, blue, 3);
			
			hud_red = str_to_num(red);
			hud_green = str_to_num(green);
			hud_blue = str_to_num(blue);
		}
		case 2:
		{
			hud_red = random(256);
			hud_green = random(256);
			hud_blue = random(256);
		}
	}
	
	new Float:hud_time = get_pcvar_float(health_time);
	
	set_hudmessage(hud_red, hud_green, hud_blue, -1.0, 0.9, get_pcvar_num(health_effects), hud_time, hud_time, 0.1, 0.2, 3);
	show_hudmessage(client, "Health: %i", get_user_health(client));
	
	if( get_pcvar_num(health_always) )
	{
		set_task(hud_time - 0.1, "ShowHealth", client);
	}
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	Silverss [2010.05.30. 10:24 ]
Hozzászólás témája:	Re: Valódi Élet kijelző \| Mind \| Ismeretlen
Screenshot?

Szerző:	CheeseDave [2010.05.30. 11:33 ]
Hozzászólás témája:	Re: Valódi Élet kijelző \| Mind \| Ismeretlen
Ott van, nem? http://img443.imageshack.us/img443/229/surfjourney0000mi6.png

Szerző:	Gosser [2010.05.30. 12:13 ]
Hozzászólás témája:	Re: Valódi Élet kijelző \| Mind \| Ismeretlen
Silverss kedvedért kiirom hogy screenshot :)

Szerző:	buster [2010.05.30. 13:14 ]
Hozzászólás témája:	Re: Valódi Élet kijelző \| Mind \| Ismeretlen
Ez hasznos plugin még zombie módban, mivel ott sem jelzi ki épp mindig hogy hány hp-d van...

Szerző:	Gosser [2010.05.30. 13:48 ]
Hozzászólás témája:	Re: Valódi Élet kijelző \| Mind \| Ismeretlen
tudom :) de amugy odairtam hogy zm :]

Szerző:	KeXxX [2010.05.30. 14:11 ]
Hozzászólás témája:	Re: Valódi Élet kijelző \| Mind \| Ismeretlen
Jó kis plugin

Szerző:	Gosser [2010.05.30. 14:58 ]
Hozzászólás témája:	Re: Valódi Élet kijelző \| Mind \| Ismeretlen
szerintemis.xP

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/