hlmod.hu ::Kör urjaindítás

hlmod.hu https://hlmod.hu/

Kör urjaindítás https://hlmod.hu/viewtopic.php?f=101&t=12582	Oldal: 1 / 2

Szerző:

events.cfg [2012.08.07. 15:57 ]

Hozzászólás témája:

Kör urjaindítás

Plugin Neve:	Kör urjaindítás	Plugint készitette:	vato loco [GE-S]
Játék:	Mind	Kategória:	Játékmenet
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

Sziasztok!

Ennek a pluginnak az lenne a lényege, hogy 25 másodperc után újra indítja a kört pálya váltás után, azaz első körben.

A plugin automatikusan vissza számol és hudban ki írja hogy még restartig hány másodperc van.

Cvarok:

amx_autorr_enable <0/1> KI/BE Kapcsolás. ALAP: 1
amx_autorr_cds <0/1> Visszaszámlálásnál legyen e hang. ALAP: 1
amx_autorr_time <Restart ideje> ALAP: 25
amx_autorr_count_color <RGB> Visszaszámlálás színe. ALAP: 255 192 203
amx_autorr_start_color <RGB> Jatek indulásnál a szín. ALAP: 0 255 255
amx_autorr_xypos <HOL LEGYEN A HUD> ALAP: [-1.0 0.25]

ZIP minden fájl tartalmaz.

Telepítés:
Mappák szerint ZIP-ben!

Sok sikert a pluginhoz!

/* Plugin generated by AMXX-Studio */

#include <amxmodx>

#define PLUGIN "Auto Restart"
#define VERSION "1.0"
#define AUTHOR "vato loco [GE-S]"

#define TIMER_TASK        123456
#define RESTART_TASK      789123

new g_counter

new g_autorestart
new g_autoenabled
new g_autocds
new g_autocount_color
new g_autostart_color
new g_auto_xypos

new g_SyncGameStart
new g_SyncRestartTimer

new bool:g_bRoundStart

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_logevent("RoundStart", 2, "1=Round_Start")
	register_event("TextMsg","RestartTask","a","2&#Game_C")   
	
	register_dictionary("auto_restart_vl.txt")
	
	g_autoenabled = register_cvar("amx_autorr_enable","1")
	g_autocds = register_cvar("amx_autorr_cds","1")
	g_autorestart = register_cvar("amx_autorr_time","25")
	g_autocount_color = register_cvar("amx_autorr_count_color","255 192 203")
	g_autostart_color = register_cvar("amx_autorr_start_color","0 255 255")
	g_auto_xypos = register_cvar("amx_autorr_xypos","-1.0 0.25")
	
	g_SyncGameStart = CreateHudSyncObj()
	g_SyncRestartTimer = CreateHudSyncObj()
}

public RoundStart()
{
	if(!get_pcvar_num(g_autoenabled))
		return PLUGIN_HANDLED
	
	if(g_bRoundStart)
	{
		static r, g, b, Float:x, Float:y
		HudMsgPos(x,y)
		HudMsgColor(g_autostart_color, r, g, b)
		
		set_hudmessage( r, g, b, x, y, 1, 5.0, 8.0, 0.0, 0.0, -1)
		ShowSyncHudMsg( 0, g_SyncGameStart, "%L",LANG_PLAYER, "GAME_STARTED")
	}
	g_bRoundStart = false
	
	return PLUGIN_CONTINUE
}

public RestartTask() 
{
	if(!get_pcvar_num(g_autoenabled))
		return PLUGIN_HANDLED
	
	set_task(1.0,"TimeCounter",TIMER_TASK,_,_,"a",get_pcvar_num(g_autorestart))
	set_task(get_pcvar_float(g_autorestart),"RestartRound",RESTART_TASK)
	
	return PLUGIN_CONTINUE
}

public TimeCounter() 
{
	g_counter++
	
	new Float:iRestartTime = get_pcvar_float(g_autorestart) - g_counter
	new Float:fSec
	fSec = iRestartTime 
	
	static r, g, b, Float:x, Float:y
	HudMsgPos(x,y)
	HudMsgColor(g_autocount_color, r, g, b)
	
	set_hudmessage( r, g, b, x, y, 0, 0.0, 1.0, 0.0, 0.0, -1)
	ShowSyncHudMsg( 0, g_SyncRestartTimer, "%L",LANG_PLAYER, "AUTO_RESTART", floatround(fSec))
	
	if(get_pcvar_num(g_autocds) && get_pcvar_num(g_autorestart) - g_counter < 11 && get_pcvar_num(g_autorestart) - g_counter !=0)
	{
		static szNum[32]
		num_to_word(get_pcvar_num(g_autorestart) - g_counter, szNum, 31)
		client_cmd(0,"speak ^"vox/%s^"", szNum)
	}
	if(g_counter == get_pcvar_num(g_autorestart))
	{
		g_bRoundStart = true
		g_counter = 0
	}
}

public RestartRound() 
{
	server_cmd("sv_restartround 1")
}

public HudMsgColor(cvar, &r, &g, &b)
{
	static color[16], piece[5]
	get_pcvar_string(cvar, color, 15)
	
	strbreak( color, piece, 4, color, 15)
	r = str_to_num(piece)
	
	strbreak( color, piece, 4, color, 15)
	g = str_to_num(piece)
	b = str_to_num(color)
}

public HudMsgPos(&Float:x, &Float:y)
{
	static coords[16], piece[10]
	get_pcvar_string(g_auto_xypos , coords, 15)
	
	strbreak(coords, piece, 9, coords, 15)
	x = str_to_float(piece)
	y = str_to_float(coords)
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

Szerző:	bladebomb [2012.08.07. 17:50 ]
Hozzászólás témája:	Re: Kör urjaindítás \| Mind \| Általános célú
Cvarok hiányoznak,majd egy moderátor is fog miatta írni. Üdv!

Szerző:	CrB [2012.08.07. 18:28 ]
Hozzászólás témája:	Re: Kör urjaindítás \| Mind \| Általános célú
#define AUTHOR "" ?? http://forums.alliedmods.net/showthread.php?p=789518 (cvarokat és a jelentésüket leírhatnád)

Szerző:	pixxa112 [2012.08.08. 04:29 ]
Hozzászólás témája:	Re: Kör urjaindítás \| Mind \| Általános célú
Insa te mekkora egy bot vagy XD AUTHOR a kukában?? Ez megy hibásnak ;)

Szerző:	kiki [2012.08.08. 08:10 ]
Hozzászólás témája:	Re: Kör urjaindítás \| Mind \| Általános célú
Author hibás!

Szerző:	VirTuaL ~` [2012.08.08. 09:57 ]
Hozzászólás témája:	Re: Kör urjaindítás \| Mind \| Általános célú
Javítva.

Szerző:	events.cfg [2012.08.08. 13:35 ]
Hozzászólás témája:	Re: Kör urjaindítás \| Mind \| Általános célú
Nekem ne magyarázz hajho. Ír valaki egy plugint és oda írod a nevedet hogy te írtad -.- senkiházi :D

Szerző:	GhostRyder [2012.08.08. 14:18 ]
Hozzászólás témája:	Re: Kör urjaindítás \| Mind \| Általános célú
Te meg kiveszed. Az se jobb xD

Szerző:	events.cfg [2012.08.08. 19:34 ]
Hozzászólás témája:	Re: Kör urjaindítás \| Mind \| Általános célú
ahham.

Szerző:	toodyka [2013.05.07. 23:51 ]
Hozzászólás témája:	Re: Kör urjaindítás \| Mind \| Általános célú
#define AUTHOR "" ?????

Oldal: 1 / 2	Minden időpont UTC+01:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/