Info Message HUD

Megválaszolatlan témák | Aktív témák

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Navigáció

Főmenü

Kezdőlap

Fórum

Kapcsolat

Képfeltöltő Amx Mod X

Letöltések

Pluginok

Fordító (Compiler) SourceMod

Letöltések

Pluginok

Fordító (Compiler) EventScript

Letöltések

Magyar scriptek Pályák

Half-Life

Half-Life 2

Jelenlévő felhasználók

Jelenleg 230 felhasználó van jelen :: 0 regisztrált, 0 rejtett és 230 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: nincs regisztrált felhasználó az elmúlt 5 percben aktív felhasználók alapján

[ Ki van itt ]

Utoljára aktív

Kereső

Moderátor: Fórum Moderátor

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 1

[ 1 hozzászólás ]

Nyomtatóbarát verzió | Barát értesítése e-mailben

Előző téma | Következő téma

Szerző

Üzenet

kengurumancs

Hozzászólás témája: Info Message HUD

HozzászólásElküldve: 2016.01.06. 17:34

Offline

Csatlakozott: 2015.03.12. 18:30
Hozzászólások: 975
Megköszönt másnak: 67 alkalommal
Megköszönték neki: 136 alkalommal

Plugin Neve:	Info Message HUD	Plugint készitette:	Blizzard/guipatinador
Játék:	Mind	Kategória:	Játékmenet
Eredeti link:	Megnézem	Jóváhagyó:	kiki

Info Message HUD
v1.3
By Blizzard_87 / guipatinador

Leírás:

Fent középen HUD-ba írja a pályából hátralévő időt (timeleft),szerver nevét, pálya nevét.

Parancsok: (konzol)

hud_color - A szín amilyennel írja a szerver, te választhatod ki
blue - kék
red - piros
green - zöld
white - fehér
purple - lila
gold - arany
silver-ezüst
orange -narancssárga
aqua -víz kék
yellow -sárga

Cvar:

hud_type -Ki lássa az információt, 1 élő játékosok, 2 halott játékosok, 3 (alap) mindenki
hud_x_pos "-1.0" - A HUD üzenet helyzete.
hud_y_pos "0.0" - A HUD üzenet helyzete.

Kép
Kép

Telepítés:
Amxx fájl a plugins mappába, majd a plugin nevét a plugins.ini -be írd be!
Sma-t scripting mappába. (nem szükséges)

#include < amxmodx >
#include < amxmisc >
#include < fakemeta >
#include < hamsandwich >

#define PLUGIN "Info Message HUD"
#define VERSION "1.3"
#define AUTHOR "Blizzard/guipatinador"

new const szColors[ ][ ] = {
    "white",
    "red",
    "green",
    "blue",
    "aqua",
    "purple",
    "orange",
    "yellow",
    "gold",
    "silver"
}

new const COLORS[ ][ ] = {
    { 255, 255, 255 },
    { 255, 0, 0 },
    { 0, 255, 0 },
    { 0, 0, 255 },
    { 0, 255, 255 },
    { 255, 0, 255 },
    { 255, 170, 0 },
    { 255, 255, 0 },
    { 212, 255, 0 },
    { 210, 210, 210 }
}

enum _:Structure {
    iRedValue,
    iGreenValue,
    iBlueValue,
}

new g_HudColors[ Structure ]

enum ( += 1 ) {
    ALIVE = 1,
    DEAD,
    ALL
}

new Trie:g_tColors
new Trie:g_tClassName

new g_szClassName[ ] = "Timer"
new g_szMapName[ 32 ]
new g_szHostname[ 64 ]

new g_pcvarHudType

new bool:g_IsAlive[ 33 ]

new x_pos, y_pos;

public plugin_init( )
{
    register_plugin( PLUGIN, VERSION, AUTHOR )
    
    get_mapname( g_szMapName, charsmax( g_szMapName ) )
    get_cvar_string( "hostname", g_szHostname, charsmax( g_szHostname ) )
    
    register_concmd( "hud_color", "ChangeColor", ADMIN_RCON, "white or red or green or blue" )
    
    x_pos = register_cvar("hud_x_pos", "-1.0");
    y_pos = register_cvar("hud_y_pos", "0.0");
    
    g_pcvarHudType = register_cvar( "hud_type", "3" )
    // 1 = csak az élő embereknek
    // 2 = csak a halott embereknek
    // 3 = mindenkinek
    
    g_tColors = TrieCreate( )
    
    new i
    for( i = 0; i < sizeof COLORS; i++ )
    {
        TrieSetCell( g_tColors, szColors[ i ], i )
    }
    
    g_tClassName = TrieCreate( )
    TrieSetCell( g_tClassName, g_szClassName, 1 )
    
    new iEnt = engfunc( EngFunc_CreateNamedEntity, engfunc( EngFunc_AllocString,"info_target" ) )
    set_pev( iEnt, pev_classname, g_szClassName )
    set_pev( iEnt, pev_nextthink, 1.0 )
    
    RegisterHam( Ham_Spawn, "player", "FwdPlayerSpawnPost", 1 )
    RegisterHam( Ham_Killed, "player", "FwdPlayerKilledPost", 1 )
    
    register_forward( FM_Think,"ForwardThink" )
}

public plugin_cfg( )
{
    server_cmd( "hud_color white" )
}

public client_connect( id )
{
    g_IsAlive[ id ] = false    
}

public FwdPlayerSpawnPost( id )
{
    if( is_user_alive( id ) )
    {
        g_IsAlive[ id ] = true
    }
}

public FwdPlayerKilledPost( iVictim )
{
    g_IsAlive[ iVictim ] = false    
}

public ChangeColor( id, level, cid )
{
    if ( !cmd_access( id, level, cid, 2 ) )
        return PLUGIN_HANDLED
    
    static szColor[ 16 ]
    read_argv( 1, szColor, charsmax( szColor ) )
    
    strtolower( szColor )
    
    static iPos
    if( TrieGetCell( g_tColors, szColor, iPos ) )
    {
        g_HudColors[ iRedValue ] = COLORS[ iPos ][ 0 ]
        g_HudColors[ iGreenValue ] = COLORS[ iPos ][ 1 ]
        g_HudColors[ iBlueValue ] = COLORS[ iPos ][ 2 ]
        
        console_print( id, "HUD szin modositva erre: %s", szColor )
    }
    
    else
    {
        console_print( id, "%s ervenytelen szin!", szColor )
    }
    
    return PLUGIN_HANDLED
}

public ForwardThink( iEnt )
{
    static szClassName[ 32 ]
    pev( iEnt, pev_classname, szClassName, charsmax( szClassName ) )
    
    if( !TrieKeyExists( g_tClassName, szClassName ) )
        return FMRES_IGNORED
    
    new iHudType = get_pcvar_num( g_pcvarHudType )
    
    new Players[ 32 ]
    new iNum
    new i
    
    get_players( Players, iNum, "ch" )
    
    for( --iNum; iNum >= 0; iNum-- )
    {
        i = Players[ iNum ]
        
        switch( iHudType )
        {
            case ALIVE:
            {
                if( g_IsAlive[ i ] )
                {
                    ShowTimer( i )
                }
            }
            
            case DEAD:
            {
                if( !g_IsAlive[ i ] )
                {
                    ShowTimer( i )
                }
            }
            
            case ALL:
            {
                ShowTimer( i )    
            }
        }
    }
    
    
    static Float:fGlobalTime
    global_get( glb_time, fGlobalTime )
    
    set_pev( iEnt, pev_nextthink, fGlobalTime + 1.0 )
    
    return FMRES_IGNORED
}

public ShowTimer( id )
{
    new iTimeLeft = get_timeleft( )
    
    set_hudmessage( g_HudColors[ iRedValue ], g_HudColors[ iGreenValue ], g_HudColors[ iBlueValue ], get_pcvar_float(x_pos), get_pcvar_float(y_pos), 0, 0.0, 1.0 )
    show_hudmessage( id, "Hátralévő idő: %d:%02d | %s | Pálya: %s", iTimeLeft / 60, iTimeLeft % 60, g_szHostname, g_szMapName )
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

_________________
Fórumi aktivitásom véget ért: 2017.09.07.
Innentől esetleg steamen vagyok elérhető.

A hozzászólást 1 alkalommal szerkesztették, utoljára kengurumancs 2016.01.06. 17:35-kor.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Hozzászólások megjelenítése: Rendezés

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 1

[ 1 hozzászólás ]

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 13 vendég

Nem nyithatsz témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Ugrás: