hlmod.hu :: surf_ski_2_ölés gátóló

hlmod.hu https://hlmod.hu/

surf_ski_2_ölés gátóló https://hlmod.hu/viewtopic.php?f=101&t=12473	Oldal: 1 / 2

Szerző:

pixxa112 [ 2012.02.29. 19:32 ]

Hozzászólás témája:

surf_ski_2_ölés gátóló

Plugin Neve:	surf_ski_2_ölés gátóló	Plugint készitette:	xPaw
Játék:	Counter-Strike	Kategória:	Játékmenet
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

Helló.

Ez a plugin surf szeró-hoz készült.
A plugin lényege ha bent vagy a márióba egy ellenségeddel akkor nem tudjátok egymást megölni + 30mp útán kidobb a GunRoom-ból | MárióRoom-ból | És Jail-ból.

Plugin telepítése:

.amxx - plugins mappába.
.sma - scripting mappába.

És a plugint beírod a cstrike/addons/amxmodx/configs/plugins.ini-be beírod ezt: surf_ski_2_ruleswatcher.amxx

Cvar:

rw_ss2_jail_nokill "0" -> Jailban legyen ölés vagy ne. 0=ne 1=igen
rw_ss2_jail_time "999999" -> Mennyi idö után dobjon ki a Jail-ból.

rw_ss2_gunroom_nokill "1" -> GunRoomban legyen ölés vagy ne legyen
rw_ss2_gunroom_time "999999" -> Mennyi idö után dobjon ki GunRoomból

rw_ss2_marioroom_nokill "1" -> Legyen ölés a márióba vagy ne legyen
rw_ss2_marioroom_time "999999" -> Mennyi idö után dobjon ki a MárióRoomból.

Plugint nem én készítettem.
Plugint magyarosototta: Virtualcfg

Remélem nem hibás, Jó játékot !!

#include < amxmodx >
#include < engine >
#include < hamsandwich >

#define IsPlayer(%1) ( 1 <= %1 <= g_iMaxPlayers )

new const g_szClassname[ ] = "trigger_rules_watch";

enum _:RoomTypes {
   JAIL,
   GUNROOM,
   MARIOROOM
};

enum _:CVARS {
   CV_JAIL_NOKILL,
   CV_JAIL_TIME,
   
   CV_GUNROOM_NOKILL,
   CV_GUNROOM_TIME,
   
   CV_MARIOROOM_NOKILL,
   CV_MARIOROOM_TIME
};

new const g_szZones[ RoomTypes ][ ] = {
   "Jail",
   "Gun room",
   "Mario room"
};

new const Float:g_flOrigins[ ][ 3 ] = {
   { -405.0, 2900.0, 720.0 },
   { -486.0, -1000.0, -275.0 },
   { -405.0, 2949.0, 2422.0 }
};

new const Float:g_flAngles[ ][ 3 ] = {
   { 0.0, 270.0, 0.0 },
   { 0.0, 270.0, 0.0 },
   { 0.0, 270.0, 0.0 }
};

new g_iMaxPlayers;
new g_iCounter[ 33 ];
new bool:g_bNoKill[ 33 ];
new Float:g_flLastTouch[ 33 ];
new g_pCvars[ CVARS ], g_iCvars[ CVARS ];

public plugin_init( ) {
   register_plugin( "surf_ski_2: Rules Watcher", "1.1", "xPaw" );
   
   register_cvar( "ss2_rules_watcher", "1.1", FCVAR_SERVER | FCVAR_SPONLY );
   
   g_iMaxPlayers = get_maxplayers( );
   
   g_pCvars[ CV_JAIL_NOKILL ]      = register_cvar( "rw_ss2_jail_nokill",      "0" );
   g_pCvars[ CV_JAIL_TIME ]        = register_cvar( "rw_ss2_jail_time",        "999999" );
   
   g_pCvars[ CV_GUNROOM_NOKILL ]   = register_cvar( "rw_ss2_gunroom_nokill",   "1" );
   g_pCvars[ CV_GUNROOM_TIME ]     = register_cvar( "rw_ss2_gunroom_time",     "999999" );
   
   g_pCvars[ CV_MARIOROOM_NOKILL ] = register_cvar( "rw_ss2_marioroom_nokill", "1" );
   g_pCvars[ CV_MARIOROOM_TIME ]   = register_cvar( "rw_ss2_marioroom_time",   "999999" );
   
   new szMap[ 12 ];
   get_mapname( szMap, 11 );
   
   if( equali( szMap, "surf_ski_2" ) ) {
      CreateTrigger( JAIL, Float:{ -579.0, 2983.0, 586.0 }, Float:{ -309.0, 3288.0, 796.0 } );
      CreateTrigger( GUNROOM, Float:{ -713.0, -990.0, -157.0 }, Float:{ -295.0, -651.0, 26.0 } );
      CreateTrigger( MARIOROOM, Float:{ 2735.0, 193.0, -2361.0 }, Float:{ 3654.0, 1118.0, -2083.0 } );
     
      register_touch( g_szClassname, "player", "FwdTriggerTouch" );
      RegisterHam( Ham_Spawn,        "player", "FwdHamPlayerSpawn", 1 );
      RegisterHam( Ham_TakeDamage,   "player", "FwdHamTakeDamage" );
      RegisterHam( Ham_TraceAttack,  "player", "FwdHamTraceAttack" );
     
      register_event( "HLTV", "EventNewRound", "a", "1=0", "2=0" );
     
      CacheCvars( );
   }
}

public EventNewRound( )
   CacheCvars( );

public FwdHamPlayerSpawn( const id ) {
   if( is_user_alive( id ) ) {
      g_bNoKill[ id ]     = false;
      g_flLastTouch[ id ] = 0.0;
      g_iCounter[ id ]    = 0;
   }
}

public FwdHamTraceAttack( const id, const iAttacker ) {
   if( IsPlayer( iAttacker ) && g_bNoKill[ id ] && id != iAttacker ) {
      if( ( g_flLastTouch[ id ] + 0.1 ) >= get_gametime( ) )
         return HAM_SUPERCEDE;
      else
         g_bNoKill[ id ] = false;
   }
   
   return HAM_IGNORED;
}

public FwdHamTakeDamage( const id, const iInflictor, const iAttacker ) {
   if( IsPlayer( iAttacker ) && g_bNoKill[ id ] && id != iAttacker ) {
      if( ( g_flLastTouch[ id ] + 0.1 ) >= get_gametime( ) )
         return HAM_SUPERCEDE;
      else
         g_bNoKill[ id ] = false;
   }
   
   return HAM_IGNORED;
}

public FwdTriggerTouch( const iEntity, const id ) {
   static Float:flGametime;
   flGametime = get_gametime( );
   
   if( flGametime > ( g_flLastTouch[ id ] + 1.2 ) ) {
      g_iCounter[ id ] = 0;
      g_flLastTouch[ id ] = flGametime;
   }
   else if( g_flLastTouch[ id ] < flGametime ) {
      g_iCounter[ id ]++;
     
      static iType, bool:bNoKill, iTime;
      iType = entity_get_int( iEntity, EV_INT_iuser1 );
     
      GetCvars( iType, bNoKill, iTime );
     
      g_bNoKill[ id ] = bNoKill;
     
      if( iTime > 0 ) {
         if( g_iCounter[ id ] >= iTime ) {
            if( iTime >= 5 ) {
               engclient_print( id, engprint_center, "^nTobb idot toltottel el mint %i masodperc %s%s-ban.^nKi lettel dobva.", iTime, iType == MARIOROOM ? "^n" : " ", g_szZones[ iType ] );
               
               client_cmd( id, "spk buttons/blip1" );
            }
           
            entity_set_vector( id, EV_VEC_angles, g_flAngles[ iType ] );
            entity_set_int( id, EV_INT_fixangle, 1 );
            entity_set_origin( id, g_flOrigins[ iType ] );
         }
         
         if( g_iCounter[ id ] < 5 ) {
            if( iTime >= 5 )
               engclient_print( id, engprint_center, "%sTe %s-ban vagy.%s^n^nEnnyi idod van hogy kimenj: %i!", bNoKill ? "" : "^n", g_szZones[ iType ], bNoKill ? "^nYou can't kill anyone here." : "", iTime );
            else
               engclient_print( id, engprint_center, "%sTe %s.%s-ban vagy", bNoKill ? "" : "^n", g_szZones[ iType ], bNoKill ? "^nItt nem tudsz megolni senkit." : "" );
         }
      }
     
      g_flLastTouch[ id ] = flGametime + 1.0;
   }
}

GetCvars( const iType, &bool:bNoKill, &iTime ) {
   static CvarNoKill, CvarTime;
   
   switch( iType ) {
      case JAIL: {
         CvarNoKill = CV_JAIL_NOKILL;
         CvarTime = CV_JAIL_TIME;
      }
      case GUNROOM: {
         CvarNoKill = CV_GUNROOM_NOKILL;
         CvarTime = CV_GUNROOM_TIME;
      }
      case MARIOROOM: {
         CvarNoKill = CV_MARIOROOM_NOKILL;
         CvarTime = CV_MARIOROOM_TIME;
      }
   }
   
   bNoKill = bool:( g_iCvars[ CvarNoKill ] );
   iTime = g_iCvars[ CvarTime ];
}

CacheCvars( ) {
   g_iCvars[ CV_JAIL_NOKILL ]      = get_pcvar_num( g_pCvars[ CV_JAIL_NOKILL ] );
   g_iCvars[ CV_JAIL_TIME ]        = get_pcvar_num( g_pCvars[ CV_JAIL_TIME ] );
   
   g_iCvars[ CV_GUNROOM_NOKILL ]   = get_pcvar_num( g_pCvars[ CV_GUNROOM_NOKILL ] );
   g_iCvars[ CV_GUNROOM_TIME ]     = get_pcvar_num( g_pCvars[ CV_GUNROOM_TIME ] );
   
   g_iCvars[ CV_MARIOROOM_NOKILL ] = get_pcvar_num( g_pCvars[ CV_MARIOROOM_NOKILL ] );
   g_iCvars[ CV_MARIOROOM_TIME ]   = get_pcvar_num( g_pCvars[ CV_MARIOROOM_TIME ] );
}

CreateTrigger( const iType, const Float:flMins[ 3 ], const Float:flMaxs[ 3 ] ) {
   new iEntity = create_entity( "info_target" );
   
   if( !is_valid_ent( iEntity ) ) {
      log_amx( "Nem sikerult letrehozni ezt: ^"%s^"", g_szZones[ iType ] );
     
      return 0;
   }
   
   entity_set_string( iEntity, EV_SZ_classname, g_szClassname );
   entity_set_int( iEntity, EV_INT_iuser1, iType );
   entity_set_int( iEntity, EV_INT_movetype, MOVETYPE_NONE );
   entity_set_int( iEntity, EV_INT_solid, SOLID_TRIGGER );
   entity_set_size( iEntity, flMins, flMaxs );
   
   return iEntity;
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	pixxa112 [ 2012.02.29. 19:36 ]
Hozzászólás témája:	Re: surf_ski_2_ölés gátóló \| Mind \| Ismeretlen
Remélem tetszeni fog azoknak akiknek van surf szerójuk. :)

Szerző:	kiki [ 2012.02.29. 19:56 ]
Hozzászólás témája:	Re: surf_ski_2_ölés gátóló \| Mind \| Ismeretlen
Frissítem leírást

Szerző:	csabi0717 [ 2012.02.29. 20:39 ]
Hozzászólás témája:	Re: surf_ski_2_ölés gátóló \| Mind \| Ismeretlen
Ha lehet a cVar-ok mellé írd oda, hogy mi mit jelent, mert szegény kis kezdő nebuló feljön, megnézi és az első kérdése: Ezek meg mit jelentenek? :) ha lehet pótoljátok. köszike :DD és a plugins.ini-be surf_ski_2_ruleswatcher.amxx-et kell írni! nem szabad lehagyni az amxx-et, mert nem fog mükszeni. vagy tévedek kiki? :D

Szerző:	GhostRyder [ 2012.02.29. 21:00 ]
Hozzászólás témája:	Re: surf_ski_2_ölés gátóló \| Mind \| Ismeretlen
Amugy ha virtual magyaroairotta akkor miér te tetted fel ??

Szerző:	pixxa112 [ 2012.02.29. 21:05 ]
Hozzászólás témája:	Re: surf_ski_2_ölés gátóló \| Mind \| Ismeretlen
Oksa mellé írom, azért én tetem fel mert rég töltötem fel plugint ;). De amúgy baj vagy mi?? Sok ember igy tölti fel a plugint, hogy lemagyarositja valaki más és és aki megkérte h magyarositja le az teszi fel :D

Szerző:	norbee.16 [ 2012.02.29. 22:00 ]
Hozzászólás témája:	Re: surf_ski_2_ölés gátóló \| Mind \| Ismeretlen
hát elég bunko szokás! mert más dolgozik te meg aratod a sikert "aratod a sikert" azt ara értem hogy te rakod fel meg nem tudom

Szerző:	norbee.16 [ 2012.02.29. 22:01 ]
Hozzászólás témája:	Re: surf_ski_2_ölés gátóló \| Mind \| Ismeretlen
hát elég bunko szokás! mert más le magyarositja a kérésedre te meg felrakod csak azért magyarositani 1 plugint hogy fel ragd...

Szerző:	pixxa112 [ 2012.02.29. 22:21 ]
Hozzászólás témája:	Re: surf_ski_2_ölés gátóló \| Mind \| Ismeretlen
Na ide figyelj kisgyerek. 1. Nem kértem meg hogy magyarositsa le. 2. Én arra kértem meg hogy írja át úgy a plugint hogy a Jailba belehsen esni, ezt megis csinálta és megköszöntem. 3. Csak jószívű a gyerek hogy megcsinálta. 4. Szoval beis foghatod a *******

Szerző:	Silent [ 2012.03.01. 07:12 ]
Hozzászólás témája:	Re: surf_ski_2_ölés gátóló \| Mind \| Ismeretlen
Kedves norbee.16! Ameddig nem írsz érthetô, átlátható magyar nyelven, addig ne is számíts rá, hogy bárki veszi a fáradságot arra h a sértegetô h.sz.eidet elolvassa. Yours, Silent ^^ xd

Oldal: 1 / 2	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/