hlmod.hu :: Fények és Színek v1.2

hlmod.hu https://hlmod.hu/

Fények és Színek v1.2 https://hlmod.hu/viewtopic.php?f=101&t=13755	Oldal: 1 / 1

Szerző:

Badboy.killer [ 2014.01.11. 12:12 ]

Hozzászólás témája:

Fények és Színek v1.2

Plugin Neve:	Fények és Színek v1.2	Plugint készitette:	Starsailor
Játék:	Mind	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	norbee.16

A plugin színes burkot képez a játékosok körül.

Terroristák - Piros
Counter-Terroristák- Kék
Bombás - Sárga
Bomba élesítésnél, hatástalanításnál Türkizes színe lesz.
A halálkor a burkok eltűnnek.

Cvarok:

glow_enabled 1/0 - plugin be és kikapcsolása
glow_custom_color 1/0 - alapbeállítások használata
glow_ct_color 255 255 0 16 - Piros - Zöld - Kék - Játékosok Száma egy csapatba
glow_terr_color 255 255 0 16 - Piros - Zöld - Kék - Játékosok Száma egy csapatba
glow_defuse_color 255 255 0 16 - Piros - Zöld - Kék - Játékosok Száma egy csapatba
glow_c4_color 255 255 0 16 - Piros - Zöld - Kék - Játékosok Száma egy csapatba

Képek:

Terroristák alapszínnel
Kép

Terroristák rendszer színekkel
Kép

CT-k alapszínnel
Kép

CT-k rendszer színekkel
Kép

Telepítés:

amxx -> addons/amxmodx/plugins mappába
Majd írd be az addons/amxmodx/configs/plugins.ini -be a plugin nevét.

/*
   Ford�totta: BBk - Death of Legend
*/

#include <amxmodx>
#include <amxmisc>
#include <fun>

#define PLUGIN "Misc Glow (Rmk)"
#define VERSION "1.2"
#define AUTHOR "Starsailor"

new pEnabled
new pDefColor
new pC4Color
new pTerrColor
new pCtColor
new pCustomizeEnabled

new Team, C4Carrier

public plugin_init(){
	
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_cvar("misc_glow_version",VERSION,FCVAR_SERVER|FCVAR_SPONLY)
	
	pEnabled = register_cvar("glow_enabled", "1")
	
	pDefColor = register_cvar("glow_defuse_color", "255 255 0 16")//Piros - Zold - Kek - Szam
	pC4Color = register_cvar("glow_c4_color", "255 255 0 16")//Piros - Zold - Kek - Szam
	pTerrColor = register_cvar("glow_terr_color", "255 255 0 16")//Piros - Zold - Kek - Szam
	pCtColor = register_cvar("glow_ct_color", "255 255 0 16")//Piros - Zold - Kek - Szam
	
	register_event("HLTV","NewRound","a","1=0","2=0")// Csapatok ellenorzese az uj korben
	register_event("DeathMsg", "DeathMsg", "a") //Ha a player meghal torlodik a burok
	
	new szMapname[32]
	get_mapname(szMapname, 31)
	
	if(equali(szMapname, "de_", 3)) //Ha de_ map regisztralja a bomba es hatastalanitas effekteket
	{
		register_event("StatusIcon", "GotBomb", "be", "1=1", "1=2", "2=c4") // Ha a player bombaval spawnolt
		register_event("TextMsg", "BombPickUp", "bc", "2&#Got_bomb")//Ha a player felvette a bombat
		register_event("TextMsg", "BombDrop", "bc", "2&#Game_bomb_d")// Ha a player eldobta a bombat
		register_event("StatusIcon", "GotDefuser", "be", "1=1", "1=2", "2=defuser")// Ha a player hatastalanitot vett
		register_event("SendAudio", "BombPlanted", "a", "2&%!MRAD_BOMBPL")// Ha valaki elesitette a bombat, megvaltozik a szine
		register_event("TextMsg", "DefPickUp", "bc", "2&#Got_defuser")// Ha valaki hatastalanitotta a bombat
	}
	
	register_event("TeamInfo", "JoinTeam", "a")
	
	pCustomizeEnabled = register_cvar("glow_custom_color", "0")
	
}

public DefPickUp(id){
	
	if(!get_pcvar_num(pEnabled))
	{
		remove_user_rendering(id)
	}
	else
	{	
		if(get_user_team(id) == 2)
		{
			if(!get_pcvar_num(pCustomizeEnabled))
			{
				set_user_rendering(id, kRenderFxGlowShell, 71, 237, 231, kRenderNormal,16)
			}
			else
			{
				color_glow_from_cvar(id,pDefColor)		
			}
		}
				
	}
	
}

public BombPickUp(id)
{	
	if(!get_pcvar_num(pEnabled))
	{
		remove_user_rendering(id)
	}
	else
	{	
		if(get_user_team(id) == 1)
		{
			if(!get_pcvar_num(pCustomizeEnabled))
			{
				set_user_rendering(id, kRenderFxGlowShell, 255, 255, 0, kRenderNormal,16)
			}
			else
			{
				color_glow_from_cvar(id,pC4Color)		
			}
		}
		C4Carrier = id
	}
}

public BombDrop(id)
{	
	if(!get_pcvar_num(pEnabled))
	{
		remove_user_rendering(id)
	}
	else
	{	
		if(get_user_team(id) == 1 && is_user_alive(id))
		{
			if(!get_pcvar_num(pCustomizeEnabled))
			{
				set_user_rendering(id, kRenderFxGlowShell, 255, 0, 0, kRenderNormal,16)
			}
			else
			{
				color_glow_from_cvar(id,pTerrColor)		
			}
		}
	}
}

public GotBomb(id)
{
	if(!get_pcvar_num(pEnabled))
	{
		remove_user_rendering(id)
	}
	else
	{	
		if(get_user_team(id) == 1 && is_user_alive(id))
		{
			if(!get_pcvar_num(pCustomizeEnabled))
			{
				set_user_rendering(id, kRenderFxGlowShell, 255, 255, 0, kRenderNormal,16)
			}
			else
			{
				color_glow_from_cvar(id,pC4Color)		
			}
		}
		C4Carrier = id
	}
}

public JoinTeam()
{
	new id = read_data(1)
	new szTeam[32]
	read_data(2, szTeam, 31)    
	
	if(!is_user_alive(id) || !get_pcvar_num(pEnabled) || szTeam[0] == 'S')
	{
		return PLUGIN_CONTINUE
	}
	else
	{
		if(szTeam[0] == 'T')
		{
			if(!get_pcvar_num(pCustomizeEnabled))
			{
				set_user_rendering(id, kRenderFxGlowShell, 255, 0, 0, kRenderNormal,16)
			}
			else
			{
				color_glow_from_cvar(id,pTerrColor)		
			}	
		}
		else if(szTeam[0] == 'C')
		{
			if(!get_pcvar_num(pCustomizeEnabled))
			{
				set_user_rendering(id, kRenderFxGlowShell, 0, 0, 255, kRenderNormal,16)
			}
			else
			{
				color_glow_from_cvar(id,pCtColor)		
			}	
		}
	}
	return PLUGIN_CONTINUE
}

public GotDefuser(id){
	if(!is_user_alive(id) || !get_pcvar_num(pEnabled) || get_user_team(id) != 2)
	{
		remove_user_rendering(id)
	}
	else if(!get_pcvar_num(pCustomizeEnabled))
	{
		set_user_rendering(id, kRenderFxGlowShell,71, 237, 231, kRenderNormal,16)
	}
	else
	{
		color_glow_from_cvar(id,pDefColor)		
	}	
	
}

public BombPlanted()
{
	if(!get_pcvar_num(pEnabled) || !is_user_alive(C4Carrier))
	{
		remove_user_rendering(C4Carrier)
	}
	
	if(!get_pcvar_num(pCustomizeEnabled))
	{
		set_user_rendering(C4Carrier, kRenderFxGlowShell, 255, 0, 0, kRenderNormal,16)
	}
	else
	{
		color_glow_from_cvar(C4Carrier,pTerrColor)		
	}

}
public DeathMsg()
{
	remove_user_rendering(read_data(2))
}

public NewRound()
{	
	new Players[32], iPnum, id
	get_players(Players, iPnum)
	
	for(new i = 0; i<iPnum; i++)
	{
		id = Players[i]
		
		Team = get_user_team(id)
		
		if(!get_pcvar_num(pEnabled))
		{
			remove_user_rendering(id)
		}
		
		else 
		{
			if(!get_pcvar_num(pCustomizeEnabled)){
				
				if(Team == 1)
				{
					set_user_rendering(id, kRenderFxGlowShell, 255, 0, 0, kRenderNormal,16)
				}
				
				else if(Team == 2)
				{
					set_user_rendering(id, kRenderFxGlowShell, 0, 0, 255, kRenderNormal,16)
				}
				
			}
			
			else 
			{
				if(Team == 1)
				{
					color_glow_from_cvar(id,pTerrColor)
				}
				
				else if(Team == 2)
				{
					color_glow_from_cvar(id,pCtColor)
				}
				
			}
		}
	}
}

stock color_glow_from_cvar(id, pcvar)
{
	new szPcvarColor[32], szRed[4], szGreen[4], szBlue[4], szAmount[4]
	get_pcvar_string(pcvar, szPcvarColor, 31)
	
	parse(szPcvarColor,szRed,3,szGreen,3,szBlue,3,szAmount,3)
	
	set_user_rendering(id, kRenderFxGlowShell, clamp(str_to_num(szRed),0,255), clamp(str_to_num(szGreen),0,255), clamp(str_to_num(szBlue),0,255), kRenderNormal,str_to_num(szAmount))
	
}

stock remove_user_rendering(player)
{

set_user_rendering(player,_,0,0,0,_,0)

}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/