hlmod.hu ::[CSO] Ethereal

hlmod.hu https://hlmod.hu/

[CSO] Ethereal https://hlmod.hu/viewtopic.php?f=101&t=23841	Oldal: 1 / 1

Szerző: |E|xTazYyyy^.~ [2016.02.03. 18:37 ]

Hozzászólás témája: [CSO] Ethereal

Plugin Neve:	[CSO] Ethereal	Plugint készitette:	KORD_12.7
Játék:	Half-Life	Kategória:	Játékmenet
Eredeti link:	Megnézem	Jóváhagyó:	kiki

Támogatott játékok:
Half Life

Szükséges modulok:
Weapon Mod
HamSandWich
Fakemeta

Leírás:
A plugin beteszi a játékba az Ethereal fegyvert CSO-ból!

Beállítások:

Kód: [Egész kijelölése] [Mutatás/Eltüntetés]

// Weapon settings
#define WEAPON_NAME          "weapon_ethereal"
#define WEAPON_SLOT         2
#define WEAPON_POSITION         5
#define WEAPON_PRIMARY_AMMO      "uranium"
#define WEAPON_PRIMARY_AMMO_MAX      100
#define WEAPON_SECONDARY_AMMO      "" // NULL
#define WEAPON_SECONDARY_AMMO_MAX   -1
#define WEAPON_MAX_CLIP         30
#define WEAPON_DEFAULT_AMMO      30
#define WEAPON_FLAGS         0
#define WEAPON_WEIGHT         15
#define WEAPON_DAMAGE         40.0
 
// Hud
#define WEAPON_HUD_TXT         "sprites/weapon_ethereal.txt"
#define WEAPON_HUD_SPR         "sprites/weapon_ethereal.spr"
 
// Models
#define MODEL_WORLD         "models/w_ethereal.mdl"
#define MODEL_VIEW         "models/v_ethereal_hev.mdl"
#define MODEL_PLAYER         "models/p_ethereal.mdl"
 
// Sounds
#define SOUND_FIRE         "weapons/ethereal-1.wav"
#define SOUND_DRAW         "weapons/ethereal_draw.wav"
#define SOUND_IDLE         "weapons/ethereal_idle1.wav"
#define SOUND_IMPACT         "weapons/shock_impact.wav"
#define SOUND_RELOAD         "weapons/ethereal_reload.wav"
 
// Sprites
#define SPRITE_LIGHTNING      "sprites/lgtning.spr"
#define SPRITE_MUZZLEFLASH      "sprites/ethereal_muzzleflash.spr"
 
// Beam
#define BEAM_LIFE         0.09
#define BEAM_COLOR         {100.0, 50.0, 253.0}
#define BEAM_BRIGHTNESS         255.0
#define BEAM_SCROLLRATE         10.0
 
// Animation
#define ANIM_EXTENSION         "gauss"

GeSHi © Codebox Plus

Videó:
https://www.youtube.com/watch?v=S2I0eSbI0Xw

/* AMX Mod X
*	Ethereal.
*
* http://aghl.ru/forum/ - Russian Half-Life and Adrenaline Gamer Community
*
* This file is provided as is (no warranties)
*/

#pragma semicolon 1
#pragma ctrlchar '\'

#include <amxmodx>
#include <hamsandwich>
/*
 * Half-Life Weapon Mod
 * Copyright (c) 2012 AGHL.RU Dev Team
 * 
 * http://aghl.ru/forum/ - Russian Half-Life and Adrenaline Gamer Community
 *
 *
 *    This program is free software; you can redistribute it and/or modify it
 *    under the terms of the GNU General Public License as published by the
 *    Free Software Foundation; either version 2 of the License, or (at
 *    your option) any later version.
 *
 *    This program is distributed in the hope that it will be useful, but
 *    WITHOUT ANY WARRANTY; without even the implied warranty of
 *    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
 *    General Public License for more details.
 *
 *    You should have received a copy of the GNU General Public License
 *    along with this program; if not, write to the Free Software Foundation,
 *    Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
 *
 *    In addition, as a special exception, the author gives permission to
 *    link the code of this program with the Half-Life Game Engine ("HL
 *    Engine") and Modified Game Libraries ("MODs") developed by Valve,
 *    L.L.C ("Valve").  You must obey the GNU General Public License in all
 *    respects for all of the code used other than the HL Engine and MODs
 *    from Valve.  If you modify this file, you may extend this exception
 *    to your version of the file, but you are not obligated to do so.  If
 *    you do not wish to do so, delete this exception statement from your
 *    version.
 *
 */

#if defined _hl_wpnmod_included
	#endinput
#endif
#define _hl_wpnmod_included

/*
 * Half-Life Weapon Mod
 * Copyright (c) 2012 AGHL.RU Dev Team
 * 
 * http://aghl.ru/forum/ - Russian Half-Life and Adrenaline Gamer Community
 *
 *
 *    This program is free software; you can redistribute it and/or modify it
 *    under the terms of the GNU General Public License as published by the
 *    Free Software Foundation; either version 2 of the License, or (at
 *    your option) any later version.
 *
 *    This program is distributed in the hope that it will be useful, but
 *    WITHOUT ANY WARRANTY; without even the implied warranty of
 *    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
 *    General Public License for more details.
 *
 *    You should have received a copy of the GNU General Public License
 *    along with this program; if not, write to the Free Software Foundation,
 *    Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
 *
 *    In addition, as a special exception, the author gives permission to
 *    link the code of this program with the Half-Life Game Engine ("HL
 *    Engine") and Modified Game Libraries ("MODs") developed by Valve,
 *    L.L.C ("Valve").  You must obey the GNU General Public License in all
 *    respects for all of the code used other than the HL Engine and MODs
 *    from Valve.  If you modify this file, you may extend this exception
 *    to your version of the file, but you are not obligated to do so.  If
 *    you do not wish to do so, delete this exception statement from your
 *    version.
 *
 */

#if defined _hl_wpnmod_const_included
	#endinput
#endif

#define _hl_wpnmod_const_included

// Maximum available weapons
#define MAX_WEAPONS						32

// Temp entity bounce sound types
#define TE_BOUNCE_NULL					0
#define TE_BOUNCE_SHELL					1
#define TE_BOUNCE_SHOTSHELL				2

// Gun volumes
#define LOUD_GUN_VOLUME					1000
#define NORMAL_GUN_VOLUME				600
#define QUIET_GUN_VOLUME				200

// Gun flash
#define	BRIGHT_GUN_FLASH				512
#define NORMAL_GUN_FLASH				256
#define	DIM_GUN_FLASH					128

// Weapon flags
#define ITEM_FLAG_SELECTONEMPTY			1
#define ITEM_FLAG_NOAUTORELOAD			2
#define ITEM_FLAG_NOAUTOSWITCHEMPTY		4
#define ITEM_FLAG_LIMITINWORLD			8
#define ITEM_FLAG_EXHAUSTIBLE			16 // A player can totally exhaust their ammo supply and lose this weapon

// Default spreads
#define VECTOR_CONE_1DEGREES			Float:{ 0.00873, 0.00873, 0.00873 }
#define VECTOR_CONE_2DEGREES			Float:{ 0.01745, 0.01745, 0.01745 }
#define VECTOR_CONE_3DEGREES			Float:{ 0.02618, 0.02618, 0.02618 }
#define VECTOR_CONE_4DEGREES			Float:{ 0.03490, 0.03490, 0.03490 }
#define VECTOR_CONE_5DEGREES			Float:{ 0.04362, 0.04362, 0.04362 }
#define VECTOR_CONE_6DEGREES			Float:{ 0.05234, 0.05234, 0.05234 }
#define VECTOR_CONE_7DEGREES			Float:{ 0.06105, 0.06105, 0.06105 }
#define VECTOR_CONE_8DEGREES			Float:{ 0.06976, 0.06976, 0.06976 }
#define VECTOR_CONE_9DEGREES			Float:{ 0.07846, 0.07846, 0.07846 }
#define VECTOR_CONE_10DEGREES			Float:{ 0.08716, 0.08716, 0.08716 }
#define VECTOR_CONE_15DEGREES			Float:{ 0.13053, 0.13053, 0.13053 }
#define VECTOR_CONE_20DEGREES			Float:{ 0.17365, 0.17365, 0.17365 }

// For CLASSIFY
#define	CLASS_NONE						0
#define CLASS_MACHINE					1
#define CLASS_PLAYER					2
#define	CLASS_HUMAN_PASSIVE				3
#define CLASS_HUMAN_MILITARY			4
#define CLASS_ALIEN_MILITARY			5
#define CLASS_ALIEN_PASSIVE				6
#define CLASS_ALIEN_MONSTER				7
#define CLASS_ALIEN_PREY				8
#define CLASS_ALIEN_PREDATOR			9
#define CLASS_INSECT					10
#define CLASS_PLAYER_ALLY				11
#define CLASS_PLAYER_BIOWEAPON			12 // Hornets and snarks, launched by players
#define CLASS_ALIEN_BIOWEAPON			13 // Hornets and snarks, launched by the alien menace

// Grenade explosion flags
#define SF_EXPLOSION_NODAMAGE			( 1 << 0 ) // When set, explosion will not actually inflict damage
#define SF_EXPLOSION_NOFIREBALL			( 1 << 1 ) // Don't draw the fireball
#define SF_EXPLOSION_NOSMOKE			( 1 << 2 ) // Don't draw the smoke
#define SF_EXPLOSION_NODECAL			( 1 << 3 ) // Don't make a scorch mark
#define SF_EXPLOSION_NOSPARKS			( 1 << 4 ) // Don't make a sparks
#define SF_EXPLOSION_NODEBRIS			( 1 << 5 ) // Don't make a debris sound

enum PLAYER_ANIM
{
	PLAYER_IDLE,
	PLAYER_WALK,
	PLAYER_JUMP,
	PLAYER_SUPERJUMP,
	PLAYER_DIE,
	PLAYER_ATTACK1,
};

enum e_AmmoFwds
{
	/**
	 * Forward params for all functions:
	 * 
	 * @param iItem				Ammobox's entity index.
	 */
	
	Fwd_Ammo_Spawn,					/* This is called whenever a ammobox entity is created. */
	Fwd_Ammo_AddAmmo,

Fwd_Ammo_End
};

enum e_WpnFwds
{
	/**
	 * Forward params for all functions:
	 * 
	 * @param iItem				Weapon's entity index.
	 * @param iPlayer			Player index, owner of weapon.
	 * @param iClip				Amount of ammo in weapon's clip.
	 * @param iAmmo				Amount of ammo in backpack on a user for weapon.
	 */
	
	Fwd_Wpn_Spawn,					/* This is called whenever a weapon entity is created. */
	Fwd_Wpn_CanDeploy,				/* Whether or not this weapon can be deployed. */
	Fwd_Wpn_Deploy,					/* Deploys a weapon. */
	Fwd_Wpn_Idle,					/* Displays the idle animation for the weapon. */
	Fwd_Wpn_PrimaryAttack,			/* Called when the main attack of a weapon is triggered. */
	Fwd_Wpn_SecondaryAttack,		/* Called when the secondary attack of a weapon is triggered. */
	Fwd_Wpn_Reload,					/* Called when the weapon is reloaded. */
	Fwd_Wpn_CanHolster,				/* Whether or not the weapon can be holstered. */
	Fwd_Wpn_Holster,				/* Holsters a weapon. */
	Fwd_Wpn_IsUseable,				/* Whether or not the weapon is usable. (has ammo, etc.) */
	Fwd_Wpn_AddToPlayer,
	Fwd_Wpn_AddToPlayer2,
	Fwd_Wpn_ItemPostFrame,

Fwd_Wpn_End
};

enum e_AmmoInfo
{
	AmmoInfo_szName,

AmmoInfo_End
};

enum e_ItemInfo
{
	ItemInfo_bCustom,

ItemInfo_iSlot,
	ItemInfo_iPosition,
	ItemInfo_iMaxAmmo1,
	ItemInfo_iMaxAmmo2,
	ItemInfo_iMaxClip,
	ItemInfo_iId,
	ItemInfo_iFlags,
	ItemInfo_iWeight,

ItemInfo_szName,
	ItemInfo_szAmmo1,
	ItemInfo_szAmmo2,
	ItemInfo_szTitle,
	ItemInfo_szAuthor,
	ItemInfo_szVersion,

ItemInfo_End
};

enum e_CBase
{
	// Weapon
	CBase_pPlayer,
	CBase_pNext,

// Player
	CBase_rgpPlayerItems,
	CBase_pActiveItem,
	CBase_pLastItem,

CBase_End
};

enum e_Offsets
{
	// Weapon
	Offset_flStartThrow,
	Offset_flReleaseThrow,
	Offset_iChargeReady,
	Offset_iInAttack,
	Offset_iFireState,
	Offset_iFireOnEmpty,				// True when the gun is empty and the player is still holding down the attack key(s).
	Offset_flPumpTime,
	Offset_iInSpecialReload,			// Are we in the middle of a reload for the shotguns.
	Offset_flNextPrimaryAttack,			// Soonest time ItemPostFrame will call PrimaryAttack.
	Offset_flNextSecondaryAttack,		// Soonest time ItemPostFrame will call SecondaryAttack.
	Offset_flTimeWeaponIdle,			// Soonest time ItemPostFrame will call WeaponIdle.
	Offset_iPrimaryAmmoType,			// "Primary" ammo index into players m_rgAmmo[].
	Offset_iSecondaryAmmoType,			// "Secondary" ammo index into players m_rgAmmo[].
	Offset_iClip,						// Number of shots left in the primary weapon clip, -1 it not used.
	Offset_iInReload,					// Are we in the middle of a reload.
	Offset_iDefaultAmmo,				// How much ammo you get when you pick up this weapon as placed by a level designer.
	
	// Player
	Offset_flNextAttack,				// Cannot attack again until this time.
	Offset_iWeaponVolume,				// How loud the player's weapon is right now.
	Offset_iWeaponFlash,				// Brightness of the weapon flash.
	Offset_iLastHitGroup,				// The last body region that took damage.
	Offset_iFOV,						// Field of view.

// Custom (for weapon and "info_target" entities only)
	Offset_iuser1,
	Offset_iuser2,
	Offset_iuser3,
	Offset_iuser4,
	Offset_fuser1,
	Offset_fuser2,
	Offset_fuser3,
	Offset_fuser4,
	
	Offset_End
};

#if AMXX_VERSION_NUM >= 175
	#pragma reqlib weaponmod
#if !defined AMXMODX_NOAUTOLOAD
	#pragma loadlib weaponmod
#endif
#else
	#pragma library weaponmod
#endif

#include <fakemeta>

#define SET_MODEL(%0,%1) engfunc(EngFunc_SetModel, %0, %1)
#define PRECACHE_MODEL(%0) engfunc(EngFunc_PrecacheModel,%0)
#define PRECACHE_SOUND(%0) engfunc(EngFunc_PrecacheSound,%0)
#define PRECACHE_GENERIC(%0) engfunc(EngFunc_PrecacheGeneric,%0)

/**
 * Register new weapon in module.
 *
 * @param szName			The weapon name.
 * @param iSlot				SlotID (1...5).
 * @param iPosition			NumberInSlot (1...5).
 * @param szAmmo1			Primary ammo type ("9mm", "uranium", "MY_AMMO" etc).
 * @param iMaxAmmo1			Max amount of primary ammo.
 * @param szAmmo2			Secondary ammo type.
 * @param iMaxAmmo2			Max amount of secondary ammo.
 * @param iMaxClip			Max amount of ammo in weapon's clip.
 * @param iFlags			Weapon's flags (see defines).
 * @param iWeight			This value used to determine this weapon's importance in autoselection.
 * 
 * @return					The ID of registerd weapon or -1 on failure. (integer)
 */
native wpnmod_register_weapon(const szName[], const iSlot, const iPosition, const szAmmo1[], const iMaxAmmo1, const szAmmo2[], const iMaxAmmo2, const iMaxClip, const iFlags, const iWeight);

/**
 * Register weapon's forward.
 *
 * @param iWeaponID			The ID of registered weapon.
 * @param iForward			Forward type to register.
 * @param szCallBack		The forward to call.
 */
native wpnmod_register_weapon_forward(const iWeaponID, const e_WpnFwds: iForward, const szCallBack[]);

/**
 * Returns any ItemInfo variable for weapon. Use the e_ItemInfo_* enum.
 *
 * @param iId			The ID of registered weapon or weapon entity Id.
 * @param iInfoType		ItemInfo type.
 *
 * @return				Weapon's ItemInfo variable.
 */
native wpnmod_get_weapon_info(const iId, const e_ItemInfo: iInfoType, any:...);

/**
 * Gets number of registered weapons.
 *
 * @return		Number of registered weapons. (integer)
 */
native wpnmod_get_weapon_count();

/**
 * Register new ammobox in module.
 *
 * @param szName			The ammobox classname.
 * 
 * @return					The ID of registerd ammobox or -1 on failure. (integer)
 */
native wpnmod_register_ammobox(const szClassname[]);

/**
 * Register ammobox's forward.
 *
 * @param iAmmoboxID		The ID of registered ammobox.
 * @param iForward			Forward type to register.
 * @param szCallBack		The forward to call.
 */
native wpnmod_register_ammobox_forward(const iWeaponID, const e_AmmoFwds: iForward, const szCallBack[]);

/**
 * Returns any AmmoInfo variable for ammobox. Use the e_AmmoInfo_* enum.
 *
 * @param iId			The ID of registered ammobox or ammobox entity Id.
 * @param iInfoType		e_AmmoInfo_* type.
 *
 * @return				Ammobox's AmmoInfo variable.
 */
 native wpnmod_get_ammobox_info(const iId, const e_AmmoInfo: iInfoType, any:...);

/**
 * Gets number of registered ammoboxes.
 *
 * @return		Number of registered ammoboxes. (integer)
 */
 native wpnmod_get_ammobox_count();

/**
 * Sets weapon's think function. Analogue of set_task native.
 * 
 * Usage: 
 * 	wpnmod_set_think(iItem, "M249_CompleteReload");
 * 	set_pev(iItem, pev_nextthink, get_gametime() + 1.52);
 *
 * @param iItem				Weapon's entity index.
 * @param szCallBack		The forward to call.
 */
native wpnmod_set_think(const iItem, const szCallBack[]);

/**
 * Sets entity's touch function. 
 * 
 * @param iEntity			Entity index.
 * @param szCallBack		The forward to call.
 */
native wpnmod_set_touch(const iEntity, const szCallBack[]);

/**
 * Plays weapon's animation.
 *
 * @param iItem				Weapon's entity index.
 * @param iAnim				Sequence number.
 */
native wpnmod_send_weapon_anim(const iItem, const iAnim);

/**
 * Sets the activity for player based on an event or current state.
 *
 * @param iPlayer			Player index.
 * @param iPlayerAnim		Animation (see PLAYER_ANIM constants).
 */
native wpnmod_set_player_anim(const iPlayer, const PLAYER_ANIM: iPlayerAnim);

/**
 * Set animation extension for player.
 *
 * @param iPlayer		Player id.
 * @param szAnimExt[]	Animation extension prefix.
 */
native wpnmod_set_anim_ext(const iPlayer, const szAnimExt[]);

/**
 * Get animation extension for player.
 *
 * @param iPlayer		Player id.
 * @param szDest[]		Buffer.
 * @param iMaxLen		Max buffer size.
 */
 native wpnmod_get_anim_ext(const iPlayer, szDest[], iMaxLen);

/**
 * Sets an integer from private data.
 *
 * @param iEntity			Entity index.
 * @param iOffset			Offset (see e_Offsets constants).
 * @param iValue			Value.
 */
native wpnmod_set_offset_int(const iEntity, const e_Offsets: iOffset, const iValue);

/**
 * Returns an integer from private data.
 *
 * @param iEntity			Entity index.
 * @param iOffset			Offset (see e_Offsets constants).
 * 
 * @return					Value from private data. (integer)
 */
native wpnmod_get_offset_int(const iEntity, const e_Offsets: iOffset);

/**
 * Sets a float from private data.
 *
 * @param iEntity			Entity index.
 * @param iOffset			Offset (see e_Offsets constants).
 * @param flValue			Value.
 */
native wpnmod_set_offset_float(const iEntity, const e_Offsets: iOffset, const Float: flValue);

/**
 * Returns a float from private data.
 *
 * @param iEntity			Entity index.
 * @param iOffset			Offset (see e_Offsets constants).
 * 
 * @return					Value from private data. (float)
 */
native Float: wpnmod_get_offset_float(const iEntity, const e_Offsets: iOffset);

/**
 * Set the corresponding cbase field in private data with the index.
 *
 * @param iEntity			The entity to examine the private data.
 * @param iOffset			Offset (See e_CBase constants).
 * @param iValue			The index to store.
 * @param iExtraOffset		The extra offset.
 */
native wpnmod_set_offset_cbase(const iEntity, const e_CBase: iOffset, const iValue, const iExtraOffset = 0);

/**
 * This will return an index of the corresponding cbase field in private data.
 *
 * @param iEntity			The entity to examine the private data.
 * @param iOffset			Offset (See e_CBase constants).
 * @param iExtraOffset		The extra offset.
 *
 * @return					Value from private data. (integer)
 */
native wpnmod_get_offset_cbase(const iEntity, const e_CBase: iOffset, const iExtraOffset = 0);

/**
 * Default deploy function.
 *
 * @param iItem				Weapon's entity index.
 * @param szViewModel		Weapon's view model (V).
 * @param szWeaponModel		Weapon's player model (P).
 * @param iAnim				Sequence number of deploy animation.
 * @param szAnimExt			Animation extension.
 */
native wpnmod_default_deploy(const iItem, const szViewModel[], const szWeaponModel[], const iAnim, const szAnimExt[]);

/**
 * Default reload function.
 *
 * @param iItem				Weapon's entity index.
 * @param iClipSize			Maximum weapon's clip size.
 * @param iAnim				Sequence number of reload animation.
 * @param flDelay			Reload delay time.
 */
native wpnmod_default_reload(const iItem, const iClipSize, const iAnim, const Float: flDelay);

/**
 * Sets the weapon so that it can play empty sound again.
 *
 * @param iItem				Weapon's entity index.
 */
native wpnmod_reset_empty_sound(const iItem);

/**
 * Plays the weapon's empty sound.
 *
 * @param iItem				Weapon's entity index.
 */
native wpnmod_play_empty_sound(const iItem);

/**
 * Fire bullets from player's weapon.
 *
 * @param iPlayer			Player index.
 * @param iAttacker			Attacker index (usualy it equal to previous param).
 * @param iShotsCount		Number of shots.
 * @param vecSpread			Spread.
 * @param flDistance		Max shot distance.
 * @param flDamage			Damage amount.
 * @param bitsDamageType	Damage type.
 * @param iTracerFreq		Tracer frequancy.
 */
native wpnmod_fire_bullets(const iPlayer, const iAttacker, const iShotsCount, const Float: vecSpread[3], const Float: flDistance, const Float: flDamage, const bitsDamageType, const iTracerFreq);

/**
 * Fire default contact grenade from player's weapon.
 *
 * @param iPlayer			Player index.
 * @param vecStart			Start position.
 * @param vecVelocity		Velocity.
 * @param szCallBack		The forward to call on explode.
 *
 * @return					Contact grenade index or -1 on failure. (integer)
 */
native wpnmod_fire_contact_grenade(const iPlayer, const Float: vecStart[3], const Float: vecVelocity[3], const szCallBack[] = "");

/**
 * Fire default timed grenade from player's weapon.
 *
 * @param iPlayer			Player index.
 * @param vecStart			Start position.
 * @param vecVelocity		Velocity.
 * @param flTime			Time before detonate.
 * @param szCallBack		The forward to call on explode.
 *
 * @return					Contact grenade index or -1 on failure. (integer)
 */
native wpnmod_fire_timed_grenade(const iPlayer, const Float: vecStart[3], const Float: vecVelocity[3], const Float: flTime = 3.0, const szCallBack[] = "");

/**
 * Make damage upon entities within a certain range.
 * 	Only damage ents that can clearly be seen by the explosion.
 *
 * @param vecSrc			Origin of explosion.
 * @param iInflictor		Entity which causes the damage impact.
 * @param iAttacker			Attacker index.
 * @param flDamage			Damage amount.
 * @param flRadius			Damage radius.
 * @param iClassIgnore		Class to ignore.
 * @param bitsDamageType	Damage type (DMG_BLAST and etc).
 */
native wpnmod_radius_damage(const Float: vecSrc[3], const iInflictor, const iAttacker, const Float: flDamage, const Float: flRadius, const iClassIgnore, const bitsDamageType);

/**
 * Same as wpnmod_radius_damage, but blocks 'ghost mines' and 'ghost nades'.
 *
 * @param vecSrc			Origin of explosion.
 * @param iInflictor		Entity which causes the damage impact.
 * @param iAttacker			Attacker index.
 * @param flDamage			Damage amount.
 * @param flRadius			Damage radius.
 * @param iClassIgnore		Class to ignore.
 * @param bitsDamageType	Damage type (DMG_BLAST and etc).
 */
native wpnmod_radius_damage2(const Float: vecSrc[3], const iInflictor, const iAttacker, const Float: flDamage, const Float: flRadius, const iClassIgnore, const bitsDamageType);

/**
 * Resets the global multi damage accumulator.
 */
 native wpnmod_clear_multi_damage();

/**
 * Inflicts contents of global multi damage register on entity.
 *
 * @param iInflictor		Entity which causes the damage impact.
 * @param iAttacker			Attacker index.
 */
 native wpnmod_apply_multi_damage(const iInflictor, const iAttacker);

/**
 * Eject a brass from player's weapon.
 *
 * @param iPlayer			Player index.
 * @param iShellModelIndex	Index of precached shell's model.
 * @param iSoundtype		Bounce sound type (see defines).
 * @param flForwardScale	Forward scale value.
 * @param flUpScale			Up scale value.
 * @param flRightScale		Right scale value.
 */
native wpnmod_eject_brass(const iPlayer, const iShellModelIndex, const iSoundtype, const Float: flForwardScale, const Float: flUpScale, const Float: flRightScale);

/**
 * Spawn an item by name.
 *
 * @param szName			Item's name.
 * @param vecOrigin			Origin were to spawn.
 * @param vecAngles			Angles.
 *
 * @return					Item entity index or -1 on failure. (integer)
 */
native wpnmod_create_item(const szName[], const Float: vecOrigin[3] = {0.0, 0.0, 0.0}, const Float: vecAngles[3] = {0.0, 0.0, 0.0});

/**
* Get player's ammo inventory.
 *
 * @param iPlayer		Player id.
 * @param szAmmoName	Ammo type. ("9mm", "uranium", "MY_AMMO" etc..)
 *
 * @return				Amount of given ammo. (integer)
*/
native wpnmod_get_player_ammo(const iPlayer, const szAmmoName[]);

/**
* Set player's ammo inventory.
 *
 * @param iPlayer		Player id.
 * @param szAmmoName	Ammo type. ("9mm", "uranium", "MY_AMMO" etc..)
 * @param iAmount		Ammo amount.
*/
native wpnmod_set_player_ammo(const iPlayer, const szAmmoName[], const iAmount);

/**
 * Returns index of random damage decal for given entity.
 *
 * @param iEntity		Entity.
 *
 * @return				Index of damage decal. (integer)
 */
native wpnmod_get_damage_decal(const iEntity);

/**
 * Get player's gun position. Result will set in vecResult.
 *
 * @param iPlayer			Player index.
 * @param vecResult			Calculated gun position.
 * @param flForwardScale	Forward scale value.
 * @param flUpScale			Up scale value.
 * @param flRightScale		Right scale value.
 */
native wpnmod_get_gun_position(const iPlayer, Float: vecResult[3], const Float: flForwardScale = 1.0, const Float: flRightScale = 1.0, const Float: flUpScale = 1.0);

/**
 * Explode and then remove entity.
 *
 * @param iEntity			Entity index.
 * @param bitsDamageType	Damage type (see CLASSIFY defines).
 * @param szCallBack		The forward to call on explode.
 */
native wpnmod_explode_entity(const iEntity, const bitsDamageType = 0, const szCallBack[] = "");

/**
 * Draw decal by index or name on trace end.
 *
 * @param iTrace			Trace handler.
 * @param iDecalIndex		Decal index.
 * @param szDecalName		Decal name.
 */
native wpnmod_decal_trace(const iTrace, const iDecalIndex = -1, const szDecalName[] = "");

/**
 * Detects the texture of an entity from a direction.
 *
 * @param iEntity			Entity index that we want to get the texture.
 * @param vecSrc			The point from where the trace starts.
 * @param vecEnd			The point where the trace ends.
 * @param szTextureName		Buffer to save the texture name.
 * @param iLen				Buffer's length.
 */
native wpnmod_trace_texture(const iEntity, const Float: vecSrc[3], const Float: vecEnd[3], szTextureName[], const iLen);
/* AMX Mod X
*	Beam entities include by KORD_12.7.
*
* Version 1.2 (last update: 16, november (11), 2012)
*
* http://aghl.ru/forum/ - Russian Half-Life and Adrenaline Gamer Community
*
* This file is provided as is (no warranties)
*/

#if defined _beams_included
	#endinput
#endif
#define _beams_included

#include <fakemeta>
#include <xs>

// These functions are here to show the way beams are encoded as entities.
// Encoding beams as entities simplifies their management in the client/server architecture.

// Beam types
enum _:Beam_Types
{
	BEAM_POINTS,
	BEAM_ENTPOINT,
	BEAM_ENTS,
	BEAM_HOSE
};

// Beam flags
#define BEAM_FSINE	0x10
#define BEAM_FSOLID	0x20
#define BEAM_FSHADEIN	0x40
#define BEAM_FSHADEOUT	0x80

#define Beam_SetType(%0,%1) set_pev(%0, pev_rendermode, (pev(%0, pev_rendermode) & 0xF0) | %1 & 0x0F)
/* stock Beam_SetType(const iBeamEntity, const iType)
	return set_pev(iBeamEntity, pev_rendermode, (pev(iBeamEntity, pev_rendermode) & 0xF0) | iType & 0x0F); */
	
#define Beam_SetFlags(%0,%1) set_pev(%0, pev_rendermode, (pev(%0, pev_rendermode) & 0x0F) | %1 & 0xF0)
/* stock Beam_SetFlags(const iBeamEntity, const iType)
	return set_pev(iBeamEntity, pev_rendermode, (pev(iBeamEntity, pev_rendermode) & 0x0F) | iType & 0xF0); */

#define Beam_SetStartPos(%0,%1) set_pev(%0, pev_origin, %1)
/* stock Beam_SetStartPos(const iBeamEntity, const Float: flVecStart[3])
	return set_pev(iBeamEntity, pev_origin, flVecStart); */

#define Beam_SetEndPos(%0,%1) set_pev(%0, pev_angles, %1)
/* stock Beam_SetEndPos(const iBeamEntity, const Float: flVecEnd[3]) 
	return set_pev(iBeamEntity, pev_angles, flVecEnd); */

#define Beam_SetStartEntity(%0,%1) \
	set_pev(%0, pev_sequence, (%1 & 0x0FFF) | ((pev(%0, pev_sequence) & 0xF000) << 12)); \
	set_pev(%0, pev_owner, %1) \
/* stock Beam_SetStartEntity(const iBeamEntity, const iEntityIndex) */

#define Beam_SetEndEntity(%0,%1) \
	set_pev(%0, pev_skin, (%1 & 0x0FFF) | ((pev(%0, pev_skin) & 0xF000) << 12)); \
	set_pev(%0, pev_aiment, %1) \
/* stock Beam_SetEndEntity(const iBeamEntity, const iEntityIndex) */

#define Beam_SetStartAttachment(%0,%1) set_pev(%0, pev_sequence, (pev(%0, pev_sequence) & 0x0FFF) | ((%1 & 0xF) << 12))
/* stock Beam_SetStartAttachment(const iBeamEntity, const iAttachment)
	return set_pev(iBeamEntity, pev_sequence, (pev(iBeamEntity, pev_sequence) & 0x0FFF) | ((iAttachment & 0xF) << 12)); */

#define Beam_SetEndAttachment(%0,%1) set_pev(%0, pev_skin, (pev(%0, pev_skin) & 0x0FFF) | ((%1 & 0xF) << 12))
/* stock Beam_SetEndAttachment(const iBeamEntity, const iAttachment)
	return set_pev(iBeamEntity, pev_skin, (pev(iBeamEntity, pev_skin) & 0x0FFF) | ((iAttachment & 0xF) << 12)); */

#define Beam_SetTexture(%0,%1) set_pev(%0, pev_modelindex, %1)
/* stock Beam_SetTexture(const iBeamEntity, const iSpriteIndex)
	return set_pev(iBeamEntity, pev_modelindex, iSpriteIndex); */

#define Beam_SetWidth(%0,%1) set_pev(%0, pev_scale, %1)
/* stock Beam_SetWidth(const iBeamEntity, const Float: flWidth)
	return set_pev(iBeamEntity, pev_scale, flWidth); */

#define Beam_SetNoise(%0,%1) set_pev(%0, pev_body, %1)
/* stock Beam_SetNoise(const iBeamEntity, const iNoise)
	return set_pev(iBeamEntity, pev_body, iNoise); */	
	
#define Beam_SetColor(%0,%1) set_pev(%0, pev_rendercolor, %1)
/* stock Beam_SetColor(const iBeamEntity, const Float: flColor[3])
	return set_pev(iBeamEntity, pev_rendercolor, flColor); */	
		
#define Beam_SetBrightness(%0,%1) set_pev(%0, pev_renderamt, %1)
/* stock Beam_SetBrightness(const iBeamEntity, const Float: flBrightness)
	return set_pev(iBeamEntity, pev_renderamt, flBrightness); */

#define Beam_SetFrame(%0,%1) set_pev(%0, pev_frame, %1)
/* stock Beam_SetFrame(const iBeamEntity, const Float: flFrame)
	return set_pev(iBeamEntity, pev_frame, flFrame); */

#define Beam_SetScrollRate(%0,%1) set_pev(%0, pev_animtime, %1)
/* stock Beam_SetScrollRate(const iBeamEntity, const Float: flSpeed)
	return set_pev(iBeamEntity, pev_animtime, flSpeed); */

#define Beam_GetType(%0) (pev(%0, pev_rendermode) & 0x0F)
/* stock Beam_GetType(const iBeamEntity)
	return pev(iBeamEntity, pev_rendermode) & 0x0F; */
	
#define Beam_GetFlags(%0) (pev(%0, pev_rendermode) & 0xF0)
/* stock Beam_GetFlags(const iBeamEntity)
	return pev(iBeamEntity, pev_rendermode) & 0xF0; */

#define Beam_GetStartEntity(%0) (pev(%0, pev_sequence) & 0xFFF)
/* stock Beam_GetStartEntity(const iBeamEntity)
	return pev(iBeamEntity, pev_sequence) & 0xFFF; */

#define Beam_GetEndEntity(%0) (pev(%0, pev_skin) & 0xFFF)
/* stock Beam_GetEndEntity(const iBeamEntity)
	return pev(iBeamEntity, pev_skin) & 0xFFF; */

stock Beam_GetStartPos(const iBeamEntity, Float: flStartPos[3])
{
	if (Beam_GetType(iBeamEntity) == BEAM_ENTS)
	{
		new iEntity = Beam_GetStartEntity(iBeamEntity);
		
		if (pev_valid(iEntity))
		{
			pev(iEntity, pev_origin, flStartPos);
			return;
		}
	}
	
	pev(iBeamEntity, pev_origin, flStartPos);
}

stock Beam_GetEndPos(const iBeamEntity, Float: flEndPos[3])
{
	new iType = Beam_GetType(iBeamEntity);
	
	if (iType == BEAM_POINTS || iType == BEAM_HOSE)
	{
		pev(iBeamEntity, pev_angles, flEndPos);
		return;
	}
	
	new iEntity = Beam_GetEndEntity(iBeamEntity);
	
	if (pev_valid(iEntity))
	{
		pev(iEntity, pev_origin, flEndPos);
		return;
	}
	
	pev(iBeamEntity, pev_angles, flEndPos);
}

#define Beam_GetTexture(%0) pev(%0, pev_modelindex)
/* stock Beam_GetTexture(const iBeamEntity)
	return pev(iBeamEntity, pev_modelindex); */
	
stock Float: Beam_GetWidth(const iBeamEntity)
{
	new Float: flScale;
	pev(iBeamEntity, pev_scale, flScale);
	
	return flScale;
}

#define Beam_GetNoise(%0) pev(%0, pev_body)
/* stock Beam_GetNoise(const iBeamEntity)
	return pev(iBeamEntity, pev_body); */
	
#define Beam_GetColor(%0,%1) pev(%0, pev_rendercolor,%1)
/* stock Beam_GetColor(const iBeamEntity, Float: flRGB[3])
	return pev(iBeamEntity, pev_rendercolor, flRGB); */

stock Float: Beam_GetBrightness(const iBeamEntity)
{
	new Float: flBrightness;
	pev(iBeamEntity, pev_renderamt, flBrightness);
	
	return flBrightness;
}

stock Float: Beam_GetFrame(const iBeamEntity)
{
	new Float: flFrame;
	pev(iBeamEntity, pev_frame, flFrame);
	
	return flFrame;
}

stock Float: Beam_GetScrollRate(const iBeamEntity)
{
	new Float: flScrollRate;
	pev(iBeamEntity, pev_animtime, flScrollRate);
	
	return flScrollRate;
}

stock Beam_Create(const szSpriteName[], const Float: flWidth)
{
	new iBeamEntity;
	static iszAllocStringCached;
	
	if (iszAllocStringCached || (iszAllocStringCached = engfunc(EngFunc_AllocString, "beam")))
	{
		iBeamEntity = engfunc(EngFunc_CreateNamedEntity, iszAllocStringCached);
	}
	
	if (pev_valid(iBeamEntity))
	{
		set_pev(iBeamEntity, pev_classname, "beam");
		Beam_Init(iBeamEntity, szSpriteName, flWidth);
		
		return iBeamEntity;
	}
	
	return FM_NULLENT;
}

stock Beam_Init(const iBeamEntity, const szSpriteName[], const Float: flWidth)
{
	set_pev(iBeamEntity, pev_flags, pev(iBeamEntity, pev_flags) | FL_CUSTOMENTITY);
	
	Beam_SetColor(iBeamEntity, Float: {255.0, 255.0, 255.0});
	Beam_SetBrightness(iBeamEntity, 255.0);
	Beam_SetNoise(iBeamEntity, 0);
	Beam_SetFrame(iBeamEntity, 0.0);
	Beam_SetScrollRate(iBeamEntity, 0.0);
	
	set_pev(iBeamEntity, pev_model, szSpriteName);
	
	Beam_SetTexture(iBeamEntity, engfunc(EngFunc_ModelIndex, szSpriteName));
	Beam_SetWidth(iBeamEntity, flWidth);
	
	set_pev(iBeamEntity, pev_skin, 0);
	set_pev(iBeamEntity, pev_sequence, 0);
	set_pev(iBeamEntity, pev_rendermode, 0);
}

stock Beam_PointsInit(const iBeamEntity, const Float: flVecStart[3], const Float: flVecEnd[3])
{
	Beam_SetType(iBeamEntity, BEAM_POINTS);
	Beam_SetStartPos(iBeamEntity, flVecStart);
	Beam_SetEndPos(iBeamEntity, flVecEnd);
	Beam_SetStartAttachment(iBeamEntity, 0);
	Beam_SetEndAttachment(iBeamEntity, 0);
	Beam_RelinkBeam(iBeamEntity);
}

stock Beam_HoseInit(const iBeamEntity, const Float: flVecStart[3], const Float: flVecDirection[3])
{
	Beam_SetType(iBeamEntity, BEAM_HOSE);
	Beam_SetStartPos(iBeamEntity, flVecStart);
	Beam_SetEndPos(iBeamEntity, flVecDirection);
	Beam_SetStartAttachment(iBeamEntity, 0);
	Beam_SetEndAttachment(iBeamEntity, 0);
	Beam_RelinkBeam(iBeamEntity);
}

stock Beam_PointEntInit(const iBeamEntity, const Float: flVecStart[3], const iEndIndex)
{
	Beam_SetType(iBeamEntity, BEAM_ENTPOINT);
	Beam_SetStartPos(iBeamEntity, flVecStart);
	Beam_SetEndEntity(iBeamEntity, iEndIndex);
	Beam_SetStartAttachment(iBeamEntity, 0);
	Beam_SetEndAttachment(iBeamEntity, 0);
	Beam_RelinkBeam(iBeamEntity);
}

stock Beam_EntsInit(const iBeamEntity, const iStartIndex, const iEndIndex)
{
	Beam_SetType(iBeamEntity, BEAM_ENTS);
	Beam_SetStartEntity(iBeamEntity, iStartIndex);
	Beam_SetEndEntity(iBeamEntity, iEndIndex);
	Beam_SetStartAttachment(iBeamEntity, 0);
	Beam_SetEndAttachment(iBeamEntity, 0);
	Beam_RelinkBeam(iBeamEntity);
}

stock Beam_RelinkBeam(const iBeamEntity)
{
	new Float: flOrigin[3];
	new Float: flStartPos[3];
	new Float: flEndPos[3];
	new Float: flMins[3];
	new Float: flMaxs[3];
	
	pev(iBeamEntity, pev_origin, flOrigin);
	
	Beam_GetStartPos(iBeamEntity, flStartPos);
	Beam_GetEndPos(iBeamEntity, flEndPos);
	
	flMins[0] = floatmin(flStartPos[0], flEndPos[0]);
	flMins[1] = floatmin(flStartPos[1], flEndPos[1]);
	flMins[2] = floatmin(flStartPos[2], flEndPos[2]);
	
	flMaxs[0] = floatmax(flStartPos[0], flEndPos[0]);
	flMaxs[1] = floatmax(flStartPos[1], flEndPos[1]);
	flMaxs[2] = floatmax(flStartPos[2], flEndPos[2]);
	
	xs_vec_sub(flMins, flOrigin, flMins);
	xs_vec_sub(flMaxs, flOrigin, flMaxs);
	
	set_pev(iBeamEntity, pev_mins, flMins);
	set_pev(iBeamEntity, pev_maxs, flMaxs);
	
	engfunc(EngFunc_SetSize, iBeamEntity, flMins, flMaxs);
	engfunc(EngFunc_SetOrigin, iBeamEntity, flOrigin);
}

#include <xs>

#define PLUGIN "Ethereal"
#define VERSION "1.0"
#define AUTHOR "KORD_12.7"

// Weapon settings
#define WEAPON_NAME 			"weapon_ethereal"
#define WEAPON_SLOT			2
#define WEAPON_POSITION			5
#define WEAPON_PRIMARY_AMMO		"uranium"
#define WEAPON_PRIMARY_AMMO_MAX		100
#define WEAPON_SECONDARY_AMMO		"" // NULL
#define WEAPON_SECONDARY_AMMO_MAX	-1
#define WEAPON_MAX_CLIP			30
#define WEAPON_DEFAULT_AMMO		30
#define WEAPON_FLAGS			0
#define WEAPON_WEIGHT			15
#define WEAPON_DAMAGE			40.0

// Hud
#define WEAPON_HUD_TXT			"sprites/weapon_ethereal.txt"
#define WEAPON_HUD_SPR			"sprites/weapon_ethereal.spr"

// Models
#define MODEL_WORLD			"models/w_ethereal.mdl"
#define MODEL_VIEW			"models/v_ethereal_hev.mdl"
#define MODEL_PLAYER			"models/p_ethereal.mdl"

// Sounds
#define SOUND_FIRE			"weapons/ethereal-1.wav"
#define SOUND_DRAW			"weapons/ethereal_draw.wav"
#define SOUND_IDLE			"weapons/ethereal_idle1.wav"
#define SOUND_IMPACT			"weapons/shock_impact.wav"
#define SOUND_RELOAD			"weapons/ethereal_reload.wav"

// Sprites
#define SPRITE_LIGHTNING		"sprites/lgtning.spr"

// Beam
#define BEAM_LIFE			0.09
#define BEAM_COLOR			{100.0, 50.0, 253.0}
#define BEAM_BRIGHTNESS			255.0
#define BEAM_SCROLLRATE			10.0

// Animation
#define ANIM_EXTENSION			"gauss"

// Animation Sequence
enum _:Animation
{
	ANIM_IDLE = 0,
	ANIM_RELOAD,
	ANIM_DRAW,
	ANIM_FIRE_1,
	ANIM_FIRE_2,
	ANIM_FIRE_3
};

#define Beam_SetLife(%0,%1) \
	wpnmod_set_think(%0, "Beam_Remove"); \
	set_pev(%0, pev_nextthink, get_gametime() + %1)
	
//**********************************************
//* Precache resources                         *
//**********************************************

public plugin_precache()
{
	PRECACHE_MODEL(MODEL_VIEW);
	PRECACHE_MODEL(MODEL_WORLD);
	PRECACHE_MODEL(MODEL_PLAYER);
	PRECACHE_MODEL(SPRITE_LIGHTNING);
	
	PRECACHE_SOUND(SOUND_FIRE);
	PRECACHE_SOUND(SOUND_DRAW);
	PRECACHE_SOUND(SOUND_IDLE);
	PRECACHE_SOUND(SOUND_IMPACT);
	PRECACHE_SOUND(SOUND_RELOAD);
	
	PRECACHE_GENERIC(WEAPON_HUD_TXT);
	PRECACHE_GENERIC(WEAPON_HUD_SPR);
}

//**********************************************
//* Register weapon.                           *
//**********************************************

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR);
	
	new iEthereal = wpnmod_register_weapon
	
	(
		WEAPON_NAME,
		WEAPON_SLOT,
		WEAPON_POSITION,
		WEAPON_PRIMARY_AMMO,
		WEAPON_PRIMARY_AMMO_MAX,
		WEAPON_SECONDARY_AMMO,
		WEAPON_SECONDARY_AMMO_MAX,
		WEAPON_MAX_CLIP,
		WEAPON_FLAGS,
		WEAPON_WEIGHT
	);
	
	wpnmod_register_weapon_forward(iEthereal, Fwd_Wpn_Spawn, "Ethereal_Spawn");
	wpnmod_register_weapon_forward(iEthereal, Fwd_Wpn_Deploy, "Ethereal_Deploy");
	wpnmod_register_weapon_forward(iEthereal, Fwd_Wpn_Idle, "Ethereal_Idle");
	wpnmod_register_weapon_forward(iEthereal, Fwd_Wpn_Reload, "Ethereal_Reload");
	wpnmod_register_weapon_forward(iEthereal, Fwd_Wpn_Holster, "Ethereal_Holster");
	wpnmod_register_weapon_forward(iEthereal, Fwd_Wpn_PrimaryAttack, "Ethereal_PrimaryAttack");
}

//**********************************************
//* Weapon spawn.                              *
//**********************************************

public Ethereal_Spawn(const iItem)
{
	// Setting world model
	SET_MODEL(iItem, MODEL_WORLD);
	
	// Give a default ammo to weapon
	wpnmod_set_offset_int(iItem, Offset_iDefaultAmmo, WEAPON_DEFAULT_AMMO);
}

//**********************************************
//* Deploys the weapon.                        *
//**********************************************

public Ethereal_Deploy(const iItem, const iPlayer)
{
	// Start idle sound
	engfunc(EngFunc_EmitSound, iPlayer, CHAN_AUTO, SOUND_IDLE, 0.4, ATTN_NORM, 0, PITCH_NORM);
	
	return wpnmod_default_deploy(iItem, MODEL_VIEW, MODEL_PLAYER, ANIM_DRAW, ANIM_EXTENSION);
}

//**********************************************
//* Called when the weapon is holster.         *
//**********************************************

public Ethereal_Holster(const iItem, const iPlayer)
{
	// Cancel any reload in progress.
	wpnmod_set_offset_int(iItem, Offset_iInReload, 0);
	
	// Stop idle sound
	engfunc(EngFunc_EmitSound, iPlayer, CHAN_AUTO, SOUND_IDLE, 0.0, 0.0, SND_STOP, PITCH_NORM);
}

//**********************************************
//* Displays the idle animation for the weapon.*
//**********************************************

public Ethereal_Idle(const iItem, const iPlayer)
{
	wpnmod_reset_empty_sound(iItem);

if (wpnmod_get_offset_float(iItem, Offset_flTimeWeaponIdle) > 0.0)
	{
		return;
	}
	
	wpnmod_send_weapon_anim(iItem, ANIM_IDLE);
	wpnmod_set_offset_float(iItem, Offset_flTimeWeaponIdle, 10.03);
}

//**********************************************
//* The main attack of a weapon is triggered.  *
//**********************************************

public Ethereal_PrimaryAttack(const iItem, const iPlayer, const iClip)
{
	if (pev(iPlayer, pev_waterlevel) == 3 || iClip <= 0)
	{
		wpnmod_play_empty_sound(iItem);
		wpnmod_set_offset_float(iItem, Offset_flNextPrimaryAttack, 0.15);
		return;
	}
	
	new Float: vecSrc[3], Float: vecEnd[3], iBeam, iTrace = create_tr2();
	
	wpnmod_get_gun_position(iPlayer, vecSrc);
	global_get(glb_v_forward, vecEnd);
	
	xs_vec_mul_scalar(vecEnd, 8192.0, vecEnd);
	xs_vec_add(vecSrc, vecEnd, vecEnd);
	
	engfunc(EngFunc_TraceLine, vecSrc, vecEnd, DONT_IGNORE_MONSTERS, iPlayer, iTrace);
	get_tr2(iTrace, TR_vecEndPos, vecEnd);
	
	if (pev_valid((iBeam = Beam_Create(SPRITE_LIGHTNING, 25.0))))
	{
		Beam_PointEntInit(iBeam, vecEnd, iPlayer);
		Beam_SetEndAttachment(iBeam, 1);
		Beam_SetBrightness(iBeam, BEAM_BRIGHTNESS);
		Beam_SetScrollRate(iBeam, BEAM_SCROLLRATE);
		Beam_SetColor(iBeam, BEAM_COLOR);
		Beam_SetLife(iBeam, BEAM_LIFE);
	}
	
	wpnmod_radius_damage2(vecEnd, iPlayer, iPlayer, WEAPON_DAMAGE, WEAPON_DAMAGE * 2.0, CLASS_NONE, DMG_ENERGYBEAM | DMG_ALWAYSGIB);
	
	engfunc(EngFunc_EmitSound, iPlayer, CHAN_AUTO, SOUND_FIRE, 0.9, ATTN_NORM, 0, PITCH_NORM);
	engfunc(EngFunc_EmitAmbientSound, 0, vecEnd, SOUND_IMPACT, 0.9, ATTN_NORM, 0, PITCH_NORM);
	
	engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, vecEnd, 0);
	write_byte(TE_DLIGHT);
	engfunc(EngFunc_WriteCoord, vecEnd[0]);
	engfunc(EngFunc_WriteCoord, vecEnd[1]);
	engfunc(EngFunc_WriteCoord, vecEnd[2]);
	write_byte(10);
	write_byte(100);
	write_byte(50);
	write_byte(253);
	write_byte(255);
	write_byte(25);
	write_byte(1);
	message_end();
	
	engfunc(EngFunc_MessageBegin, MSG_PVS, SVC_TEMPENTITY, vecEnd, 0);
	write_byte(TE_SPARKS);
	engfunc(EngFunc_WriteCoord, vecEnd[0]);
	engfunc(EngFunc_WriteCoord, vecEnd[1]);
	engfunc(EngFunc_WriteCoord, vecEnd[2]);
	message_end();
	
	wpnmod_decal_trace(iTrace, engfunc(EngFunc_DecalIndex, "{smscorch1") + random_num(0, 2));
	
	wpnmod_set_offset_int(iItem, Offset_iClip, iClip - 1);
	wpnmod_set_offset_int(iPlayer, Offset_iWeaponVolume, LOUD_GUN_VOLUME);
	wpnmod_set_offset_int(iPlayer, Offset_iWeaponFlash, BRIGHT_GUN_FLASH);
	
	wpnmod_set_offset_float(iItem, Offset_flNextPrimaryAttack, 0.1);
	wpnmod_set_offset_float(iItem, Offset_flTimeWeaponIdle, 1.03);
	
	wpnmod_set_player_anim(iPlayer, PLAYER_ATTACK1);
	wpnmod_send_weapon_anim(iItem, random_num(ANIM_FIRE_1, ANIM_FIRE_3));
	
	free_tr2(iTrace);
}

//**********************************************
//* Called when the weapon is reloaded.        *
//**********************************************

public Ethereal_Reload(const iItem, const iPlayer, const iClip, const iAmmo)
{
	if (iAmmo <= 0 || iClip >= WEAPON_MAX_CLIP)
	{
		return;
	}
	
	wpnmod_default_reload(iItem, WEAPON_MAX_CLIP, ANIM_RELOAD, 3.03);
}

//**********************************************
//* Beam remove think.                         *
//**********************************************

public Beam_Remove(const iBeam)
{
	set_pev(iBeam, pev_flags, FL_KILLME);
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1038\\ f0\\ fs16 \n\\ par }
*/

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

Szerző:	kiki [2016.02.03. 19:12 ]
Hozzászólás témája:	Re: [CSO] Ethereal
Biztos jó a játék? hl_wpnmod-ot kér, aminek az oldalán ezt írja: Supporeted mods: Half-Life (its recommended to use Bugfixed and improved HL release) Opposing Force Adrenaline Gamer Adrenaline Gamer Mini

Szerző:	\|E\|xTazYyyy^.~ [2016.02.03. 19:23 ]
Hozzászólás témája:	Re: [CSO] Ethereal
Hát ezt benéztem. :S Akkor bocsánat. :S

Szerző:	kiki [2016.02.03. 19:30 ]
Hozzászólás témája:	Re: [CSO] Ethereal
Igazából nem gond, maradhat fent. Majd átállítom a játékot a megfelelőre ha utána néztem. Nem igérem hogy ma, de talán.

Szerző:	\|E\|xTazYyyy^.~ [2016.02.03. 21:48 ]
Hozzászólás témája:	Re: [CSO] Ethereal
Oké, köszi. Alliedmodders-en volt fenn. Nézd ott meg. Et onnan szedtem.

Szerző:	SZILARD [2016.02.04. 07:05 ]
Hozzászólás témája:	Re: [CSO] Ethereal
Akkor miért nem adtad hozzá az Eredeti Linket?

Szerző:	SmaCk [2016.02.04. 07:46 ]
Hozzászólás témája:	Re: [CSO] Ethereal
SZILARD írta: Akkor miért nem adtad hozzá az Eredeti Linket? https://forums.alliedmods.net/showthread.php?t=203050

Szerző:	\|E\|xTazYyyy^.~ [2016.02.04. 15:17 ]
Hozzászólás témája:	Re: [CSO] Ethereal
SZILARD írta: Akkor miért nem adtad hozzá az Eredeti Linket? Hogy megint beletudjál kötni valamibe. Nemhiszem, hogy annyira zavar téged, hogy nem adtam hozzá. Magaddal foglalkozz. Ha töltöttél fel plugin, akkor van egy ilyen szép kis leírás ,,A *-al megjelölt helyeket kötelező kitölteni'' Szóval ink csitt. u.i : Szerintem, nem lényeg, hogy hozzáadta-e vagy sem. Ugyanaz van ide feltéve ami oda, egy kezdőbb fórumozó több mint valúszínű, hogy nem az alliedmodders-en keresi ha már itt fennvan. De köszönöm Smacknek- hogy linkelte Szilárdkának.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/