hlmod.hu :: [ZP] Addon: Classes In Chat

hlmod.hu https://hlmod.hu/

[ZP] Addon: Classes In Chat https://hlmod.hu/viewtopic.php?f=101&t=14553	Oldal: 1 / 1

Szerző:

barnamate17 [ 2014.02.23. 16:16 ]

Hozzászólás témája:

[ZP] Addon: Classes In Chat

Plugin Neve:	[ZP] Addon: Classes In Chat	Plugint készitette:	@bdul!
Játék:	Counter-Strike	Kategória:	Játékmenet
Eredeti link:	Nincs megadva	Jóváhagyó:	kiki

A Plugin lényege: Ez a plugin Zombie Plague -hoz készült. A Chatben a neved előtt lesz hogy milyen "vagy" (Human,Zombie...stb)

Telepítés:
- .amxx fájlt felrakod: addons/amxmodx/plugins
- .amxx fájlt beírod: addons/amxmodx/configs/plugins-zombieplague.ini

Eredeti Link

Megjegyzés:
- .zip fájl tartalmazza a "Zombie Advanced" .sma-t
- .zip fájl tartalmazza a "Zombie Plague" .sma-t
- Nem akartam magyarosítani mivel szerintem így jó.

Képek:
Kép

/***************************************************************************\
		    =====================================
		     * || [ZP] Classes In Chat v1.1 || *
		    =====================================

-------------------
	 *||DESCRIPTION||*
	-------------------

This plugins adds classes in chat for eg:
	If a person is survivor and he says something then this is what it
	would look like
	[Survivor] Player: Hi I am a survivor
	To make the chat more interesting, the chat is in colors

Original Plugin thread is located here:
	http://forums.alliedmods.net/showthread.php?t=120557

---------------
	 *||CREDITS||*
	---------------

- MeRcyLeZZ ----> For some of the natives
	- My Sister ----> For taking the some screen shots

------------------
	 *||CHANGE LOG||*
	------------------
	
	v1.0 ====> - Initial Release
	v1.0 ====> - Re-wrote the whole plugin
		   - Removed the color chat include and added a new color chat
		      system.
		   - Fixed almost, all the bugs which were reported

\***************************************************************************/

#include <amxmodx>
#include <cstrike>
#if defined _zombieplague_included
  #endinput
#endif
#define _zombieplague_included

#define ZP_TEAM_ZOMBIE (1<<0)
#define ZP_TEAM_HUMAN (1<<1)
#define ZP_TEAM_NEMESIS (1<<2)
#define ZP_TEAM_SURVIVOR (1<<3)

enum
{
	MODE_INFECTION = 1,
	MODE_NEMESIS,
	MODE_SURVIVOR,
	MODE_SWARM,
	MODE_MULTI,
	MODE_PLAGUE
}

enum
{
	WIN_NO_ONE = 0,
	WIN_ZOMBIES,
	WIN_HUMANS
}

#define ZP_PLUGIN_HANDLED 97

native zp_get_user_zombie(id)
native zp_get_user_nemesis(id)
native zp_get_user_survivor(id)
native zp_get_user_first_zombie(id)
native zp_get_user_last_zombie(id)
native zp_get_user_last_human(id)
native zp_get_user_zombie_class(id)
native zp_get_user_next_class(id)
native zp_set_user_zombie_class(id, classid)
native zp_get_user_ammo_packs(id)
native zp_set_user_ammo_packs(id, amount)
native zp_get_zombie_maxhealth(id)
native zp_get_user_batteries(id)
native zp_set_user_batteries(id, charge)
native zp_get_user_nightvision(id)
native zp_set_user_nightvision(id, set)
native zp_infect_user(id, infector = 0, silent = 0, rewards = 0)
native zp_disinfect_user(id, silent = 0)
native zp_make_user_nemesis(id)
native zp_make_user_survivor(id)
native zp_respawn_user(id, team)
native zp_force_buy_extra_item(id, itemid, ignorecost = 0)
native zp_override_user_model(id, const newmodel[], modelindex = 0)
native zp_has_round_started()
native zp_is_nemesis_round()
native zp_is_survivor_round()
native zp_is_swarm_round()
native zp_is_plague_round()
native zp_get_zombie_count()
native zp_get_human_count()
native zp_get_nemesis_count()
native zp_get_survivor_count()
native zp_register_extra_item(const name[], cost, teams)
native zp_register_zombie_class(const name[], const info[], const model[], const clawmodel[], hp, speed, Float:gravity, Float:knockback)
native zp_get_extra_item_id(const name[])
native zp_get_zombie_class_id(const name[])
native zp_get_zombie_class_info(classid, info[], len)
forward zp_round_started(gamemode, id)
forward zp_round_ended(winteam)
forward zp_user_infected_pre(id, infector, nemesis)
forward zp_user_infected_post(id, infector, nemesis)
forward zp_user_humanized_pre(id, survivor)
forward zp_user_humanized_post(id, survivor)
forward zp_user_infect_attempt(id, infector, nemesis)
forward zp_user_humanize_attempt(id, survivor)
forward zp_extra_item_selected(id, itemid)
forward zp_user_unfrozen(id)
forward zp_user_last_zombie(id)
forward zp_user_last_human(id)

#define ZP_TEAM_ANY 0
#define ZP_TEAM_NO_ONE 0

// Variables
new g_msg_saytext, g_msg_teaminfo, g_new_round

// Team names used by the team info message
new const team_names[][] =
{
	"UNASSIGNED",
	"TERRORIST",
	"CT",
	"SPECTATOR"
}

// Color indexes for color chat message
enum
{
	RED = 1,
	BLUE,
	GREY
}

public plugin_init()
{
	// Register the plugin
	register_plugin("[ZP] Classes In Chat", "1.1", "@bdul!")
	
	// Client say commands
	register_clcmd("say", "hook_say")
	register_clcmd("say_team", "hook_team_say")
	
	// Round start event
	register_event("HLTV", "event_round_start", "a", "1=0", "2=0")
	
	// Message IDs'
	g_msg_saytext = get_user_msgid("SayText")
	g_msg_teaminfo = get_user_msgid("TeamInfo")
	
	// This var should be set true to prevent a bug
	g_new_round = true
}

// Check for new round and update the var accordingly
public event_round_start() g_new_round = true
public zp_round_started() g_new_round = false

// Player's chat hook
public hook_say(id)
{
	// Retrieve the player's chat
	static chat[192], name[32], users_team
	read_args(chat, 191)
	remove_quotes(chat)
	
	// Trying to fool us ?
	if(!chat[0])
		return PLUGIN_CONTINUE
	
	// Retrieve player's name
	get_user_name(id, name, charsmax(name))
	
	// Retrieve player's team
	users_team = _:cs_get_user_team(id)
	
	// Alive user chat
	if (is_user_alive(id))
	{
		if (zp_get_user_zombie(id))
			color_chat(0, id, users_team, RED,  "^3[%s]^4 %s:^1 %s", zp_get_user_nemesis(id) ? "Nemesis" : "Zombie", name, chat)
		else
			color_chat(0, id, users_team, BLUE, "^3[%s]^4 %s:^1 %s", zp_get_user_survivor(id) ? "Survivor" : "Human", name, chat)
	}
	
	// Dead user's chat
	else color_chat(0, id, users_team, users_team, "^3[%s]^4 %s:^1 %s", users_team == _:CS_TEAM_SPECTATOR ? "SPEC" : "DEAD", name, chat)
	
	return PLUGIN_HANDLED
}

// Player's team say hook
public hook_team_say(id)
{
	// Retrieve the player's chat
	static chat[192], name[32], users_team
	read_args(chat, 191)
	remove_quotes(chat)
	
	// Trying to fool us ?
	if(!chat[0])
		return PLUGIN_CONTINUE
	
	// Retrieve player's name
	get_user_name(id, name, charsmax(name))
	
	// Retrieve player's team
	users_team = _:cs_get_user_team(id)
	
	// Alive user
	if (is_user_alive(id))
	{
		if (zp_get_user_zombie(id))
			color_chat(1, id, users_team, RED,  "^3[%s](Team Message)^4 %s:^1 %s", zp_get_user_nemesis(id) ? "Nemesis" : "Zombie", name, chat)
		else
			color_chat(g_new_round ? 0 : 1, id, users_team, BLUE, "^3[%s](Team Message)^4 %s:^1 %s", zp_get_user_survivor(id) ? "Survivor" : "Human", name, chat)
	}
	
	// Dead user's chat
	else color_chat(1, id, users_team, users_team, "^3[%s](Team Message)^4 %s:^1 %s", users_team == _:CS_TEAM_SPECTATOR ? "SPEC" : "DEAD", name, chat)
	
	return PLUGIN_HANDLED
}

// An improved color chat function
color_chat(team_format, player, player_team, color, const chat_msg[], ...)
{
	// Format the chat message
	static msg[192]
	vformat(msg, charsmax(msg) - 1, chat_msg, 6)
	
	// We need to display the chat message to only the player's team
	if (team_format)
	{
		// Get amount of players present
		static id, i, players[32], count
		get_players(players, count, "e", team_names[player_team])
		
		// Loop through them
		for (i = 0; i < count; i++)
		{
			// Save player's id so we dont re-index
			id = players[i]
			
			// Just in case...
			if (!id) continue;
			
			// Send the colored text message
			message_begin(MSG_ONE_UNRELIABLE, g_msg_saytext, _, id)
			write_byte(player)
			write_string(msg)
			message_end()
			
		}
	}
	else
	{
		// Do we need to change the player's team ?
		if (player_team == color)
		{
			// Send the colored text message
			message_begin(MSG_BROADCAST, g_msg_saytext)
			write_byte(player)
			write_string(msg)
			message_end()
		}
		else
		{
			// Change his team first
			message_begin(MSG_BROADCAST, g_msg_teaminfo)
			write_byte(player)
			write_string(team_names[color])
			message_end()
			
			// Send the colored text message
			message_begin(MSG_BROADCAST, g_msg_saytext)
			write_byte(player)
			write_string(msg)
			message_end()
			
			// Restore player's team
			message_begin(MSG_BROADCAST, g_msg_teaminfo)
			write_byte(player)
			write_string(team_names[player_team])
			message_end()
		}
	}
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

Szerző:	kiki [ 2014.02.27. 18:46 ]
Hozzászólás témája:	Re: [ZP] Addon: Classes In Chat
Idézet: - Nem akartam magyarosítani mivel szerintem így jó. Ja, jóváhagyva.

Szerző:	nyalka17 [ 2014.02.27. 19:48 ]
Hozzászólás témája:	Re: [ZP] Addon: Classes In Chat
ez már fent van magyarul! A forumon és kiki darkangel tedtefel!

Szerző:	barnamate17 [ 2014.02.28. 17:28 ]
Hozzászólás témája:	Re: [ZP] Addon: Classes In Chat
adj egy linket akkor ha fent van!

Szerző:	ToxicDreams [ 2014.06.11. 15:40 ]
Hozzászólás témája:	Re: [ZP] Addon: Classes In Chat
[ZP] Kiegészítő : Típus a chatbe

Szerző:	Anonymous1337 [ 2014.06.11. 18:11 ]
Hozzászólás témája:	Re: [ZP] Addon: Classes In Chat
Jo lett volna magyarositani, de igy is jo.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/