hlmod.hu ::Bomba Csík

hlmod.hu https://hlmod.hu/

Bomba Csík https://hlmod.hu/viewtopic.php?f=101&t=12299	Oldal: 1 / 1

Szerző:

kiki [2011.08.23. 13:31 ]

Hozzászólás témája:

Bomba Csík

Plugin Neve:	Bomba Csík	Plugint készitette:	K.K.Lv
Játék:	Counter-Strike	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

A bomba lerakása után a bomba körül vonalak jelennek meg, ezt sem tudom jól elmagyarázni ezért mutatok egy képet!
Pic: http://www.dt-club.net/forum/attachment ... fa5836.jpg

Cvarok:
bb_color "250250250" RRRGGGBBB - a körvonal szine!

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN "Bomb Blast"
#define VERSION "0.4"
#define AUTHOR "K.K.Lv"

new HamHook:g_BombThink

new g_Bomb

new g_SpriteCircle

new Float:g_fExplodeTime
new Float:g_fNextBlastGameTime

new g_pCvarColor

public plugin_precache()
{
	g_SpriteCircle = precache_model( "sprites/shockwave.spr" )
}

public plugin_init()
{
	register_plugin( PLUGIN, VERSION, AUTHOR )
	
	g_pCvarColor = register_cvar( "bb_color", "250250250" )	//RRRGGGBBB
	
	if( find_ent_by_class( FM_NULLENT, "func_bomb_target" ) || find_ent_by_class( FM_NULLENT, "info_bomb_target" ) )
	{
		g_BombThink = RegisterHam( Ham_Think, "grenade", "Bomb_Think", 1 )
		
		register_event( "HLTV", "Stop", "a", "1=0", "2=0" )
		register_logevent( "Stop", 2, "1=Round_End" )
		
		register_logevent( "PlantedBomb", 3, "2=Planted_The_Bomb" )
	}
}

public Stop()
{
	g_Bomb = 0
	DisableHamForward( g_BombThink)
}

public PlantedBomb()
{
	new C4 = FM_NULLENT
	while( ( C4 = find_ent_by_class( C4, "grenade" ) ) )
	{
		if ( get_pdata_int( C4, 96 ) & ( 1<<8 ) )
		{
			g_Bomb = C4
			g_fExplodeTime = get_pdata_float( g_Bomb, 100 )
			EnableHamForward( g_BombThink )
			
			g_fNextBlastGameTime = 0.0
			break 
		}
	}
}

public Bomb_Think( iEnt )
{
	if ( g_Bomb != iEnt )
		return
	
	new Float:fGameTime = get_gametime()
	if( g_fNextBlastGameTime > fGameTime )
		return
	
	new Float:fTime, iTime, Float:fThinkTime
	
	fTime = g_fExplodeTime - fGameTime
	iTime = floatround( fTime )
	
	if ( iTime > 13 ) fThinkTime = 1.0
	else if ( iTime > 7 ) fThinkTime = 0.5
	else  fThinkTime = 0.3
	
	g_fNextBlastGameTime = fGameTime + fThinkTime
	
	create_blast_circle( iEnt )
}

public create_blast_circle( iEnt ) {
	new Float:fOrigin[ 3 ]
	
	pev( iEnt, pev_origin, fOrigin )
	
	new szColor[ 12 ], iColor[ 3 ]
	get_pcvar_string( g_pCvarColor, szColor, charsmax( szColor ) )
	
	iColor[ 2 ] = str_to_num( szColor[ 6 ] )
	
	szColor[ 6 ] = 0
	iColor[ 1 ] = str_to_num( szColor[ 3 ] )
	
	szColor[ 3 ] = 0
	iColor[ 0 ] = str_to_num( szColor[ 0 ] )
	
	engfunc( EngFunc_MessageBegin, MSG_BROADCAST, SVC_TEMPENTITY, fOrigin )
	write_byte( TE_BEAMCYLINDER )
	engfunc( EngFunc_WriteCoord, fOrigin[ 0 ] )
	engfunc( EngFunc_WriteCoord, fOrigin[ 1 ] )
	engfunc( EngFunc_WriteCoord, fOrigin[ 2 ] )
	engfunc( EngFunc_WriteCoord, fOrigin[ 0 ] )
	engfunc( EngFunc_WriteCoord, fOrigin[ 1 ] )
	engfunc( EngFunc_WriteCoord, fOrigin[ 2 ] + 125 )
	write_short( g_SpriteCircle )
	write_byte( 0 )
	write_byte( 1 )
	write_byte( 6 )
	write_byte( 8 )
	write_byte( 1 )
	write_byte( iColor[ 0 ] )
	write_byte( iColor[ 1 ] )
	write_byte( iColor[ 2 ] )
	write_byte( 128 )
	write_byte( 5 )
	message_end()
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	kiki [2011.08.24. 12:40 ]
Hozzászólás témája:	Re: Bomba Csík \| Mind \| Szórakoztató
1; Eéőzőnél nincs róla kép! 2; Előzőnek a leírásában nem találom a cvart. vagyis az mehet hibásnak-,-

Szerző:	kiki [2011.08.24. 12:41 ]
Hozzászólás témája:	Re: Bomba Csík \| Mind \| Szórakoztató
De amugy most nézem-,-,-,-,-,-,- Elöbb nézd meg a forráskódot utána mondjad hogy ugyan aze e vagy nem-,-,-,-,-,-,--,

Szerző:	kiki [2011.08.24. 12:44 ]
Hozzászólás témája:	Re: Bomba Csík \| Mind \| Szórakoztató
1; Az amit linkeltél az 0.1es verzió-,- 2; Az említett linkednél hiányos a leírás! ÉS ajánlom allieden a changelog olvasását-,-

Szerző:	winniestyle [2011.08.24. 14:08 ]
Hozzászólás témája:	Re: Bomba Csík \| Mind \| Szórakoztató
rég felraktam

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/