hlmod.hu :: Weapon Skin System [WSS]

hlmod.hu https://hlmod.hu/

Weapon Skin System [WSS] https://hlmod.hu/viewtopic.php?f=101&t=23966	Oldal: 1 / 8

Szerző: 6almasok [ 2016.02.11. 17:22 ]

Hozzászólás témája: Weapon Skin System [WSS]

Plugin Neve:	Weapon Skin System [WSS]	Plugint készitette:	6almasok
Játék:	Counter-Strike	Kategória:	Játékmenet
Eredeti link:	Nincs megadva	Jóváhagyó:	kiki

● Üdvözlök minden kedves fórumozót! Még párhéttel ezelőtt az egyik hozzászólásomba (6almasok @ Fegyver Skin Csomagok v2.1) megígértem hogy ebből a pluginból várható egy nagy update és hogy lesz egy teljes bug fix illetve pár új dolog is belefog kerülni ebbe az új verzióba. Ez így röviden és tömören az előzménye volt az egésznek és most a pluginról "párszót".

Kép

● Lényegében annyi a dolgod hogy ölnöd kell! Az ölésekért kapsz "Ölés"-t (Ezt átírhatod akár milyen mennyiségre, nekem most így van megadva) vagy a játékos holttestéből egy kis csomagot amiben találhatsz kreditet (ez egy fajta speciális mennyiség amivel tudjuk unlockolni a "Speed Knife"-ot). Maga az ötlet, alap és az elképzelés maradt a régi, például az ölésekből még mindig fegyver csomagokat tudunk megszerezni (persze ezek skinezve vannak) és a játékosok öléseit + kreditjeit megtudjuk tekinteni egy menüből. De lett pár új dolog amit lentebb megtudsz majd tekinteni.

Kép

● Ez a része most egy kicsit sokkal összébb lett foglalva mivel minden bekerült egy egész menüpontba

● say /menu ► Megnyitja a főmenüt

Az admin parancsok kiszedésre kerültek mivel az egész rendszer kapott egy fvaultos mentést és a data vault ba azokat mi egyszerűen tudjuk módosítani

Kép

① "wss_hudenable" "1" → Engedélyezi a hud kijelzőt a játékosok számára [0:Ki/1:Be]
② "wss_advertmp" "40.0" → Hány másodpercenként hírdessen a plugin [Alap: 40.0]
③ "kill_recived" "1" → Mennyi ölést kapjon a játékos egy sima ölésért [Alap: 1]
④ "hs_recived" "2" → Mennyi ölést kapjon a játékos fejlövésért [Alap: 2]
⑤ "found_kredit" "1" → Ha a játékos talál egy csomagot abból mennyi kreditet szerezzen [Alap: 1]

Kép

● Modelt hozzáadni a wss_models be tudjuk. Amit kell csinálni az az hogy lemegyünk az ini legaljára nyomunk egy tabot és beírjuk az elérési utat.
Példa: "models/uj_model/uj_pack/v_ak47.mdl"

Ha itt megvan vissza bemegyünk az SMA-ba és a curweapon eventnél beállítsuk melyik fegyvernél váltson át a megadott modelre

Egy nagyon kényes dolog van mégpedig az hogy a curweaponba a model lekérés soronként zajlik. Vagyis ha megadjuk ezt például ezt ModelData[1] ez azt jelenti hogy az ini-ben az első sorból kéri le a modelt ha mondjuk ModelData[2] akkor meg a második sorból kéri le! Ezért van szépen függőlegesen levezetve egymás alá a modellek elérési útja szóval ha pl nyomunk egy entert a két model közé az ini-ben az gyakorlatilag a semmi lesz a kezünkbe amikor átváltunk a fegyverre

Így kell legyen a levezetés:
Kép

● Ezt egyszerűen megtehetjük mivel szinte az egész szöveges rész const-okba van rendszerezve

Kód: [Egész kijelölése] [Mutatás/Eltüntetés]

new const prefix[] = "WSS"
 
/*Rust Kills | Silver Kills | Gold Kills | Veteran Kills | Knife Kredit*/
new const need_kills[] = { 500, 1000, 2000, 4000, 500 }
 
/*Pack Names*/
new const csomagmsg[6][] = { "Nincs","Rozsdás Csomag","Ezüst Csomag","Arany Csomag","Veterán Csomag","Speed Knife" }
 
new const knifedisenable[2][] = { "Kikapcsolva", "Bekapcsolva" }
 
new const menuszoveg[][][] = {
    {"Rozsdás Csomag \r[MEGSZEREZVE]", "\dRozsdás Csomag \r[%i/%i Ölés]"}, //0
    {"Ezüst Csomag \r[MEGSZEREZVE]", "\dEzüst Csomag \r[%i/%i Ölés]"}, //1
    {"Arany Csomag \r[MEGSZEREZVE]", "\dArany Csomag \r[%i/%i Ölés]"}, //2
    {"Veterán Csomag \r[MEGSZEREZVE]", "\dVeterán Csomag \r[%i/%i Ölés]"}, //3
    {"Speed Knife \r[MEGSZEREZVE]^n", "\dSpeed Knife \r[%i/%i Ölés]^n"}, //4
    {"\ySkin Csomagok \r[KIKAPCSOLVA]", "\ySkin Csomagok \r[BEKAPCSOLVA]"} //5
}
new const chatszoveg[10][] = 
{
    "^4[%s]^1 FEJLÖVÉS!^3 %s ^1megöléséért kaptál ^3+%i^1 ölést!",
    "^4[%s]^3 %s ^1megöléséért kaptál ^3+%i^1 ölést!",
    "^4[%s]^3 %s ^1kapott ^3+1 ^1ölést ember lesebzésért!",
    "^4[%s]^1 Találtál^3 +%i^1 kreditet a csomagbol!",
    "^4[%s]^1 Kiválasztottad a(z)^3 %s^1-ot!",
    "^4[%s]^1 Sajnos nincs elég ölésed!",
    "^4[%s]^1 Kikapcsoltad a Skin Csomagokat!",
    "^4[%s]^1 Bekapcsoltad a Skin Csomagokat!",
    "^4[%s]^1 A Szerveren Jelenleg a(z) ^3Weapon Skin System^1 fut. Megnyitáshoz írd be ^3/menu^1.",
    "^4[%s]^1 Sajnos nincs elég kredited!"
}

GeSHi © Codebox Plus

Játékos HUD
Kép

Főmenü

Skin Csomagok
Kép

Játékos Információk
Kép

MODT

Hírdetett Szöveg
Kép

Kiválasztott Csomag
Kép

▪ v1.0.0 Szerkezet elkészítése [Csak skin menü+Mentés]
▪ v1.1.0 Ölés rendszer hozzá adása [Cvarokkal]
▪ v1.3.0 Skinek és képességek hozzáadása [PUBLIKÁLT]
▪ v1.4.0 Teljes bug fix
▪ v1.5.0 Kredit rendszer megírása [Időre kapta a játékos a kreditet]
▪ v1.6.5 Kredit rendszer tovább fejlesztése [Játékos dropból kapta a kreditet]
▪ v1.8.0 Információs MODT Hozzáadása [Pluginban készülős fajta]
▪ v1.9.0 Ölés elosztó Hozzáadása
▪ v2.1.0 Játékos Infók és Beváltó menü elkészítése....
╔═══════════════════════╣Final Update╠═══════════════════════╗
╚════════════════════════╣ v1.0.0 ╠══════════════════════════╝
▪ Egész Plugin újragondolva
▪ Könnyebb model elérés és letöltés hozzáadása [Beolvasással]
▪ Ki/Be-kapcsolható HUD hozzáadása [Jobb átláthatóságért]
▪ Szövegek és A szükséges ölést jelző const-ok rendszerezve az SMA-ban
▪ set_task-os hírdető cvarhoz kötve
▪ Drop, Menü, Ölés elosztó teljesen FIXÁLVA
▪ Plugin átrakva FVAULT-os mentésre Csak 4 Mentés miatt SQL-re nem akartam rárakni + local-on írogattam a plugint

Kép

● AMXX fájl-t a(z) → cstrike/addons/amxmodx/plugins/ Mappába majd a nevét írjuk bele a plugins.ini-be
● SMA fájl-t a(z) → cstrike/addons/amxmodx/scripting/ Mappába (Hanyagolható)
● ZIP fájl-t pedig a mappák szerint!

Rengetegszer tesztelve volt a plugin ha valami hibát véltek még felfedezni ami figyelmen kívül hagyott jelezzétek!

Welcome to the AMX Mod X 1.8.1-300 Compiler.
Copyright (c) 1997-2013 ITB CompuPhase, AMX Mod X Team

Header size: 2292 bytes
Code size: 26644 bytes
Data size: 21544 bytes
Stack/heap size: 16384 bytes; estimated max. usage=2874 cells (11496 bytes)
Total requirements: 66864 bytes

Done.

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <fun>
#include <engine>
#include <fakemeta>
#include <hamsandwich>
#include <fakemeta_util>
enum Color
{
	NORMAL = 1, // clients scr_concolor cvar color
	GREEN, // Green Color
	TEAM_COLOR, // Red, grey, blue
	GREY, // grey
	RED, // Red
	BLUE, // Blue
}

new TeamName[][] = 
{
	"",
	"TERRORIST",
	"CT",
	"SPECTATOR"
}

ColorChat(id, Color:type, const msg[], {Float,Sql,Result,_}:...)
{
	static message[256];

switch(type)
	{
		case NORMAL: // clients scr_concolor cvar color
		{
			message[0] = 0x01;
		}
		case GREEN: // Green
		{
			message[0] = 0x04;
		}
		default: // White, Red, Blue
		{
			message[0] = 0x03;
		}
	}

vformat(message[1], 251, msg, 4);
	message[192] = '^0';

static team, ColorChange, index, MSG_Type;
	
	if(id)
	{
		MSG_Type = MSG_ONE;
		index = id;
	} else {
		index = FindPlayer();
		MSG_Type = MSG_ALL;
	}
	
	team = get_user_team(index);
	ColorChange = ColorSelection(index, MSG_Type, type);

ShowColorMessage(index, MSG_Type, message);
		
	if(ColorChange)
	{
		Team_Info(index, MSG_Type, TeamName[team]);
	}
}

ShowColorMessage(id, type, message[])
{
	message_begin(type, get_user_msgid("SayText"), _, id);
	write_byte(id)		
	write_string(message);
	message_end();	
}

Team_Info(id, type, team[])
{
	message_begin(type, get_user_msgid("TeamInfo"), _, id);
	write_byte(id);
	write_string(team);
	message_end();

return 1;
}

ColorSelection(index, type, Color:Type)
{
	switch(Type)
	{
		case RED:
		{
			return Team_Info(index, type, TeamName[1]);
		}
		case BLUE:
		{
			return Team_Info(index, type, TeamName[2]);
		}
		case GREY:
		{
			return Team_Info(index, type, TeamName[0]);
		}
	}

return 0;
}

FindPlayer()
{
	static i;
	i = -1;

while(i <= get_maxplayers())
	{
		if(is_user_connected(++i))
		{
			return i;
		}
	}

return -1;
}

#if defined _file_vault_included
	#endinput
#endif

#define _file_vault_included

/**
 * FVault was created by Exolent on 8/24/08
 * This vault system uses actual files and no modules
 * It is very flexible and has many features
 * Visit this page for more information: http://forums.alliedmods.net/showthread.php?t=76453
 */

#include <amxmodx>

stock const _vault_dir[] = "addons/amxmodx/data/file_vault";
stock const _temp_vault[] = "fvault_temp.txt";

/** 
 * Retrieves a key name specified by its number
 * 
 * @param vaultname	Vault name to look in
 * @param keynum	Key number within the vault to find key name
 * @param key		String which key name will be copied to
 * @param len		Length of key name
 * @return		Returns 1 on success, 0 on failue.
 */
stock fvault_get_keyname(const vaultname[], const keynum, key[], len)
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	if( !file_exists(filename) )
	{
		return 0;
	}
	
	new vault = fopen(filename, "rt");
	
	new _data[64], _other[3];
	
	new line = -1;
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		
		if( ++line == keynum )
		{
			parse(_data, key, len, _other, sizeof(_other) - 1);
			
			fclose(vault);
			
			return 1;
		}
	}
	
	fclose(vault);
	
	return 0;
}

/** 
 * Retrieves a key number specified by its name
 * 
 * @param vaultname	Vault name to look in
 * @param key		Key name to search for
 * @return		Returns key number on success, -1 on failure
 */
stock fvault_get_keynum(const vaultname[], const key[])
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	if( !file_exists(filename) )
	{
		return -1;
	}
	
	new vault = fopen(filename, "rt");
	
	new _data[70], _key[64], _other[3];
	
	new line = -1;
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		parse(_data, _key, sizeof(_key) - 1, _other, sizeof(_other) - 1);
		
		line++;
		
		if( equal(_key, key) )
		{
			fclose(vault);
			
			return line;
		}
	}
	
	fclose(vault);
	
	return -1;
}

/** 
 * Retrieves data specified by a key
 * 
 * @param vaultname	Vault name to look in
 * @param key		Key name to look for the data
 * @param data		String which data will be copied to
 * @param len		Length of data
 * @param timestamp	The unix time of when the data was last set ( -1 if permanent data, 0 if old fvault version ) ( optional param )
 * @return		Returns 1 on success, 0 on failue.
 */
stock fvault_get_data(const vaultname[], const key[], data[], len, ×tamp=0)
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	if( !file_exists(filename) )
	{
		return 0;
	}
	
	new vault = fopen(filename, "rt");
	
	new _data[512], _key[64], _time[32];
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		parse(_data, _key, sizeof(_key) - 1);
		
		if( equal(_key, key) )
		{
			new _len = strlen(_key) + 4; // + 2 = quotes on key, + 1 = space, + 1 = first quote
			for( new i = copy(data, len, _data[_len]) - 1; i > 0; i-- )
			{
				if( data[i] == '"' ) break;
				
				if( data[i] == ' '
				&& data[i - 1] == '"' )
				{
					data[i - 1] = '^0';
					
					copy(_time, sizeof(_time) - 1, data[i + 1]);
					timestamp = str_to_num(_time);
					break;
				}
			}
			
			fclose(vault);
			
			return 1;
		}
	}
	
	fclose(vault);
	
	copy(data, len, "");
	
	return 0;
}

/** 
 * Sets data of a key with current timestamp
 * 
 * @param vaultname	Vault name to look in
 * @param key		Key name to which data will be set
 * @param data		Data to set to key
 * @return		Does not return a value.
 */
stock fvault_set_data(const vaultname[], const key[], const data[])
{
	_fvault_set_data(vaultname, key, data, get_systime());
}

/** 
 * Sets data of a key permanently (can't be removed with fvault_prune)
 * 
 * @param vaultname	Vault name to look in
 * @param key		Key name to which data will be set
 * @param data		Data to set to key
 * @return		Does not return a value.
 */
stock fvault_pset_data(const vaultname[], const key[], const data[])
{
	_fvault_set_data(vaultname, key, data, -1);
}

_fvault_set_data(const vaultname[], const key[], const data[], const timestamp)
{
	new file = fopen(_temp_vault, "wt");
	
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	new vault = fopen(filename, "rt");
	
	new _data[512], _key[64], _other[3];
	
	new bool:replaced = false;
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		parse(_data, _key, sizeof(_key) - 1, _other, sizeof(_other) - 1);
		
		if( equal(_key, key) && !replaced )
		{
			fprintf(file, "^"%s^" ^"%s^" %i^n", key, data, timestamp);
			
			replaced = true;
		}
		else
		{
			fputs(file, _data);
		}
	}
	
	fclose(file);
	fclose(vault);
	
	if( !replaced )
	{
		file = fopen(filename, "a+");
		fprintf(file, "^"%s^" ^"%s^" %i^n", key, data, timestamp);
		fclose(file);
		
		delete_file(_temp_vault);
	}
	else
	{
		delete_file(filename);
		
		while( !rename_file(_temp_vault, filename, 1) ) { }
	}
}

/** 
 * Removes a key from a vault
 * 
 * @param vaultname	Vault name to look in
 * @param key		Key to remove
 * @return		No return
 */
stock fvault_remove_key(const vaultname[], const key[])
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	if( !file_exists(filename) )
	{
		return;
	}
	
	new file = fopen(_temp_vault, "wt");
	
	new vault = fopen(filename, "rt");
	
	new _data[512], _key[64], _other[3];
	new bool:found_key;
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		parse(_data, _key, sizeof(_key) - 1, _other, sizeof(_other) - 1);
		
		if( equal(_key, key) )
		{
			found_key = true;
			continue;
		}
		
		fputs(file, _data);
	}
	
	fclose(file);
	fclose(vault);
	
	if( found_key )
	{
		delete_file(filename);
		
		while( !rename_file(_temp_vault, filename, 1) ) { }
	}
	else
	{
		delete_file(_temp_vault);
	}
}

/**
 * Prunes the vault for keys that are within the given timestamps
 * 
 * @param vaultname	Vault name to look in
 * @param start		If timestamp is after this Unix Time (set -1 to prune from very start)
 * @param end		If timestamp is before this Unix Time (set -1 to prune to most time)
 * @return		Returns number of keys pruned
 */
stock fvault_prune(const vaultname[], const start=-1, const end=-1)
{
	if( start == -1 && end == -1 )
	{
		new keys = fvault_size(vaultname);
		if( keys )
		{
			fvault_clear(vaultname);
		}
		
		return keys;
	}
	
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	if( !file_exists(filename) )
	{
		return 0;
	}
	
	new file = fopen(_temp_vault, "wt");
	new vault = fopen(filename, "rt");
	
	new keys;
	
	new data[512], i, _time[32], timestamp;
	while( !feof(vault) )
	{
		fgets(vault, data, sizeof(data) - 1);
		
		if( data[0] )
		{
			_time[0] = 0;
			
			for( i = strlen(data) - 1; i >= 0; i-- )
			{
				if( data[i] == '"' ) break;
				
				if( data[i] == ' ' )
				{
					copy(_time, sizeof(_time) - 1, data[i + 1]);
					break;
				}
			}
			
			timestamp = str_to_num(_time);
			if( timestamp != -1 )
			{
				if( start == -1 && timestamp <= end
				|| end == -1 && timestamp >= start
				|| start <= timestamp <= end )
				{
					keys++;
					continue;
				}
			}
		}
		
		fputs(file, data);
	}
	
	fclose(file);
	fclose(vault);
	
	if( keys )
	{
		delete_file(filename);
		
		while( !rename_file(_temp_vault, filename, 1) ) { }
	}
	else
	{
		delete_file(_temp_vault);
	}
	
	return keys;
}

/**
 * Updates the timestamp on a key located within the vault
 * 
 * @param vaultname	Vault name to look in
 * @param key		Key to update timestamp (if it doesn't exist, a blank value will be set)
 * @param timestamp	Unix Time to set for the key (-1 for current time)
 * @return		Returns 2 on new entry, 1 on success, 0 on failure for the key having a permanent timestamp
 */
stock fvault_touch(const vaultname[], const key[], const timestamp=-1)
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	static new_time;
	if( (new_time = timestamp) == -1 )
	{
		new_time = get_systime();
	}
	
	if( !file_exists(filename) )
	{
		new vault = fopen(filename, "wt");
		fprintf(vault, "^"%s^" ^"^" %i^n", key, new_time);
		fclose(vault);
		return 2;
	}
	
	new file = fopen(_temp_vault, "wt");
	new vault = fopen(filename, "rt");
	
	new bool:updated;
	
	new data[512], _key[64], len, i, _time[32];
	while( !feof(vault) )
	{
		fgets(vault, data, sizeof(data) - 1);
		parse(data, _key, sizeof(_key) - 1);
		
		if( equal(_key, key) )
		{
			_time[0] = 0;
			
			for( i = strlen(data) - 1; i >= 0; i-- )
			{
				if( data[i] == '"' ) break;
				
				if( data[i] == ' ' )
				{
					data[i] = '^0';
					copy(_time, sizeof(_time) - 1, data[i + 1]);
					break;
				}
			}
			
			if( str_to_num(_time) == -1 )
			{
				fclose(file);
				fclose(vault);
				
				delete_file(_temp_vault);
				
				return 0;
			}
			
			fprintf(file, "%s %i^n", data, new_time);
			
			updated = true;
		}
		else
		{
			fputs(file, data);
		}
	}
	
	if( !updated )
	{
		fprintf(file, "^"%s^" ^"^" %i^n", key, new_time);
	}
	
	fclose(file);
	fclose(vault);
	
	delete_file(filename);
	
	while( !rename_file(_temp_vault, filename, 1) ) { }
	
	return (_:(!updated) + 1);
}

/** 
 * Retrieves total keys located within the vault
 * 
 * @param vaultname	Vault name to look in
 * @return		Returns amount of keys in vault
 */
stock fvault_size(const vaultname[])
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	return file_exists(filename) ? file_size(filename, 1) - 1 : 0;
}

/** 
 * Clears all key entries for a vault
 * 
 * @param vaultname	Vault name to erase
 * @return		No return
 */
stock fvault_clear(const vaultname[])
{
 	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	fclose(fopen(filename, "wt"));
}

/** 
 * Retrieves a vault name specified by its number
 * 
 * @param vaultnum	Vault number to find the vault name
 * @param vaultname	String which vault name will be copied to
 * @param len		Length of vault name
 * @return		Returns 1 on success, 0 on failue.
 */
stock fvault_get_vaultname(const vaultnum, vaultname[], len)
{
	if( !dir_exists(_vault_dir) )
	{
		mkdir(_vault_dir);
		return 0;
	}
	
	new filenum;
	
	new dir = open_dir(_vault_dir, vaultname, len);
	
	do
	{
		if( equal(vaultname, ".") || equal(vaultname, "..") )
		{
			continue;
		}
		
		if( filenum == vaultnum )
		{
			close_dir(dir);
			
			replace(vaultname, len, ".txt", "");
			
			return 1;
		}
		
		++filenum;
	}
	while( next_file(dir, vaultname, len) );
	
	close_dir(dir);
	
	copy(vaultname, len, "");
	
	return 0;
}

/** 
 * Retrieves a vault number specified by its name
 * 
 * @param vaultname	Vault name to find the number
 * @return		Returns vault number on success, -1 on failure
 */
stock fvault_get_vaultnum(const vaultname[])
{
	if( !dir_exists(_vault_dir) )
	{
		mkdir(_vault_dir);
		return -1;
	}
	
	new filename[128], filenum;
	
	new dir = open_dir(_vault_dir, filename, sizeof(filename) - 1);
	
	do
	{
		if( equal(filename, ".") || equal(filename, "..") )
		{
			continue;
		}
		
		replace(filename, sizeof(filename) - 1, ".txt", "");
		
		if( equal(filename, vaultname) )
		{
			close_dir(dir);
			
			return filenum;
		}
		
		++filenum;
	}
	while( next_file(dir, filename, sizeof(filename) - 1) );
	
	close_dir(dir);
	
	copy(vaultname, len, "");
	
	return -1;
}

/** 
 * Retrieves total vaults ever created
 * 
 * @return		Returns amount of vaults
 */
stock fvault_total()
{
	if( !dir_exists(_vault_dir) )
	{
		mkdir(_vault_dir);
		return 0;
	}
	
	new vaultname[128], filename[128];
	new dir = open_dir(_vault_dir, vaultname, sizeof(vaultname) - 1);
	
	new filenum;
	do
	{
		if( equal(vaultname, ".") || equal(vaultname, "..") )
		{
			continue;
		}
		
		formatex(filename, sizeof(filename) - 1, "%s/%s", _vault_dir, vaultname);
		if( file_exists(filename) )
		{
			++filenum;
		}
	}
	while( next_file(dir, vaultname, sizeof(vaultname) - 1) );
	
	close_dir(dir);
	
	return filenum;
}

/**
 * Gets all vault keys, data, and timestamps
 * 
 * @param		vaultname - Vault name to look in
 * @param		keys - cellarray holding all of the keys
 * @param		datas - cellarray holding all of the data values
 * @param		timestamps - cellarray holding all of the timestamps
 * 
 * @return		Returns total number of entries in vault
 * 
 * @note		keys needs to be created like this: ArrayCreate(64)
 * 			datas needs to be created like this: ArrayCreate(512)
 * 			timestamps need to be created like this: ArrayCreate()
 */
stock fvault_load(const vaultname[], Array:keys=Invalid_Array, Array:datas=Invalid_Array, Array:timestamps=Invalid_Array)
{
	new filename[128];
	_FormatVaultName(vaultname, filename, 127);
	
	if( !file_exists(filename) )
	{
		return 0;
	}
	
	new vault = fopen(filename, "rt");
	
	new array_size;
	
	new filedata[1024];
	new key[64], data[512], timestamp[32];
	while( !feof(vault) )
	{
		fgets(vault, filedata, 1023);
		
		if( parse(filedata, key, 63, data, 511, timestamp, 31) < 2 )
		{
			continue;
		}
		
		if( keys != Invalid_Array )
		{
			ArrayPushString(keys, key);
		}
		if( datas != Invalid_Array )
		{
			ArrayPushString(datas, data);
		}
		if( timestamps != Invalid_Array )
		{
			ArrayPushCell(timestamps, str_to_num(timestamp));
		}
		
		array_size++;
	}
	
	fclose(vault);
	
	return array_size;
}
 
stock _FormatVaultName(const vaultname[], filename[], len)
{
	static const invalid_chars[][] =
	{
		"/", "\", "*", ":", "?", "^"", "<", ">", "|"
	};
	
	static tempvault[128], i;
	copy(tempvault, sizeof(tempvault) - 1, vaultname);
	
	for( i = 0; i < sizeof(invalid_chars); i++ )
	{
		replace_all(tempvault, sizeof(tempvault) - 1, invalid_chars[i], "");
	}
	
	if( !dir_exists(_vault_dir) )
	{
		mkdir(_vault_dir);
	}
	
	formatex(filename, len, "%s/%s.txt", _vault_dir, tempvault);
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/

#define PLUGIN "Weapon Skin System [WSS]"
#define VERSION "1.0"
#define AUTHOR "6almasok"

#define IsValidPlayers(%1,%2) ((1 <= %1 <= 32) && (1 <= %2 <= 32))

new oles[33],csomag[33], kredit[33],switchbutton[33],knife[33],getfrag[3][33]
new ModelData[40][64], ModelNum, MaximumBtton

new const File[] = "addons/amxmodx/configs/wss_models.ini"
new const szVaultName[] = "wss_vault"
new const prefix[] = "WSS"

/*Rust Kills | Silver Kills | Gold Kills | Veteran Kills | Knife Kredit*/
new const need_kills[] = { 500, 1000, 2000, 4000, 500 }

/*Pack Names*/
new const csomagmsg[6][] = { "Nincs","Rozsdás Csomag","Ezüst Csomag","Arany Csomag","Veterán Csomag","Speed Knife" }

new const knifedisenable[2][] = { "Kikapcsolva", "Bekapcsolva" }

new const menuszoveg[][][] = {
	{"Rozsdás Csomag \r[MEGSZEREZVE]", "\dRozsdás Csomag \r[%i/%i Ölés]"}, //0
	{"Ezüst Csomag \r[MEGSZEREZVE]", "\dEzüst Csomag \r[%i/%i Ölés]"}, //1
	{"Arany Csomag \r[MEGSZEREZVE]", "\dArany Csomag \r[%i/%i Ölés]"}, //2
	{"Veterán Csomag \r[MEGSZEREZVE]", "\dVeterán Csomag \r[%i/%i Ölés]"}, //3
	{"Speed Knife \r[MEGSZEREZVE]^n", "\dSpeed Knife \r[%i/%i Ölés]^n"}, //4
	{"\ySkin Csomagok \r[KIKAPCSOLVA]", "\ySkin Csomagok \r[BEKAPCSOLVA]"} //5
}
new const chatszoveg[10][] = 
{
	"^4[%s]^1 FEJLÖVÉS!^3 %s ^1megöléséért kaptál ^3+%i^1 ölést!",
	"^4[%s]^3 %s ^1megöléséért kaptál ^3+%i^1 ölést!",
	"^4[%s]^3 %s ^1kapott ^3+1 ^1ölést ember lesebzésért!",
	"^4[%s]^1 Találtál^3 +%i^1 kreditet a csomagbol!",
	"^4[%s]^1 Kiválasztottad a(z)^3 %s^1-ot!",
	"^4[%s]^1 Sajnos nincs elég ölésed!",
	"^4[%s]^1 Kikapcsoltad a Skin Csomagokat!",
	"^4[%s]^1 Bekapcsoltad a Skin Csomagokat!",
	"^4[%s]^1 A Szerveren Jelenleg a(z) ^3Weapon Skin System^1 fut. Megnyitáshoz írd be ^3/menu^1.",
	"^4[%s]^1 Sajnos nincs elég kredited!"
}
public plugin_init() {
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	/* Client Command */
	register_clcmd("say /menu" , "fomenu")
	
	/* Events */
	register_event("CurWeapon", "changeweapon", "be", "1=1")
	register_event("Damage", "sebzes_event", "be", "2!0", "3=0", "4!0")
	register_event("DeathMsg","Halal","a")
	
	/* Cvars */
	register_cvar("wss_hudenable", "1");
	register_cvar("wss_advertmp", "40.0");
	register_cvar("kill_recived", "1");
	register_cvar("hs_recived", "2");
	register_cvar("found_kredit", "1");
	
	/* Other */
	register_forward(FM_Touch,"ForwardTouch" );
	RegisterHam(Ham_Spawn, "player", "spawn_event", 1)
	set_task(1.0, "infohud", 0, _, _, "b")
	set_task(get_cvar_float("wss_advertmp"), "advertist", 0, "", 0, "b", 0)

LoadModel();
}
public advertist(){ 
	ColorChat(0, GREEN, chatszoveg[8],prefix); 
	return PLUGIN_HANDLED;
}
public plugin_precache() {
	
	new Len, btton[196], Data[64], Letoltes[40][64];
	MaximumBtton = file_size(File, 1);
	
	for(new Num = 0; Num < MaximumBtton; Num++){
		read_file(File, Num, btton, 196, Len);
		parse(btton, Data, 63);
		remove_quotes(btton);
		if(btton[0] == ';')
		{
			continue;
		}
		remove_quotes(Data);
		format(Letoltes[Num], 63, "%s", Data);
		precache_model(Letoltes[Num]);
	}
	precache_model("models/wss/pack/kredit.mdl");
}
public LoadModel()
{
	new Len, btton[196], Data[64];
	MaximumBtton = file_size(File, 1);
	for(new Num; Num < MaximumBtton; Num++){
		ModelNum++;
		read_file(File, Num, btton, 196, Len);
		parse(btton, Data, 63);
		remove_quotes(btton);
		if(btton[0] == ';')
		{
			continue;
		}
		remove_quotes(Data);
		format(ModelData[ModelNum], 63, "%s", Data);
	}
}
public changeweapon(id)
{
	if(!is_user_alive(id) || !is_user_connected(id) || id < 1 || id > 32 || switchbutton[id] == 1)
	return
	
	new fegyver = get_user_weapon(id)
	
	if(csomag[id] == 1){
		if(fegyver == CSW_AK47)set_pev(id, pev_viewmodel2, ModelData[1]) //Rozsdas ak
		if(fegyver == CSW_AWP)set_pev(id, pev_viewmodel2, ModelData[2]) //Rozsdas awp
		if(fegyver == CSW_DEAGLE)set_pev(id, pev_viewmodel2, ModelData[3]) //Rozsdas desi
		if(fegyver == CSW_M4A1)set_pev(id, pev_viewmodel2, ModelData[4]) //Rozsdas m4
	}
	else if(csomag[id] == 2){
		if(fegyver == CSW_AK47)set_pev(id, pev_viewmodel2, ModelData[5]) //ezust ak
		if(fegyver == CSW_AWP)set_pev(id, pev_viewmodel2, ModelData[6]) //ezust awp
		if(fegyver == CSW_DEAGLE)set_pev(id, pev_viewmodel2, ModelData[7]) //ezust desi
		if(fegyver == CSW_M4A1)set_pev(id, pev_viewmodel2, ModelData[8]) //ezust m4
	}
	else if(csomag[id] == 3){
		if(fegyver == CSW_AK47)set_pev(id, pev_viewmodel2, ModelData[9]) //arany ak
		if(fegyver == CSW_AWP)set_pev(id, pev_viewmodel2, ModelData[10]) //arany awp
		if(fegyver == CSW_DEAGLE)set_pev(id, pev_viewmodel2, ModelData[11]) //arany desi
		if(fegyver == CSW_M4A1)set_pev(id, pev_viewmodel2, ModelData[12]) //arany m4
	}
	else if(csomag[id] == 4){
		if(fegyver == CSW_AK47)set_pev(id, pev_viewmodel2, ModelData[13]) //veteran ak
		if(fegyver == CSW_AWP)set_pev(id, pev_viewmodel2, ModelData[14]) //veteran awp
		if(fegyver == CSW_DEAGLE)set_pev(id, pev_viewmodel2, ModelData[15]) //veteran desi
		if(fegyver == CSW_M4A1)set_pev(id, pev_viewmodel2, ModelData[16]) //veteran m4
	}
	if(knife[id] == 1 && fegyver == CSW_KNIFE){
		
		set_user_maxspeed(id, Float:320.0)
		set_pev(id, pev_viewmodel2, ModelData[17]) //knife
	}
 
}
public spawn_event(id){
	getfrag[0][id] = 0;
	getfrag[1][id] = 0;
	getfrag[2][id] = 0;
}
public sebzes_event(id)
{
	new tamado = get_user_attacker(id);
	if(id == tamado  || !IsValidPlayers(id, tamado )) return;
	getfrag[1][tamado] += read_data(2);
 
	if(!getfrag[2][id] && getfrag[1][tamado] >= 50)
	{
		getfrag[0][tamado] = id;
		getfrag[2][id] = tamado;
	}
}
public Halal() {
	
	new attacker = read_data(1)
	new victim = read_data(2)
	
	new nev[32]
	get_user_name(victim, nev, charsmax(nev))
	
	if(attacker == victim || attacker == 0)
		return PLUGIN_HANDLED
	
	if(read_data( 3 )){
		oles[attacker] += get_cvar_num("hs_recived");
		ColorChat(attacker, GREEN, chatszoveg[0] ,prefix ,nev, get_cvar_num("hs_recived"))
	}
	else{
		oles[attacker] += get_cvar_num("kill_recived");
		ColorChat(attacker, GREEN, chatszoveg[1],prefix, nev, get_cvar_num("kill_recived"))
	}
	if(getfrag[2][victim] && getfrag[2][victim] != attacker){
		new fragetkap = getfrag[2][victim];
		new fragetkapneve[32];
		getfrag[0][fragetkap] = 0;
		getfrag[1][fragetkap] = 0;
		getfrag[2][victim] = 0;
		get_user_name(fragetkap, fragetkapneve, charsmax(fragetkapneve));
		oles[fragetkap]++
		ColorChat(0, GREEN, chatszoveg[2],prefix ,fragetkapneve);
	}
	switch(random_num(1,3)){
		case 1: dropdobas()
	}
	return PLUGIN_HANDLED;
}
public dropdobas()
{	
	new victim = read_data( 2 );
 
	static Float:origin[ 3 ];
	pev( victim, pev_origin, origin );
 
	new ent = engfunc( EngFunc_CreateNamedEntity, engfunc( EngFunc_AllocString, "info_target" ) );
	origin[ 2 ] -= 36; 
	engfunc( EngFunc_SetOrigin, ent, origin );
 
	if( !pev_valid( ent ) )
	{
		return PLUGIN_HANDLED;
	}
	
	set_pev( ent, pev_classname, "kredit" );
	engfunc( EngFunc_SetModel, ent, "models/wss/pack/kredit.mdl" );
	dllfunc( DLLFunc_Spawn, ent );
	set_pev( ent, pev_solid, SOLID_BBOX );
	set_pev( ent, pev_movetype, MOVETYPE_NONE );
	engfunc( EngFunc_SetSize, ent, Float:{ -23.160000, -13.660000, -0.050000 }, Float:{ 11.470000, 12.780000, 6.720000 } );
	engfunc( EngFunc_DropToFloor, ent );
 
	return PLUGIN_HANDLED;
}
public ForwardTouch( ent, id )
{
	if(pev_valid(ent))
	{
	new classname[ 32 ];
	pev( ent, pev_classname, classname, charsmax( classname ) );
 
	if( !equal( classname, "kredit") )
	{
		return FMRES_IGNORED;
	}
 
	kredit[id] += get_cvar_num("found_kredit");
	ColorChat(id, GREEN, chatszoveg[3],prefix, get_cvar_num("found_kredit"));
	
	engfunc( EngFunc_RemoveEntity, ent );
	}
	return FMRES_IGNORED
}
public logevent_round_start()
{
	new hkt = FM_NULLENT;
	while ( ( hkt = fm_find_ent_by_class( hkt, "kredit") ) )
	{
		engfunc( EngFunc_RemoveEntity, hkt );
	}	
}
public fomenu(id)
{
	new String[96]
	format(String, charsmax(String), "\r[Weapon Skin System] \wFőmenü^n\yÖlések: \d%i \w|\y Kreditek: \d%i", oles[id],kredit[id])
	new menu = menu_create(String, "fomenu_MyMenu");

menu_additem(menu, "Fegyver Skin Csomagok", "0");
	menu_additem(menu, "Játékos Infók", "1");
	menu_additem(menu, "Pack Információk", "2");

menu_setprop(menu, MPROP_EXIT, MEXIT_ALL);
	menu_setprop(menu, MPROP_EXITNAME, "\rKilépés");

menu_display(id, menu, 0);

return PLUGIN_HANDLED;
}
public fomenu_MyMenu(id, menu, item)
{
	if(item == MENU_EXIT)
	{
		menu_destroy(menu);
		return PLUGIN_HANDLED;
	}

new command[6], name[64], access, callback;
	menu_item_getinfo(menu, item, access, command, sizeof command - 1, name, sizeof name - 1, callback);

switch(item)
	{
		case 0: fegymenu(id)
		case 1: playerinfo(id)
		case 2: show_motd(id, "addons/amxmodx/configs/wssinfo.txt", "[WSS] Infok")
	}

menu_destroy(menu);

return PLUGIN_HANDLED;
}
public playerinfo(id)
{	
	new some[256], menu
	static players[32],szTemp[10],pnum
	get_players(players,pnum,"ch");
 
	formatex(some,255,"\r[Weapon Skin System] \wJátékos \d|\w Ölés \d|\w Kredit");
	menu = menu_create(some,"pinfo_Handler");
 
	for (new i; i < pnum; i++)
	{
		formatex(some,256,"%s \r(\yÖlése: \w%i \d| \yKreditje: \w%i\r)",get_player_name(players[i]), oles[players[i]],kredit[players[i]]);
		num_to_str(players[i],szTemp,charsmax(szTemp));
		menu_additem(menu, some, szTemp);
	}
 
	menu_setprop(menu, MPROP_EXIT, MEXIT_ALL );
	menu_setprop(menu, MPROP_EXITNAME, "Kilépés");
	menu_display(id, menu);
	return PLUGIN_HANDLED;
}
public pinfo_Handler(id,menu, item)
{
	if(item == MENU_EXIT)
	{
		menu_destroy(menu);
		return;
	}

playerinfo(id)
}
public fegymenu(id)
{
	new String[96]
	format(String, charsmax(String), "\r[Weapon Skin System] \wSkin csomagok^n\yKiválasztott Csomag: \d[%s]", csomagmsg[csomag[id]])
	new menu = menu_create(String, "fegymenu_handler" )

format(String, charsmax(String), oles[id] >= need_kills[0] ? (menuszoveg[0][0]):(menuszoveg[0][1]), oles[id], need_kills[0]);
	menu_additem(menu, String, "0" );
	formatex(String, charsmax(String), oles[id] >= need_kills[1] ? (menuszoveg[1][0]):(menuszoveg[1][1]), oles[id], need_kills[1]);
	menu_additem(menu, String, "1");
	formatex(String, charsmax(String), oles[id] >= need_kills[2] ? (menuszoveg[2][0]):(menuszoveg[2][1]), oles[id], need_kills[2]);
	menu_additem(menu, String, "2");
	format(String, charsmax(String), oles[id] >= need_kills[3] ? (menuszoveg[3][0]):(menuszoveg[3][1]), oles[id], need_kills[3]);
	menu_additem(menu, String, "3");
	formatex(String, charsmax(String), kredit[id] >= need_kills[4] ? (menuszoveg[4][0]):(menuszoveg[4][1]), kredit[id], need_kills[4]);
	menu_additem(menu, String, "4");
	menu_additem(menu, switchbutton[id] == 1 ? (menuszoveg[5][0]):(menuszoveg[5][1]), "5");

menu_setprop(menu, MPROP_EXIT, MEXIT_ALL);
	menu_setprop(menu, MPROP_BACKNAME, "Vissza");
	menu_setprop(menu, MPROP_NEXTNAME, "Előre");
	menu_setprop(menu, MPROP_EXITNAME, "Kilépés");

menu_display(id, menu, 0);
	return PLUGIN_HANDLED;
}
public fegymenu_handler(id, menu, item)
{
	if(item == MENU_EXIT)
	{
		menu_destroy(menu)
		return PLUGIN_HANDLED;
	}

new command[6], name[64], access, callback;
	menu_item_getinfo(menu, item, access, command, sizeof command - 1, name, sizeof name - 1, callback);

switch(item)
	{
		case 0: {
			if(oles[id] >= need_kills[0]) {
			csomag[id] = 1
			ColorChat(id, GREEN, chatszoveg[4],prefix, csomagmsg[csomag[id]]);
			}
			else  {
			ColorChat(id, GREEN, chatszoveg[5],prefix);
			}
		}
		case 1: {
			if(oles[id] >= need_kills[1]) {
			csomag[id] = 2
			ColorChat(id, GREEN, chatszoveg[4],prefix, csomagmsg[csomag[id]]);
			}
			else  {
			ColorChat(id, GREEN, chatszoveg[5],prefix);
			}
		}
		case 2: {
			if(oles[id] >= need_kills[2]) {
			csomag[id] = 3
			ColorChat(id, GREEN, chatszoveg[4],prefix, csomagmsg[csomag[id]]);
			}
			else  {
			ColorChat(id, GREEN, chatszoveg[5],prefix);
			}
		}
		case 3: {
			if(oles[id] >= need_kills[3]) {
			csomag[id] = 4
			ColorChat(id, GREEN, chatszoveg[4],prefix, csomagmsg[csomag[id]]);
			}
			else  {
			ColorChat(id, GREEN, chatszoveg[5],prefix);
			}
		}
		case 4: {
			if(kredit[id] >= need_kills[4]) {
			knife[id] = 1
			ColorChat(id, GREEN, chatszoveg[4],prefix, csomagmsg[5]);
			}
			else  {
			ColorChat(id, GREEN, chatszoveg[9],prefix);
			}
		}
		case 5: {
			if(switchbutton[id] == 0){
			switchbutton[id] = 1
			csomag[id] = 0
			knife[id] = 0
			ColorChat(id, GREEN, chatszoveg[6],prefix);
			}
			else {
			switchbutton[id] = 0
			ColorChat(id, GREEN, chatszoveg[7],prefix);
			}
		}
		case 6: {
			ColorChat(id, GREEN, chatszoveg[5],prefix);
		}
	}

fegymenu(id)
	return PLUGIN_HANDLED;
}
public infohud() {
	
	if(!get_cvar_num("wss_hudenable")) return PLUGIN_HANDLED
	
	static id
	for(id = 1; id <= get_maxplayers(); id++)
	{
		if(is_user_alive(id)){
			set_hudmessage(0, 127, 255, 0.01, 0.20, 0, 6.0, 1.0)
			show_hudmessage(id, "[Ölés: %i]^n[Kredit: %i]^n[Kiválasztott Csomag: %s]^n[Speed Knife: %s]", oles[id],kredit[id],csomagmsg[csomag[id]], knifedisenable[knife[id]])
		}
		else{
			new target = entity_get_int(id, EV_INT_iuser2);
			
			if(!target)
			return PLUGIN_CONTINUE;
				
			set_hudmessage(255, 255, 255, 0.01, 0.20, 0, 6.0, 1.0)
			show_hudmessage(id, "[Ölés: %i]^n[Kredit: %i]^n[Kiválasztott Csomag: %s]^n[Speed Knife: %s]", oles[target],kredit[target],csomagmsg[csomag[target]], knifedisenable[knife[target]])
		}
	}
	return PLUGIN_CONTINUE;
}
stock get_player_name(id){
	static szName[32];
	get_user_name(id,szName,31);
	return szName;
}
public client_disconnect(id){
	if(is_user_bot(id)) return;
	
	save(id);
}
public client_putinserver( id ) {
	if(is_user_bot(id)) return;
	
	oles[id] = 0;
	kredit[id] = 0;
	csomag[id] = 0;
	switchbutton[id] = 0;
	load(id);
}
load(id) {
	new szAuthid[32], szData[32];
	get_user_name( id, szAuthid, charsmax(szAuthid));
	new s1[16],s2[16],s3[16],s4[16]
	fvault_get_data( szVaultName, szAuthid, szData, 31 );
	parse( szData, s1, 15, s2, 15 , s3 , 15, s4 ,15);
	oles[id] = str_to_num(s1);
	kredit[id] = str_to_num(s2);
	csomag[id] = str_to_num(s3);
	switchbutton[id] = str_to_num(s4);
}
save(id) {
	new szAuthid[ 32 ], szData[ 32 ];
	get_user_name( id, szAuthid, charsmax(szAuthid));
	
	formatex( szData, 31, "%i %i %i %i", oles[id], kredit[id], csomag[id], switchbutton[id]);
	fvault_set_data( szVaultName, szAuthid, szData );
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

Szerző:	adek02 [ 2016.02.11. 17:46 ]
Hozzászólás témája:	Re: Weapon Skin System [WSS]
Szép leírás!Amint jóváhagyták tesztelem.! Szerintem sokan várták ezt a nagy update-tet! Egy kérdésem lenne! Nem lehetne megoldani azt,hogy a speed knife-t kivenni és csak két csomag lenne.

Szerző:	6almasok [ 2016.02.11. 18:00 ]
Hozzászólás témája:	Re: Weapon Skin System [WSS]
adek02 írta: Szép leírás!Amint jóváhagyták tesztelem.! Szerintem sokan várták ezt a nagy update-tet! Egy kérdésem lenne! Nem lehetne megoldani azt,hogy a speed knife-t kivenni és csak két csomag lenne. Lehet. De szerintem még te is megtudod csinálni mivel ahogy montam könnyű kezelő felületet kapott

Szerző:	kiki [ 2016.02.11. 18:28 ]
Hozzászólás témája:	Re: Weapon Skin System [WSS]
Akkor az előző témát amit linkeltél töröljem, hogy már ez az új? Illetve szép a leírás, ha az összes képet összeszeded egy rarba vagy zipbe, és elküldöd, akkor fel teszem oldal tárhelyére, így biztosan megmarad amég az oldal fut. A külső képfeltöltő tárhely ki tudja meddig őrzi meg a képeket.

Szerző:	6almasok [ 2016.02.11. 19:37 ]
Hozzászólás témája:	Re: Weapon Skin System [WSS]
Nem tudom , hogy akarja-e még valaki használni , de szerintem törölheted + a képeket a mai nap folyamán vagy holnap elküldöm

Szerző:	Hell [ 2016.02.11. 19:38 ]
Hozzászólás témája:	Re: Weapon Skin System [WSS]
Nagyon jo mikor lesz jovahagyva ? _

Szerző:	kiki [ 2016.02.11. 20:19 ]
Hozzászólás témája:	Re: Weapon Skin System [WSS]
6almasok írta: Nem tudom , hogy akarja-e még valaki használni , de szerintem törölheted + a képeket a mai nap folyamán vagy holnap elküldöm Rendben, majd akkor jövő hétig küld el kérlek. És majd kifogom cserélni a kép linkeket a helyi linkre. Ha akarod akkor törlöm az előzőt, ha nem akkor nem. Rajtad múlik. (Csak így lehet ha valaki nem találja meg ezt, akkor a régebbit fogja használni)

Szerző:	Anonymous1337 [ 2016.02.11. 21:07 ]
Hozzászólás témája:	Re: Weapon Skin System [WSS]
kiki írta: Akkor az előző témát amit linkeltél töröljem, hogy már ez az új? Illetve szép a leírás, ha az összes képet összeszeded egy rarba vagy zipbe, és elküldöd, akkor fel teszem oldal tárhelyére, így biztosan megmarad amég az oldal fut. A külső képfeltöltő tárhely ki tudja meddig őrzi meg a képeket. Én összeszedtem a képeket, ha nem baj: Csatolmány: képek.rar [310.24 KiB] Letöltve 371 alkalommal.

Szerző:	CrB [ 2016.02.11. 22:19 ]
Hozzászólás témája:	Re: Weapon Skin System [WSS]
Példaértékű leírás gratulálok hozzá.

Szerző:	FonoK [ 2016.02.12. 18:45 ]
Hozzászólás témája:	Re: Weapon Skin System [WSS]
Nagyon igényes feltöltés, köszönöm! Nekem annyi kérdésem lenne, hogy a szerveremet egy ilyen plugin (fun szerver, szóval alapból elég sok plugin van rajta, pl. sapka skin plugin..) nem terhelné nagyon le?

Oldal: 1 / 8	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/