hlmod.hu :: Mikulás Sapka [2mdl]

hlmod.hu https://hlmod.hu/

Mikulás Sapka [2mdl] https://hlmod.hu/viewtopic.php?f=101&t=12353	Oldal: 1 / 1

Szerző:

kiki [ 2011.12.12. 15:16 ]

Hozzászólás témája:

Mikulás Sapka [2mdl]

Plugin Neve:	Mikulás Sapka [2mdl]	Plugint készitette:	xPaw
Játék:	Counter-Strike	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

A script mikulás sapkát ad mindenkinek! 2model van hozzá, 1piros és 1 kék sapka, szóval csapat színek szerint!

Cvar Nincs!

A zipben csak a modellek vannak benne!

#include < amxmodx >
#include < engine >
#include < cstrike >
#include < hamsandwich >

new const g_szHatModel[ CsTeams ][ ] = {
    "",
    "models/santahat.mdl",
    "models/santahat_blue.mdl",
    ""
};

new g_iHats[ 33 ];

public plugin_init( ) {
    register_plugin( "Team Santa Hat", "1.3", "xPaw" );
    
    register_cvar( "santa_hat", "1.3", FCVAR_SERVER );
    
    register_event( "TeamInfo", "EventTeamInfo", "a" );
    
    RegisterHam( Ham_Spawn, "player", "FwdHamPlayerSpawn", 1 );
}

public plugin_precache( ) {
    
    precache_model( g_szHatModel[ CS_TEAM_T ] );
    precache_model( g_szHatModel[ CS_TEAM_CT ] );
}

public client_disconnect( id )
    if( is_valid_ent( g_iHats[ id ] ) )
        remove_entity( g_iHats[ id ] );

public FwdHamPlayerSpawn( const id ) {
    if( is_user_alive( id ) ) {
        new iEntity = g_iHats[ id ];
        
        if( !is_valid_ent( iEntity ) ) {
            if( !( iEntity = g_iHats[ id ] = create_entity( "info_target" ) ) )
                return;
            
            new CsTeams:iTeam = cs_get_user_team( id );
            
            if( iTeam != CS_TEAM_T && iTeam != CS_TEAM_CT )
                iTeam = CS_TEAM_T;
            
            entity_set_model( iEntity, g_szHatModel[ iTeam ] );
            entity_set_int( iEntity, EV_INT_movetype, MOVETYPE_FOLLOW );
            entity_set_edict( iEntity, EV_ENT_aiment, id );
        }
    }
}

public EventTeamInfo( ) {
    new id = read_data( 1 ), iEntity = g_iHats[ id ];
    
    if( !is_valid_ent( iEntity ) ) {
        if( iEntity > 0 )
            g_iHats[ id ] = 0;
        
        return;
    }
    
    new szTeam[ 2 ];
    read_data( 2, szTeam, 1 );
    
    if( szTeam[ 0 ] == 'C' )
        entity_set_model( iEntity, g_szHatModel[ CS_TEAM_CT ] );
    else
        entity_set_model( iEntity, g_szHatModel[ CS_TEAM_T ] );
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

Szerző:	rericsi8 [ 2011.12.12. 16:45 ]
Hozzászólás témája:	Re: Mikulás Sapka [2mdl] \| Mind \| Szórakoztató
ezt kerestem :DD

Szerző:	GhostRyder [ 2011.12.20. 14:17 ]
Hozzászólás témája:	Re: Mikulás Sapka [2mdl] \| Mind \| Szórakoztató
Nagyon menő plugin ...:D xD

Szerző:	koCFG [ 2012.11.24. 20:14 ]
Hozzászólás témája:	Re: Mikulás Sapka [2mdl] \| Mind \| Szórakoztató
zsir

Szerző:	kiki [ 2013.11.25. 06:56 ]
Hozzászólás témája:	Re: Mikulás Sapka [2mdl] \| Mind \| Szórakoztató
Wrong játék, csak csénél fut el a cstrike modul. SMA Forráskód: [ Mindet kijelol ] #include < cstrike > Jóváhagyók figyeljenek. Fixed

Szerző:	david-kill [ 2013.11.27. 17:49 ]
Hozzászólás témája:	Re: Mikulás Sapka [2mdl] \| Counter-Strike \| Szórakoztató
Ez nem olyan bugos mint a 1 mdl-es?Mert az 1 modelles nekem késen nagyon bugos volt.. Ha nem bugos akkor köszi kiki a feltöltést

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/