AFK Manager

Megválaszolatlan témák | Aktív témák

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Navigáció

Főmenü

Kezdőlap

Fórum

Kapcsolat

Képfeltöltő Amx Mod X

Letöltések

Pluginok

Fordító (Compiler) SourceMod

Letöltések

Pluginok

Fordító (Compiler) EventScript

Letöltések

Magyar scriptek Pályák

Half-Life

Half-Life 2

Jelenlévő felhasználók

Jelenleg 273 felhasználó van jelen :: 1 regisztrált, 0 rejtett és 272 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: Majestic-12 [Bot] az elmúlt 5 percben aktív felhasználók alapján

[ Ki van itt ]

Utoljára aktív

Kereső

Moderátor: Fórum Moderátor

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 2

[ 13 hozzászólás ]

Oldal 1 2 Következő

Nyomtatóbarát verzió | Barát értesítése e-mailben

Előző téma | Következő téma

Szerző

Üzenet

kengurumancs

Hozzászólás témája: AFK Manager

HozzászólásElküldve: 2016.02.11. 19:49

Offline

Csatlakozott: 2015.03.12. 18:30
Hozzászólások: 975
Megköszönt másnak: 67 alkalommal
Megköszönték neki: 136 alkalommal

Plugin Neve:	AFK Manager	Plugint készitette:	Leon McVeran
Játék:	Counter-Strike	Kategória:	Játékmenet
Eredeti link:	Megnézem	Jóváhagyó:	kiki

AFK Manager v1.6
by Leon McVeran

Leírás:
Ez egy igen egyszerű kis plugin, ami magába foglal több plugint. Lényegében annyi, hogy aki nincs gépnél a szerveren azt nem szereti, bomba átadás, AFK áthelyező nézők közé, AFK kirúgó nézők közül.

Cvar:
afk_check "1"
- 0: Plugin letiltása.
- 1: Plugin engedélyezése, játékosok ellenőrzése.
- 2: Plugin engedélyezése, utolsó aktivitás nézése.

afk_drop_bomb "2"
- 0: Funkció letiltása.
- 1: Eldobja a bombát.
- 2: Bomba átadása egy csapattársnak.

afk_transfer_time "9" (minimum 6)
- A játékost ki nem mozdul, mennyi idő múlva tegye át nézőbe. (1=5 másodperc, azaz 9=45 másodperc)

afk_kick_time "24" (minimum 6)
- Mennyi idő múlva rúgja ki a játékost a nézők közül. (1=5 másodperc, azaz 24=120 másodperc

afk_kick_players "12"
- Hány játékosnál rúgja ki a nézőket? 0 letiltja a funkciót.

afk_spec_pw "jelszó"
- Jelszó ami az immunitást adja. (Minden map váltásnál be kell írni)

Telepítés:
Amxx fájl a plugins mappába, majd a plugin nevét a plugins.ini -be írd be!
Sma-t scripting mappába. (nem szükséges)
Miután a zip-et letöltötted,kicsomagoltad, afk_manager.txt rakd bele a data/lang mappába!
ColorChat mondul hiba esetén:

► Spoiler mutatása

VirusTotal

► Spoiler mutatása

#define PLUGIN 	"AFK Manager"
#define AUTHOR 	"Leon McVeran"
#define VERSION 	"v1.6"
#define PDATE 	"2nd August 2011"

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <fakemeta>

#define KICK_IMMUNITY 		ADMIN_BAN

#define TASK_AFK_CHECK 		142500
#define FREQ_AFK_CHECK 		5.0
#define MAX_WARN 		3

static const OFFSET_LINUX = 5
new const m_iJoiningState = 125

new bool:g_bSpec[33]
new bool:g_bSpecAccess[33]
new Float:g_fLastActivity[33]
new g_iAFKCheck
new g_iAFKTime[33]
new g_iDropBomb
new g_iKickTime
new g_iMaxPlayers
new g_iMinPlayers
new g_iTransferTime
new g_iWarn[33]
new g_vOrigin[33][3]

new CVAR_afk_drop_bomb
new CVAR_afk_check
new CVAR_afk_transfer_time
new CVAR_afk_kick_time
new CVAR_afk_kick_players

new CVAR_afk_spec_pw

public plugin_init(){
	register_plugin(PLUGIN, VERSION, AUTHOR)
	register_dictionary("afk_manager.txt")

register_logevent("event_round_end", 2, "0=World triggered", "1=Round_End")
	register_logevent("event_round_start", 2, "0=World triggered", "1=Round_Start")

// Support der alten Men�s
	register_clcmd("jointeam", "cmd_jointeam") // new menu
	register_menucmd(register_menuid("Team_Select", 1), 511, "cmd_jointeam") // old menu

register_clcmd("joinclass", "cmd_joinclass") // new menu
	register_menucmd(register_menuid("Terrorist_Select", 1), 511, "cmd_joinclass") // old menu
	register_menucmd(register_menuid("CT_Select", 1), 511, "cmd_joinclass") // old menu

register_clcmd("say", "cmd_say")

CVAR_afk_check = register_cvar("afk_check", "1")
	CVAR_afk_drop_bomb = register_cvar("afk_drop_bomb", "2")
	CVAR_afk_transfer_time = register_cvar("afk_transfer_time", "9")
	CVAR_afk_kick_time = register_cvar("afk_kick_time", "24")
	CVAR_afk_kick_players = register_cvar("afk_kick_players", "12")

CVAR_afk_spec_pw = register_cvar("afk_spec_pw", "password")
}

public plugin_cfg(){
	g_iMaxPlayers = get_maxplayers()
}

public client_connect(id){

// Spieler als Spectator entmarkieren
	g_bSpec[id] = false
	g_bSpecAccess[id] = false

// Positionen zur�cksetzen
	g_vOrigin[id] = {0, 0, 0}

// Counter zur�cksetzen
	g_iAFKTime[id] = 0
	g_iWarn[id] = 0
}

public event_round_start(){

// AFK Check eingeschaltet
	g_iAFKCheck = get_pcvar_num(CVAR_afk_check)
	if (g_iAFKCheck){

// Spawn-Positionen aktualisieren
		new iPlayers[32], pNum
		get_players(iPlayers, pNum, "a")
		for (new p = 0; p < pNum; p++){
			get_user_origin(iPlayers[p], g_vOrigin[iPlayers[p]])
		}

// Loop anlegen falls nicht vorhanden
		if (!task_exists(TASK_AFK_CHECK)) set_task(FREQ_AFK_CHECK, "func_afk_check", TASK_AFK_CHECK, _, _, "b")

// Kick und Transferzeiten festlegen
		if (get_pcvar_num(CVAR_afk_transfer_time) < 6) set_pcvar_num(CVAR_afk_transfer_time, 6)
		if (get_pcvar_num(CVAR_afk_kick_time) < 6) set_pcvar_num(CVAR_afk_kick_time, 6)
		g_iDropBomb = get_pcvar_num(CVAR_afk_drop_bomb)
		g_iTransferTime = get_pcvar_num(CVAR_afk_transfer_time)
		g_iKickTime = get_pcvar_num(CVAR_afk_kick_time)
		g_iMinPlayers = get_pcvar_num(CVAR_afk_kick_players)
	}

// AFK Check ausgeschaltet
	else{

// Loop l�schen falls vorhanden
		if (task_exists(TASK_AFK_CHECK)) remove_task(TASK_AFK_CHECK)
	}

}

public event_round_end(){

// Check darf nicht durchgef�hrt werden
	g_iAFKCheck = 0
}

public cmd_jointeam(id){

// Spieler als Spectator markieren, sonst kann man den Kick umgehen, indem man keiner Klasse joined.
	g_bSpec[id] = true
}

public cmd_joinclass(id){

// Spieler als Spectator entmarkieren
	g_bSpec[id] = false

// Positionen zur�cksetzen
	g_vOrigin[id] = {0, 0, 0}

// Counter zur�cksetzen
	g_iAFKTime[id] = 0
	g_iWarn[id] = 0
}

public cmd_say(id){
	new szMsg[64], szCommand[16], szTrash[2]
	read_args(szMsg, 63)
	remove_quotes(szMsg)
	parse(szMsg, szCommand, 15, szTrash, 1)

// Wir interessieren uns nur f�r Chatnachrichten die nicht mehr als 2 W�rter beinhalten
	if (!szTrash[0]){

new szPassword[32]
		get_pcvar_string(CVAR_afk_spec_pw, szPassword, 31)
		if (equal(szCommand, szPassword)){
			print_color(id, "!g[AMXX] %L", LANG_PLAYER, "AFK_ACCESS_GRANTED")
			g_bSpecAccess[id] = true
			return PLUGIN_HANDLED
		}
	}
	return PLUGIN_CONTINUE
}

public func_afk_check(taskid){
	if (g_iAFKCheck){
		new CsTeams:eTeam

// Alle Spieler �berpr�fen
		for (new id = 1; id <= g_iMaxPlayers; id++){

// Bots nicht �berpr�fen
			if (is_user_bot(id)) continue

// AFK Funktionen f�r Specs
			if (is_user_connected(id) && !is_user_hltv(id)){
				eTeam = cs_get_user_team(id)
				if (eTeam == CS_TEAM_SPECTATOR || eTeam == CS_TEAM_UNASSIGNED || g_bSpec[id]){

// Counter erh�hen
					g_iAFKTime[id]++

// Spec-Kick
					if (g_iAFKTime[id] >= g_iKickTime - MAX_WARN){
						func_kick_player(id)
					}
				}
			}

// AFK Funktionen f�r lebende Spieler
			if (is_user_alive(id)){

// Positionen �berpr�fen
				if (g_iAFKCheck == 1){
					new vOrigin[3]
					get_user_origin(id, vOrigin)

if (g_vOrigin[id][0] != vOrigin[0] || g_vOrigin[id][1] != vOrigin[1]){
						g_vOrigin[id][0] = vOrigin[0]
						g_vOrigin[id][1] = vOrigin[1]
						g_vOrigin[id][2] = vOrigin[2]
						g_iAFKTime[id] = 0
						g_iWarn[id] = 0
					}
					else{
						g_iAFKTime[id]++
					}
				}

// Letzte Aktivit�t ermitteln
				else{
					new Float:fLastActivity
					fLastActivity = cs_get_user_lastactivity(id)

if (fLastActivity != g_fLastActivity[id]){
						g_fLastActivity[id] = fLastActivity
						g_iAFKTime[id] = 0
						g_iWarn[id] = 0
					}
					else{
						g_iAFKTime[id] = floatround((get_gametime() - fLastActivity) / FREQ_AFK_CHECK)
					}
				}

// Bombentransfer
				if (g_iDropBomb && g_iAFKTime[id] >= 3){
					if (g_iDropBomb == 1){
						if (pev(id, pev_weapons) & (1 << CSW_C4)) engclient_cmd(id, "drop", "weapon_c4")
					}
					else{
						func_transfer_bomb(id)
					}
				}

// Spec-Switch
				if (g_iAFKTime[id] >= g_iTransferTime - MAX_WARN){
					func_transfer_player(id)
				}
			}
		}
	}
}

public func_transfer_bomb(id){

// Abbrechen wenn der Spieler keine Bombe hat
	if (!(pev(id, pev_weapons) & (1 << CSW_C4))) return

// Ermittle alle lebenden Terroristen
	new iPlayers[32], pNum
	get_players(iPlayers, pNum, "ae", "TERRORIST")

// Abbrechen falls weniger als 2 Terroristen leben
	if (pNum < 2) return

// Finde den n�chsten Terroristen der nicht AFK ist
	new vCarrier[3], vRecipient[3], iRecipient, iDistance, iMinDistance = 999999
	get_user_origin(id, vCarrier)
	for (new p = 0; p < pNum; p++){
		if (g_iAFKTime[iPlayers[p]] < 2){
			get_user_origin(iPlayers[p], vRecipient)
			iDistance = get_distance(vCarrier, vRecipient)
			if (iDistance < iMinDistance){
				iMinDistance = iDistance
				iRecipient = iPlayers[p]
			}
		}
	}

// Abbrechen wenn alle Terroristen AFK sind
	if (!iRecipient) return

// Bombe transferieren
	engclient_cmd(id, "drop", "weapon_c4")
	new iC4 = engfunc(EngFunc_FindEntityByString, -1, "classname", "weapon_c4")
	if (pev_valid(iC4)){
		new iBackpack = pev(iC4, pev_owner)
		if (iBackpack > g_iMaxPlayers){
			set_pev(iBackpack, pev_flags, pev(iBackpack, pev_flags) | FL_ONGROUND)
			dllfunc(DLLFunc_Touch, iBackpack, iRecipient)
		}
	}

// Nachrichten anzeigen
	new szRecipient[32], szMsg[128]
	get_user_name(iRecipient, szRecipient, 31)
	set_hudmessage(255, 255, 0, -1.0, 0.8, 0, 3.0, 6.0, 0.1, 0.2, -1)
	for (new p = 0; p < pNum; p++){
		if (iPlayers[p] != iRecipient){
			format(szMsg, 127, "%L", iPlayers[p], "AFK_TRANSFER_BOMB", szRecipient)
			show_hudmessage(iPlayers[p], "%s", szMsg)
		}
	}
	format(szMsg, 127, "%L", iRecipient, "AFK_GOT_BOMB")
	show_hudmessage(iRecipient, szMsg)
}

public func_transfer_player(id){

// Warnung anzeigen, wenn nicht schon max-mal verwarnt
	if (g_iWarn[id] < MAX_WARN){
		print_color(id,"!g[AMXX] %L", LANG_PLAYER, "AFK_TRANSFER_WARN", floatround(FREQ_AFK_CHECK) * (MAX_WARN - g_iWarn[id]))
		g_iWarn[id]++
		return
	}

// Eigentlich sollte die Bombe schon transferiert worden sein
	if (pev(id, pev_weapons) & (1 << CSW_C4)){
		engclient_cmd(id, "drop", "weapon_c4")
	}

// Spieler tranferieren
	if (is_user_alive(id)) user_silentkill(id)

// Allow players to choose a team more than one time per round (Thanks ConnorMcLeod)
	// I use this method caused of some issue with deathmatch (Player will be respawned as T or CT)
	set_pdata_int(id, m_iJoiningState, get_pdata_int(id, m_iJoiningState, OFFSET_LINUX) & ~(1<<8), OFFSET_LINUX)
	engclient_cmd(id, "jointeam", "6")
	set_pdata_int(id, m_iJoiningState, get_pdata_int(id, m_iJoiningState, OFFSET_LINUX) & ~(1<<8), OFFSET_LINUX)
	//cs_set_user_team(id, CS_TEAM_SPECTATOR)
	//cs_reset_user_model(id)

// Positionen zur�cksetzen
	g_vOrigin[id] = {0, 0, 0}

// Counter zur�cksetzen
	g_iAFKTime[id] = 0
	g_iWarn[id] = 0

// Nachrichten anzeigen
	new szName[32]
	get_user_name(id, szName, 31)
	print_color( 0 , "!g[AMXX] %L", LANG_PLAYER, "AFK_TRANSFER_PLAYER", szName)
	log_amx(" %s jatekos at keralt nezobe, AFK miatt.", szName)
}

public func_kick_player(id){

// Abbrechen wenn es sich um einen Admin handelt
	if (get_user_flags(id) & KICK_IMMUNITY || g_bSpecAccess[id]) return

// Anzahl der  aktuellen Spieler ermitteln
	new iCurrentPlayers = get_playersnum(1)

// Sind noch Pl�tze frei?
	if (iCurrentPlayers < g_iMinPlayers || !g_iMinPlayers) return

// Warnung anzeigen, wenn nicht schon max-mal verwarnt
	if (g_iWarn[id] < MAX_WARN){
		print_color(id, "!g[AMXX] %L", LANG_PLAYER, "AFK_KICK_WARN", floatround(FREQ_AFK_CHECK) * (MAX_WARN - g_iWarn[id]))
		g_iWarn[id]++
		return
	}

// Spieler kicken
	new szMsg[192]
	format(szMsg, 191, "%L", id, "AFK_KICK_REASON")
	server_cmd("kick #%d ^"%s^"", get_user_userid(id), szMsg)

// Nachrichten anzeigen
	new szName[32]
	get_user_name(id, szName, 31)
	print_color( 0 , "!g[AMXX] %L", LANG_PLAYER, "AFK_KICK_PLAYER", szName)
	log_amx("Player ^"%s^" kirugtak, amiert AFK.", szName)
}
stock print_color(const id, const input[], any:...) {
        new count = 1, players[32]
        static msg[191]
        vformat(msg, 190, input, 3)
 
        replace_all(msg, 190, "!g", "^4")
        replace_all(msg, 190, "!y", "^1")
        replace_all(msg, 190, "!t", "^3")    
 
        if (id) players[0] = id; else get_players(players, count, "ch")
        {
                for (new i = 0; i < count; i++)
                {
                        if (is_user_connected(players[i]))
                        {
                                message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, players[i])
                                write_byte(players[i])
                                write_string(msg)
                                message_end()
                        }
                }
        }
        return PLUGIN_HANDLED
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

_________________
Fórumi aktivitásom véget ért: 2017.09.07.
Innentől esetleg steamen vagyok elérhető.

A hozzászólást 4 alkalommal szerkesztették, utoljára kengurumancs 2016.02.13. 12:01-kor.

Ők köszönték meg kengurumancs nek ezt a hozzászólást: titkos (2016.04.17. 20:44)

Népszerűség: 2.27%

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

gyurc1111

Hozzászólás témája: Re: AFK Manager

HozzászólásElküldve: 2016.02.12. 12:11

Offline

Csatlakozott: 2014.01.04. 18:31
Hozzászólások: 326
Megköszönt másnak: 79 alkalommal
Megköszönték neki: 7 alkalommal

Amikor felrakom a plugint, nem fut mert hiányzik valami colorchat modul

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

kengurumancs

Hozzászólás témája: Re: AFK Manager

HozzászólásElküldve: 2016.02.12. 17:36

Offline

Csatlakozott: 2015.03.12. 18:30
Hozzászólások: 975
Megköszönt másnak: 67 alkalommal
Megköszönték neki: 136 alkalommal

Szia!
https://forums.alliedmods.net/showthread.php?p=1693613

_________________
Fórumi aktivitásom véget ért: 2017.09.07.
Innentől esetleg steamen vagyok elérhető.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

gyurc1111

Hozzászólás témája: Re: AFK Manager

HozzászólásElküldve: 2016.02.15. 12:11

Offline

Csatlakozott: 2014.01.04. 18:31
Hozzászólások: 326
Megköszönt másnak: 79 alkalommal
Megköszönték neki: 7 alkalommal

A 2 .zip-et rakjam fel?

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

kengurumancs

Hozzászólás témája: Re: AFK Manager

HozzászólásElküldve: 2016.02.15. 15:17

Offline

Csatlakozott: 2015.03.12. 18:30
Hozzászólások: 975
Megköszönt másnak: 67 alkalommal
Megköszönték neki: 136 alkalommal

Hogy érted, hogy a második zip-et?

_________________
Fórumi aktivitásom véget ért: 2017.09.07.
Innentől esetleg steamen vagyok elérhető.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

kiki

Hozzászólás témája: Re: AFK Manager

HozzászólásElküldve: 2016.02.15. 19:53

Offline

Csatlakozott: 2011.06.01. 21:11
Hozzászólások: 7962
Megköszönt másnak: 295 alkalommal
Megköszönték neki: 535 alkalommal

Biztos nem emiatt a plugin miatt írja neked hogy hiányzik a colorchat modul

_________________
http://www.easyrankup.eu

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

kengurumancs

Hozzászólás témája: Re: AFK Manager

HozzászólásElküldve: 2016.02.15. 21:13

Offline

Csatlakozott: 2015.03.12. 18:30
Hozzászólások: 975
Megköszönt másnak: 67 alkalommal
Megköszönték neki: 136 alkalommal

kiki írta:

Biztos nem emiatt a plugin miatt írja neked hogy hiányzik a colorchat modul

Az biztos, mert most nézem Stock-al színeztem ki (utólag)

_________________
Fórumi aktivitásom véget ért: 2017.09.07.
Innentől esetleg steamen vagyok elérhető.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

jokypapa

Hozzászólás témája: Re: AFK Manager

HozzászólásElküldve: 2016.02.16. 22:35

Offline

Csatlakozott: 2014.10.30. 10:18
Hozzászólások: 468
Megköszönt másnak: 235 alkalommal
Megköszönték neki: 34 alkalommal

kengurumancs írta:

kiki írta:

Biztos nem emiatt a plugin miatt írja neked hogy hiányzik a colorchat modul

Az biztos, mert most nézem Stock-al színeztem ki (utólag)

Én sem tudtam egy másik pluginba lefordítani, hiába h stock! Holott Amxx-Studio 1.4.3 final-t használom

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

gyurc1111

Hozzászólás témája: Re: AFK Manager

HozzászólásElküldve: 2016.02.21. 20:53

Offline

Csatlakozott: 2014.01.04. 18:31
Hozzászólások: 326
Megköszönt másnak: 79 alkalommal
Megköszönték neki: 7 alkalommal

csak simán beírom consoleba:

afk_spec_pw "jelszó"
- Jelszó ami az immunitást adja. (Minden map váltásnál be kell írni)

pl:
afk_spec_pw "hlmod"

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

kengurumancs

Hozzászólás témája: Re: AFK Manager

HozzászólásElküldve: 2016.02.21. 21:17

Offline

Csatlakozott: 2015.03.12. 18:30
Hozzászólások: 975
Megköszönt másnak: 67 alkalommal
Megköszönték neki: 136 alkalommal

jokypapa írta:

kengurumancs írta:

kiki írta:

Biztos nem emiatt a plugin miatt írja neked hogy hiányzik a colorchat modul

Az biztos, mert most nézem Stock-al színeztem ki (utólag)

Én sem tudtam egy másik pluginba lefordítani, hiába h stock! Holott Amxx-Studio 1.4.3 final-t használom

Ajánlhatom 1.8.3-as verziót...

gyurc1111 írta:

csak simán beírom consoleba:

afk_spec_pw "jelszó"
- Jelszó ami az immunitást adja. (Minden map váltásnál be kell írni)

pl:
afk_spec_pw "hlmod"

igen, cvar..

_________________
Fórumi aktivitásom véget ért: 2017.09.07.
Innentől esetleg steamen vagyok elérhető.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Hozzászólások megjelenítése: Rendezés

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 2

[ 13 hozzászólás ]

Oldal 1 2 Következő

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 13 vendég

Nem nyithatsz témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Ugrás: