hlmod.hu ::Resetscore System

hlmod.hu https://hlmod.hu/

Resetscore System https://hlmod.hu/viewtopic.php?f=101&t=20178	Oldal: 1 / 1

Szerző:

mforce [2015.04.06. 00:15 ]

Hozzászólás témája:

Resetscore System

Plugin Neve:	Resetscore System	Plugint készitette:	OciXCrom
Játék:	Counter-Strike	Kategória:	Általános célú
Eredeti link:	Megnézem	Jóváhagyó:	Badboy.killer

Resetscore System
v1.0 by OciXCrom
Fordította: mforce

Leírás:
Egy jobb verzió az ölések és halálok nullázásához (kills/deaths). Tartalmaz sok cvart az optimális beállításokhoz. Limitet adhatsz meg, hogy maponként hányszor nullázhatják a statisztikájukat, akár VIP joghoz kötheted.

Parancsok:

Kód:

/rs,
/resetscore
rs
resetscore
.rs
.resetscore
!rs
!resetscore

Cvarok:
resetscore_prefix -- alap: "!g[Resetscore System]" -- Változtasd meg a prefixet a szervered nevére.
resetscore_alive -- Állíthatod,hogy csak a halottak tudják használni 0= be 1= ki. alap: "1"
resetscore_viponly -- Váltsd át "1" -re, ha csak a VIP-knek engeded használni a statisztika nullázást. alap: "0"
resetscore_vipflag -- Ez a flag a VIP-knak, ha bekapcsoltad a csak VIP-t. alap: "b"
resetscore_limit -- Ha ez a szám nagyobb,mint 0, akkor a plugin limitálja a parancs használatát maponként a megadott limitre. Ha átállítod a cvart "5"-re, akkor csak 5x tudod használni a parancsot egy mapon. alap: "0"
resetscore_resetkills -- Ölések nullázása 0-ki 1-be. alap: "1"
resetscore_resetdeaths -- Halálok nullázása 0-ki 1-be. alap: "1"
resetscore_resetmoney -- Pénz nullázása 0-ki 1-be. alap: "0"
resetscore_notifyall -- Beállíthatod, hogy mindenki látja,hogy ki nullázta a statisztikáját, vagy csak aki nullázta.. alap: "0"
resetscore_sound -- Hang lejátszás a parancs használatakor ("0" = nem; "1" = igen, de csak aki használta a parancsot annak; "2" = igen, mindenkinek). alap: "1"
resetscore_chat -- Kiírja-e a parancs nevét használatkor chatre,vagy ne mutassa. 0- ne mutassa 1- mutassa alap: "0"
resetscore_adverttime -- Hány másodpercenként reklámozza a parancs használatát a chaten. 0- kikapcsolás alap: "180"

Kép:
(a plugin teljesen magyar, csak a kép angol!)

Kép

#include <amxmodx>
#include <cstrike>
#include <fun>

#define PLUGIN_NAME "Resetscore System"
#define PLUGIN_VERSION "1.0"
#define PLUGIN_AUTHOR "OciXCrom"

#define sReset "buttons/bell1.wav"
#define sResetAll "buttons/lightswitch2.wav"

enum Color
{
	NORMAL = 1, // clients scr_concolor cvar color
	GREEN, // Green Color
	TEAM_COLOR, // Red, grey, blue
	GREY, // grey
	RED, // Red
	BLUE, // Blue
}

new TeamName[][] = 
{
	"",
	"TERRORIST",
	"CT",
	"SPECTATOR"
}

new const g_Commands[][] = {
	"say /rs",
	"say /resetscore",
	"say_team /rs",
	"say_team /resetscore",
	"say rs",
	"say resetscore",
	"say_team rs",
	"say_team resetscore",
	"say .rs",
	"say .resetscore",
	"say_team .rs",
	"say_team .resetscore",
	"say !rs",
	"say !resetscore",
	"say_team !rs",
	"say_team !resetscore"
}

new cvar_prefix, cvar_alive, cvar_viponly, cvar_vipflag, cvar_limit, cvar_resetkills, cvar_resetdeaths, cvar_resetmoney, cvar_notifyall, cvar_sound, cvar_chat, cvar_adverttime
new limit[33], advert

public plugin_init()
{
	register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
	
	cvar_prefix = 			register_cvar("resetscore_prefix", 			"!g[Register System]")
	cvar_alive = 			register_cvar("resetscore_alive", 			"1")
	cvar_viponly = 			register_cvar("resetscore_viponly", 		"0")
	cvar_vipflag = 			register_cvar("resetscore_vipflag", 		"b")
	cvar_limit =			register_cvar("resetscore_limit", 			"0")
	cvar_resetkills = 		register_cvar("resetscore_resetkills", 		"1")
	cvar_resetdeaths = 		register_cvar("resetscore_resetdeaths", 	"1")
	cvar_resetmoney = 		register_cvar("resetscore_resetmoney",		"0")
	cvar_notifyall = 		register_cvar("resetscore_notifyall", 		"0")
	cvar_sound = 			register_cvar("resetscore_sound", 			"1")
	cvar_chat = 			register_cvar("resetscore_chat", 			"0")
	cvar_adverttime = 		register_cvar("resetscore_adverttime", 		"180")
	
	advert = get_pcvar_num(cvar_adverttime)
	if(advert > 0) set_task(float(advert), "rs_advertise", 2222, "", 0, "b", 0)
	
	for(new i = 0; i < sizeof(g_Commands); i++)
		register_clcmd(g_Commands[i], "cmd_resetscore")
}

public cmd_resetscore(id)
{
	static szPrefix[100]
	szPrefix = get_prefix()
	
	static cmd_limit
	cmd_limit = get_pcvar_num(cvar_limit)
	
	if(get_pcvar_num(cvar_alive) == 0)
	{
		if(is_user_alive(id))
		{
			ColorChat(id, TEAM_COLOR, "%s ^1Nem tudod ^3nullázni ^1a ^4statisztikád ^1amíg ^3életben vagy^1.", szPrefix)
			return PLUGIN_HANDLED
		}
	}
	
	if(get_pcvar_num(cvar_viponly) == 1)
	{
		if(!user_has_flag(id, cvar_vipflag))
		{
			new flag_vip[2]
			get_pcvar_string(cvar_vipflag, flag_vip, charsmax(flag_vip))
			
			ColorChat(id, TEAM_COLOR, "%s ^1Flag ^3%s ^1szükséges a ^4statisztikád nullázásához^1.", szPrefix, flag_vip)
			return PLUGIN_HANDLED
		}
	}
	
	if(cmd_limit > 0)
	{
		if(limit[id] == cmd_limit)
		{
			ColorChat(id, TEAM_COLOR, "%s ^1Csak ^3%ix ^1lehet ^4nullázni a statisztikád ^1egy mapon.", szPrefix, cmd_limit)
			return PLUGIN_HANDLED
		}
		
		if(limit[id] < cmd_limit)
			limit[id]++
	}
	
	new limit_left = cmd_limit - limit[id]
	
	switch(get_pcvar_num(cvar_notifyall))
	{
		case 0:
		{
			if(cmd_limit > 0)
			{
				if(limit_left == 0) ColorChat(id, TEAM_COLOR, "%s ^3Nem tudod többször nullázni ^1a ^4statisztikád^1.", szPrefix)
				else ColorChat(id, TEAM_COLOR, "%s ^1Sikeresen ^3nulláztad ^1a ^4statisztikád^1. Még megteheted ezt ^3%ix^1.", szPrefix, limit_left)
			}
			else ColorChat(id, TEAM_COLOR, "%s ^1Sikeresen ^3nulláztad ^1a ^4statisztikád^1.", szPrefix)
		}
		case 1:
		{
			new name[32]
			get_user_name(id, name, charsmax(name))
			
			if(cmd_limit > 0) ColorChat(0, TEAM_COLOR, "%s ^3%s ^4nullázta a statisztikáját ^1[^4Limit: ^3%i^1/^3%i^1]", szPrefix, name, limit[id], cmd_limit)
			else ColorChat(0, TEAM_COLOR, "%s ^3%s ^4nullázta ^1a ^4statisztikáját^1.", szPrefix, name)
		}
	}
	
	switch(get_pcvar_num(cvar_sound))
	{
		case 1: client_cmd(id, "spk %s", sReset)
		case 2: client_cmd(0, "spk %s", sResetAll)
	}
	
	resetscore(id)
	return (get_pcvar_num(cvar_chat) == 1) ? PLUGIN_CONTINUE : PLUGIN_HANDLED
}

public rs_advertise()
	ColorChat(0, TEAM_COLOR, "%s ^1Írd be, hogy ^3/rs ^1vagy ^3/resetscore ^1a ^4statisztikád nullázásához^1.", get_prefix())

resetscore(id)
{
	if(get_pcvar_num(cvar_resetkills) == 1) set_user_frags(id, 0)
	if(get_pcvar_num(cvar_resetdeaths) == 1) cs_set_user_deaths(id, 0)
	if(get_pcvar_num(cvar_resetmoney) == 1) cs_set_user_money(id, get_cvar_num("mp_startmoney"))
}

stock get_prefix()
{
	static szPrefix[100]
	get_pcvar_string(cvar_prefix, szPrefix, charsmax(szPrefix))
	
	replace_all(szPrefix, charsmax(szPrefix), "!n", "^1")
	replace_all(szPrefix, charsmax(szPrefix), "!t", "^3")
	replace_all(szPrefix, charsmax(szPrefix), "!g", "^4")
	
	return szPrefix
}

stock user_has_flag(id, cvar)
{
	new flags[32]
	get_flags(get_user_flags(id), flags, charsmax(flags))
	
	new vip_flag[2]
	get_pcvar_string(cvar, vip_flag, charsmax(vip_flag))
	
	return (contain(flags, vip_flag) != -1) ? true : false
}

public plugin_precache()
{
	precache_sound(sReset)
	precache_sound(sResetAll)
}

/* ColorChat */

ColorChat(id, Color:type, const msg[], {Float,Sql,Result,_}:...)
{
	static message[256];

switch(type)
	{
		case NORMAL: // clients scr_concolor cvar color
		{
			message[0] = 0x01;
		}
		case GREEN: // Green
		{
			message[0] = 0x04;
		}
		default: // White, Red, Blue
		{
			message[0] = 0x03;
		}
	}

vformat(message[1], 251, msg, 4);

// Make sure message is not longer than 192 character. Will crash the server.
	message[192] = '^0';

static team, ColorChange, index, MSG_Type;
	
	if(id)
	{
		MSG_Type = MSG_ONE;
		index = id;
	} else {
		index = FindPlayer();
		MSG_Type = MSG_ALL;
	}
	
	team = get_user_team(index);
	ColorChange = ColorSelection(index, MSG_Type, type);

ShowColorMessage(index, MSG_Type, message);
		
	if(ColorChange)
	{
		Team_Info(index, MSG_Type, TeamName[team]);
	}
}

ShowColorMessage(id, type, message[])
{
	message_begin(type, get_user_msgid("SayText"), _, id);
	write_byte(id)		
	write_string(message);
	message_end();	
}

Team_Info(id, type, team[])
{
	message_begin(type, get_user_msgid("TeamInfo"), _, id);
	write_byte(id);
	write_string(team);
	message_end();

return 1;
}

ColorSelection(index, type, Color:Type)
{
	switch(Type)
	{
		case RED:
		{
			return Team_Info(index, type, TeamName[1]);
		}
		case BLUE:
		{
			return Team_Info(index, type, TeamName[2]);
		}
		case GREY:
		{
			return Team_Info(index, type, TeamName[0]);
		}
	}

return 0;
}

FindPlayer()
{
	static i;
	i = -1;

while(i <= get_maxplayers())
	{
		if(is_user_connected(++i))
		{
			return i;
		}
	}

return -1;
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	babapiskóta.~ [2015.05.22. 11:28 ]
Hozzászólás témája:	Re: Resetscore System
mit lehet 1 rs pluginon ennyit extrázni?xD nem is értem...

Szerző:	`[A]£TerNaTe. [2015.06.06. 14:41 ]
Hozzászólás témája:	Re: Resetscore System
Ez fent van gamebananan -.-"

Szerző:	mforce [2015.06.06. 16:18 ]
Hozzászólás témája:	Re: Resetscore System
Ha nem tudod minek készült a hlmod ne szólj hozzá légyszives. Le lett a plugin magyarosítva és feltéve a magyar közösségnek. Eredeti forrás link is ott van a helyén. Látom most jöttél,de már okoskodsz.

Szerző:	Zeei [2015.06.06. 16:57 ]
Hozzászólás témája:	Re: Resetscore System
Offot nem kérünk,kedves új látogató. Utolsó figyelmeztetés!

Szerző:	*GrafitY* [2015.12.29. 12:48 ]
Hozzászólás témája:	Re: Resetscore System
Hol tudnám kicserélni a hangot?

Szerző:	Akosch:. [2015.12.29. 12:51 ]
Hozzászólás témája:	Re: Resetscore System
Ha belenéznél a kódba kiszúrná a szemed. Kód: [Egész kijelölése] [Mutatás/Eltüntetés] `#define sReset "buttons/bell1.wav" #define sResetAll "buttons/lightswitch2.wav"` GeSHi © Codebox Plus

Szerző:	*GrafitY* [2015.12.29. 12:54 ]
Hozzászólás témája:	Re: Resetscore System
De ha keresem nincs sehol a sounds mappában

Szerző:	Akosch:. [2015.12.29. 12:58 ]
Hozzászólás témája:	Re: Resetscore System
Ne csak a cstrike mappát nézd. .../valve/sound/buttons... Alap hangok, írd át az sma-ban és akkor azt fel is teszi letöltési listára és azt is fogja lejátszani.

Szerző:	*GrafitY* [2015.12.29. 13:05 ]
Hozzászólás témája:	Re: Resetscore System
de webadminban csak cstrike mappa van.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/