hlmod.hu :: Animált spray Logo

hlmod.hu https://hlmod.hu/

Animált spray Logo https://hlmod.hu/viewtopic.php?f=101&t=12711	Oldal: 1 / 1

Szerző:

laki5000 [ 2013.10.11. 20:20 ]

Hozzászólás témája:

Animált spray Logo

Plugin Neve:	Animált spray Logo	Plugint készitette:	ConnorMcLeod
Játék:	Mind	Kategória:	Általános célú
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

Az elején feltüntetem, nem én írtam a plugint, még egy barátom mutatta nekem alliedmoddersen, de nem láttam még az oldalon, tehát gondolom felteszem, mert eléggé jól jöhet és vicces.

A lényege, hogy MINDENKI spray logoját egy lambdára változtatja, ami nem egyszerre jelenik meg, hanem több részletbe, pontosan nem tudom, de pl először egy fél kör, aztán egész kör, lambda egyik szára, majd lambda másik szára

Remélem érthető leírás volt,
Telepítés: .amxx fájl plugins mappába, és beleírni nevét a plugins.ini-be
.sma fájl elhanyagolható:)

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <xs>

#define VERSION "0.0.1"
#define PLUGIN "Animated Spray"

//#define m_nCustomSprayFrames 485
#define m_flNextDecalTime 486
#define GetCustomDecalFrames(%0)    6 // get_pdata_int(%0,m_nCustomSprayFrames)
// #define SetCustomDecalFrames(%0,%1)    set_pdata_int(%0,m_nCustomSprayFrames,%1)

#define MAX_PLAYERS 32

#define UTIL_MakeVectors(%0)    engfunc(EngFunc_MakeVectors,%0)
#define TRACE_LINE(%0,%1,%2,%3,%4)    engfunc(EngFunc_TraceLine,%0,%1,%2,%3,%4)
#define ALLOC_STRING(%0) engfunc(EngFunc_AllocString, %0)
#define CREATE_NAMED_ENTITY(%0) engfunc(EngFunc_CreateNamedEntity, %0)
#define REMOVE_ENTITY(%0) engfunc(EngFunc_RemoveEntity, %0)
#define WRITE_COORD(%0) engfunc(EngFunc_WriteCoord,%0)

new const SPRAY_SOUND[] = "player/sprayer.wav"
new const INFO_TARGET[] = "info_target"
new g_iFirstDecalIndex
new decalfrequency
new g_iMaxPlayers
new g_iPlayerSprayCan[MAX_PLAYERS+1]

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    decalfrequency = get_cvar_pointer("decalfrequency")
    RegisterHam(Ham_Player_ImpulseCommands, "player", "CBasePlayer_ImpulseCommands")
    RegisterHam(Ham_Think, INFO_TARGET, "CSprayCan_Think")
    g_iFirstDecalIndex = engfunc(EngFunc_DecalIndex, "{lambda01")
    g_iMaxPlayers = get_maxplayers()
}

public plugin_precache()
{
    precache_sound(SPRAY_SOUND)
}

public CBasePlayer_ImpulseCommands( id )
{
    if( pev(id, pev_impulse) == 201 )
    {
        static Float:flGameTime ; flGameTime = get_gametime()
        if( flGameTime >= get_pdata_float(id, m_flNextDecalTime) )
        {
            new Float:start[3], Float:end[3], Float:origin[3], Float:v_angle[3]
            pev(id, pev_v_angle, v_angle)
            UTIL_MakeVectors(v_angle)
            pev(id, pev_origin, origin)
            pev(id, pev_view_ofs, end)
            xs_vec_add(origin, end, start)
            global_get(glb_v_forward, end)
            xs_vec_mul_scalar(end, 128.0, end)
            xs_vec_add(start, end, end)

UTIL_TraceLine ( start, end, IGNORE_MONSTERS, id)

new Float:flFraction
            get_tr2(0, TR_flFraction, flFraction)

if ( flFraction != 1.0 )
            {
                set_pdata_float(id, m_flNextDecalTime, flGameTime + get_pcvar_float(decalfrequency))
                static info_target
                if( !info_target )
                {
                    info_target = ALLOC_STRING( INFO_TARGET )
                }
                new ent = CREATE_NAMED_ENTITY( info_target )
                origin[2] += 32.0
                set_pev(ent, pev_origin, origin)
                set_pev(ent, pev_angles, v_angle)

g_iPlayerSprayCan[id] = ent
                set_pev(ent, pev_frame, 0.0)
                
                set_pev(ent, pev_nextthink, flGameTime + 0.1)
                emit_sound(ent, CHAN_VOICE, SPRAY_SOUND, 1.0, ATTN_NORM, 0, PITCH_NORM)
            }
        }
        set_pev(id, pev_impulse, 0)
    }
}

public CSprayCan_Think( ent )
{
    new id
    for(id = g_iMaxPlayers; id>=0; id--)
    {
        if( g_iPlayerSprayCan[id] == ent )
        {
            break
        }
    }
    if( id <= 0 )
    {
        return
    }

new nFrames = GetCustomDecalFrames( id )

new Float:start[3], Float:end[3]
    pev(ent, pev_angles, start)
    UTIL_MakeVectors( start )
    
    pev(ent, pev_origin, start)
    global_get(glb_v_forward, end)
    xs_vec_mul_scalar(end, 128.0, end)
    xs_vec_add(end, start, end)

UTIL_TraceLine (start, end, IGNORE_MONSTERS, id)

new Float:frame
    pev(ent, pev_frame, frame)
    UTIL_DecalTrace(0, g_iFirstDecalIndex - floatround(frame))

if ( ++frame >= nFrames)
    {
        REMOVE_ENTITY(ent)
        g_iPlayerSprayCan[id] = 0
        return
    }
    set_pev(ent, pev_frame, frame)
    set_pev(ent, pev_nextthink, get_gametime() + 0.1)
}

UTIL_DecalTrace( pTrace, index )
{
    static entityIndex, pHit,
        message, Float:vecEndPos[3]

pHit = get_tr2(pTrace, TR_pHit)

if ( pev_valid(pHit) )
    {
        if ( !ExecuteHam(Ham_IsBSPModel, pHit) )
            return;
        entityIndex = pHit
    }
    else 
        entityIndex = 0

message = TE_DECAL;
    if ( entityIndex != 0 )
    {
        if ( index > 255 )
        {
            message = TE_DECALHIGH;
            index -= 256
        }
    }
    else
    {
        message = TE_WORLDDECAL;
        if ( index > 255 )
        {
            message = TE_WORLDDECALHIGH;
            index -= 256
        }
    }

get_tr2(pTrace, TR_vecEndPos, vecEndPos)

message_begin( MSG_BROADCAST, SVC_TEMPENTITY )
    {
        write_byte( message )
        WRITE_COORD( vecEndPos[0] )
        WRITE_COORD( vecEndPos[1] )
        WRITE_COORD( vecEndPos[2] )
        write_byte( index )
        if ( entityIndex )
        {
            write_short( entityIndex )
        }
    }
    message_end()
}

UTIL_TraceLine( Float:vecStart[3], Float:vecEnd[3], igmon, pentIgnore, ptr=0 )
{
    TRACE_LINE( vecStart, vecEnd, igmon == IGNORE_MONSTERS, pentIgnore, ptr )
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	laki5000 [ 2013.10.12. 00:35 ]
Hozzászólás témája:	Re: Animált spray Logo \| Mind \| Ismeretlen
Nincsmit:)

Szerző:	laki5000 [ 2013.10.12. 12:35 ]
Hozzászólás témája:	Re: Animált spray Logo \| Mind \| Ismeretlen
IGEN, köszi hogy mellettem állsz:)

Szerző:	DeteCT0R [ 2013.10.12. 19:14 ]
Hozzászólás témája:	Re: Animált spray Logo \| Mind \| Ismeretlen
Miert ha mar nem irom oda hogy nem en irtam a plugint az mar nem tisztesseges?

Szerző:	laki5000 [ 2013.10.12. 20:00 ]
Hozzászólás témája:	Re: Animált spray Logo \| Mind \| Ismeretlen
Nem, ő arra gondolt, hogy sok kezdő egy olyan plugin mellé irja hogy ő irta, amit kb mindenki tudja, hogy nem ő irta, és ráadásul még alig tudja leirni mit tud a plugin, vagy hibásan. A lényeg, hogy nem kell hazudni, hogy "Én irtam a plugint" akármilyen más rokonértelmű kifejezésével, mert attól nem fog joban tisztelni senki

Szerző:	norbee.16 [ 2013.10.13. 23:29 ]
Hozzászólás témája:	Re: Animált spray Logo \| Mind \| Ismeretlen
És nem lehet újra írni? Lehet van bene pár hiba és ész szerű dolog újra írni estleg nem tudta, hogy létezik...

Szerző:	laki5000 [ 2013.11.06. 16:06 ]
Hozzászólás témája:	Re: Animált spray Logo \| Mind \| Ismeretlen
mi kellene bele?

Szerző:	kiki [ 2013.11.19. 17:24 ]
Hozzászólás témája:	Re: Animált spray Logo \| Mind \| Ismeretlen
Frissítsd smat.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/