hlmod.hu ::[ReApi] Bomba Elvétel

hlmod.hu https://hlmod.hu/

[ReApi] Bomba Elvétel https://hlmod.hu/viewtopic.php?f=101&t=28480	Oldal: 1 / 1

Szerző:

Jucika [2017.11.28. 10:00 ]

Hozzászólás témája:

[ReApi] Bomba Elvétel

Plugin Neve:	[ReApi] Bomba Elvétel	Plugint készitette:	Vaqtincha
Játék:	Counter-Strike	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	6almasok

Bomba Elvétel

By Vaqtincha

Leírás:
A plugin segítségével el tudjuk venni a játékosoktól a bombát.
Alapértelmezett billentyű: E

Telepítés:
Amxx fájl a plugins mappába, majd a plugin nevét a plugins.ini-be írd be!
Sma-t scripting mappába. (nem szükséges)

#include <amxmodx>
#include <hamsandwich>
#include <reapi>

#define PL_VERSION 				"0.0.1b"

#define PLAYER_USE_RADIUS		75

new g_iHudSync

public plugin_init()
{
	register_plugin("Bomba Elvetel", PL_VERSION, "Vaqtincha")

if(bool:get_member_game(m_bMapHasBombTarget))
	{
		RegisterHam(Ham_ObjectCaps, "bot", "CBasePlayer_ObjectCaps", .Post = false)
		RegisterHam(Ham_ObjectCaps, "player", "CBasePlayer_ObjectCaps", .Post = false)
		RegisterHam(Ham_Use, "bot", "CBasePlayer_PlayerUse", .Post = true)
		RegisterHam(Ham_Use, "player", "CBasePlayer_PlayerUse", .Post = true)

register_event("StatusValue", "Event_StatusValue_Show", "be", "1=3"/*HEALTH*/, "2>0")
		register_event("StatusValue", "Event_StatusValue_Hide", "b", "1=1", "2=0")
		
		g_iHudSync = CreateHudSyncObj()
	}
	else {
		pause("ad") 
	}
}

public CBasePlayer_ObjectCaps(const pPlayer)
{
	SetHamReturnInteger(FCAP_ONOFF_USE)
	return HAM_SUPERCEDE
}

public CBasePlayer_PlayerUse(const pPlayer, const pActivator, const pCaller, const use_type, const Float:value)
{
	if(value == 0.0 || !is_user_alive(pActivator) || get_member(pActivator, m_iTeam) != TEAM_TERRORIST)
		return

if(is_user_alive(pPlayer) && CanUseThisPlayer(pPlayer)) {
		rg_transfer_c4(pPlayer, pActivator)
	}
}

public Event_StatusValue_Hide(const pPlayer) {
	ClearSyncHud(pPlayer, g_iHudSync)
}

public Event_StatusValue_Show(const pPlayer)
{
	if(get_member(pPlayer, m_iTeam) != TEAM_TERRORIST)
		return

new pTarget, iBody
	get_user_aiming(pPlayer, pTarget, iBody, PLAYER_USE_RADIUS)

if(pTarget > 0 && iBody > 0 && is_user_alive(pTarget) && CanUseThisPlayer(pTarget))
	{
		set_hudmessage(INFO_HUD_COLOR, INFO_HUD_POSITION, .holdtime = 1.5, .fadeintime = 0.5, .fadeouttime = 0.5)
		ShowSyncHudMsg(pPlayer, g_iHudSync, "A bomba elvételéhez nyomd az ^"E^" betűt!")
	}
	else {
		ClearSyncHud(pPlayer, g_iHudSync)
	}
}

stock bool:CanUseThisPlayer(pPlayer)
{
	if(!get_member(pPlayer, m_bHasC4))
		return false

#if defined BOT_WAIT_TIME_IGNORE
	if(is_user_bot(pPlayer))
		return true
#endif

return bool:((get_gametime() - Float:get_member(pPlayer, m_fLastMovement)) > PLAYER_MAX_WAIT_TIME.0)
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Oldal: 1 / 1	Minden időpont UTC+01:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/