hlmod.hu :: Simple RoundEndSounds

hlmod.hu https://hlmod.hu/

Simple RoundEndSounds https://hlmod.hu/viewtopic.php?f=101&t=23310	Oldal: 1 / 3

Szerző:

mforce [ 2015.12.30. 16:47 ]

Hozzászólás témája:

Simple RoundEndSounds

Plugin Neve:	Simple RoundEndSounds	Plugint készitette:	mforce
Játék:	Counter-Strike	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	ultraibolya

[kozep]Simple RoundEndSounds
v1.1 by mforce[/kozep]

Leírás:
Egyszerű de nagyszerű körvégi zene plugin, ami fájlból olvas be 1x és lejátssza sorban a zenéket, mikor valamelyik csapat nyer.

Parancsok:
/korvegi - KI-BE kapcsolhatók a körvégi zenék (a változtatás elmentődik a játékos kliensébe)

Konfiguráció:
Alapból van egy max zene érték meghatározva, ami 32. Ennek módosításához az .sma fájlon belül

Kód:

#define MAX_MUSIC 32

Azonkívül a szerverprefix is állítható:

Kód:

new const PREFIX[] = "RoundEndSounds"

Zenéket a configs/korvegi_zene.ini fájlban adhatunk hozzá a következőképp:
"mappa/zene1.mp3"
"mappa/zene2.mp3"

VirusTotal: [ablak]https://www.virustotal.com/hu/file/70c0c5d1ebac5b3b1a900fbd543e60491107addc01ff7204aa8bcd33b3b3a239/analysis/1451490265/[/ablak]

#include <amxmodx>

#define PLUGIN	"Simple RoundEndSounds"
#define VERSION	"1.1"
#define AUTHOR	"mforce"

#define MAX_MUSIC 32
new const PREFIX[] = "RoundEndSounds"

new musics[MAX_MUSIC][64], music_count, play_count, bool:musicon[33];

public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR);
	register_clcmd("say /korvegi", "music_on")
	register_event("SendAudio", "PlayMusic", "a", "2&%!MRAD_ctwin")
	register_event("SendAudio", "PlayMusic", "a", "2&%!MRAD_terwin")
}

public plugin_precache() {
	new sBuffer[192], sFile[128], sData[64], pFile;
	get_localinfo("amxx_configsdir", sFile, charsmax(sFile));
	format(sFile, charsmax(sFile), "%s/korvegi_zene.ini", sFile);

pFile = fopen(sFile, "rt");

if(pFile) {		
		while(music_count < MAX_MUSIC && !feof(pFile)) {
			fgets(pFile, sBuffer, charsmax(sBuffer));
			trim(sBuffer);
			if(sBuffer[0] != ';' && parse(sBuffer, sData, charsmax(sData))) {
				if(contain(sData, ".mp3") != -1) {
					precache_sound(sData)
					copy(musics[music_count++], charsmax(musics[]), sData)
				}
			}
		}
		fclose(pFile);
	}
	else
		write_file(sFile, ";^"mappa/valami.mp3^"");

if(!music_count) set_fail_state("Nem talaltunk zeneket! Ellenorizd a fajlt ^"addons/amxmodx/configs/korvegi_zene.ini^"");
}

public music_on(id) {
	switch(musicon[id]) {
		case true: {
			ChatColor(id, "^4[%s]^1 Kikapcsoltad a körvégi zenéket.", PREFIX)
			musicon[id] = false;
			client_cmd(id, "setinfo korvegi 0")
		}
		case false: {
			ChatColor(id, "^4[%s]^1 Bekapcsoltad a körvégi zenéket.", PREFIX)
			musicon[id] = true;
			client_cmd(id, "setinfo korvegi 1")
		}
	}
}

public client_putinserver(id) {
	if(user_roundmusic(id)) {
		musicon[id] = true;
	}
}

public client_disconnect(id) {
	musicon[id] = false;
}

public PlayMusic() {
	new Mp3File[128], players[32], num, tempid;
	formatex(Mp3File, charsmax(Mp3File), "sound/%s", musics[play_count == music_count ? (play_count = 0) : play_count++]);
	get_players(players, num, "c");
	for(new i; i < num; i++) {
		tempid = players[i];
		if(musicon[tempid]) {
			client_cmd(tempid, "mp3 play %s", Mp3File);
		}
	}
}

stock bool:user_roundmusic(id) {
	new azonosit[8];
	get_user_info(id, "korvegi", azonosit, charsmax(azonosit));
	if(equal(azonosit, "0")) return false;
	return true;
}

stock ChatColor(const id, const szMessage[], any:...) {
	static pnum, players[32], szMsg[190], IdMsg; 
	vformat(szMsg, charsmax(szMsg), szMessage, 3);
	
	if(!IdMsg) IdMsg = get_user_msgid("SayText");
	
	if(id) { 
		if(!is_user_connected(id)) return;
		players[0] = id;
		pnum = 1; 
	} 
	else get_players(players, pnum, "ch");
	
	for(new i; i < pnum; i++) {
		message_begin(MSG_ONE, IdMsg, .player = players[i]);
		write_byte(players[i]);
		write_string(szMsg);
		message_end();
	}
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

Szerző:	Andrew [ 2015.12.30. 16:52 ]
Hozzászólás témája:	Re: Simple RoundEndSounds
Tesztelve! No Problem.. Köszönöm!

Szerző:	CoCo [ 2015.12.30. 17:21 ]
Hozzászólás témája:	Re: Simple RoundEndSounds
Lobby írta: Hy MForce! I'm a begginer plugin maker.. And im dont know the code snippets. Do you help me in this "plugin code snippets". I mean the HUD Message or some of this... If you help me, i very thank you. Good

Szerző:	mforce [ 2015.12.30. 20:30 ]
Hozzászólás témája:	Re: Simple RoundEndSounds
Még egyik másik modi se fogadja el pls.

Szerző:	PistaCFG [ 2015.12.30. 21:04 ]
Hozzászólás témája:	Re: Simple RoundEndSounds
Minek ennyi körvégi zene plugin?

Szerző:	mforce [ 2015.12.30. 21:07 ]
Hozzászólás témája:	Re: Simple RoundEndSounds
Hasonlítsd már össze a többivel az .sma-t mielőtt megszólalsz...

Szerző:	kengurumancs [ 2015.12.30. 21:14 ]
Hozzászólás témája:	Re: Simple RoundEndSounds
Jó plugin, én felraknám a szerverre, ha ki lehetne kapcsolni..

Szerző:	PistaCFG [ 2015.12.30. 22:19 ]
Hozzászólás témája:	Re: Simple RoundEndSounds
A többi is körvégi zene, az mindegy, nem az smát kell nézni, hanem hogy már van e ilyen plugin

Szerző:	mforce [ 2015.12.30. 22:24 ]
Hozzászólás témája:	Re: Simple RoundEndSounds
Ja te jobban tudod bocs főnök Nem az sma-t kell nézni, hogy maga a tökély, hanem, hogy az összes többi bugos, de jó az úgy, mert te megmondtad a frankót a hozzáértők helyett is.

Szerző:	PistaCFG [ 2015.12.30. 22:25 ]
Hozzászólás témája:	Re: Simple RoundEndSounds
mforce írta: Ja te jobban tudod bocs főnök Nem az sma-t kell nézni, hogy maga a tökély, hanem, hogy az összes többi bugos, de jó az úgy, mert te megmondtad a frankót a hozzáértők helyett is. Na látod, tudod te ha akarod

Oldal: 1 / 3	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/