Szint rendszer (KÉS)

Megválaszolatlan témák | Aktív témák

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Navigáció

Főmenü

Kezdőlap

Fórum

Kapcsolat

Képfeltöltő Amx Mod X

Letöltések

Pluginok

Fordító (Compiler) SourceMod

Letöltések

Pluginok

Fordító (Compiler) EventScript

Letöltések

Magyar scriptek Pályák

Half-Life

Half-Life 2

Jelenlévő felhasználók

Jelenleg 323 felhasználó van jelen :: 0 regisztrált, 0 rejtett és 323 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: nincs regisztrált felhasználó az elmúlt 5 percben aktív felhasználók alapján

[ Ki van itt ]

Utoljára aktív

Kereső

Szint rendszer (KÉS)

Moderátor: Fórum Moderátor

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 2

[ 16 hozzászólás ]

Oldal 1 2 Következő

Nyomtatóbarát verzió | Barát értesítése e-mailben

Előző téma | Következő téma

Szerző

Üzenet

loleee

Hozzászólás témája: Szint rendszer (KÉS)

HozzászólásElküldve: 2015.02.22. 02:01

Offline

Csatlakozott: 2015.02.14. 01:11
Hozzászólások: 28
Megköszönték neki: 6 alkalommal

Plugin Neve:	Szint rendszer (KÉS)	Plugint készitette:	SnusMumrikeN
Játék:	Counter-Strike	Kategória:	Admin parancsok
Eredeti link:	Nincs megadva	Jóváhagyó:	ultraibolya

Leírás:

Felmerülhet bennetek a kérdés mire jó a plugin?
Azt a célt szolgálja ha megölsz valakit kapsz pontot
Ha meghalsz el veszik valamennyi pontod

És mire jók a pontok?
Szintek találhatók melyet az ini fileba tudtok szerkeszteni.
Ezeket a szinteket modellekre lehet beosztani
(Pl: "kellő pont" "szint neve" "v_modell" "p_modell"
"0" "Új játékos" "models/v_knife.mdl" "models/p_knife.mdl")

De ezt persze meglehet fegyver skinnel is csinálni!
(Pl: "kellő pont" "szint neve" "v_modell" "p_modell"
"0" "Új játékos" "models/v_ak47.mdl" "models/p_ak47.mdl")
Használjátok egészséggel!

Kellő include-ok:
colorchat: https://forums.alliedmods.net/showthread.php?t=94960
nvault_util: https://forums.alliedmods.net/showthread.php?t=139584

Cvarok:
g_pCvar_Kill = register_cvar("cvar_kill", "2") // (+2) Ha meg ölsz egy embert ezzel tudod állítani hány pontot kapjon

g_pCvar_Headshot = register_cvar("cvar_headshot", "4") // (+4) Ha fejbelősz valakit ezzel tudod állítani hány pontot kapjon a pontokhoz

g_pCvar_Win = register_cvar("cvar_win", "3") // (+3) Ha megnyerik a kört ezzel tudod állítani hány pontot kapjonak
g_pCvar_Dying = register_cvar("cvar_dying", "2") // (-2) Ha meghal ezzel tudod állítani hány pontot vegyen el
g_pCvar_Suicide = register_cvar("cvar_suicide", "3") // (-3) Ha ki killeli magát vagy (pl. le esik valahonnan) ezzel tudod állítani hány pontot vegyen el.
g_pCvar_Logadmin = register_cvar("cvar_logadmin", "0") // (alap 0 ha szeretnéd, hogy mentse akkor ír át 1-re!) ide menti az admin által végrehajtott addolásokat: (addons/amxmodx/logs/levelmod.txt)
[Ezeket az értékeket az amxmodmenün belül a pluginscvarsba szerkeztheted!]

Telepítés:
Mennyünk fel az FTP-re vagy házi szerver esetén a cs mappába
[cstrike/addons/amxmodx/plugins] Ebbe a mappába tegyük bele az .amxx filet!
[cstrike] Ebbe a mappába pedig csak egyszerűen húzzátok bele a .zip filban lévő mappákat!

Parancsok:
/lvl
/szint
/top
/pontadas (Csak ADMIN_LEVEL_A jog tudja használni!)

#include <amxmodx>
#include <cstrike>
#include <engine>
#include <hamsandwich>
enum Color
{
	NORMAL = 1, // clients scr_concolor cvar color
	GREEN, // Green Color
	TEAM_COLOR, // Red, grey, blue
	GREY, // grey
	RED, // Red
	BLUE, // Blue
}

new TeamName[][] = 
{
	"",
	"TERRORIST",
	"CT",
	"SPECTATOR"
}

ColorChat(id, Color:type, const msg[], {Float,Sql,Result,_}:...)
{
	static message[256];

switch(type)
	{
		case NORMAL: // clients scr_concolor cvar color
		{
			message[0] = 0x01;
		}
		case GREEN: // Green
		{
			message[0] = 0x04;
		}
		default: // White, Red, Blue
		{
			message[0] = 0x03;
		}
	}

vformat(message[1], 251, msg, 4);
	message[192] = '^0';

static team, ColorChange, index, MSG_Type;
	
	if(id)
	{
		MSG_Type = MSG_ONE;
		index = id;
	} else {
		index = FindPlayer();
		MSG_Type = MSG_ALL;
	}
	
	team = get_user_team(index);
	ColorChange = ColorSelection(index, MSG_Type, type);

ShowColorMessage(index, MSG_Type, message);
		
	if(ColorChange)
	{
		Team_Info(index, MSG_Type, TeamName[team]);
	}
}

ShowColorMessage(id, type, message[])
{
	message_begin(type, get_user_msgid("SayText"), _, id);
	write_byte(id)		
	write_string(message);
	message_end();	
}

Team_Info(id, type, team[])
{
	message_begin(type, get_user_msgid("TeamInfo"), _, id);
	write_byte(id);
	write_string(team);
	message_end();

return 1;
}

ColorSelection(index, type, Color:Type)
{
	switch(Type)
	{
		case RED:
		{
			return Team_Info(index, type, TeamName[1]);
		}
		case BLUE:
		{
			return Team_Info(index, type, TeamName[2]);
		}
		case GREY:
		{
			return Team_Info(index, type, TeamName[0]);
		}
	}

return 0;
}

FindPlayer()
{
	static i;
	i = -1;

while(i <= get_maxplayers())
	{
		if(is_user_connected(++i))
		{
			return i;
		}
	}

return -1;
}

/*	
	nVault Utility
	     v0.1
	   by bugsy
*/

#if defined _nvault_util_included
	#endinput
#endif
#define _nvault_util_included

#if !defined _nvault_included
	#include <nvault>
#endif

#if !defined _amxmisc_included
	#include <amxmisc>
#endif

#define MAX_KEY_LEN	255
#define MAX_VAL_LEN	512
#define BUFFER_SIZE	128

#define OFFSET_ENTRYCOUNT	6
#define OFFSET_DATASTART	10

#define MinSize(%1,%2)	(%1<%2?%1:%2)

stock nvault_util_open( const szVault[] )
{
	new szFile[ 64 ];
	
	formatex( szFile[ get_datadir( szFile , charsmax( szFile ) ) ] , charsmax( szFile ) , "/vault/%s.vault" , szVault );
	
	return fopen( szFile , "rb" );
}

stock nvault_util_close( iVaultHandle )
{
	fclose( iVaultHandle );
}

stock nvault_util_count( iVaultHandle )
{
	new DataBuffer[ 1 ];

fseek( iVaultHandle , OFFSET_ENTRYCOUNT , SEEK_SET );
	fread_raw( iVaultHandle , DataBuffer , 1 , BLOCK_INT );
	
	return DataBuffer[ 0 ];
}

stock nvault_util_read( iVaultHandle , iOffset , szKey[] , iKeySize , szVal[] , iValSize , &iTimeStamp )
{
	static iKeyLen , iValLen , DataBuffer[ BUFFER_SIZE ];
	
	fseek( iVaultHandle , iOffset ? iOffset : OFFSET_DATASTART , SEEK_SET );
	
	fread_raw( iVaultHandle , DataBuffer , 1 , BLOCK_INT );
	iTimeStamp = DataBuffer[ 0 ];
	
	fread_raw( iVaultHandle , DataBuffer , 1 , BLOCK_BYTE );
	iKeyLen = DataBuffer[ 0 ] & 0xFF;
	
	fread_raw( iVaultHandle , DataBuffer , 1 , BLOCK_SHORT );
	iValLen = DataBuffer[ 0 ] & 0xFFFF;
	
	fread_raw( iVaultHandle , DataBuffer , iKeyLen , BLOCK_CHAR );
	ReadString( szKey , MinSize( iKeySize , iKeyLen ) , DataBuffer , sizeof( DataBuffer ) );
	
	fread_raw( iVaultHandle , DataBuffer , iValLen , BLOCK_CHAR );
	ReadString( szVal , MinSize( iValSize , iValLen ) , DataBuffer , sizeof( DataBuffer ) );
	
	return ftell( iVaultHandle );
}

stock nvault_util_readall( iVaultHandle , const szForwardFunc[] , Data[] = {0} , iSize=0 )
{
	new iFwdHandle = CreateMultiForward( szForwardFunc , ET_IGNORE , FP_CELL , FP_CELL , FP_STRING , FP_STRING , FP_CELL , FP_STRING , FP_CELL );
	
	if ( iFwdHandle <= 0 )
		set_fail_state( "nvault_util_readall() failed to create forward" );
		
	new iRet , iPos , iNumEntries = nvault_util_count( iVaultHandle );
	new szKey[ MAX_KEY_LEN ] , szValue[ MAX_VAL_LEN ] , iTimeStamp;

for ( new iCurrent = 1 ; iCurrent <= iNumEntries ; iCurrent++ )
	{
		iPos = nvault_util_read( iVaultHandle , iPos , szKey , charsmax( szKey ) , szValue , charsmax( szValue ) , iTimeStamp );
		
		ExecuteForward( iFwdHandle , iRet , iCurrent , iNumEntries , szKey , szValue , iTimeStamp , Data , iSize );
	}
	
	return iRet;
}

stock nvault_util_pos( iVaultHandle )
{
	return ftell( iVaultHandle );
}

stock ReadString( szDestString[] , iMaxLen , const SourceData[] , iSourceSize )
{
	/*    Memory layout
	szDest[ 0 ] = Source{ 3 }
	szDest[ 1 ] = Source{ 2 }
	szDest[ 2 ] = Source{ 1 }
	szDest[ 3 ] = Source{ 0 }
	szDest[ 4 ] = Source{ 7 }
	szDest[ 5 ] = Source{ 6 }
	szDest[ 6 ] = Source{ 5 }
	szDest[ 7 ] = Source{ 4 }
	szDest[ 8 ] = Source{ 11 }
	*/
	   
	new iDestPos = -1;
	new iBytePos = 4;
	new iOffset = 1;
	new iSourceMax = ( iSourceSize * 4 );
	
	while ( ( ++iDestPos < iMaxLen ) && ( iBytePos < iSourceMax ) )
	{
		szDestString[ iDestPos ] = SourceData{ iBytePos - iOffset++ };

if ( iDestPos && ( ( iDestPos % 4 ) == 3 ) )
		{
			iBytePos += 4;
			iOffset = 1;
		}
	}
	
	szDestString[ iDestPos ] = EOS;
}

#define TAG "Szint mod"

#define ADMIN_LEVEL ADMIN_KICK

#define MaxLevels 100

#define TopNumber 15

#define MAX_PLAYERS 32

new g_pCvar_Kill, g_pCvar_Headshot, g_pCvar_Win
new g_pCvar_Suicide, g_pCvar_Dying, g_pCvar_Logadmin

new g_iHeadshot, g_iKill, g_iDying
new g_iWin, g_iSuicide, g_iLogadmin

new g_iLevel[MAX_PLAYERS +1], g_iPoints[MAX_PLAYERS +1], g_iName[MAX_PLAYERS +1]
new g_szLevels[MaxLevels], g_szLevelNames[MaxLevels][MAX_PLAYERS +1]
new g_szKnife[MaxLevels][2][64], bool:g_bGiveRemove

new const SPECIAL_CHAR[2] = "-"
new g_iVault
new g_szTopMotd[1024]

//function by fysiks
public plugin_precache( )
{
	new cfgdir[64]
	get_localinfo("amxx_configsdir", cfgdir, charsmax(cfgdir))
	format(cfgdir, charsmax(cfgdir), "%s/levelmod.ini", cfgdir)
	
	new file = fopen(cfgdir, "rt");
	
	if( file )
	{
		new i = 0;
		new szLevel[5], sfLineData[128];
		
		while( !feof(file) && i < MaxLevels )
		{
			fgets(file, sfLineData, charsmax(sfLineData));
			
			if( !sfLineData[0] || sfLineData[0] == ';' || sfLineData[0] == '/' && sfLineData[1] == '/' ) continue;
			
			parse(sfLineData, szLevel, charsmax(szLevel), g_szLevelNames[i], charsmax(g_szLevelNames[]), g_szKnife[i][0], charsmax(g_szKnife[][]), g_szKnife[i][1], charsmax(g_szKnife[][]));
			g_szLevels[i] = str_to_num(szLevel);
			
			precache_model(g_szKnife[i][0]);
			precache_model(g_szKnife[i][1]);
			i++;
		}

fclose(file);
	}
	else
	{
		set_fail_state("amxmodx/configs/levelmod.ini doesnt exist. Stops plugin.");
	}
}

public plugin_cfg( )
{
	g_iHeadshot = get_pcvar_num(g_pCvar_Headshot)
	g_iKill = get_pcvar_num(g_pCvar_Kill)
	g_iSuicide = get_pcvar_num(g_pCvar_Suicide)
	g_iWin = get_pcvar_num(g_pCvar_Win)
	g_iDying = get_pcvar_num(g_pCvar_Dying)
	g_iLogadmin = get_pcvar_num(g_pCvar_Logadmin)
}

public plugin_init()
{
	register_plugin("Szint plugin", "1.0", "SnusMumrikeN")
	
	register_clcmd("say", "Cmd_Say")
	register_clcmd("say_team", "Cmd_Say")
	
	register_clcmd( "PointsAmount", "PointsAction" )
	
	g_pCvar_Kill = register_cvar("cvar_kill", "2") // alap +2
	g_pCvar_Headshot = register_cvar("cvar_headshot", "4") // alap +4
	g_pCvar_Win = register_cvar("cvar_win", "3") // alap +3
	g_pCvar_Dying = register_cvar("cvar_dying", "2") // alap -2
	g_pCvar_Suicide = register_cvar("cvar_suicide", "3") // alap -3
	g_pCvar_Logadmin = register_cvar("cvar_logadmin", "1") // alap 0
	
	register_event( "DeathMsg", "Event_DeathMsg", "a" );
	
	register_message(get_user_msgid("TextMsg") ,"Message_Win")
	
	RegisterHam( Ham_Item_Deploy, "weapon_knife", "Ham_KnifeDeploy", 1 );
	
	g_iVault = nvault_open("levelmod")
	FormatTop(TopNumber)
	
	set_task( 300.0, "Task_Advertise", .flags="b" );
}

public plugin_end() 
	nvault_close(g_iVault)

public Cmd_Say(id)
{
	new args[101], arg1[10], arg2[64]
	read_args(args, charsmax(args))
	remove_quotes(args)
	parse(args, arg1, charsmax(args), arg2, charsmax(arg2))
	
	if(equali(arg1, "/szint" ) || equali(arg1, "/lvl" ))
	{
		new iPlayer = cmd_target(id, arg2, 0)
		if(!arg2[0] || !iPlayer)
		{
			if( g_szLevels[g_iLevel[id]+1] != 0)
			{
				ColorChat(id, GREY, "^4[%s]^1 Következő szint:^3 %i ^1[^3%s^1] | Ennyi pont kell a következő szinthez:^3 %i", TAG, g_iLevel[id]+1, g_szLevelNames[g_iLevel[id]+1], g_szLevels[g_iLevel[id]+1] - g_szLevels[g_iLevel[id]]);
				ColorChat(id, GREY, "^4[%s]^1 Jelenlegi ponjaid: ^3 %i^1 | Jelenlegi szinted:^3 %i ^1[^3%s^1]", TAG, g_iPoints[ id ], g_iLevel[id], g_szLevelNames[g_iLevel[id]]);
			}
			else
			{
				ColorChat(id, GREY, "^4[%s]^1 Jelenlegi pontjaid: ^3 %i^1 | Jelenlegi szinted:^3 %i ^1[^3%s^1] (^4TELJES SZINT^1)", TAG, g_iPoints[ id ], g_iLevel[id], g_szLevelNames[g_iLevel[id]]);
			}
		}
		else
		{
			new iName[32]
			get_user_name(iPlayer, iName, 31)
		
			if( g_szLevels[g_iLevel[iPlayer]+1] != 0)
			{
				ColorChat(id, GREY, "^4[%s]^1 Következő szint:^3 %i ^1[^3%s^1] | Ennyi pont kell a következő szinthez:^3 %i", TAG, g_iLevel[iPlayer]+1, g_szLevelNames[g_iLevel[iPlayer]+1], g_szLevels[g_iLevel[iPlayer]+1] - g_szLevels[g_iLevel[iPlayer]]);
				ColorChat(id, GREY, "^4[%s]^3 %s^1 Kapott^3 %i^1 pontot | Szint:^3 %i ^1[^3%s^1]", TAG, iName, g_iPoints[ iPlayer ], g_iLevel[iPlayer], g_szLevelNames[g_iLevel[iPlayer]]);
			}
			else
			{
				ColorChat(id, GREY, "^4[%s]^3 %s^1 kapott^3 %i^1 pontot | Jelenlegi szintje:^3 %i ^1[^3%s^1] (^4TELJES SZINT^1)", TAG, iName, g_iPoints[ iPlayer ], g_iLevel[iPlayer], g_szLevelNames[g_iLevel[iPlayer]]);
			}
		}
	}
	else if(equali(arg1, "/top")) 
	{
		show_motd( id, g_szTopMotd, "Top Pont lista" )
	}
	else if(equali(arg1, "/pontadas")) 
	{
		Playerlist( id ) 
	}
}

Playerlist( id ) 
{
	if(get_user_flags( id ) & ADMIN_LEVEL_A )
	{
		new Playermenu, Temp[64]
	
		formatex(Temp, charsmax(Temp), "\w[\r%s\w]\y \rAddolás menü^n\wVálaszdi ki a játékost", TAG)
		Playermenu = menu_create(Temp, "PlayerlistHandler");
	
		new players[32], pnum, tempid;
		new szName[32], szTempid[10];
		
		formatex(Temp, charsmax(Temp), "\y[\r%s\y]^n", g_bGiveRemove ? "ELVÉTEL" : "ADÁS");  
		menu_additem(Playermenu, Temp, "0")
	
		get_players(players, pnum, "ch");
		for( new i; i<pnum; i++ )
		{
			tempid = players[i];
		
			get_user_name(tempid, szName, charsmax(szName));
			num_to_str(tempid, szTempid, charsmax(szTempid));
			menu_additem(Playermenu, szName, szTempid, 0);
		}
	
		menu_display(id, Playermenu);
	}
	return PLUGIN_HANDLED
}

public PlayerlistHandler(id, menu, item) {
	if( item == MENU_EXIT )
	{
		menu_destroy(menu);
		return PLUGIN_HANDLED;
	}
	
	new data[6], szName[32];
	new access, callback;
	menu_item_getinfo(menu, item, access, data, charsmax(data), szName, charsmax(szName), callback);
	
	new key = str_to_num(data);
	if( key == 0 )
	{
		if((g_bGiveRemove = !g_bGiveRemove)) 
		{
			g_bGiveRemove = true
			
			menu_destroy(menu);
			Playerlist( id ) 
			return PLUGIN_HANDLED
		}
		else 
		{
			g_bGiveRemove = false
			
			menu_destroy(menu);
			Playerlist( id ) 
			return PLUGIN_HANDLED
		}	
	}
	
	g_iName[id] = key
	
	client_cmd(id, "messagemode PointsAmount");
	client_cmd(id, "spk fvox/blip");
	
	menu_destroy(menu);
	return PLUGIN_HANDLED;
}

public PointsAction(id)
{
	if(!is_user_connected(id))
		return PLUGIN_HANDLED
		
	new iAmount[50]
	read_argv(1,iAmount,49)
	
	new szName[2][32]
	get_user_name(id, szName[0], 31)
	get_user_name(g_iName[id], szName[1], 31)
	
	if( str_to_num(iAmount) >= 9999999 )
	{
		ColorChat(id, GREY, "^4[%s]^1  ^3 %s^1 pontot", TAG, g_bGiveRemove ? "elvettek tőled" : "kaptál");
		return PLUGIN_HANDLED;
	}
	if(!is_user_connected(g_iName[id]))
	{
		ColorChat(id, GREY, "^4[%s]^1 Felhasználó^3 %s^1 nem online", TAG, szName[1]);
		return PLUGIN_HANDLED
	}
	
	if( g_iLogadmin == 1 )
	{
		new message[200], Time[64];
		get_time("%c", Time, charsmax(Time)); 
		format ( message, charsmax(message), "[%s] %s %s %s %i points", Time, szName[0], g_bGiveRemove ? "elvett" : "adott", szName[1], str_to_num(iAmount));
		write_file ( "addons/amxmodx/logs/levelmod.txt", message )
	}
	
	ColorChat(0, GREY, "^4[%s]^3 %s^1 %s^3 %s^4 %i^1 pontot", TAG, szName[0], g_bGiveRemove ? "elvett" : "adott", szName[1], str_to_num(iAmount));
	
	set_hudmessage(255, 0, 0, -1.0, 0.1, 0, 1.0, 7.0, 0.1, 1.0)
	show_hudmessage( 0, "[%s] %s %s %s %i pontot", TAG, szName[0], g_bGiveRemove ? "elvett" : "adott", szName[1], str_to_num(iAmount));
	
	client_cmd(0, "spk buttons/bell1");
	
	if( g_bGiveRemove )
		g_iPoints[g_iName[id]] -= str_to_num(iAmount)
	else
		g_iPoints[g_iName[id]] += str_to_num(iAmount)
	
	CheckLevel(g_iName[id])
	
	return PLUGIN_HANDLED
}

CheckLevel(id)
{
	if( g_iPoints[id] >= g_szLevels[g_iLevel[id]+1] && g_szLevels[g_iLevel[id]+1] != 0)
	{
		g_iLevel[id]++;
		
		if( g_iPoints[id] >= g_szLevels[g_iLevel[id]+1] && g_szLevels[g_iLevel[id]+1] != 0)
		{
			CheckLevel(id)
			return PLUGIN_HANDLED
		}
			
		new g_iName[ 32 ]
		get_user_name( id, g_iName, charsmax(g_iName) );
		
		ColorChat ( 0, GREY, "^4[%s]^1 Gratulálunk ^3 %s^1 elérte a ^3 %i^1 szintet! [^3%s^1]", TAG, g_iName, g_iLevel[id], g_szLevelNames[g_iLevel[id]])
		
		client_cmd(0, "spk events/task_complete.wav");
		
		if( is_user_alive( id ) && get_user_weapon( id ) == CSW_KNIFE )
		{	
			entity_set_string( id, EV_SZ_viewmodel, g_szKnife[g_iLevel[id]][0] );
			entity_set_string( id, EV_SZ_weaponmodel, g_szKnife[g_iLevel[id]][1] );
		}
	}
	else if( g_iLevel[id] != 0 && g_iPoints[id] <= g_szLevels[g_iLevel[id]-1])
	{
		g_iLevel[id]--;
		
		if( g_iLevel[id] != 0 && g_iPoints[id] <= g_szLevels[g_iLevel[id]-1] )
		{
			CheckLevel(id)
			return PLUGIN_HANDLED
		}	
		if( is_user_alive( id ) && get_user_weapon( id ) == CSW_KNIFE )
		{
			entity_set_string( id, EV_SZ_viewmodel, g_szKnife[g_iLevel[id]][0] );
			entity_set_string( id, EV_SZ_weaponmodel, g_szKnife[g_iLevel[id]][1] );
		}
		ColorChat ( id, GREY, "^4[%s]^1 Szinted csökkent. Jelenlegi szinted^3 %i^1 [^3%s^1]", TAG, g_iLevel[id], g_szLevelNames[g_iLevel[id]])
	}
	
	return PLUGIN_HANDLED
}

public Event_DeathMsg()
{
	new g_iKiller = read_data(1);
	new g_iVictim = read_data(2);
	
	if( 1 <= g_iKiller <= get_maxplayers() && cs_get_user_team( g_iVictim ) != cs_get_user_team( g_iKiller )
	&& is_user_connected( g_iKiller ))
	{
		new g_iNames[2][32]
		get_user_name(g_iKiller, g_iNames[0], 31)
		get_user_name(g_iVictim, g_iNames[1], 31)
	
		if( read_data( 3 ) && g_iHeadshot != 0 )
		{
			g_iPoints[ g_iKiller ] += g_iHeadshot
			ColorChat ( g_iKiller, GREY, "^4[%s]^1 Kaptál ^3 %i^1 pontot mert megölted ^3 %s^1 [^3FEJLÖVÉS^1]", TAG, g_iHeadshot, g_iNames[1])
		}
		else if( g_iKill != 0 )
		{
			g_iPoints[ g_iKiller ] += g_iKill
			ColorChat ( g_iKiller, GREY, "^4[%s]^1 Kaptál ^3 %i^1 pontot mert megölted ^3 %s", TAG, g_iKill, g_iNames[1])
		}
		else if( g_iDying != 0 )
		{
			g_iPoints[ g_iVictim ] -= g_iDying
			ColorChat ( g_iVictim, GREY, "^4[%s]^1 Elvesztettél ^3 %i^1 pontot mert megölt téged^3 %s", TAG, g_iDying, g_iNames[0])
		}
		
	}	
	else if( g_iSuicide != 0 && g_iVictim == g_iKiller)
	{
		g_iPoints[ g_iKiller ] -= g_iSuicide
		ColorChat ( g_iKiller, GREY, "^4[%s]^1 Elvesztettél ^3 %i^1 pontot mert meghaltál!", TAG, g_iSuicide)
	}
	CheckLevel(g_iKiller)
	CheckLevel(g_iVictim)
}

public Ham_KnifeDeploy(iWeapon)
{
	new id = get_pdata_cbase(iWeapon, 41, 4)
	
	if(is_user_alive(id))
	{
		entity_set_string( id, EV_SZ_viewmodel, g_szKnife[g_iLevel[id]][0] );
		entity_set_string( id, EV_SZ_weaponmodel, g_szKnife[g_iLevel[id]][1] );
	}
}

public Message_Win(const MsgId, const MsgDest, const MsgEntity)
{
	if( g_iWin == 0 )
		return PLUGIN_HANDLED	
		
	new Flags[32], iPlayers[32], iNum, id
	
	new Message[ 16 ];
	get_msg_arg_string( 2, Message, charsmax( Message ) );

switch(Message[1]) 
	{ 
		case 'T': 
		{ 
			copy(Flags, charsmax(Flags), "TERRORIST") 
		} 
		case 'C': 
		{ 
			copy(Flags, charsmax(Flags), "CT") 
		}
	}

get_players( iPlayers, iNum, "ae", Flags);

for( new i; i < iNum; i++ )
	{
		id = iPlayers[i];
			
		g_iPoints[ id ] += g_iWin
		ColorChat ( id, GREY, "^4[%s]^1 Kaptál^3 %i^1 pontot mert megnyertétek a kört", TAG, g_iWin)
		CheckLevel(id)
	}
	return PLUGIN_HANDLED
}

public Task_Advertise()
{
	ColorChat(0, GREY, "^4[%s]^1 A szerveren szint rendszer fut!^3 ^1 magyarosította: ^3loleee", TAG);
}

stock FormatTop(iNum)
{	
	if(g_iVault == INVALID_HANDLE)
		set_fail_state("nVault returned invalid handle")
		
	enum _:VaultData
	{
		VD_Key[33],
		VD_Value,
		VD_szName[33]
	};
	
	new Vault2 = nvault_util_open("levelmod")
	new iSize = nvault_util_count(Vault2)
	
	new Array:entries = ArrayCreate(VaultData);
	new sizeEntries
	
	new data[VaultData], value[256], data2[VaultData]

for(new i = 0, pos, timestamp; i < iSize; i++)
	{
		pos = nvault_util_read(Vault2, pos, data[VD_Key], charsmax(data[VD_Key]), value, charsmax(value), timestamp);
	
		if(contain(data[VD_Key], SPECIAL_CHAR) != -1)
			continue;
		
		else
		{
			formatex(data[VD_szName], charsmax(data[VD_szName]), "%s%s", data[VD_Key], SPECIAL_CHAR)
			nvault_get(g_iVault, data[VD_szName], data[VD_szName], charsmax(data[VD_szName]))
		}

data[VD_Value] = str_to_num(value);
        
		if(sizeEntries == 0)
		{
			ArrayPushArray(entries, data);
			sizeEntries++;
			continue;
		}
		
		else
		{
			for(timestamp = 0; timestamp <= sizeEntries; timestamp++)
			{
				if(timestamp == sizeEntries)
				{
					if(sizeEntries < iNum)
					{
						ArrayPushArray(entries, data);
						sizeEntries++;
					}
                    
					break;
				}
          
				ArrayGetArray(entries, timestamp, data2);
                
				if(data[VD_Value] >= data2[VD_Value])
				{
					ArrayInsertArrayBefore(entries, timestamp, data);
                    
					if(sizeEntries < iNum)
					{
						sizeEntries++;
					} 
					else 
					{
						ArrayDeleteItem(entries, sizeEntries);
					}
                    
					break;
				}
			}
		}
	}
	
	new iLen
	
	new len = charsmax(g_szTopMotd)
	
	iLen = formatex(g_szTopMotd, len, "<STYLE>body{background:#212121;color:#d1d1d1;font-family:Arial}table{width:100%%;font-size:28px}</STYLE><table cellpadding=1 cellspacing=1 border=0>")
	iLen += formatex(g_szTopMotd[iLen], len - iLen, "<tr bgcolor=#333333><th width=1%%><align=left font color=white> %s <th width=5%%> %-22.22s <th width=5%%> %s", "#", "N�v", "Pontok")

new i
	for(i = 0; i < sizeEntries; i++)
	{
		ArrayGetArray(entries, i, data);
        
		data[VD_Key][32] = 0;
		data[VD_szName][32] = 0
		
		replace_all(data[VD_szName], charsmax(data[VD_szName]), "<", "<")
		replace_all(data[VD_szName], charsmax(data[VD_szName]), ">", ">")
        
		iLen += formatex(g_szTopMotd[iLen], len - iLen, "<tr align=left%s><td align=left><font color=white> %d. <td> %-22.22s <td> %d", " bgcolor=#2b5b95", (i+1), data[VD_szName], data[VD_Value])
	}
    
	ArrayDestroy(entries);
	
	iLen += formatex(g_szTopMotd[iLen], len - iLen, "</table></body>")
}

public client_putinserver(id)
{
	if( is_user_hltv(id)  || is_user_bot(id) )
		return;

Load(id)
}

public client_disconnect(id)
{
	if( is_user_hltv(id)  || is_user_bot(id) )
		return;
	
	Save(id)
}

stock Save(id)
{
	if(g_iVault == INVALID_HANDLE)
		set_fail_state("nVault returned invalid handle")
	
	new szAuthId[35]; 
	get_user_authid(id, szAuthId, charsmax(szAuthId))
	
	new szName[32]; 
	get_user_name(id, szName, 31)
	
	new szData[256];
	formatex(szData, charsmax(szData), "%i %i", g_iPoints[id], g_iLevel[id]);
	
	nvault_remove(g_iVault, szAuthId)
	nvault_set(g_iVault, szAuthId, szData)
		
	format(szAuthId, charsmax(szAuthId), "%s%s", szAuthId, SPECIAL_CHAR)
	nvault_remove(g_iVault, szAuthId)
	nvault_set(g_iVault, szAuthId, szName)
}

stock Load(id)
{
	if(g_iVault == INVALID_HANDLE)
		set_fail_state("nVault returned invalid handle")
		
	new szSavedName[32]
	new szName[32]; get_user_name(id, szName, charsmax(szName))
	new szAuthId[33]; get_user_authid(id, szAuthId, charsmax(szAuthId))
	
	new szData[256], iTimeStamp
	if( !nvault_lookup(g_iVault, szAuthId, szData, charsmax(szData), iTimeStamp) )
	{
		nvault_set(g_iVault, szAuthId, "0")
		
		format(szAuthId, charsmax(szAuthId), "%s%s", szAuthId, SPECIAL_CHAR)
		nvault_set(g_iVault, szAuthId, szName)
		
		return 0
	}
	
	ParseLoadData(id, szData);
	
	format(szAuthId, charsmax(szAuthId), "%s%s", szAuthId, SPECIAL_CHAR)
	nvault_get(g_iVault, szAuthId, szSavedName)
	
	if(!equal(szName, szSavedName))
	{
		nvault_remove(g_iVault, szAuthId)
		nvault_set(g_iVault, szAuthId, szName)
	}
	return 0
}

ParseLoadData(id, szData[256])
{
	static szNum[11];
	strbreak(szData, szNum, charsmax(szNum), szData, charsmax(szData));
	g_iPoints[id] = str_to_num(szNum);
	
	strbreak(szData, szNum, charsmax(szNum), szData, charsmax(szData));
	g_iLevel[id] = str_to_num(szNum);
}

/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1053\\ f0\\ fs16 \n\\ par }
*/

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

_________________

Ha segítettem ne felejtsd el meg köszönni! :)

[steam]loleee[/steam]

A hozzászólást 3 alkalommal szerkesztették, utoljára loleee 2015.03.06. 20:31-kor.

Ők köszönték meg loleee nek ezt a hozzászólást: AlphaHun (2016.02.09. 04:05)

Népszerűség: 2.27%

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

6almasok

Hozzászólás témája: Re: Szint rendszer (KÉS)

HozzászólásElküldve: 2015.02.22. 13:41

Offline

Csatlakozott: 2014.11.16. 12:37
Hozzászólások: 686
Megköszönt másnak: 32 alkalommal
Megköszönték neki: 131 alkalommal

Kicsit több időt el lehetne szánni a leírásra....

_________________
Kép

"I wouldn't hold my breath if I was you
Cause I'll forget but I'll never forgive you
Don't you know, don't you know?
True friends stab you in the front."

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

loleee

Hozzászólás témája: Re: Szint rendszer (KÉS)

HozzászólásElküldve: 2015.02.22. 15:07

Offline

Csatlakozott: 2015.02.14. 01:11
Hozzászólások: 28
Megköszönték neki: 6 alkalommal

6almasok írta:

Kicsit több időt el lehetne szánni a leírásra....

Okés majd bővítem!
Hajnali 3-kor írtam.

_________________

Ha segítettem ne felejtsd el meg köszönni! :)

[steam]loleee[/steam]

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

ultraibolya

Hozzászólás témája: Re: Szint rendszer (KÉS)

HozzászólásElküldve: 2015.02.22. 15:11

Offline

Csatlakozott: 2012.03.22. 18:22
Hozzászólások: 2978
Megköszönt másnak: 115 alkalommal
Megköszönték neki: 368 alkalommal

Ja meg kérlek kicsit varázsold szebbé,ez alatt azt értem,hogy bontsd részekre: leírás stb...
persze ez csak esztétikailag,csak egy tipp,ha nem,akkor is jóvá lesh hagyva.

_________________
Blasenkampfwagen

https://discord.gg/uBYnNnZP
GTA:PURSUIT MTA

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

ultraibolya

Hozzászólás témája: Re: Szint rendszer (KÉS)

HozzászólásElküldve: 2015.03.06. 17:51

Offline

Csatlakozott: 2012.03.22. 18:22
Hozzászólások: 2978
Megköszönt másnak: 115 alkalommal
Megköszönték neki: 368 alkalommal

Kerlek a cvarokat fejtsd ki jobban hogy mi-mit csinal.

_________________
Blasenkampfwagen

https://discord.gg/uBYnNnZP
GTA:PURSUIT MTA

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

loleee

Hozzászólás témája: Re: Szint rendszer (KÉS)

HozzászólásElküldve: 2015.03.07. 13:51

Offline

Csatlakozott: 2015.02.14. 01:11
Hozzászólások: 28
Megköszönték neki: 6 alkalommal

Bővítve

_________________

Ha segítettem ne felejtsd el meg köszönni! :)

[steam]loleee[/steam]

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

AsdFighter00

Hozzászólás témája: Re: Szint rendszer (KÉS)

HozzászólásElküldve: 2015.04.04. 10:37

Offline

Csatlakozott: 2015.02.05. 20:04
Hozzászólások: 7
Megköszönt másnak: 2 alkalommal

Ő és ha én azt akarom hogy kapjon 1 j kés skint+Fegyver skint pl 200 ölésnél azt hogy tudom be álitani ? Mit kell be írni ?

_________________
Élvezd az életet amíg van és ne hátrálj meg ! :)

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

FloxaY

Hozzászólás témája: Re: Szint rendszer (KÉS)

HozzászólásElküldve: 2015.04.04. 10:39

Offline

Csatlakozott: 2015.02.01. 11:40
Hozzászólások: 670
Megköszönt másnak: 16 alkalommal
Megköszönték neki: 99 alkalommal

AsdFighter00 írta:

Ő és ha én azt akarom hogy kapjon 1 j kés skint+Fegyver skint pl 200 ölésnél azt hogy tudom be álitani ? Mit kell be írni ?

"200" "Új játékos" "models/v_ak47.mdl" "models/p_ak47.mdl"
"200" "Új játékos" "models/v_knife.mdl" "models/p_knife.mdl"

_________________
http://steamcommunity.com/id/floxay/

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

mforce

Hozzászólás témája: Re: Szint rendszer (KÉS)

HozzászólásElküldve: 2015.04.04. 12:59

Offline

Csatlakozott: 2014.09.08. 22:21
Hozzászólások: 3014
Megköszönt másnak: 96 alkalommal
Megköszönték neki: 555 alkalommal

Fegyver skin nincs beleírva...

_________________
GitHub - mforce

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

FloxaY

Hozzászólás témája: Re: Szint rendszer (KÉS)

HozzászólásElküldve: 2015.04.04. 13:02

Offline

Csatlakozott: 2015.02.01. 11:40
Hozzászólások: 670
Megköszönt másnak: 16 alkalommal
Megköszönték neki: 99 alkalommal

mforce írta:

Fegyver skin nincs beleírva...

De ezt persze meglehet fegyver skinnel is csinálni!
(Pl: "kellő pont" "szint neve" "v_modell" "p_modell"
"0" "Új játékos" "models/v_ak47.mdl" "models/p_ak47.mdl")
én sma-ba nem fogok belenézni, aztírja megy akkor megy

_________________
http://steamcommunity.com/id/floxay/

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Hozzászólások megjelenítése: Rendezés

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 2

[ 16 hozzászólás ]

Oldal 1 2 Következő

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 13 vendég

Nem nyithatsz témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Ugrás:

hlmod.hu

Szint rendszer (KÉS)

Ki van itt