hlmod.hu ::Élethű Ugrás v1.3

hlmod.hu https://hlmod.hu/

Élethű Ugrás v1.3 https://hlmod.hu/viewtopic.php?f=101&t=12549	Oldal: 1 / 1

Szerző:

Bence98007 [2012.06.19. 21:23 ]

Hozzászólás témája:

Élethű Ugrás v1.3

Plugin Neve:	Élethű Ugrás v1.3	Plugint készitette:	OT
Játék:	Counter-Strike	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	Badboy.killer

-(-)-Leírás-(-)-
Ez a plugin arra szolgál, hogy amikor ráugrunk egy ellenségre, csapattársra vagy akár széttörhető tárgyra, akkor az meghal ill. széttörik.

-(-)-Videó-(-)-
http://www.youtube.com/watch?v=k2z2V60sjRg

-(-)-Cvarok-(-)-
mp_lr_damage 1 / 0 // Ha csapattárs fejére ugrunk, meghaljon-e (1=igen, 2=ne)

-(-)-Telepítés-(-)-
land_reality.amxx -> a plugins mappába, majd a nevét a configs/plugins.ini-be
land_reality.sma |ELHANYAGOLHATÓ!| scripting mappába.

-(-)-Megjegyzés-(-)-
Ajánlom fun szerverekre.

#include <amxmodx>
#include <cstrike>
#include <engine>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN					"Land Reality"
#define AUTHOR					"OT"
#define VERSION					"1.3"

// You can modify
#define MAX_PLAYERS				32

#define MIN_DAMAGE_VELOCITY		150.0
#define UNIT_MAKE_MORE_DAMAGE	50

// Do not modify
#define OFFSET_PL_FALLVEL		251
#define EXTRA_PL_OFFSET			5

new Float:old_fall_vel[MAX_PLAYERS + 1]
new Float:fall_vel[MAX_PLAYERS + 1]
new bool:was_on_ladder[MAX_PLAYERS + 1]
new g_maxplayers

new pcv_ff
new pcv_da

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_cvar("land_real_version", VERSION, FCVAR_SPONLY | FCVAR_SERVER)
	
	pcv_ff = get_cvar_pointer("mp_friendlyfire")
	pcv_da = register_cvar("mp_lr_damage", "1") // 0 - do not damage teammates, 1 - follow FF
	
	g_maxplayers = get_maxplayers()
}

public client_PreThink(id)
{
	if ( !is_user_alive(id) )
		return PLUGIN_CONTINUE
	
	fall_vel[id] = get_pdata_float(id, OFFSET_PL_FALLVEL, EXTRA_PL_OFFSET)
	static	ground_ent
	ground_ent = entity_get_edict(id, EV_ENT_groundentity)
	
	if (fall_vel[id] == 0.0 && old_fall_vel[id] > MIN_DAMAGE_VELOCITY && !was_on_ladder[id])
	{
		if (is_breakable(ground_ent))
		{
			if ( 1 <= ground_ent <= g_maxplayers)
			{
				if (cs_get_user_team(id) != cs_get_user_team(ground_ent))
				{
					ExecuteHamB(Ham_TakeDamage, ground_ent, 0, id, (10.0 + (float(  floatround(old_fall_vel[id] - MIN_DAMAGE_VELOCITY) / UNIT_MAKE_MORE_DAMAGE ) * 5.0)), DMG_FALL)
				}
				else
				{
					if (get_pcvar_num(pcv_ff) != 0 && get_pcvar_num(pcv_da) == 1)
					{
						ExecuteHamB(Ham_TakeDamage, ground_ent, 0, id, (5.0 + (float(  floatround(old_fall_vel[id] - MIN_DAMAGE_VELOCITY) / UNIT_MAKE_MORE_DAMAGE ) * 2.5)), DMG_FALL)
					}
				}
			}
			else
			{
				ExecuteHamB(Ham_TakeDamage, ground_ent, 0, id, (10.0 + (float(  floatround(old_fall_vel[id] - MIN_DAMAGE_VELOCITY) / UNIT_MAKE_MORE_DAMAGE ) * 5.0)), DMG_FALL)
			}
			
			if ((!is_valid_ent(ground_ent)) || (( 1 <= ground_ent <= g_maxplayers) && !is_user_alive(ground_ent)))
			{
				// IF entity was destroyed fall velocity continues!
				fall_vel[id] = old_fall_vel[id] - MIN_DAMAGE_VELOCITY
				set_pdata_float(id, OFFSET_PL_FALLVEL, fall_vel[id], EXTRA_PL_OFFSET)
				return PLUGIN_CONTINUE
			}
			
		}
	}
	
	was_on_ladder[id] = (entity_get_int(id, EV_INT_movetype) == MOVETYPE_FLY)
	old_fall_vel[id] = fall_vel[id]
	
	return PLUGIN_CONTINUE
}

stock is_breakable(ent)
{
	if (ent == 0)
		return 0
	
	if ((entity_get_float(ent, EV_FL_health) > 0.0) && (entity_get_float(ent, EV_FL_takedamage) > 0.0) && !(entity_get_int(ent, EV_INT_spawnflags) & SF_BREAK_TRIGGER_ONLY))
		return 1
	
	return 0
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	spyron44 [2012.06.19. 21:46 ]
Hozzászólás témája:	Re: Halálos ugrás \| Mind \| Szórakoztató
Nem is akkor hülyeség :D , De ez jó akkor is ha pl: Crazyjumpon a magasból ugrasz le egy ember fejére?:D Szóval akkor aki ugrott a magasból az is megdöglik?:D

Szerző:	HunGamer [2012.06.20. 09:30 ]
Hozzászólás témája:	Re: Halálos ugrás \| Mind \| Szórakoztató
Az ugróra nincs hatással, tehát ugyanúgy sebződik, mint eddig.(Crazyjumpon valószínű, hogy meghal.)

Szerző:	kiki [2012.06.20. 13:38 ]
Hozzászólás témája:	Re: Halálos ugrás \| Mind \| Szórakoztató
Hnsre jó

Szerző:	Bence98007 [2012.06.22. 20:28 ]
Hozzászólás témája:	Re: Halálos ugrás \| Mind \| Szórakoztató
spyron44: az nem döglődik meg, aki ráugrott, mivel crazyjumpon víz van, így nem hal bele. Eddig nem láttam értelmét ennek a pluginnak, de kösz az ötletet!

Szerző:	VirTuaL ~` [2012.06.23. 08:10 ]
Hozzászólás témája:	Re: Halálos ugrás \| Mind \| Szórakoztató
Igen,de ha valaki áll egy helyen,és közben valaki zuhan,és aki zuhan ráesik arra aki alatta áll?Akkor meghal.

Szerző:	Bence98007 [2012.06.24. 09:52 ]
Hozzászólás témája:	Re: Halálos ugrás \| Mind \| Szórakoztató
Pontosan

Szerző:	oroszrulett [2012.07.27. 06:51 ]
Hozzászólás témája:	Re: Halálos ugrás \| Mind \| Szórakoztató
Alapból, ha a valóságban olyan magasról leugrana valaki, akkor azt nem fogja megmenteni az a hihetetlenül magas víztócsa...

Szerző:	VirTuaL ~` [2012.07.30. 10:39 ]
Hozzászólás témája:	Re: Halálos ugrás \| Mind \| Szórakoztató
Amúgy hiányos a leírás,most hogy jobban megnézem a kódot,nem csak emberre vonatkozik,hanem ha van az adott pályán széttörhető tárgy (entity),akkor arra is hat ez a plugin :D

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/