hlmod.hu ::Havazik

hlmod.hu https://hlmod.hu/

Havazik https://hlmod.hu/viewtopic.php?f=101&t=22992	Oldal: 1 / 1

Szerző:

mforce [2015.12.12. 18:13 ]

Hozzászólás témája:

Havazik

Plugin Neve:	Havazik	Plugint készitette:	mforce
Játék:	Counter-Strike	Kategória:	Eseményhez
Eredeti link:	Nincs megadva	Jóváhagyó:	ultraibolya

Havazik
v1.0.1 by mforce

Leírás:
A plugin felhasználja az alap Counter-Strike időjárást és bekapcsolja a havazást.
Készült hozzá egy menü is, ahol ki- és bekapcsolható a havazás, valamint állítható annak erőssége 3 fokozatban (gyenge, közepes, erős).
A választást elmenti, valamint be is tölti a játékos SteamID-jére.

Alap beállítás mindenkinek a Gyenge havazás.

Parancs:
/ho - megnyitja a havazás menüt

Konfiguráció:
A prefix állítható a 9. sorban.
[sma]new const PREFIX[] = "Havazik";[/sma]

Változtatások:
v1.0.1 - nvault zárás hozzáadva

#include <amxmodx>
#include <engine>
#include <nvault>

#define PLUGIN "Havazik"
#define VERSION "1.0.1"
#define AUTHOR "mforce"

new const PREFIX[] = "Havazik";

new havazas[33] = 1;
new vault;

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);
	register_clcmd("say /ho", "snow_menu");
	set_task(183.0, "esikahoocsem", .flags = "b");
	vault = nvault_open("havazas");
}

public plugin_precache() {
	create_entity("env_snow");
}

public esikahoocsem() {
	ChatColor(0, "^4[%s]^1 A szerveren hóesés van, kikapcsolás és állítás: ^3/ho", PREFIX);
}

public snow_menu(id) {
	new temp[128], temp2[32];
	formatex(temp, charsmax(temp), "\r[\y%s\r] \wHavazás menü by \y%s", PREFIX, AUTHOR);
	new menu = menu_create(temp, "snow_menu_h");
	
	formatex(temp, charsmax(temp), "\wHavazás: \r[%s]", havazas[id] == 0 ? "Kikapcsolva":"Bekapcsolva");
	menu_additem(menu,temp, "0", 0);
	switch(havazas[id]) {
		case 0: formatex(temp2, charsmax(temp2), "Nincs");
		case 1: formatex(temp2, charsmax(temp2), "Gyenge");
		case 2: formatex(temp2, charsmax(temp2), "Közepes");
		case 3: formatex(temp2, charsmax(temp2), "Erős");
	}
	formatex(temp, charsmax(temp), "%sErősség: \r[%s]", havazas[id] == 0 ? "\d":"\w", temp2);
	menu_additem(menu,temp, "1", 0);
	
	menu_setprop(menu, MPROP_EXIT, MEXIT_ALL);
	menu_setprop(menu, MPROP_EXITNAME, "Kilépés");
	menu_display(id, menu, 0);
}

public snow_menu_h(id, menu, item) {
	switch(item) {
		case 0: {
			if(havazas[id] == 0) {
				havazas[id] = 1;
				client_cmd(id, "cl_weather 1");
			}
			else {
				havazas[id] = 0;
				client_cmd(id, "cl_weather 0");
			}
			mentes(id);
			snow_menu(id);
		}
		case 1: {
			switch(havazas[id]) {
				case 1: {
					havazas[id] = 2;
					client_cmd(id, "cl_weather 2");
				}
				case 2: {
					havazas[id] = 3;
					client_cmd(id, "cl_weather 3");
				}
				case 3: {
					havazas[id] = 1;
					client_cmd(id, "cl_weather 1");
				}
			}
			mentes(id);
			snow_menu(id);
		}
	}
	
	menu_destroy(menu);
	return PLUGIN_HANDLED;
}

public client_authorized(id) {
	if(!is_user_bot(id) && !is_user_hltv(id)) {
		betoltes(id);
	}
}

public client_disconnect(id) {
	havazas[id] = 1;
}

public mentes(id) {
	new vaultkey[32], vaultdata[128];
	get_user_authid(id, vaultkey, charsmax(vaultkey));
	formatex(vaultdata, charsmax(vaultdata), "%i", havazas[id]);
	nvault_set(vault, vaultkey, vaultdata);
}

public betoltes(id) {
	new vaultkey[32], vaultdata[128];
	get_user_authid(id, vaultkey, charsmax(vaultkey));
	formatex(vaultdata, charsmax(vaultdata), "%i", havazas[id]);
	if(nvault_get(vault, vaultkey, vaultdata, charsmax(vaultdata))) {
		new ho[8];
		parse(vaultdata, ho, charsmax(ho));
		havazas[id] = str_to_num(ho);
		switch(havazas[id]) {
			case 0: client_cmd(id, "cl_weather 0");
			case 1: client_cmd(id, "cl_weather 1");
			case 2: client_cmd(id, "cl_weather 2");
			case 3: client_cmd(id, "cl_weather 3");
		}
	}
	else {
		havazas[id] = 1;
		client_cmd(id, "cl_weather 1");
	}
}

public plugin_end() {
	nvault_close(vault);
}

stock ChatColor(const id, const szMessage[], any:...) {
	static pnum, players[32], szMsg[190], IdMsg; 
	vformat(szMsg, charsmax(szMsg), szMessage, 3);
	
	if(!IdMsg) IdMsg = get_user_msgid("SayText");
	
	if(id) { 
		if(!is_user_connected(id)) return;
		players[0] = id;
		pnum = 1; 
	} 
	else get_players(players, pnum, "ch");
	
	for(new i; i < pnum; i++) {
		message_begin(MSG_ONE, IdMsg, .player = players[i]);
		write_byte(players[i]);
		write_string(szMsg);
		message_end();
	}
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	lili [2015.12.12. 22:26 ]
Hozzászólás témája:	Re: Havazik
Nekem mikor felraktam, akkor valami gond volt, az ns-ek ha csatlakoztak, akkor csak droppoltak és kész. Nem engedte fel őket :\ Mitől lehetett?

Szerző:	Anonymous1337 [2015.12.12. 23:01 ]
Hozzászólás témája:	Re: Havazik
Nem is tudtam hogy meg lehet hívni az authort, %s segítségével menübe, vagy chatbe. Erre gondolok: SMA Forráskód: [ Mindet kijelol ] formatex(temp, charsmax(temp), "\r[\y%s\r] \wHavazás menü by \y%s", PREFIX, AUTHOR);

Szerző:	mforce [2015.12.12. 23:13 ]
Hozzászólás témája:	Re: Havazik
lili - Tele a szerverem és fenn a plugin. Igen lassan éjfél van. Anonymous1337 - Miért ne lehetne? Csak ugye konstans megfelelőbb lenne neki, ha 1-nél többször van lekérve, de nem oszt nem szoroz.

Szerző:	Anonymous1337 [2015.12.12. 23:29 ]
Hozzászólás témája:	Re: Havazik
mforce írta: lili - Tele a szerverem és fenn a plugin. Igen lassan éjfél van. Anonymous1337 - Miért ne lehetne? Csak ugye konstans megfelelőbb lenne neki, ha 1-nél többször van lekérve, de nem oszt nem szoroz. Ezt a módszert még nem láttam, csak konstansal, azért kérdeztem rá. De ha 1x van lekérve, akkor no problem ezek szerint.

Oldal: 1 / 1	Minden időpont UTC+01:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/