hlmod.hu ::Deathrun: Ingyen Kör

hlmod.hu https://hlmod.hu/

Deathrun: Ingyen Kör https://hlmod.hu/viewtopic.php?f=101&t=17713	Oldal: 1 / 1

Szerző:

Badboy.killer [2014.10.24. 21:06 ]

Hozzászólás témája:

Deathrun: Ingyen Kör

Plugin Neve:	Deathrun Ingyen Kör	Plugint készitette:	xPaw
Játék:	Counter-Strike	Kategória:	Általános célú
Eredeti link:	Megnézem	Jóváhagyó:	norbee.16

Deathrun Ingyen Kör

A plugin engedélyezi a terroristák számára, hogy szabad kört szavaztassanak. A szabad kör előtt van idő, hogy a játékosok szavazzanak, akarják-e vagy sem. Megszavazás után minden játékosnál csak kés van, a terroristáknál a nyomógombok inaktívak. A terroristák ezt az opciót kétszer engedélyezhetik. A szabad körök közti "x" kör késleltetést a cvar segítségével lehet beállítani.

Parancsok:

- /free és /freeround - szabad kör szavazásának indítása

Cvarok:

- freerun_wait_rounds 0-∞ - szabad körök közötti késleltetés (alap: 5 kör)

Telepítés:

amxx -> addons/amxmodx/plugins mappába
Majd írd be az addons/amxmodx/configs/plugins.ini -be a plugin nevét.

/*
	Ford�totta: BBk
*/

#include < amxmodx >
#include < cstrike >
#include < fakemeta >
#include < hamsandwich >

const m_toggle_state = 41;

#define TASK_VOTE  237439

enum _:VOTES {
	VOTE_YES,
	VOTE_NO
};

new g_iVotes[ VOTES ];
new bool:g_bVoted[ 33 ];
new bool:g_bFreeRound;
new bool:g_bWillFree;
new bool:g_bVoting;
new g_iCountdown;
new g_iRounds;
new g_iPrinted;
new g_iMenuID;
new g_iMaxplayers;
new g_iMsgSayText;
new g_pWaitRounds;

public plugin_init( ) {
	new const VERSION[ ] = "1.0";
	
	register_plugin( "Halalfutam: Szabad-Kor", VERSION, "xPaw" );
	
	new p = register_cvar( "deathrun_freeround", VERSION, FCVAR_SERVER | FCVAR_SPONLY );
	set_pcvar_string( p, VERSION );
	
	g_pWaitRounds = register_cvar( "freerun_wait_rounds", "5" );
	g_iMaxplayers = get_maxplayers( );
	g_iMsgSayText = get_user_msgid( "SayText" );
	g_iMenuID     = register_menuid( "DrunFreeRoundVote" );
	
	register_menucmd( g_iMenuID, ( MENU_KEY_1 | MENU_KEY_2 | MENU_KEY_0 ), "HandleVote" );
	
	register_clcmd( "say /free",      "CmdFreeRound" );
	register_clcmd( "say /freeround", "CmdFreeRound" );
	
	RegisterHam( Ham_Use, "func_rot_button", "FwdHamUse_Button" );
	RegisterHam( Ham_Use, "func_button",     "FwdHamUse_Button" );
	RegisterHam( Ham_Use, "button_target",   "FwdHamUse_Button" );
	
	register_event( "CurWeapon", "EventCurWeapon", "be", "1=1", "2!29" );
	register_event( "HLTV",      "EventNewRound",  "a",  "1=0", "2=0" );
	register_event( "TextMsg",   "EventRestart",   "a",  "2&#Game_C", "2&#Game_w" );
}

public EventNewRound( ) {
	if( g_bFreeRound ) {
		g_bFreeRound = false;
		g_iRounds    = 0;
		g_iPrinted   = 0;
		
		return;
	}
	else if( g_bWillFree ) {
		g_iRounds    = 0;
		g_iPrinted   = 0;
		g_bWillFree  = false;
		g_bFreeRound = true;
		
		set_task( 2.0, "PrintMessage" );
		
		return;
	}
	
	g_iRounds++;
	
	if( g_iPrinted < 4 && g_iRounds >= get_pcvar_num( g_pWaitRounds ) ) {
		GreenPrint( 0, "Ez a szerver^3 a Deathrun Szabad-Kor Rendszert hasznalja^1 Keszitette:^4 xPaw^1, ird be^4 /free^1 a szavazas megkezdesehez!" );
		
		g_iPrinted++;
	}
}

public EventRestart( ) {
	g_bFreeRound = false;
	g_bWillFree  = false;
	g_bVoting    = false;
	g_iPrinted   = 0;
	g_iRounds    = 0;
	
	remove_task( TASK_VOTE );
}

public EventCurWeapon( id )
	if( g_bFreeRound )
		engclient_cmd( id, "weapon_knife" );

public CmdFreeRound( id ) {
	if( cs_get_user_team( id ) != CS_TEAM_T ) {
		GreenPrint( id, "Ez a parancs csak a terroristak szamara elerheto!" );
		
		return PLUGIN_CONTINUE;
	}
	else if( g_bFreeRound ) {
		GreenPrint( id, "Mar szabad-kor van!" );
		
		return PLUGIN_CONTINUE;
	}
	else if( g_bVoting ) {
		GreenPrint( id, "A szavazas mar folyamatban van!" );
		
		return PLUGIN_CONTINUE;
	}
	else if( g_bWillFree ) {
		GreenPrint( id, "A Kovetkezo kor szabad lesz!" );
		
		return PLUGIN_CONTINUE;
	}
	
	new iWaitRounds = get_pcvar_num( g_pWaitRounds ) - g_iRounds;
	
	if( iWaitRounds > 0 ) {
		GreenPrint( id, "Varnod kell meg^3 %i^1 kort a szavazas elinditasahoz!", iWaitRounds );
		
		return PLUGIN_CONTINUE;
	}
	
	new szName[ 32 ];
	get_user_name( id, szName, 31 );
	
	GreenPrint( 0, "A Szavazas elkezdodott:^3 %s^1.", szName );
	
	set_hudmessage( 222, 70, 0, -1.0, 0.3, 1, 3.0, 3.0, 2.0, 1.0, -1 );
	show_hudmessage( 0, "A Szabad-kor szavazasa elkezdodott: %s^nA szavazas hamarosan megkezdodik.", szName );
	
	g_iVotes[ VOTE_YES ] = 0;
	g_iVotes[ VOTE_NO ] = 0;
	g_iRounds = 0;
	g_bVoting = true;
	g_iPrinted = 0;
	g_bWillFree = false;
	
	arrayset( g_bVoted, false, 32 );
	
	remove_task( TASK_VOTE );
	g_iCountdown = 15;
	
	set_task( 3.5, "PreTask", TASK_VOTE );
	
	return PLUGIN_CONTINUE;
}

public PrintMessage( ) {
	GreenPrint( 0, "Ez egy^4 Szabad kor^1, nincsenek fegyverek es csapdak!" );
	
	set_hudmessage( 0, 90, 0, -1.0, 0.35, 1, 3.0, 3.0, 2.0, 1.0, -1 );
	show_hudmessage( 0, "SZABAD-KOR!" );
}

public PreTask( ) {
	remove_task( TASK_VOTE );
	
	set_task( 1.0, "TaskVoteTimer", TASK_VOTE, _, _, "b" );
}

public TaskVoteTimer( ) {
	g_iCountdown--;
	
	if ( !g_iCountdown ) {
		remove_task( TASK_VOTE );
		
		g_bVoting = false;
		
		new iVotes, iHighVotes, iHighVotesID;
		
		for( new i; i < VOTES; i++ ) {
			iVotes = g_iVotes[ i ];
			
			if( iVotes >= iHighVotes ) {
				iHighVotes = iVotes;
				iHighVotesID = i;
			}
		}
		
		if( iHighVotes > 0 ) {
			if( iHighVotesID == VOTE_YES )
				g_bWillFree = true;
			
			GreenPrint( 0, "A szavazas veget ert. %s^1 [^3 %i^1 szavazata (^4%i%%) ^1]", g_bWillFree ? "A Kovetkezo kor szabad!" : "A Kovetkezo kor nem szabad!", iHighVotes, GetPercent( g_iVotes[ iHighVotesID ], g_iVotes[ VOTE_YES ] + g_iVotes[ VOTE_NO ] ) );
		} else
			GreenPrint( 0, "A szavazasnak vege. Nincs szavazat." );
		
		for( new i = 1; i <= g_iMaxplayers; i++ )
			if( is_user_connected( i ) )
				ShowVoteMenu( i, 1 );
	} else {
		for( new i = 1; i <= g_iMaxplayers; i++ )
			if( is_user_connected( i ) )
				ShowVoteMenu( i, 0 );
	}
}

ShowVoteMenu( id, bResults = 0 ) {
	new iMenu = GetUserMenu( id );
	
	if( ( iMenu && iMenu != g_iMenuID ) && g_iCountdown <= 14 )
		return;
	
	menu_cancel( id ); // Radios and other piece of shit bug fix :D
	
	new szMenu[ 196 ], iLen;
	
	if( bResults )
		iLen = formatex( szMenu, charsmax( szMenu ), "\rA szavazas eredmenyei:^n^n" );
	else
		iLen = formatex( szMenu, charsmax( szMenu ), "\rSzeretnel egy szabad kort?^n^n" );
	
	new iVotesTotal = g_iVotes[ VOTE_YES ] + g_iVotes[ VOTE_NO ];
	
	iLen += formatex( szMenu[ iLen ], charsmax( szMenu ) - 1, "\r1. \wIgen \d(%i%%)^n", GetPercent( g_iVotes[ VOTE_YES ], iVotesTotal ) );
	iLen += formatex( szMenu[ iLen ], charsmax( szMenu ) - 1, "\r2. \wNem \d(%i%%)^n^n", GetPercent( g_iVotes[ VOTE_NO ], iVotesTotal ) );
	
	if( bResults ) {
		if( g_bWillFree )
			iLen += formatex( szMenu[ iLen ], charsmax( szMenu ) - 1, "  \yA Kovetkezo kor szabad lesz!" );
		else {
			if( !iVotesTotal )
				iLen += formatex( szMenu[ iLen ], charsmax( szMenu ) - 1, "  \yNincs szavazat!" );
		}
		
		show_menu( id, ( MENU_KEY_1 | MENU_KEY_2 | MENU_KEY_0 ), szMenu, -1, "DrunFreeRoundVote" );
		
		set_task( 5.0, "CloseMenu", id );
	} else {
		iLen += formatex( szMenu[ iLen ], charsmax( szMenu ) - 1, "  \dvisszaszamlalas: \r%i", g_iCountdown );
		
		show_menu( id, ( MENU_KEY_1 | MENU_KEY_2 ), szMenu, -1, "DrunFreeRoundVote" );
	}
}

public CloseMenu( id )
	if( GetUserMenu( id ) == g_iMenuID )
		client_cmd( id, "slot1" );

GetUserMenu( id ) {
	new iMenu, iKeys;
	get_user_menu( id, iMenu, iKeys );
	
	return iMenu;
}

public HandleVote( id, iKey ) {
	if( !g_bVoting || !task_exists( TASK_VOTE ) )
		return;
	
	if( g_bVoted[ id ] ) {
		ShowVoteMenu( id, 0 );
		
		return;
	}
	
	if( iKey > 1 )
		return;
	
	new iVotes = ( /* get_user_flags( id ) & ADMIN_KICK ||*/ get_user_team( id ) == 1 ) ? 2 : 1;
	
	g_bVoted[ id ] = true;
	g_iVotes[ iKey ] += iVotes;
	
	new szName[ 32 ];
	get_user_name( id, szName, 31 );
	
	GreenPrint( 0, "^3%s^1 szavazata:^4 %s^1. [^4+%i^1 szavazat]", szName, iKey == VOTE_YES ? "Igen" : "Nem", iVotes);
	
	ShowVoteMenu( id, 0 );
}

public FwdHamUse_Button( iEntity, id, iActivator, iUseType, Float:flValue ) {
	if( g_bFreeRound && iUseType == 2 && flValue == 1.0 && is_user_alive( id )
	&&  get_user_team( id ) == 1 && get_pdata_int( iEntity, m_toggle_state, 4 ) == 1 ) {
		/* Oh hi this code actually happen! :D */
		
		set_hudmessage( 0, 100, 255, -1.0, 0.25, 0, 2.0, 2.0, 0.2, 0.2, 3 );
		show_hudmessage( id, "Szabad kor!^nA gombok inaktivak!" );
		
		return HAM_SUPERCEDE;
	}
	
	return HAM_IGNORED;
}

GetPercent( is, of ) // Brad
	return ( of != 0 ) ? floatround( floatmul( float( is ) / float( of ), 100.0 ) ) : 0;

GreenPrint( id, const message[ ], any:... ) {
	static szMessage[ 192 ], iLen;
	if( !iLen )
		iLen = formatex( szMessage, 191, "^4[Halalfutam Szabad-Kor]^1 " );
	
	vformat( szMessage[ iLen ], 191 - iLen, message, 3 );
	
	message_begin( id ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, g_iMsgSayText, _, id );
	write_byte( id ? id : 1 );
	write_string( szMessage );
	message_end( );
	
	return 1;
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	DeR0iD [2014.10.25. 09:10 ]
Hozzászólás témája:	Re: Deathrun: Ingyen Kör
Ez nem a legjobb plugin Ha terrorista végig nyomja a gombokat és utána írjbe hogy "free" akkor is free van.

Szerző:	Badboy.killer [2014.10.25. 10:41 ]
Hozzászólás témája:	Re: Deathrun: Ingyen Kör
Valaki kérte, nem láttam fent, gondoltam felteszem, nem tudom, hogy működik, több mint fél éve nem néztem fel, meg nem játszok már, nem tudom ellenőrizni. Ha megtennéd, hogy ellenőrzöd, hogy lefordítja-e a fordító, nem-e ejtettem benne hibát. Köszönöm

Szerző:	MeSter [2014.10.25. 11:05 ]
Hozzászólás témája:	Re: Deathrun: Ingyen Kör
Badboy.killer írta: Valaki kérte, nem láttam fent, gondoltam felteszem, nem tudom, hogy működik, több mint fél éve nem néztem fel, meg nem játszok már, nem tudom ellenőrizni. Ha megtennéd, hogy ellenőrzöd, hogy lefordítja-e a fordító, nem-e ejtettem benne hibát. Köszönöm Kód: Welcome to the AMX Mod X 1.8.1-300 Compiler. Copyright (c) 1997-2013 ITB CompuPhase, AMX Mod X Team Header size: 1408 bytes Code size: 8200 bytes Data size: 6484 bytes Stack/heap size: 16384 bytes; max. usage is unknown, due to recursion Total requirements: 32476 bytes Done. Leforditsa!

Oldal: 1 / 1	Minden időpont UTC+01:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/