hlmod.hu :: Ultimate Chat

hlmod.hu https://hlmod.hu/

Ultimate Chat https://hlmod.hu/viewtopic.php?f=101&t=16881	Oldal: 1 / 1

Szerző:

Jerikoo [ 2014.08.08. 23:16 ]

Hozzászólás témája:

Ultimate Chat

Plugin Neve:	Ultimate Chat	Plugint készitette:	[ --<-@ ]
Játék:	Counter-Strike	Kategória:	Szerver kezelés
Eredeti link:	Megnézem	Jóváhagyó:	crazyboy

Sziasztok!

Gondoltam feltöltök egy plugint ami szerintem elég hasznos (ha nem szeretnénk allchatet, akkor az Admin funkciókat használhatjuk), bár ez nézőpont kérdése.

A plugin lényege:

Cvarok segítségével beállíthatjuk hogy a játékosok és az adminok mit lássanak a chatben (pl.: A halott lássa-e az élő ellensége üzenetét). A cvaroknál betűkkel állítgathatjuk ezt!

A plugin az Admin funkciót csak kick joggal rendelkező Adminok esetén alkalmazza.
Ez a negyedik sorban állítható!

Kód:

#define ADMIN_LEVEL ADMIN_KICK

Cvarok:

uc_adminmode - Mit lásson az Admin a chatben -- Alap: "abcdefghij"
uc_playermode - Mit lásson a játékos a chatben -- Alap: "abe"

a = A halott játékos látja az élő csapattársa írását
b = A halott játékos látja az élő ellenség írását
c = Az élő játékos látja a halott csapattársa írását
d = Az élő játékos látja a halott ellenség írását
e = A halott játékos látja az élő csapattársa csapat üzenetét (say_team)
f = Az élő játékos látja a halott csapattársa csapat üzenetét (say_team)
g = A halott játékos látja a halott ellensége csapat üzenetét (say_team)
h = Az élő játékos látja az élő ellensége csapat üzenetét (say_team)
i = A halott játékos látja az élő ellensége csapat üzenetét (say_team)
j = Az élő játékos látja a halott ellensége csapat üzenetét (say_team)

Telepítés:
.amxx fájlt tedd a "cstrike/addons/amxmodx/plugins" mappába
.sma fájlt tedd a "cstrike/addons/amxmodx/scripting" mappába [Nem fontos]
Írd be a .amxx fájl nevét a "cstrike/addons/amxmodx/configs/plugins.ini" -be

Teszt volt, nálam 100%-osan működött!

Jó játékot!

#include <amxmodx>
#include <cstrike>

#define ADMIN_LEVEL ADMIN_KICK

/***************************************************************************************************
uc_adminmode & uc_playermode:

a = The dead can see the general chat messages of alive teammates
b = The dead can see the general chat messages of alive enemies
c = The alive can see the general chat messages of dead teammates
d = The alive can see the general chat messages of dead enemies
e = The dead can see the team messages of alive teammates
f = The alive can see the team messages of dead teamates
g = The dead can see the team messages of dead enemies
h = The alive can see the team messages of alive enemies
i = The dead can see the team messages of alive enemies
j = The alive can see the team messages of dead enemies
***************************************************************************************************/

/*
Author & Creator:

[ --<-@ ] Black Rose

Profile:      http://forums.alliedmods.net/member.php?u=7263

Email:        rob1n_@hotmail.com

Plugin link : http://forums.alliedmods.net/showthread.php?t=64698

Cred goes out to cs1.6 who requested it.
He also patiently tested it and found bugs.
*/

new g_msgid_SayText;
new g_maxPlayers;

new pcvar_adminmode;
new pcvar_playermode;

new const textchannels[][] = {
	"#Cstrike_Chat_T",
	"#Cstrike_Chat_CT",
	"#Cstrike_Chat_Spec",
	"#Cstrike_Chat_All",
	"#Cstrike_Chat_AllSpec",
	"#Cstrike_Chat_AllDead",
	"#Cstrike_Chat_T_Dead",
	"#Cstrike_Chat_CT_Dead"
};

public plugin_init() {
	register_plugin("Ultimate Chat", "1.2", "[ --<-@ ]");
	pcvar_adminmode = register_cvar("uc_adminmode", "abcdefghij");
	pcvar_playermode = register_cvar("uc_playermode", "abe");
	
	g_msgid_SayText = get_user_msgid("SayText");
	g_maxPlayers = get_maxplayers();
	
	register_clcmd("say", "HandleSay");
	register_clcmd("say_team", "HandleSay");
}

public HandleSay(id) {
	
	if ( ! is_user_connected(id) )
		return PLUGIN_HANDLED;
	
	new message[192], is_alive = is_user_alive(id), is_admin;
	
	read_argv(0, message, 5);
	new is_team_msg = message[3] == '_';
	
	get_pcvar_string(pcvar_playermode, message, 31);
	new playermode = read_flags(message);
	
	get_pcvar_string(pcvar_adminmode, message, 31);
	new adminmode = read_flags(message);
	
	new CsTeams:userTeam = cs_get_user_team(id);
	
	read_args(message, 191);
	remove_quotes(message);
	trim(message);
	
	for ( new i = 0 ; i < g_maxPlayers ; i++ ) {
		
		if ( ! is_user_connected(i) )
			continue;
		
		is_admin = get_user_flags(i) & ADMIN_LEVEL;
		
		if (
		( ( ( adminmode &   1 && is_admin ) || playermode &   1 ) && ! is_team_msg &&   is_alive && ! is_user_alive(i) && userTeam == cs_get_user_team(i) ) ||
		( ( ( adminmode &   2 && is_admin ) || playermode &   2 ) && ! is_team_msg &&   is_alive && ! is_user_alive(i) && userTeam != cs_get_user_team(i) ) ||
		( ( ( adminmode &   4 && is_admin ) || playermode &   4 ) && ! is_team_msg && ! is_alive &&   is_user_alive(i) && userTeam == cs_get_user_team(i) ) ||
		( ( ( adminmode &   8 && is_admin ) || playermode &   8 ) && ! is_team_msg && ! is_alive &&   is_user_alive(i) && userTeam != cs_get_user_team(i) ) ||
		( ( ( adminmode &  16 && is_admin ) || playermode &  16 ) && is_team_msg && userTeam == cs_get_user_team(i) &&   is_alive && ! is_user_alive(i) ) ||
		( ( ( adminmode &  32 && is_admin ) || playermode &  32 ) && is_team_msg && userTeam == cs_get_user_team(i) && ! is_alive &&   is_user_alive(i) ) ||
		( ( ( adminmode &  64 && is_admin ) || playermode &  64 ) && is_team_msg && userTeam != cs_get_user_team(i) && ! is_alive && ! is_user_alive(i) ) ||
		( ( ( adminmode & 128 && is_admin ) || playermode & 128 ) && is_team_msg && userTeam != cs_get_user_team(i) &&   is_alive &&   is_user_alive(i) ) ||
		( ( ( adminmode & 256 && is_admin ) || playermode & 256 ) && is_team_msg && userTeam != cs_get_user_team(i) &&   is_alive && ! is_user_alive(i) ) ||
		( ( ( adminmode & 512 && is_admin ) || playermode & 512 ) && is_team_msg && userTeam != cs_get_user_team(i) && ! is_alive &&   is_user_alive(i) )
		) {
			message_begin(MSG_ONE_UNRELIABLE, g_msgid_SayText, {0,0,0}, i);
			write_byte(id);
			write_string(textchannels[get_user_text_channel(id, userTeam, is_team_msg)]);
			write_string("");
			write_string(message);
			message_end();
		}
	}
	return PLUGIN_CONTINUE;
}

stock get_user_text_channel(id, CsTeams:userTeam, is_team_msg) {
    if ( is_team_msg ) {
        switch ( userTeam ) {
            case CS_TEAM_T : {
                if ( is_user_alive(id) )
                    return 0;
                else
                    return 6;
            }
            case CS_TEAM_CT : {
                if ( is_user_alive(id) )
                    return 1;
                else
                    return 7;
            }
            case CS_TEAM_SPECTATOR, CS_TEAM_UNASSIGNED :
                return 2;
        }
    }
    
    else {
        if ( is_user_alive(id) )
            return 3;
        else if ( userTeam == CsTeams:3 )
            return 4;
    }
    return 5;
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	Applee [ 2014.08.09. 23:09 ]
Hozzászólás témája:	Re: Ultimate Chat
Szép! Ez nem akad össze az előtag pluginnal?

Szerző:	pixxa112 [ 2014.08.10. 12:18 ]
Hozzászólás témája:	Re: Ultimate Chat
Applee írta: Szép! Ez nem akad össze az előtag pluginnal? Ha az allchattel össze akad akkor ezzel is.. (Szerintem)

Szerző:	FonoK [ 2017.01.25. 16:50 ]
Hozzászólás témája:	Re: Ultimate Chat
Hasznos kis pllugin, köszönöm szépen a feltöltést. Mondjuk a halott/élő közti chates kommunikáció megszüntetése gondolom a súgás elkerülése végett lett kitalálva. Mivel a játékosoknak lehetősége van hangalapú kommunikációra, így szerintem ez (ha erre a célra használnák) felesleges.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/