hlmod.hu :: Sniper Manager

hlmod.hu https://hlmod.hu/

Sniper Manager https://hlmod.hu/viewtopic.php?f=101&t=24715	Oldal: 1 / 2

Szerző:

demon [ 2016.04.25. 19:49 ]

Hozzászólás témája:

Sniper Manager

Plugin Neve:	Sniper Manager	Plugint készitette:	Demon
Játék:	Counter-Strike	Kategória:	Játékmenet
Eredeti link:	Nincs megadva	Jóváhagyó:	LyleChriss

Sniper Manager

Leírás:
Ez a plugin only sniper szerverekhez egy kiegészítő. Lényegében annyit csinál, hogy scout és awp pályákon tiltja a vásárlást, törli az összes földön található armoury_entity-t, kör elején elveszi a fegyvereket, és a pályának megfelelően ad tele tárral egy awp-t | scout-ot és ezek mellé egy kést.

Cvar:
scout_gravity 215 --> Scout pályákon gravitációt lehet állítani (0 - alap gravitáció)

#include <amxmodx>
#include <engine>

#pragma semicolon 1

public plugin_init()
{
	register_plugin( "Sniper Manager", "1.0", "Demon" );
	register_cvar("Sniper Manager", "By Demon", FCVAR_SERVER);
}

public plugin_precache() 
{
	new scout_gravity = get_pcvar_num( register_cvar( "scout_gravity", "215" ) );
	new sMapName[ 32 ], Entity;
	
	get_mapname( sMapName, charsmax( sMapName ) );
	
	Entity = create_entity( "info_map_parameters" );
	DispatchKeyValue( Entity, "buying", "3" );
	DispatchKeyValue( Entity, "bombradius", "500" );
	DispatchSpawn( Entity );
	
	Entity = create_entity( "player_weaponstrip" );
	DispatchKeyValue( Entity, "targetname", "stripper" );
	DispatchSpawn( Entity );
	
	Entity = create_entity( "game_player_equip" );
	DispatchKeyValue( Entity, "weapon_knife"  , "1" );
	
	if ( containi( sMapName, "awp" ) != -1 )
	{
		DispatchKeyValue( Entity, "weapon_awp", "1" );
		DispatchKeyValue( Entity, "ammo_338magnum", "3" );
	}
	else if ( containi( sMapName, "scout" ) != -1 )
	{
		DispatchKeyValue( Entity, "weapon_scout", "1" );
		DispatchKeyValue( Entity, "ammo_762nato", "9" );
		
		if ( scout_gravity > 0 )
			set_task( 2.0, "set_gravity", scout_gravity );
	}
	
	DispatchKeyValue( Entity, "targetname", "equipment" );
	DispatchSpawn( Entity );
	
	Entity = create_entity( "multi_manager" );
	DispatchKeyValue( Entity, "equipment" , "1" );
	DispatchKeyValue( Entity, "stripper"  , "0"   );
	DispatchKeyValue( Entity, "targetname", "game_playerspawn" );
	DispatchKeyValue( Entity, "spawnflags", "1"   );
	DispatchSpawn( Entity );
}

public set_gravity( gravity ) server_cmd( "sv_gravity %d", gravity );

public pfn_keyvalue( Entity )
{ 
	new ClassName[ 20 ], KeyName[ 16 ], Value[ 20 ];
	
	copy_keyvalue( ClassName, charsmax( ClassName ), KeyName, charsmax( KeyName ), Value, charsmax( Value ) );
	
	if ( equal( ClassName, "info_map_parameters" ) || equal( ClassName, "func_buyzone" )
		|| equal( ClassName, "game_player_equip" ) || equal( ClassName, "player_weaponstrip" ))
	{ 
		remove_entity( Entity );
		return PLUGIN_HANDLED;
	}
	else if ( equal( ClassName, "multi_manager" ) && equal( KeyName, "targetname" ) && equal( Value, "game_playerspawn" ) )
	{
		remove_entity( Entity );
		return PLUGIN_HANDLED;
	}
	else if ( equal( ClassName, "armoury_entity" ) )
	{
		remove_entity( Entity );
		return PLUGIN_HANDLED;
	}
	
	return PLUGIN_CONTINUE;
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	mforce [ 2016.04.25. 20:40 ]
Hozzászólás témája:	Re: Sniper Manager
szó? Kód: [Egész kijelölése] [Mutatás/Eltüntetés] #include <fakemeta> new const g_iMapWeapons[][] = {"armoury_entity", "game_player_equip", "player_weaponstrip"} new const g_iMapObjects[][] = {"func_bomb_target", "func_hostage_rescue", "func_escapezone", "func_vip_safetyzone", "info_bomb_target", "info_hostage_rescue", "info_vip_start", "hostage_entity", "monster_scientist"} public plugin_init() { register_forward(FM_Spawn, "Spawn_Entity_Pre", 0); } public Spawn_Entity_Pre(ent) { if(!pev_valid(ent)) return FMRES_IGNORED; static classname[32]; pev(ent, pev_classname, classname, charsmax(classname)); for(new i; i<sizeof(g_iMapObjects); ++i) { if(equal(classname, g_iMapObjects[i])) { engfunc(EngFunc_RemoveEntity, ent); return FMRES_SUPERCEDE; } } for(new i; i<sizeof(g_iMapWeapons); ++i) { if(equal(classname, g_iMapWeapons[i])) { engfunc(EngFunc_RemoveEntity, ent); return FMRES_SUPERCEDE; } } return FMRES_IGNORED; } GeSHi © Codebox Plus Mivel jobb a te verziód?

Szerző:	demon [ 2016.04.25. 21:09 ]
Hozzászólás témája:	Re: Sniper Manager
Ez csak törli az entityket, az én pluginom létre is hoz 4 entityt. Nincs kedvem a magyarázkodáshoz, ha megfigyelnéd a plugint rájönnél.

Szerző:	mforce [ 2016.04.25. 21:11 ]
Hozzászólás témája:	Re: Sniper Manager
Tudom, de miért? Én nem értem, pont ezért kérdezem.

Szerző:	demon [ 2016.04.25. 21:25 ]
Hozzászólás témája:	Re: Sniper Manager
A plugin törli a plugin betöltésekor a már létező info_map_parameters, func_buyzone, game_player_equip, player_weaponstrip entityket. Majd létrehoz 4 entity-t a megfelelő paraméterekkel. info_map_parameters - vásárlást tiltja player_weaponstrip - minden kör elején elveszi az összes fegyver game_player_equip - itt adom meg, hogy milyen fegyvereket kapjon a játékos minden körkezdéskor (scout pályán scout és kés, awp pályán awp és kés) multi_manager - ez hívja meg a fenti entityket minden spawnoláskor Amit te küldtél plugin csak törli a tömbökben megadott entityket. Elvileg az én pluginom gyorsabb is, mivel a plugin_precache előbb lefut mint a plugin_init, illetve a pfn_keyvalue még előbb lefut mint a plugin_precache.

Szerző:	mforce [ 2016.04.25. 21:31 ]
Hozzászólás témája:	Re: Sniper Manager
Már így átlátom Érdekes kis gamedll turkapiszka, ilyet még nem láttam, mindenesetre tetszik!

Szerző:	SmaCk [ 2017.02.05. 21:05 ]
Hozzászólás témája:	Re: Sniper Manager
Nálam úgy tűnik valamiféle probléma van, fut a plugin viszont vásárolni is lehet. Valami ötlet? (rehlds)

Szerző:	demon [ 2017.02.05. 21:31 ]
Hozzászólás témája:	Re: Sniper Manager
Csak a 2. körtől fog működni a vásárlás tíltás.

Szerző:	SmaCk [ 2017.02.19. 17:37 ]
Hozzászólás témája:	Re: Sniper Manager
Továbbra sem működik néhány mapon, pl awp_india vagy india2. Vagy csak nálam?

Szerző:	kengurumancs [ 2017.02.21. 08:12 ]
Hozzászólás témája:	Re: Sniper Manager
SmaCk írta: Továbbra sem működik néhány mapon, pl awp_india vagy india2. Vagy csak nálam? Masik plugin blokkolja. Ui.: Nalam azokon a mapokon alapbol le van tiltva.

Oldal: 1 / 2	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/