E betűvel fegyver felvétel

Megválaszolatlan témák | Aktív témák

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Navigáció

Főmenü

Kezdőlap

Fórum

Kapcsolat

Képfeltöltő Amx Mod X

Letöltések

Pluginok

Fordító (Compiler) SourceMod

Letöltések

Pluginok

Fordító (Compiler) EventScript

Letöltések

Magyar scriptek Pályák

Half-Life

Half-Life 2

Jelenlévő felhasználók

Jelenleg 550 felhasználó van jelen :: 0 regisztrált, 0 rejtett és 550 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: nincs regisztrált felhasználó az elmúlt 5 percben aktív felhasználók alapján

[ Ki van itt ]

Utoljára aktív

Kereső

E betűvel fegyver felvétel

Moderátor: Fórum Moderátor

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 2

[ 11 hozzászólás ]

Oldal 1 2 Következő

Nyomtatóbarát verzió | Barát értesítése e-mailben

Előző téma | Következő téma

Szerző

Üzenet

Levii@Peace

Hozzászólás témája: E betűvel fegyver felvétel

HozzászólásElküldve: 2015.12.23. 19:45

Offline

Csatlakozott: 2015.12.05. 20:51
Hozzászólások: 179
Megköszönt másnak: 7 alkalommal
Megköszönték neki: 12 alkalommal

Plugin Neve:	E betűvel fegyver felvétel	Plugint készitette:	Sh!nE
Játék:	Counter-Strike	Kategória:	Játékmenet
Eredeti link:	Nincs megadva	Jóváhagyó:	mforce

Leírás: Ez egy olyan plugin ami ha van a földön egy fegyver [ akármilyen ] , azt nem automatikusan veszed fel ha rámész, hanem ha ránézel a fegyverre és megnyomod az E betűt.

Cvar:

Kód:

   onoff = register_cvar("amx_rwpickup","1") // A Plugin ki/ be kapcsolása , 1 = be , 0 = ki
   dist = register_cvar("amx_rwp_distance","150") // hány méterről lehessen felvenni a fegyvert
   glow = register_cvar("amx_rwp_glow","1") // Fegyver világítás be/ki kapcsolása , 1= be, 0 = ki
   glow_color = register_cvar("amx_rwp_glow_color","255 4 44") // Világítás RGB színben.

Ha tetszik, és örülsz hogy feltöltöttem akkor jöhet a kéz

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <hamsandwich>
#include <fakemeta_util>

#define MSG_SHOW_MIN_TIME 0.1

new is_glowing[33]

new last_ent[33],can_touch[33]
new onoff,dist,glow,glow_color

new red,green,blue

public plugin_init() {
	register_plugin("E bet�re fegyver felv�tel","0.9","Sh!nE")
	
	onoff = register_cvar("amx_rwpickup","1")
	dist = register_cvar("amx_rwp_distance","150")
	glow = register_cvar("amx_rwp_glow","1")
	glow_color = register_cvar("amx_rwp_glow_color","255 4 44")
	
	register_logevent("round_start",2,"1=Round_Start")
	
	register_forward(FM_CmdStart,"cmd_start")
	
	RegisterHam(Ham_Touch,"weaponbox","touch_weapon")
	RegisterHam(Ham_Touch,"armoury_entity","touch_weapon")
	RegisterHam(Ham_Touch,"weapon_shield","touch_weapon")
	
	register_forward(FM_AddToFullPack,"addtofullpack",1)
}

public round_start() {
	new temp_rgb[12],temp_rgb2[3][4]
	get_pcvar_string(glow_color,temp_rgb,11)
	
	parse(temp_rgb,temp_rgb2[0],3,temp_rgb2[1],3,temp_rgb2[2],3)
	
	red=str_to_num(temp_rgb2[0])
	green=str_to_num(temp_rgb2[1])
	blue=str_to_num(temp_rgb2[2])
}

public addtofullpack(es_handle,e,ent,id,hostflags,player,pSet) {
	if(!is_user_alive(id) || !get_pcvar_num(onoff) || !get_pcvar_num(glow) || (id==ent) || is_user_bot(id)) return FMRES_IGNORED
	
	if(is_glowing[id]==ent) {
		new rgb[3]
		
		rgb[0]=red
		rgb[1]=green
		rgb[2]=blue
		
		set_es(es_handle,ES_RenderMode,kRenderNormal)
		set_es(es_handle,ES_RenderFx,kRenderFxGlowShell)
		set_es(es_handle,ES_RenderAmt,16)
		set_es(es_handle,ES_RenderColor,rgb)
	}
	return FMRES_IGNORED
}

public cmd_start(id,uc_handle,random_seed) {
	if(!is_user_alive(id) || !get_pcvar_num(onoff) || is_user_bot(id)) return FMRES_IGNORED
	
	static buttons
	buttons=get_uc(uc_handle,UC_Buttons)
	
	new ent = get_aim_origin_ent(id)
	
	if(ent!=last_ent[id]) {
		is_glowing[id]=0
		last_ent[id]=ent
	}
	
	if(!ent) {
		remove_task(id)
		return FMRES_IGNORED
	}
	
	is_glowing[id]=ent
	
	if(!task_exists(id)) set_task(MSG_SHOW_MIN_TIME,"show_pickup",id,_,_,"b")
	
	if(buttons & IN_USE) {
		can_touch[id]=ent
		dllfunc(DLLFunc_Touch,ent,id)
	}
	else if(!(buttons & IN_USE)) can_touch[id]=0
		
	return FMRES_IGNORED
}

public show_pickup(id) {
	set_hudmessage(0,255,0,-1.0,0.88,0,6.0,MSG_SHOW_MIN_TIME)
	show_hudmessage(id,"Nyomd meg az   E   betűt, hogy felvedd")
}

public client_disconnect(id) {
	is_glowing[id]=0
	last_ent[id]=0
	can_touch[id]=0
	
	remove_task(id)
}

public touch_weapon(ent,id) {
	if(!is_user_alive(id) || !get_pcvar_num(onoff) || is_user_bot(id)) return HAM_IGNORED
	
	if(can_touch[id]==ent) {
		can_touch[id]=0
		return HAM_IGNORED
	}
	return HAM_SUPERCEDE
}

stock get_aim_origin_ent(id) {
	new ent=-1
	static Float:origin[2][3]
	
	pev(id,pev_origin,origin[0])
	fm_get_aim_origin(id,origin[1])
	
	if(get_distance_f(origin[0],origin[1]) > float(get_pcvar_num(dist))) return 0
	
	while((ent = engfunc(EngFunc_FindEntityInSphere,ent,origin[1],5.0))) {
		static classname[33]
		pev(ent,pev_classname,classname,32)
		
		if(equal(classname,"weaponbox") || equal(classname,"armoury_entity") || equal(classname,"weapon_shield")) return ent
	}
	return 0
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

_________________
.:[*|P|eac|E|*]:.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

mforce

Hozzászólás témája: Re: E betűfel fegyver felvétel

HozzászólásElküldve: 2015.12.25. 13:04

Offline

Csatlakozott: 2014.09.08. 22:21
Hozzászólások: 3014
Megköszönt másnak: 96 alkalommal
Megköszönték neki: 555 alkalommal

A plugin eredeti neve el van írva + ha ansi, akkor kerüld az ékezetet + nem E betűFel

_________________
GitHub - mforce

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

NuD[!]e

Hozzászólás témája: Re: E betűfel fegyver felvétel

HozzászólásElküldve: 2015.12.30. 13:04

Offline

Csatlakozott: 2014.05.10. 16:41
Hozzászólások: 721
Megköszönt másnak: 43 alkalommal
Megköszönték neki: 64 alkalommal

A plugin akkor lenne hasznos, hogyha nem kellene rá állni a fegyverre, hanem ránézel is kiírja, hogy e betűvel vedd fel!

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

mforce

Hozzászólás témája: Re: E betűvel fegyver felvétel

HozzászólásElküldve: 2016.01.06. 22:11

Offline

Csatlakozott: 2014.09.08. 22:21
Hozzászólások: 3014
Megköszönt másnak: 96 alkalommal
Megköszönték neki: 555 alkalommal

Nem igazán erőltetted meg magad, hogy átírd a nevet, átírtam és elfogadom, de első volt és utolsó.

_________________
GitHub - mforce

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Levii@Peace

Hozzászólás témája: Re: E betűvel fegyver felvétel

HozzászólásElküldve: 2016.01.06. 22:30

Offline

Csatlakozott: 2015.12.05. 20:51
Hozzászólások: 179
Megköszönt másnak: 7 alkalommal
Megköszönték neki: 12 alkalommal

mforce írta:

Nem igazán erőltetted meg magad, hogy átírd a nevet, átírtam és elfogadom, de első volt és utolsó.

Mármint a téma nevet?
vagy a Plugin készítőjét? (mert azt nem tudom...)

_________________
.:[*|P|eac|E|*]:.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

mforce

Hozzászólás témája: Re: E betűvel fegyver felvétel

HozzászólásElküldve: 2016.01.06. 22:31

Offline

Csatlakozott: 2014.09.08. 22:21
Hozzászólások: 3014
Megköszönt másnak: 96 alkalommal
Megköszönték neki: 555 alkalommal

Témanév. "betűfel" volt.

_________________
GitHub - mforce

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Levii@Peace

Hozzászólás témája: Re: E betűvel fegyver felvétel

HozzászólásElküldve: 2016.01.06. 22:34

Offline

Csatlakozott: 2015.12.05. 20:51
Hozzászólások: 179
Megköszönt másnak: 7 alkalommal
Megköszönték neki: 12 alkalommal

mforce írta:

Témanév. "betűfel" volt.

Elnézést, figyelmetlenségi hiba , törölheted a kommenteket [ Ha gondolod ]...

_________________
.:[*|P|eac|E|*]:.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

CoopCola

Hozzászólás témája: Re: E betűvel fegyver felvétel

HozzászólásElküldve: 2017.06.16. 08:14

Offline

Csatlakozott: 2015.08.11. 14:21
Hozzászólások: 215
Megköszönt másnak: 50 alkalommal
Megköszönték neki: 6 alkalommal

Meg lehet oldani, hogy E betűvel, és ha rámész egyaránt felvegye?

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

The Peace

Hozzászólás témája: Re: E betűvel fegyver felvétel

HozzászólásElküldve: 2017.06.16. 08:21

Offline

Csatlakozott: 2016.03.06. 14:20
Hozzászólások: 964
Megköszönt másnak: 102 alkalommal
Megköszönték neki: 134 alkalommal

CoopCola írta:

Meg lehet oldani, hogy E betűvel, és ha rámész egyaránt felvegye?

Bármi megoldható..

_________________

!	Moderátori megjegyzés (kiki):
	Kérlek csekkold az aláírásra vonatkozó szabályokat!

Ők köszönték meg The Peace nek ezt a hozzászólást: ultraibolya (2017.06.16. 21:01)

Népszerűség: 2.27%

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

CoopCola

Hozzászólás témája: Re: E betűvel fegyver felvétel

HozzászólásElküldve: 2017.06.17. 08:46

Offline

Csatlakozott: 2015.08.11. 14:21
Hozzászólások: 215
Megköszönt másnak: 50 alkalommal
Megköszönték neki: 6 alkalommal

És megoldanád nekem?:D

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Hozzászólások megjelenítése: Rendezés

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 2

[ 11 hozzászólás ]

Oldal 1 2 Következő

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 41 vendég

Nem nyithatsz témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Ugrás:

hlmod.hu

E betűvel fegyver felvétel

Ki van itt