hlmod.hu :: C4 stílusos visszaszámláló

hlmod.hu https://hlmod.hu/

C4 stílusos visszaszámláló https://hlmod.hu/viewtopic.php?f=101&t=27486	Oldal: 1 / 1

Szerző:

kengurumancs [ 2017.03.26. 23:18 ]

Hozzászólás témája:

C4 stílusos visszaszámláló

Plugin Neve:	C4 stílusos visszaszámláló	Plugint készitette:	OciXCrom
Játék:	Counter-Strike	Kategória:	Általános célú
Eredeti link:	Megnézem	Jóváhagyó:	6almasok

Style C4 Timer

Leírás:

Ez a plugin a robbanási időt 'számolja' vissza. Több visszaszámláló fajta(stílus) közül lehet választani, bele értve az alapértelmezettet is. A mérő csík megváltoztatja a színét is bizonyos időnél.
Alapból zöld, 10 másodperc alatt sárgára, és 5 másodperc alatt ki pirosodik.

Cvarok:

A színek és az X & Y pozíciót akkor lehet állítani, ha HUD vagy DHUD-ra van beállítva a plugin!
c4timer_style < alapértelmezett : "1"> - Visszaszámláló stílus (láthatod őket alább).
c4timer_random < alapértelmezett : „0”> - véletlenszerű színek (ha engedélyezve van, az alábbi két cvars blokkolva lesz).
c4timer_yellow < alapértelmezett : „10”> - hány másodperc múlva változtatja a színét sárgára.
c4timer_red < alapértelmezett : „5”> - hány másodperc múlva változtatja a színét pirosra.
c4timer_xpos < alapértelmezett : "-1,0"> - X helyzetben a képernyőn.
c4timer_ypos < alapértelmezett : "0.80"> - Y helyzetben a képernyőn.
c4timer_type < alapértelmezett : "0"> - Az üzenet típusa (0 = HUD; 1 = DHUD; 2 = center)

Képek: (két nézett lemaradt róla!!!!)

Kép

Stílus 0 : C4: 10
Stílus 1 : [| | | | | - - - - - - - - - -]
Stílus 2 : oooooooooo
Stílus 3 : | >>>> O>>>>>>>>>> |
Stílus 4 : | >>>> C4>>>>>>>>>> |
Stílus 5 : [+ + + + + - - - - - - - - - -]
Stílus 6 : [- - - -> - - - - - - - - - -]

Videó:

https://www.youtube.com/watch?time_continue=36&v=8sY01OhAO5E

Telepítés:

Amxx fájl a plugins mappába, majd a plugin nevét a plugins.ini-be írd be!
Sma-t scripting mappába. (nem szükséges)
Miután a zip-et letöltötted,kicsomagoltad, C4Styles.ini rakd bele a configs mappába!

► Spoiler mutatása

#include <amxmodx>
#include <amxmisc>
#include <csx>

#if AMXX_VERSION_NUM < 183
	#if defined _dhudmessage_included
    #endinput
#endif

#define _dhudmessage_included

#include <amxmodx>

stock __dhud_color;
stock __dhud_x;
stock __dhud_y;
stock __dhud_effect;
stock __dhud_fxtime;
stock __dhud_holdtime;
stock __dhud_fadeintime;
stock __dhud_fadeouttime;
stock __dhud_reliable;

stock set_dhudmessage( red = 0, green = 160, blue = 0, Float:x = -1.0, Float:y = 0.65, effects = 2, Float:fxtime = 6.0, Float:holdtime = 3.0, Float:fadeintime = 0.1, Float:fadeouttime = 1.5, bool:reliable = false )
{
    #define clamp_byte(%1)       ( clamp( %1, 0, 255 ) )
    #define pack_color(%1,%2,%3) ( %3 + ( %2 << 8 ) + ( %1 << 16 ) )

__dhud_color       = pack_color( clamp_byte( red ), clamp_byte( green ), clamp_byte( blue ) );
    __dhud_x           = _:x;
    __dhud_y           = _:y;
    __dhud_effect      = effects;
    __dhud_fxtime      = _:fxtime;
    __dhud_holdtime    = _:holdtime;
    __dhud_fadeintime  = _:fadeintime;
    __dhud_fadeouttime = _:fadeouttime;
    __dhud_reliable    = _:reliable;

return 1;
}

stock show_dhudmessage( index, const message[], any:... )
{
    new buffer[ 128 ];
    new numArguments = numargs();

if( numArguments == 2 )
    {
        send_dhudMessage( index, message );
    }
    else if( index || numArguments == 3 )
    {
        vformat( buffer, charsmax( buffer ), message, 3 );
        send_dhudMessage( index, buffer );
    }
    else
    {
        new playersList[ 32 ], numPlayers;
        get_players( playersList, numPlayers, "ch" );

if( !numPlayers )
        {
            return 0;
        }

new Array:handleArrayML = ArrayCreate();

for( new i = 2, j; i < numArguments; i++ )
        {
            if( getarg( i ) == LANG_PLAYER )
            {
                while( ( buffer[ j ] = getarg( i + 1, j++ ) ) ) {}
                j = 0;

if( GetLangTransKey( buffer ) != TransKey_Bad )
                {
                    ArrayPushCell( handleArrayML, i++ );
                }
            }
        }

new size = ArraySize( handleArrayML );

if( !size )
        {
            vformat( buffer, charsmax( buffer ), message, 3 );
            send_dhudMessage( index, buffer );
        }
        else
        {
            for( new i = 0, j; i < numPlayers; i++ )
            {
                index = playersList[ i ];

for( j = 0; j < size; j++ )
                {
                    setarg( ArrayGetCell( handleArrayML, j ), 0, index );
                }

vformat( buffer, charsmax( buffer ), message, 3 );
                send_dhudMessage( index, buffer );
            }
        }

ArrayDestroy( handleArrayML );
    }

return 1;
}

stock send_dhudMessage( const index, const message[] )
{
    message_begin( __dhud_reliable ? ( index ? MSG_ONE : MSG_ALL ) : ( index ? MSG_ONE_UNRELIABLE : MSG_BROADCAST ), SVC_DIRECTOR, _, index );
    {
        write_byte( strlen( message ) + 31 );
        write_byte( DRC_CMD_MESSAGE );
        write_byte( __dhud_effect );
        write_long( __dhud_color );
        write_long( __dhud_x );
        write_long( __dhud_y );
        write_long( __dhud_fadeintime );
        write_long( __dhud_fadeouttime );
        write_long( __dhud_holdtime );
        write_long( __dhud_fxtime );
        write_string( message );
    }
    message_end();
}

#endif

#define PLUGIN_VERSION "2.1"
#define SYM_NEWLINE "%n%"

enum
{
	RED = 0,
	GREEN,
	BLUE
}

enum
{
	HUD = 0,
	DHUD,
	CENTER
}

enum _:RegisteredCvars
{
	CVAR_STYLE,
	CVAR_RANDOM,
	CVAR_YELLOW,
	CVAR_RED,
	CVAR_XPOS,
	CVAR_YPOS,
	CVAR_TYPE,
	CVAR_ORIGINAL
}

enum _:CvarValues
{
	CV_STYLE,
	bool:CV_RANDOM,
	CV_YELLOW,
	CV_RED,
	Float:CV_XPOS,
	Float:CV_YPOS,
	CV_TYPE,
	CV_ORIGINAL
}

enum _:Styles
{
	Begin[64],
	Add[20],
	End[20],
	ReplaceSymbol[20],
	ReplaceWith[20],
	bool:DoReplace
}

new g_eRegisteredCvars[RegisteredCvars]
new g_eCvarValues[CvarValues]
new g_eTimer[Styles]
new Array:g_aStyles
 
new g_szTimer[128], g_iCurrentTimer, g_iMessage
new bool:g_bPlanted
new g_iStyles
 
public plugin_init()
{
	register_plugin("Style C4 Timer", PLUGIN_VERSION, "OciXCrom")
	register_cvar("StyleC4Timer", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	register_logevent("RemoveTimer", 2, "1=Round_Start")
	register_logevent("RemoveTimer", 2, "1=Round_End")
	register_logevent("RemoveTimer", 2, "1&Restart_Round_")
	g_aStyles = ArrayCreate(Styles)
	
	g_eRegisteredCvars[CVAR_STYLE] 			= 		register_cvar("c4timer_style", "1")
	g_eRegisteredCvars[CVAR_RANDOM]			= 		register_cvar("c4timer_random", "0")
	g_eRegisteredCvars[CVAR_YELLOW] 		= 		register_cvar("c4timer_yellow", "10")
	g_eRegisteredCvars[CVAR_RED] 			= 		register_cvar("c4timer_red", "5")
	g_eRegisteredCvars[CVAR_XPOS] 			= 		register_cvar("c4timer_xpos", "-1.0")
	g_eRegisteredCvars[CVAR_YPOS] 			= 		register_cvar("c4timer_ypos", "0.80")
	g_eRegisteredCvars[CVAR_TYPE] 			= 		register_cvar("c4timer_type", "0")
	g_eRegisteredCvars[CVAR_ORIGINAL]		= 		get_cvar_pointer("mp_c4timer")
	
	g_iMessage = CreateHudSyncObj()
	ReadFile()
}

public plugin_end()
	ArrayDestroy(g_aStyles)

ReadFile()
{
	new szConfigsName[256], szFilename[256]
	get_configsdir(szConfigsName, charsmax(szConfigsName))
	formatex(szFilename, charsmax(szFilename), "%s/C4Styles.ini", szConfigsName)
	new iFilePointer = fopen(szFilename, "rt")
	
	if(iFilePointer)
	{
		new szData[96], szKey[32], szValue[64]
		new eStyle[Styles]
		
		while(!feof(iFilePointer))
		{
			fgets(iFilePointer, szData, charsmax(szData))
			trim(szData)
			
			switch(szData[0])
			{
				case EOS, ';': continue
				case '{': g_iStyles++
				case '}':
				{
					eStyle[DoReplace] = !is_blank(eStyle[Add])
					ArrayPushArray(g_aStyles, eStyle)
					
					eStyle[Begin][0] = EOS
					eStyle[Add][0] = EOS
					eStyle[End][0] = EOS
					eStyle[ReplaceSymbol][0] = EOS
					eStyle[ReplaceWith][0] = EOS
				}
				default:
				{
					replace_all(szData, charsmax(szData), SYM_NEWLINE, "^n")
					strtok(szData, szKey, charsmax(szKey), szValue, charsmax(szValue), ':')
					trim(szKey); trim(szValue); remove_quotes(szValue)
					
					if(equali(szKey, "begin"))
						copy(eStyle[Begin], charsmax(eStyle[Begin]), szValue)
					else if(equali(szKey, "add"))
						copy(eStyle[Add], charsmax(eStyle[Add]), szValue)
					else if(equali(szKey, "end"))
						copy(eStyle[End], charsmax(eStyle[End]), szValue)
					else if(equali(szKey, "replace symbol"))
						copy(eStyle[ReplaceSymbol], charsmax(eStyle[ReplaceSymbol]), szValue)
					else if(equali(szKey, "replace with"))
						copy(eStyle[ReplaceWith], charsmax(eStyle[ReplaceWith]), szValue)
				}
			}
		}
		
		fclose(iFilePointer)
	}
}
 
public bomb_planted()
{
	CheckCvars()
	g_bPlanted = true
	g_iCurrentTimer = g_eCvarValues[CV_ORIGINAL]
	FormTimer()
	DisplayTimer()
}
 
public bomb_defused()
	RemoveTimer()
 
public bomb_explode()
	RemoveTimer()

CheckCvars()
{
	g_eCvarValues[CV_STYLE] 		= 		clamp(get_pcvar_num(g_eRegisteredCvars[CVAR_STYLE]), 0, g_iStyles)
	g_eCvarValues[CV_RANDOM] 		=	 	bool:get_pcvar_num(g_eRegisteredCvars[CVAR_RANDOM])
	g_eCvarValues[CV_YELLOW] 		= 		get_pcvar_num(g_eRegisteredCvars[CVAR_YELLOW])
	g_eCvarValues[CV_RED] 			= 		get_pcvar_num(g_eRegisteredCvars[CVAR_RED])
	g_eCvarValues[CV_XPOS] 			=		_:get_pcvar_float(g_eRegisteredCvars[CVAR_XPOS])
	g_eCvarValues[CV_YPOS] 			= 		_:get_pcvar_float(g_eRegisteredCvars[CVAR_YPOS])
	g_eCvarValues[CV_TYPE] 			= 		get_pcvar_num(g_eRegisteredCvars[CVAR_TYPE])
	g_eCvarValues[CV_ORIGINAL] 		= 		get_pcvar_num(g_eRegisteredCvars[CVAR_ORIGINAL])
	
	ArrayGetArray(g_aStyles, g_eCvarValues[CV_STYLE], g_eTimer)
}

FormTimer()
{
	ClearTimer()
	
	if(g_eTimer[DoReplace])
	{
		AddToTimer(g_eTimer[Begin])
		
		for(new i; i < g_iCurrentTimer; i++)
			AddToTimer(g_eTimer[Add])
			
		AddToTimer(g_eTimer[End])
	}
	else
		formatex(g_szTimer, charsmax(g_szTimer), g_eTimer[Begin], g_iCurrentTimer)
}

UpdateTimer()
{
	if(g_eTimer[DoReplace])
		ReplaceInTimer(g_eTimer[ReplaceSymbol], g_eTimer[ReplaceWith])
	else
		formatex(g_szTimer, charsmax(g_szTimer), g_eTimer[Begin], g_iCurrentTimer)
}

ClearTimer()
	g_szTimer[0] = EOS
	
AddToTimer(const szString[])
	add(g_szTimer, charsmax(g_szTimer), szString)
	
ReplaceInTimer(const szString[], const szString2[])
	replace(g_szTimer, charsmax(g_szTimer), szString, szString2)
	
public DisplayTimer()
{   
	if(g_bPlanted)
	{	
		if(g_iCurrentTimer >= 0)
		{			
			switch(g_eCvarValues[CV_TYPE])
			{
				case HUD:
				{
					new iColor[3]; GetColors(iColor)
					set_hudmessage(iColor[0], iColor[1], iColor[2], g_eCvarValues[CV_XPOS], g_eCvarValues[CV_YPOS], 0, 1.0, 1.0, 0.01, 0.01)
					ShowSyncHudMsg(0, g_iMessage, g_szTimer, g_iCurrentTimer)
				}
				case DHUD:
				{
					new iColor[3]; GetColors(iColor)
					set_dhudmessage(iColor[0], iColor[1], iColor[2], g_eCvarValues[CV_XPOS], g_eCvarValues[CV_YPOS], 0, 1.0, 1.0, 0.01, 0.01)
					show_dhudmessage(0, g_szTimer, g_iCurrentTimer)
				}
				case CENTER: client_print(0, print_center, g_szTimer, g_iCurrentTimer)
			}
			
			g_iCurrentTimer--
			
			UpdateTimer()
			set_task(1.0, "DisplayTimer")
		}
	}
}

public RemoveTimer()
{
	if(g_bPlanted)
	{
		g_bPlanted = false
		g_iCurrentTimer = -1
	}
}

GetColors(iColor[3])
{
	if(g_eCvarValues[CV_RANDOM])
	{
		for(new i; i < BLUE; i++)
			iColor[i] = random(256)
	}
	else
	{
		if(g_iCurrentTimer > g_eCvarValues[CV_YELLOW]) iColor[GREEN] = 100
		else if(g_iCurrentTimer > g_eCvarValues[CV_RED])
		{
			iColor[RED] = 255
			iColor[GREEN] = 255
		}
		else iColor[RED] = 255
	}
}

bool:is_blank(szString[])
	return szString[0] == EOS

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

Szerző:	*GrafitY* [ 2017.03.27. 17:23 ]
Hozzászólás témája:	Re: C4 stílusos visszaszámláló
viewtopic.php?f=101&t=25478 Mintha már láttam volna fórumon elfogadva.

Szerző:	6almasok [ 2017.03.27. 17:50 ]
Hozzászólás témája:	Re: C4 stílusos visszaszámláló
GrafitY írta: https://hlmod.hu/viewtopic.php?f=101&t=25478 Mintha már láttam volna fórumon elfogadva. Az érzés amikor direkt nem nézed meg hogy fent van-e az adott plugin mivel egy nagyobb rangú ember töltötte fel... felbecsülhetetlen... Viszont ha már megtörtént szerintem nem kérdés hogy melyik marad

Szerző:	kengurumancs [ 2017.03.27. 18:15 ]
Hozzászólás témája:	Re: C4 stílusos visszaszámláló
Ezt jól benéztem.

Szerző:	*GrafitY* [ 2017.03.27. 19:13 ]
Hozzászólás témája:	Re: C4 stílusos visszaszámláló
6almasok írta: Az érzés amikor direkt nem nézed meg hogy fent van-e az adott plugin mivel egy nagyobb rangú ember töltötte fel... felbecsülhetetlen... Viszont ha már megtörtént szerintem nem kérdés hogy melyik marad Írtam, hogy azt hiszem már láttam fent, minek kell offolni? Egy hangya fasznyit nem érdekel a nagyobb rangú ember feltöltése. Csak mert nekem nem "kezdő", vagy mi a fene a rangom, akkor az alacsonyabb rangúak által már feltöltött plugint bármikor feltöltöm, mert nekem nagyobb a rangom Nem kérdés hogy melyik maradna .. Értelmetlen volt idézned, Nagyúr

Szerző:	6almasok [ 2017.03.27. 21:07 ]
Hozzászólás témája:	Re: C4 stílusos visszaszámláló
GrafitY írta: 6almasok írta: Az érzés amikor direkt nem nézed meg hogy fent van-e az adott plugin mivel egy nagyobb rangú ember töltötte fel... felbecsülhetetlen... Viszont ha már megtörtént szerintem nem kérdés hogy melyik marad Írtam, hogy azt hiszem már láttam fent, minek kell offolni? Egy hangya fasznyit nem érdekel a nagyobb rangú ember feltöltése. Csak mert nekem nem "kezdő", vagy mi a fene a rangom, akkor az alacsonyabb rangúak által már feltöltött plugint bármikor feltöltöm, mert nekem nagyobb a rangom Nem kérdés hogy melyik maradna .. Értelmetlen volt idézned, Nagyúr Milyen offról beszélsz? Szerk: a nem kérdés hogy melyik marad alatt a formalításra gondoltam (Hasonlítsd össze a kettő leírást). Nem hittem hogy lesz olyan akinek nem fog leesni

Szerző:	Maxi [ 2017.03.27. 21:34 ]
Hozzászólás témája:	Re: C4 stílusos visszaszámláló
Másikat töröltem. Kenguru, köszi a plusz munkát xddd tudod hogy szeretlek

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/