hlmod.hu :: Lite Kill Assists

hlmod.hu https://hlmod.hu/

Lite Kill Assists https://hlmod.hu/viewtopic.php?f=101&t=22996	Oldal: 1 / 1

Szerző:

mforce [ 2015.12.12. 18:41 ]

Hozzászólás témája:

Lite Kill Assists

Plugin Neve:	Lite Kill Assists	Plugint készitette:	neygomon
Játék:	Counter-Strike	Kategória:	Általános célú
Eredeti link:	Megnézem	Jóváhagyó:	ultraibolya

Lite Kill Assists
v1.17 by neygomon

Leírás:
Fragelosztó plugin, ami nem változtat nicknevet és könnyen konfigurálható.
Ha valaki más megöl egy ellenfelet, akibe te 50-et sebeztél minimum, akkor te is kapsz egy fraget.

Ezt a következőképp jelzi:
[KillAssists] Kaptál +1 fraget, mert segítettél mforce megölésében.

Konfiguráció:
A prefix és az azonnali vagy kör eleji frissítés módosítható az 5. és a 8. sorban az .sma-n belül.
[sma]new const PREFIX[] = "KillAssists" // Vedd ki a // jelet a # elől, ha azonnal frissíteni szeretnéd a fragek számát elosztáskor, nem csak kör elején.//#define LIVE_UPDATE[/sma]

#include <amxmodx>
#include <fun>
#include <cstrike>

new const PREFIX[] = "KillAssists"

// Vedd ki a // jelet a # elől, ha azonnal frissíteni szeretnéd a fragek számát elosztáskor, nem csak kör elején.
//#define LIVE_UPDATE

#define IsValidPlayers(%1,%2) ((1 <= %1 <= 32) && (1 <= %2 <= 32))

new g_iAssist[33];
new g_iAssDamage[33][33];

public plugin_init()
{
	register_plugin("Lite Kill Assists", "1.17", "neygomon");
	
	register_event("HLTV",     "eRoundStart", "a", "1=0", "2=0");
	register_event("DeathMsg", "eDeathMsg", "a", "1>0");
	register_event("Damage",   "eDamage", "be", "2!0", "3=0", "4!0");
}

public client_disconnect(id)
	ResetAssist(id);

public eRoundStart()
{
	new pl[32], pnum; get_players(pl, pnum);
	for(new i; i < pnum; i++)
		ResetAssist(pl[i]);
}
	
public eDeathMsg()
{
	static pKiller, pVictim;
	pKiller = read_data(1);
	pVictim = read_data(2);
	if(pKiller == pVictim || pKiller == g_iAssist[pVictim] || !is_user_connected(g_iAssist[pVictim])) return;
	
	cs_set_user_money(g_iAssist[pVictim], cs_get_user_money(g_iAssist[pVictim]) + 300);
	static iFrags; iFrags = get_user_frags(g_iAssist[pVictim]) + 1;
	set_user_frags(g_iAssist[pVictim], iFrags);
#if defined LIVE_UPDATE
	static mScoreInfo; if(!mScoreInfo) mScoreInfo = get_user_msgid("ScoreInfo");
	message_begin(MSG_ALL, mScoreInfo);
	write_byte(g_iAssist[pVictim]);
	write_short(iFrags);
	write_short(get_user_deaths(g_iAssist[pVictim]));
	write_short(0);
	write_short(get_user_team(g_iAssist[pVictim]));
	message_end();
#endif
	static victim[32];
	get_user_name(pVictim, victim, charsmax(victim));
	ChatColor(g_iAssist[pVictim], "^4[%s] ^1Kaptál ^4+1 ^1fraget, mert segítettél ^3%s ^1megölésében.", PREFIX, victim);	
	ResetAssist(pVictim);
}

public eDamage(id)
{
	static pAttacker; pAttacker = get_user_attacker(id);
	if(id == pAttacker || !IsValidPlayers(id, pAttacker)) return;
	g_iAssDamage[id][pAttacker] += read_data(2);
	if(!g_iAssist[id] && g_iAssDamage[id][pAttacker] >= 50)
		g_iAssist[id] = pAttacker;
}

ResetAssist(id)
{
	g_iAssist[id] = 0;
	arrayset(g_iAssDamage[id], 0, sizeof g_iAssDamage[]);
}

stock ChatColor(const id, const szMessage[], any:...) {
	static pnum, players[32], szMsg[190], IdMsg; 
	vformat(szMsg, charsmax(szMsg), szMessage, 3);
	
	if(!IdMsg) IdMsg = get_user_msgid("SayText");
	
	if(id) { 
		if(!is_user_connected(id)) return;
		players[0] = id;
		pnum = 1; 
    } 
	else get_players(players, pnum, "ch");
	
	for(new i; i < pnum; i++) {
		message_begin(MSG_ONE, IdMsg, .player = players[i]);
		write_byte(players[i]);
		write_string(szMsg);
		message_end();
	}
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:

regener [ 2016.01.05. 22:40 ]

Hozzászólás témája:

Re: Lite Kill Assists

Ezt naplózza, talán is_user_connected(id) kell neki?

Kód:

L 01/05/2016 - 22:11:14: [AMXX] Run time error 10 (plugin "lite_kill.amxx") (native "get_user_attacker") - debug not enabled!
L 01/05/2016 - 22:11:14: [AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes).

Szerző:	mforce [ 2016.01.05. 22:46 ]
Hozzászólás témája:	Re: Lite Kill Assists
Nálam vagy fél éve bent a plugin, most néztem logokat, semmi error, úgyhogy valami nálad lehet. Esetleg a compilerrel vagy nem tudom, ha nem módosítottál bele.

Szerző:	regener [ 2016.01.06. 12:10 ]
Hozzászólás témája:	Re: Lite Kill Assists
Hibarészlet: Idézet: L 01/06/2016 - 11:49:26: Start of error session. L 01/06/2016 - 11:49:26: Info (map "css_inferno") (file "addons/amxmodx/logs/error_20160106.log") L 01/06/2016 - 11:49:26: Invalid player id 0 L 01/06/2016 - 11:49:26: [AMXX] Displaying debug trace (plugin "lite_kill.amxx") L 01/06/2016 - 11:49:26: [AMXX] Run time error 10: native error (native "get_user_attacker") L 01/06/2016 - 11:49:26: [AMXX] [0] lite_kill_assists.sma::eDamage (line 62) Talán az a baja hogy 0-s ID-ről kérne infót mikor a 0-s ID mindenkit jelent egyes parancsoknál?

Szerző:	mforce [ 2016.01.06. 16:45 ]
Hozzászólás témája:	Re: Lite Kill Assists
Ismételjem meg?

Szerző:	regener [ 2016.01.06. 21:45 ]
Hozzászólás témája:	Re: Lite Kill Assists
mforce írta: Ismételjem meg? Nem véletlen nem válaszoltam. A prefix lett csak átírva, más nem.

Szerző:	mforce [ 2016.01.06. 21:53 ]
Hozzászólás témája:	Re: Lite Kill Assists
Kód: [Egész kijelölése] [Mutatás/Eltüntetés] `public eDamage(id) { if(!is_user_connected(id)) return; static pAttacker; pAttacker = get_user_attacker(id); if(id == pAttacker \|\| !IsValidPlayers(id, pAttacker)) return; g_iAssDamage[id][pAttacker] += read_data(2); if(!g_iAssist[id] && g_iAssDamage[id][pAttacker] >= 50) g_iAssist[id] = pAttacker; }` GeSHi © Codebox Plus Kipróbálhatod esetleg.

Szerző:	regener [ 2016.01.06. 22:12 ]
Hozzászólás témája:	Re: Lite Kill Assists
mforce írta: Kód: [Egész kijelölése] [Mutatás/Eltüntetés] `public eDamage(id) { if(!is_user_connected(id)) return; static pAttacker; pAttacker = get_user_attacker(id); if(id == pAttacker \|\| !IsValidPlayers(id, pAttacker)) return; g_iAssDamage[id][pAttacker] += read_data(2); if(!g_iAssist[id] && g_iAssDamage[id][pAttacker] >= 50) g_iAssist[id] = pAttacker; }` GeSHi © Codebox Plus Kipróbálhatod esetleg. Köszi, jelentkezem holnap hogy naplózott-e hibát. Szerk: úgy tűnik megszűnt a hiba, köszi!

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/