hlmod.hu :: Ikon szín cserélő

hlmod.hu https://hlmod.hu/

Ikon szín cserélő https://hlmod.hu/viewtopic.php?f=101&t=13055	Oldal: 1 / 1

Szerző:

RapperFeri [ 2013.12.03. 12:27 ]

Hozzászólás témája:

Ikon szín cserélő

Plugin Neve:	Ikon szín cserélő	Plugint készitette:	xPaw
Játék:	Counter-Strike	Kategória:	Technikai/Fejlesztő
Eredeti link:	Nincs megadva	Jóváhagyó:	Ismeretlen

Sziasztok
Találtam egy olyan plugint az interneten hogy lecseréli a menekülő zona,vásárló zona,vip zone,túsz zona, bomba és a bomba hatástalanító ikon színét

Cvarok:

icons_c4 255 135 0 - C4 ikon színe (Narancssárga színű)
icons_escape 255 240 0 - Menekülő zona (escape) (Sárga színű)
icons_rescue 255 50 0 - Túsz zona (Piros színű)
icons_defuser 0 100 255 - Bomba hatástalanító (defuser kit) (Világoskék színű)
icons_buyzone 0 200 0 - Vásárló zona (Zöld színű)
icons_vipsafety 175 0 255 - VIP zona (Lila színű)

FONTOS: A cvarok RGB színkódban értendődik.

A plugint nem én csináltam!!! De leteszteltem és nagyon jól müködik...Nem fagyaszt,nem csinál semmi log fájlt,nem laggoltat és nem láttam benne fölösleges sorokat

#include <amxmodx>

enum Icon {
	C4,
	Escape,
	Rescue,
	Defuser,
	Buyzone,
	VipSafety
}

new Cvars[Icon]
new CvarsDefaultValues[Icon][] = { "255 135 0", "255 240 0", "255 50 0 ", "0 100 255","0 200 0","175 0 255"}
new IconNames[Icon][] = {"c4","escape","rescue","defuser","buyzone","vipsafety"}

new Trie:TrieIconNames

public plugin_init() {
	register_plugin( "Ikon szin lecserelo", "1.0", "xPaw" );
	
	TrieIconNames = TrieCreate();
	
	new cvarName[20]
	
	new append = formatex(cvarName, charsmax(cvarName), "icons_");
	
	for(new Icon:i = C4 ; i<Icon;i++) {
		formatex(cvarName[append], charsmax(cvarName) - append, IconNames[i]);
		Cvars[i] = register_cvar(cvarName,CvarsDefaultValues[i]);
		
		TrieSetCell(TrieIconNames,IconNames[i],i);
	}
	
	register_message( get_user_msgid("StatusIcon"), "msgStatusIcon" );
}

public msgStatusIcon( msgId, msgDest, id ) {
	if( get_msg_arg_int( 1 ) == 0 )
		return PLUGIN_CONTINUE;
	
	new szIcon[10]
	get_msg_arg_string( 2, szIcon, 9 );
	
	new Icon:icon
	
	if( TrieGetCell(TrieIconNames,szIcon,icon) ) {
		new szColor[ 12 ], rgb[ 3 ][ 4 ], iRed, iGreen, iBlue;
		
		get_pcvar_string( Cvars[icon] , szColor, charsmax( szColor ) );
		parse( szColor, rgb[ 0 ], 3 , rgb[ 1 ], 3 , rgb[ 2 ], 3 );

iRed	= clamp( str_to_num( rgb[ 0 ] ), 0, 255 );
		iGreen	= clamp( str_to_num( rgb[ 1 ] ), 0, 255 );
		iBlue	= clamp( str_to_num( rgb[ 2 ] ), 0, 255 );
		
		set_msg_arg_int( 3, ARG_BYTE, iRed );
		set_msg_arg_int( 4, ARG_BYTE, iGreen );
		set_msg_arg_int( 5, ARG_BYTE, iBlue );
	}
	
	return PLUGIN_CONTINUE;
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	johnny [ 2013.12.04. 16:22 ]
Hozzászólás témája:	Re: Ikon szín cserélő \| Counter-Strike \| Technikai/Fejlesztő
Végre 1 értelmes plugin:D Gomb ->>

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/