hlmod.hu ::Jailbreak VIP Plugin

hlmod.hu https://hlmod.hu/

Jailbreak VIP Plugin https://hlmod.hu/viewtopic.php?f=101&t=12468	Oldal: 1 / 1

Szerző:

Kozsla [2012.02.24. 19:39 ]

Hozzászólás témája:

Jailbreak VIP Plugin

Plugin Neve:	Jailbreak VIP Plugin	Plugint készitette:	lolz123
Játék:	Counter-Strike	Kategória:	Admin parancsok
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

<Eredeti készítő: lolz123>
<Magyar fordítás: Kozsla>

Ez Jailbreak módhoz tartozó VIP plugin!
(Szerintem ez minden elárul

)

A VIP-k alapból kapnak:
2db flash-t!
1db smoke-ot!
+20% Életet!
+50% Golyóállómellényt!
+A chatben a neved előtt ez áll: [VIP] (zölden)

Parancsok:
/vip - Megmutatja a szerveren lévő VIP-ket!

Konzolos parancsok:
jb_set_user_vip <név> - Ezzel tudsz hozzáadni VIP-t!
jb_remove_user_vip <név> - Ezzel tudsz törölni VIP-t!

Cvarok:
amx_cvar jb_vip 1/0 - Plugin Be/Kikapcsolása
amx_cvar jb_list 1/0 - VIP lista Be/Kikapcsolása

Használjátok egészséggel!
Bármi probléma van írjatok!

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <nvault>
enum Color
{
	NORMAL = 1, // clients scr_concolor cvar color
	GREEN, // Green Color
	TEAM_COLOR, // Red, grey, blue
	GREY, // grey
	RED, // Red
	BLUE, // Blue
}

new TeamName[][] = 
{
	"",
	"TERRORIST",
	"CT",
	"SPECTATOR"
}

ColorChat(id, Color:type, const msg[], {Float,Sql,Result,_}:...)
{
	static message[256];

switch(type)
	{
		case NORMAL: // clients scr_concolor cvar color
		{
			message[0] = 0x01;
		}
		case GREEN: // Green
		{
			message[0] = 0x04;
		}
		default: // White, Red, Blue
		{
			message[0] = 0x03;
		}
	}

vformat(message[1], 251, msg, 4);
	message[192] = '^0';

static team, ColorChange, index, MSG_Type;
	
	if(id)
	{
		MSG_Type = MSG_ONE;
		index = id;
	} else {
		index = FindPlayer();
		MSG_Type = MSG_ALL;
	}
	
	team = get_user_team(index);
	ColorChange = ColorSelection(index, MSG_Type, type);

ShowColorMessage(index, MSG_Type, message);
		
	if(ColorChange)
	{
		Team_Info(index, MSG_Type, TeamName[team]);
	}
}

ShowColorMessage(id, type, message[])
{
	message_begin(type, get_user_msgid("SayText"), _, id);
	write_byte(id)		
	write_string(message);
	message_end();	
}

Team_Info(id, type, team[])
{
	message_begin(type, get_user_msgid("TeamInfo"), _, id);
	write_byte(id);
	write_string(team);
	message_end();

return 1;
}

ColorSelection(index, type, Color:Type)
{
	switch(Type)
	{
		case RED:
		{
			return Team_Info(index, type, TeamName[1]);
		}
		case BLUE:
		{
			return Team_Info(index, type, TeamName[2]);
		}
		case GREY:
		{
			return Team_Info(index, type, TeamName[0]);
		}
	}

return 0;
}

FindPlayer()
{
	static i;
	i = -1;

while(i <= get_maxplayers())
	{
		if(is_user_connected(++i))
		{
			return i;
		}
	}

return -1;
}

#include <fakemeta_util>
#include <hamsandwich>

#define VIPTAG			"[Vip]"
#define DEADVIPTAG		"[Vip]"

new Vip[33], g_max_clients, VipVault;
new VipCvar, VipList;

public plugin_init() {
	register_plugin("Jailbreak VIP", "1.0", "lolz123")
	
	VipCvar = register_cvar( "jb_vip", "1" )
	VipList = register_cvar( "jb_vip_list", "1" )
	
	register_clcmd("jb_set_user_vip", "SetVip")
	register_clcmd("jb_remove_user_vip", "RemoveVip")
	
	register_clcmd("say /vip", "print_viplist")
	register_clcmd("say !vip", "print_viplist")
	
	register_clcmd("say", "HandleSay")
	
	RegisterHam(Ham_Spawn, "player", "HamPlayerSpawn", 1) 
	
	g_max_clients = get_maxplayers();
}

public plugin_cfg()
{
	VipVault = nvault_open( "Vip" );
	
	if ( VipVault == INVALID_HANDLE )
		set_fail_state( "Error opening Vip Vault" );
}

public plugin_end()
{
	nvault_close(VipVault);
}

public plugin_natives()
{
	register_library("Vip");
	register_native("is_user_vip", "_user_vip");
}

public _user_vip(plugin, params)
{
	return IsVip(get_param(1));
}

public client_putinserver(id)
{
	LoadVip(id);
}

public HamPlayerSpawn(id)
{
	if(!get_pcvar_num(VipCvar))
		return PLUGIN_HANDLED;
		
	if(cs_get_user_team(id) == CS_TEAM_T && IsVip(id))
	{
		cs_set_user_armor(id, 100, CS_ARMOR_VESTHELM);
		fm_give_item(id, "weapon_flashbang")
		fm_give_item(id, "weapon_flashbang")
		fm_give_item(id, "weapon_smokegrenade")
		fm_set_user_health(id, 120)
		fm_set_user_armor(id, 50)
	}
	return PLUGIN_HANDLED;
}

public SetVip(id)
{
	if(!get_pcvar_num(VipCvar))
		return PLUGIN_HANDLED;
		
	if(!(get_user_flags(id) & ADMIN_CVAR))
	{
		client_print(id, print_console, "Nincs hozzaferesed ehez a parancshoz!");
		return PLUGIN_HANDLED;
	}
	
	new arg[32], name[32];
	read_argv (1, arg, 31);
	
	new player = cmd_target(id,arg,3);
	
	get_user_name(player, name, 31);
	
	if(!player)
	{
		client_print(id, print_console, "Nincs ilyen nevu jatekos!");
		return PLUGIN_HANDLED;
	}
	if(IsVip(player))
	{
		client_print(id, print_console, "%s VIP jatekos!", name);
		return PLUGIN_HANDLED;
	}
	set_player_vip(player)
	
	return PLUGIN_HANDLED;
}

public RemoveVip(id)
{
	if(!get_pcvar_num(VipCvar))
		return PLUGIN_HANDLED;
		
	if(!(get_user_flags(id) & ADMIN_CVAR))
	{
		client_print(id, print_console, "Nincs hozzaferesed ehez a parancshoz!");
		return PLUGIN_HANDLED;
	}
	
	new arg[32], name[32];
	read_argv (1, arg, 31);
	
	new player = cmd_target(id,arg,3);
	
	get_user_name(player, name, 31);
	
	if(!player)
	{
		client_print(id, print_console, "Nincs ilyen nevu jatekos!");
		return PLUGIN_HANDLED;
	}
	if(!IsVip(player))
	{
		client_print(id, print_console, "%s Mar nem VIP jatekos!", name);
		return PLUGIN_HANDLED;
	}
	remove_player_vip(player)
	
	return PLUGIN_HANDLED;
}

set_player_vip(player)
{
	if(is_user_connected(player) && Vip[player] == 0)
	{
		Vip[player] = 1;
		
		new name[32];
		get_user_name(player, name, 31);
		
		client_print(player, print_center, "VIP jatekos lettel!!");
		client_print(0, print_chat, "%s VIP jatekos lett!", name);

SaveVip(player);
	}
}

remove_player_vip(player)
{
	if(is_user_connected(player) && Vip[player] == 1)
	{
		Vip[player] = 0;
		
		new name[32];
		get_user_name(player, name, 31);
		
		client_print(player, print_center, "Mar nem vagy VIP jatekos!");
		client_print(0, print_chat, "%s Mar nem VIP jatekos!", name);
		
		SaveVip(player);
	}
}

public SaveVip(id)
{
	new authid[32]; 
	get_user_authid(id,authid,31);

new vaultkey[64], vaultdata[64]; 
  
	format(vaultkey,63,"Vip-%s",authid)
	format(vaultdata,63,"%d", Vip[id]); 
	
	nvault_set( VipVault , vaultkey , vaultdata );
}

public LoadVip(id)
{
	new authid[32], vaultkey[64];
	get_user_authid(id,authid,31); 
    
	formatex( vaultkey , charsmax( vaultkey ) , "Vip-%s" , authid);

Vip[id] = nvault_get( VipVault, vaultkey );
}

public HandleSay(id)
{
	if(!get_pcvar_num(VipCvar))
		return PLUGIN_CONTINUE;
		
	new message[192], VipName[32], none[2][32], chat[192];
	
	read_args (message, 191)
	remove_quotes (message)
	
	formatex(none[0], 31, ""), formatex(none[1], 31, " ")
	
	if (message[0] == '@' || message[0] == '/' || message[0] == '!' || equal (message, ""))
		return PLUGIN_HANDLED;
		
	if(IsVip(id) && !equali(message, none[0]) && !equali(message, none[1]) && cs_get_user_team(id) != CS_TEAM_SPECTATOR)
	{
		get_user_name(id, VipName, 31);
		
		if(is_user_alive(id))
			formatex(chat, 191, "^4%s^3 %s^1 :  %s", VIPTAG, VipName, message)
		else
			formatex(chat, 191, "^4%s^3 %s^1 :  %s", DEADVIPTAG, VipName, message)
			
		switch(cs_get_user_team(id))
		{
			case 1: ColorChat(0, RED, chat)
			case 2: ColorChat(0, BLUE, chat)
		}
		return PLUGIN_HANDLED;
	}
	return PLUGIN_CONTINUE;
}

public print_viplist(user) 
{
	if(!get_pcvar_num(VipCvar) || !get_pcvar_num(VipList))
		return PLUGIN_HANDLED;
		
	new vipnames[33][32]
	new message[256]
	new id, count, x, len
	
	for(id = 1 ; id <= g_max_clients ; id++)
	{
		if(is_user_connected(id))
		{
			if(IsVip(id))
			{
				get_user_name(id, vipnames[count++], 31)
			}
		}
	}

len = format(message, 255, "^x04 Online VIP jatekosok:^x03 ")
	
	if(count > 0)
	{
		len = format(message, 255, "^x04 Online VIP jatekosok:")
		for(x = 0 ; x < count ; x++)
		{
			len += format(message[len], 255-len, "^x03 %s%s ", vipnames[x], x < (count-1) ? " ,":"")
		}
		ColorChat(user, BLUE, message)
	}
	else
	{
		len += format(message, 255, "^x04 Nincs Online VIP!")
		ColorChat(user, BLUE, message)
	}
	return PLUGIN_HANDLED;
}

bool:IsVip(player)
{
	if(Vip[player] == 1)
	{
		return true;
	}
	return false;
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ fbidis\\ ansi\\ ansicpg1252\\ deff0{\\ fonttbl{\\ f0\\ fnil\\ fcharset0 Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ ltrpar\\ lang1037\\ f0\\ fs16 \n\\ par }
*/

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	StarFighteer [2012.03.16. 10:21 ]
Hozzászólás témája:	Re: Jailbreak VIP Plugin \| Mind \| Ismeretlen
hogy lehet beállítani hogy ne mindent 2x írjon le?

Szerző:	eroscsavo [2012.03.24. 11:14 ]
Hozzászólás témája:	Re: Jailbreak VIP Plugin \| Mind \| Ismeretlen
Nekem ez nem megy Kozsla ha tudsz segiteni add le a yahood vagy a skype-od pls

Szerző:	Kozsla [2012.03.28. 19:27 ]
Hozzászólás témája:	Re: Jailbreak VIP Plugin \| Mind \| Ismeretlen
Skype: alcoholic-skype Mi nem megy? :D

Szerző:	balintfan [2012.05.05. 12:29 ]
Hozzászólás témája:	Re: Jailbreak VIP Plugin \| Mind \| Ismeretlen
berakom és befagy tőle szeró mért?

Szerző:	Draguiska™ [2012.05.10. 19:17 ]
Hozzászólás témája:	Re: Jailbreak VIP Plugin \| Mind \| Ismeretlen
Azért ír mindent le 2x mert egy másik plugin álltalában (Admin Chat Color vagy Chat Addon NEW) de lehet más bezavarja.

Szerző:	Bour.cfg [2012.07.30. 11:16 ]
Hozzászólás témája:	Re: Jailbreak VIP Plugin \| Mind \| Ismeretlen
tedd be team colorra.és akkor nem ir le mindent kétszer!És az admin szinesen is tud irni.

Szerző:	vajdatamas10 [2013.01.18. 17:31 ]
Hozzászólás témája:	Re: Jailbreak VIP Plugin \| Mind \| Ismeretlen
csak 1 gondvan vele hogy ha az admin,camera meg sanksound bevannak rakva a VIP-plugin nemfogja őket engedni :)

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/