hlmod.hu :: Legjobb sebesseg

hlmod.hu https://hlmod.hu/

Legjobb sebesseg https://hlmod.hu/viewtopic.php?f=101&t=15538	Oldal: 1 / 1

Szerző:

alfaanero [ 2014.04.26. 10:16 ]

Hozzászólás témája:

Legjobb sebesseg

Plugin Neve:	Legjobb sebesseg	Plugint készitette:	No Swear
Játék:	Counter-Strike	Kategória:	Statisztikai
Eredeti link:	Nincs megadva	Jóváhagyó:	crazyboy

ezzel a Pluginnal meglehet nézni,hogy ki volt a leggyorsabb a mappon és mennyi volt a sebessége

Cvarok:
sm_enabled 1 //Plugin ki/be
sm_upadte 0.1 //Milyen idonkent frissitsen HUD-ban
sm_terro 1 //Sebesseg meres

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <fakemeta>
#include <nvault>
#include <hamsandwich>
#include <amxmisc>

#define PLUGIN "SpeedMeter"
#define VERSION "2.1"
#define AUTHOR "No Swear"

#define ACCESS_RESET	 ADMIN_IMMUNITY
#define MAX_PLAYERS	 32

//Zmienne
new Float:fPlayerMaxSpeed[MAX_PLAYERS+1], Float: fPlayerActualSpeed[MAX_PLAYERS+1], szPlayerName[MAX_PLAYERS+1][32]
new szKeySpeed[32], szKeyName[34]
new bool:NewRecord = false, szMapName[32];
new szChampionName[32], Float:fMapRecord
new nVault
new HudObj
new pcvarEnabled, pcvarUpadte, pcvarTerro
new HudBot
public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	//Cvars
	pcvarEnabled = register_cvar("sm_enabled", "1")  //Plugin ki/be
	pcvarUpadte = register_cvar("sm_upadte", "0.1") //Milyen idonkent frissitsen HUD-ban
	pcvarTerro = register_cvar("sm_terro", "1") //Sebesseg meres
	//FM Part
	register_forward(FM_PlayerPreThink, "Fw_PlayerPreThink")
	register_forward(FM_ClientUserInfoChanged, "Fw_ClientUserInfoChanged", 1)
	//Others
	get_mapname(szMapName, charsmax(szMapName))
	HudObj = CreateHudSyncObj()
	register_clcmd("sm_reset", "CmdSpeedReset", ACCESS_RESET)
	//nVaultPart
	formatex(szKeySpeed,63,"%s-Speed",szMapName)
	formatex(szKeyName,63,"%s-Name",szMapName)
}
public plugin_cfg()
{
	nVault = nvault_open("SpeedRecord")
	if (nVault == INVALID_HANDLE)
		set_fail_state( "Error opening nVault");
		
	fMapRecord = float(nvault_get(nVault,szKeySpeed))
	nvault_get(nVault, szKeyName, szChampionName, 31)
	
	CreateHudBot()
}
public plugin_end() 
{
	if (!NewRecord)
		return
		
	new szNewRecord[32]
	float_to_str(fMapRecord, szNewRecord, 31)
	
	nvault_set(nVault,szKeySpeed, szNewRecord)
	nvault_set(nVault,szKeyName,szChampionName)
	nvault_close(nVault)
}
public client_authorized(id)
{
	if (!get_pcvar_num(pcvarEnabled))
		return
		
	get_user_name(id, szPlayerName[id], 31)
	fPlayerMaxSpeed[id] = 0.0
}
public Fw_ClientUserInfoChanged(id)
{
	get_user_name(id, szPlayerName[id], 31)
}
public Fw_PlayerPreThink(id)
{
	if (!is_user_alive(id)|| !get_pcvar_num(pcvarEnabled))
		return FMRES_IGNORED;
	
	if (get_pcvar_num(pcvarTerro) == 0 && get_user_team(id) == 1) 
		return FMRES_IGNORED;
		
	fPlayerActualSpeed[id] = Player_Speed(id)

if (fPlayerActualSpeed[id] > fPlayerMaxSpeed[id])
		fPlayerMaxSpeed[id] = fPlayerActualSpeed[id]		
	
	return FMRES_IGNORED;	
}
public CreateHudBot()
{
	HudBot = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString,"info_target"));
	
	if(!pev_valid(HudBot))
		return;
		
	set_pev(HudBot, pev_classname, "HudBot");
	set_pev(HudBot, pev_nextthink, get_gametime()+ get_pcvar_float(pcvarUpadte))
	
	RegisterHamFromEntity(Ham_Think, HudBot, "Think_HudBot")
}
public Think_HudBot(Bot)
{
	if (!pev_valid(Bot) || Bot != HudBot)
		return HAM_IGNORED;
		
	if (get_pcvar_num(pcvarEnabled))
	{
		new iPlayers[32], iNum, id
		get_players(iPlayers, iNum)
		for(new i= 0; i<iNum; i++)
		{
			id = iPlayers[i];
			if (!is_user_alive(id))
				continue
			
			set_hudmessage(255, 170, 42, 0.7, 0.2, 1, 0.01, get_pcvar_float(pcvarUpadte), 0.01, 0.01, 3)
			
			if (get_pcvar_num(pcvarTerro) == 0 && get_user_team(id) == 1) 
				ShowSyncHudMsg(id, HudObj, "Mapp Rekord: %.2f^nCsinalta: %s", fMapRecord,szChampionName)
			else
				ShowSyncHudMsg(id, HudObj, "Sebesseged: %.2f^nRekordod:: %.2f^nMapp Rekord: %.2f^nCsinalta:: %s", fPlayerActualSpeed[id], fPlayerMaxSpeed[id], fMapRecord,szChampionName)
			
			if (fPlayerMaxSpeed[id] > fMapRecord)
				SetNewRecord(fPlayerMaxSpeed[id], szPlayerName[id])
		}
	}
	
	set_pev(Bot, pev_nextthink, get_gametime()+get_pcvar_float(pcvarUpadte))
	
	return HAM_IGNORED;
}
stock SetNewRecord(Float:Speed, Name[32])
{
	fMapRecord = Speed
	szChampionName = Name
	NewRecord = true
}
stock Float:Player_Speed(id)
{
	new Float:fVect[3]
	pev(id, pev_velocity,fVect)
	return floatsqroot(fVect[0]*fVect[0]+fVect[1]*fVect[1])
}
public CmdSpeedReset(id, level, cid) 
{ 
	if(!cmd_access(id,level, cid, 1)) 
		return PLUGIN_HANDLED; 
	
	new iPlayers[32], iNum
	get_players(iPlayers, iNum)
	for(new i=0; i<iNum; i++)
		fPlayerMaxSpeed[iPlayers[i]] = 0.0
		
	SetNewRecord(0.0, "HeHaudeH")
	client_print(id, print_console, "Uj Rekord!!!!")
	return PLUGIN_HANDLED 
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1058\\ f0\\ fs16 \n\\ par }
*/

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	boldi99 [ 2014.04.26. 16:58 ]
Hozzászólás témája:	Re: Legjobb sebesseg
2 hete keresem ezt és végre most egész véletlenül rá kattintottam és meg van:D

Szerző:	alfaanero [ 2014.04.26. 19:30 ]
Hozzászólás témája:	Re: Legjobb sebesseg
örülök,hogy segíthettem,én is csak véletlen találtam rá miközben egy másik plugint kerestem.

Szerző:	alfaanero [ 2014.04.28. 21:13 ]
Hozzászólás témája:	Re: Legjobb sebesseg
Hibás ,hogy nincs jóváhagyva vagy valami hiba van vele????? ------------------------- UI: Köszönöm crazyboy

Szerző:	*~DestroyanonymousCL** [ 2014.05.03. 13:22 ]
Hozzászólás témája:	Re: Legjobb sebesseg
Köszi , nekem mukodik

Szerző:	*D3M0~** [ 2014.05.22. 16:47 ]
Hozzászólás témája:	Re: Legjobb sebesseg
PaintBall-ra Jó <3

Szerző:	KaszasKiller [ 2017.09.24. 09:19 ]
Hozzászólás témája:	Re: Legjobb sebesseg
Azt tudod hogy lehet nullázni? :D Hogy a map rekord 0 legyen megint. :D

Szerző:	fear_ezmegmi [ 2017.09.24. 12:46 ]
Hozzászólás témája:	Re: Legjobb sebesseg
KaszasKiller írta: Azt tudod hogy lehet nullázni? Hogy a map rekord 0 legyen megint. sm_reset

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/