hlmod.hu :: [Grenade Timer] Gránát robbanási idő beállítás

hlmod.hu https://hlmod.hu/

[Grenade Timer] Gránát robbanási idő beállítás https://hlmod.hu/viewtopic.php?f=101&t=28477	Oldal: 1 / 1

Szerző:

Pika [ 2017.11.27. 14:46 ]

Hozzászólás témája:

[Grenade Timer] Gránát robbanási idő beállítás

Plugin Neve:	[Grenade Timer] Gránát robbanási idő beállítás	Plugint készitette:	BboYGruN
Játék:	Counter-Strike	Kategória:	Játékmenet
Eredeti link:	Megnézem	Jóváhagyó:	6almasok

Leírás:
A plugin segítségével, a gránát eldobása után a beállított idő után robban fel.

Cvarok
Grenade_TIME_HE : ( Alapértelmezett: 3.0 ) // HEGRENADE
Grenade_TIME_FL : ( Alapértelmezett: 2.0 ) // FLASHBANG
Grenade_TIME_SK : ( Alapértelmezett: 4.0 ) // SMOKEGRENADE

Megjegyzés: Ha 0-ra állítod, akkor nem állítja át a robbanási időt.
Megjegyzés:Miután álítottál a cvaron, indítsd újra a kört különben nem fogja lecserélni.

#include < amxmodx > 
#include < fakemeta > 
#include < hamsandwich >

#define VERSION "2.0"

const m_fBombStatus = 	96;
const m_usEvent     = 	114;
    
const fBombPlanted = 	1 << 8;
const fExploEvent  = 	1 << 0;
const fSmokeEvent  = 	1 << 1;

new pCvar_TimeHe, pCvar_TimeFlash, pCvar_TimeSmoke;
new HamHook: SmokeThink;

public plugin_init( )  
{ 
	register_plugin("Grenade explosion TIME",VERSION,"BboY GruN");
	
	register_cvar( "Grenade_Explosion_Time",VERSION,FCVAR_SERVER | FCVAR_SPONLY ); 
	set_cvar_string( "Grenade_Explosion_Time", VERSION ); 
	
	pCvar_TimeHe =		register_cvar( "Grenade_TIME_HE", "3.0" ); 
	pCvar_TimeFlash =	register_cvar( "Grenade_TIME_FL", "2.0" );
	pCvar_TimeSmoke =	register_cvar( "Grenade_TIME_SK", "4.0" ); 
	
	register_event( "HLTV", "roundBegin", "a", "1=0", "2=0" );
	register_forward( FM_SetModel,  "Fw_NadeModel", 1 );
	
	if( get_pcvar_float( pCvar_TimeSmoke ) > 0.0 )
	{
		SmokeThink = RegisterHam( Ham_Think, "grenade", "Fw_NadeThink" );
	}
	
	roundBegin( );
}

public roundBegin( )
{
	if( get_pcvar_float( pCvar_TimeSmoke ) <= 0.0 )
	{
		if( SmokeThink )
		{
			DisableHamForward( SmokeThink );
		}
	}
	else
	{
		if( SmokeThink )
		{
			EnableHamForward( SmokeThink );
		}
		else
		{
			SmokeThink = RegisterHam( Ham_Think, "grenade", "Fw_NadeThink" ); 
		}
	}
}

public Fw_NadeModel( const nade, const NadeModel[ ] ) 
{ 
	if( pev_valid( nade ) ) 
	{ 
		static nade_ID;
		nade_ID = grenade_type( nade, 1 );
		
		if( nade_ID ) // nem HE - FLASH - SMOKE gr�n�t
		{ 
			new Float: nadeCvar;
			
			switch( nade_ID )
			{
				case CSW_HEGRENADE:
				{
					nadeCvar = get_pcvar_float( pCvar_TimeHe );
					
					if( nadeCvar )
					{
						set_pev( nade, pev_dmgtime, get_gametime( ) + nadeCvar ) 
					}
				}
				case CSW_FLASHBANG:
				{
					nadeCvar = get_pcvar_float( pCvar_TimeFlash );
					
					if( nadeCvar )
					{
						set_pev( nade, pev_dmgtime, get_gametime( ) + nadeCvar ) 
					}
				}
				case CSW_SMOKEGRENADE: 
				{
					nadeCvar = get_pcvar_float( pCvar_TimeSmoke );
					
					if( nadeCvar )
					{
						set_pev( nade, pev_dmgtime, get_gametime( ) + nadeCvar ) 
					}
				}
			}
		}
	}
}

public Fw_NadeThink( const nade ) 
{ 
	if( pev_valid( nade ) && grenade_type( nade ) == CSW_SMOKEGRENADE ) 
	{ 
		set_pev( nade, pev_flags, FL_ONGROUND ) 
	}
} 
stock grenade_type( const index, const checkClassName = 0 )  
{ 
	static classname[ 9 ] 
	
	if( checkClassName ) 
	{ 
		pev( index, pev_classname, classname, 8 ) 
		if ( !equal( classname, "grenade") ) 
		{ 
			return 0;
		} 
	} 
	
	if( get_pdata_int( index, m_fBombStatus ) & fBombPlanted )
	{
		return 0;
	}
	
	static bits; bits = get_pdata_int( index, m_usEvent ) 
	
	if ( bits & fExploEvent ) 
	{ 
		return CSW_HEGRENADE;
	} 
	
	else if( !bits ) 
	{ 
		return CSW_FLASHBANG;
	} 
	
	else if( bits & fSmokeEvent ) 
	{ 
		return CSW_SMOKEGRENADE;
	} 
	
	return 0;
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1038\\ f0\\ fs16 \n\\ par }
*/

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	Prohacker171 [ 2018.11.04. 12:11 ]
Hozzászólás témája:	Re: [Grenade Timer] Gránát robbanási idő beállítás
Szia, a plugin nagyon tetszik de nálam van egy probléma ha eldobom a bombát egyből felroban nem vár pl 3-másodpercet eldobod és robban is egyből.

Szerző:

Heist [ 2018.11.04. 13:11 ]

Hozzászólás témája:

Re: [Grenade Timer] Gránát robbanási idő beállítás

Prohacker171 írta:

Szia, a plugin nagyon tetszik de nálam van egy probléma ha eldobom a bombát egyből felroban nem vár pl 3-másodpercet eldobod és robban is egyből.

Próbáld.

Csatolmányok:

granat_dobas.sma [2.97 KiB]
Letöltve 107 alkalommal.

Szerző:	Prohacker171 [ 2018.11.04. 14:51 ]
Hozzászólás témája:	Re: [Grenade Timer] Gránát robbanási idő beállítás
Heist írta: Prohacker171 írta: Szia, a plugin nagyon tetszik de nálam van egy probléma ha eldobom a bombát egyből felroban nem vár pl 3-másodpercet eldobod és robban is egyből. Próbáld. Most már jó de sokára robban fel.

Szerző:	Heist [ 2018.11.04. 18:02 ]
Hozzászólás témája:	Re: [Grenade Timer] Gránát robbanási idő beállítás
Cvaral tudod állítani. Grenade_TIME_HE : ( Alapértelmezett: 3.0 ) // HEGRENADE Grenade_TIME_FL : ( Alapértelmezett: 2.0 ) // FLASHBANG Grenade_TIME_SK : ( Alapértelmezett: 4.0 ) // SMOKEGRENADE

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/