hlmod.hu ::[ReApi] Játékos Modellek

hlmod.hu https://hlmod.hu/

[ReApi] Játékos Modellek https://hlmod.hu/viewtopic.php?f=101&t=28487	Oldal: 1 / 1

Szerző: Jucika [2017.11.28. 19:20 ]

Hozzászólás témája: [ReApi] Játékos Modellek

Plugin Neve:	[ReApi] Játékos Modellek	Plugint készitette:	Vaqtincha
Játék:	Counter-Strike	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	6almasok

[ReApi] Játékos Modellek

By Vaqtincha

Leírás:
A plugin segítségével játékos kinézetet tudtok adni jogokra.

Beállítások

Kód: [Egész kijelölése] [Mutatás/Eltüntetés]

// a mappának és a model névnek, megkell egyeznie.
 
// "Terrorista Model" "Counter-Terrorista Model" "Jog"   // így lehet még modelt hozzáírni.
 
// Jelenleg ezek vannak:
{ "snowleet", "lolgign", ADMIN_BAN },
{ "viptt", "vipct", ADMIN_LEVEL_H },
{ "bomjtt", "bomjct", ADMIN_ALL },

GeSHi © Codebox Plus

Telepítés
Fordításhoz ReAPI.inc szükséges!

Amxx fájl a plugins mappába, majd a plugin nevét a plugins.ini-be írd be!
Sma-t scripting mappába. (nem szükséges)

Kompatibilis:
Amx Mod X 1.8.2(Re) Amx Mod X 1.8.3-dev

U.i.: Modelleket nem csatoltam viszont a példák benne vannak a pluginba.

#include <amxmodx>
#include <reapi>
 
enum player_models { szTTModel[64], szCTModel[64], iFlag }
 
#define SET_MODELINDEX
#define MAX_MODEL_PATH_LEN     128
 
/// FORMAT: "Terrorist Model" "Counter-Terrorist Model"  "Access Flag"
 
new const g_eModelsData[][player_models] =
{
    { "snowleet", "lolgign", ADMIN_LEVEL_B },
    { "viptt", "vipct", ADMIN_LEVEL_H },
    { "bomjtt", "bomjct", ADMIN_ALL },
 
    {"", "", -1}
}
 
#define IsValidArrayIndex(%1)         (0 <= %1 <= sizeof(g_eModelsData)-1)
 
#if defined SET_MODELINDEX
    new g_iTTModelIndex[sizeof(g_eModelsData)], g_iCTModelIndex[sizeof(g_eModelsData)]
#endif
 
 
public plugin_precache()
{
    if(g_eModelsData[0][iFlag] == -1)
    {
        set_fail_state("Array g_eModelsData are empty!")
        return
    }
 
    for(new i = 0; i < sizeof(g_eModelsData)-1; i++)
    {
    #if defined SET_MODELINDEX
        g_iTTModelIndex[i] = precache_player_model(g_eModelsData[i][szTTModel])
        g_iCTModelIndex[i] = precache_player_model(g_eModelsData[i][szCTModel])
    #else
        precache_player_model(g_eModelsData[i][szTTModel])
        precache_player_model(g_eModelsData[i][szCTModel])
    #endif
    }
}
 
public plugin_init()
{
    register_plugin("[ReAPI] Admin Models", "0.0.2", "Vaqtincha")
 
    RegisterHookChain(RG_CBasePlayer_SetClientUserInfoModel, "SetClientUserInfoModel", .post = false)
}
 
 
public SetClientUserInfoModel(const pPlayer, infobuffer[], szNewModel[])
{
    new iArrayIndex = get_user_model_by_flag(get_user_flags(pPlayer))
 
    if(!IsValidArrayIndex(iArrayIndex))
        return HC_CONTINUE
 
    switch(get_member(pPlayer, m_iTeam))
    {
        case TEAM_TERRORIST: {
        #if defined SET_MODELINDEX
            set_member(pPlayer, m_modelIndexPlayer, g_iTTModelIndex[iArrayIndex])
        #endif
            SetHookChainArg(3, ATYPE_STRING, g_eModelsData[iArrayIndex][szTTModel])
        }
        case TEAM_CT: {
        #if defined SET_MODELINDEX
            set_member(pPlayer, m_modelIndexPlayer, g_iCTModelIndex[iArrayIndex])
        #endif
            SetHookChainArg(3, ATYPE_STRING, g_eModelsData[iArrayIndex][szCTModel])
        }
        default: return HC_CONTINUE
    }
 
    return HC_CONTINUE
}
 
 
get_user_model_by_flag(const iUserFlags)
{
    const INVALID_INDEX = -1
 
    for(new i = 0; i < sizeof(g_eModelsData)-1; i++)
    {
        if(iUserFlags & g_eModelsData[i][iFlag] || g_eModelsData[i][iFlag] == ADMIN_ALL)
            return i
    }
 
    return INVALID_INDEX // non admin player
}
 
precache_player_model(const szModel[])
{
    new szFileToPrecache[MAX_MODEL_PATH_LEN], szErrMsg[MAX_MODEL_PATH_LEN + 64]
 
    formatex(szFileToPrecache, charsmax(szFileToPrecache), "models/player/%s/%s.mdl", szModel, szModel)
 
    if(!file_exists(szFileToPrecache))
    {
        formatex(szErrMsg, charsmax(szErrMsg), "[Admin Models] ERROR: Model ^"%s^" not found!", szFileToPrecache)
        set_fail_state(szErrMsg)
        return 0
    }
 
    return precache_model(szFileToPrecache)
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	Pika [2017.11.28. 19:31 ]
Hozzászólás témája:	Re: [ReApi] Admin Ruházat
Jucika írta: *Admin Ruházat* *By Vaqtincha* *Leírás:* A plugin segítségével játékos kinézetet tudok adni jogokra. Beállítások Kód: [Egész kijelölése] [Mutatás/Eltüntetés] `"models/player/%s/%s.mdl" // a mappának és a model névnek, meg kell egyeznie. "Terrorist Model" "Counter-Terrorist Model" "Jog" // így lehet még modelt hozzáírni. Jelenleg ezek vannak: { "snowleet", "lolgign", ADMIN_BAN }, { "viptt", "vipct", ADMIN_LEVEL_H }, { "bomjtt", "bomjct", ADMIN_ALL },` GeSHi © Codebox Plus *Telepítés* Fordításhoz ReAPI.inc szükséges! Amxx fájl a plugins mappába, majd a plugin nevét a plugins.ini-be írd be! Sma-t scripting mappába. (nem szükséges) *Kompatibilis:* Amx Mod X 1.8.2(Re) Amx Mod X 1.8.3-dev Belejavíthatnék, de nem fogok. 1-2 helyesírási hibát javítsd kérlek.

Szerző:	Jucika [2017.11.28. 20:34 ]
Hozzászólás témája:	Re: [ReApi] Admin Ruházat
Pika írta: Jucika írta: *Admin Ruházat* *By Vaqtincha* *Leírás:* A plugin segítségével játékos kinézetet tudok adni jogokra. Beállítások Kód: [Egész kijelölése] [Mutatás/Eltüntetés] `"models/player/%s/%s.mdl" // a mappának és a model névnek, meg kell egyeznie. "Terrorist Model" "Counter-Terrorist Model" "Jog" // így lehet még modelt hozzáírni. Jelenleg ezek vannak: { "snowleet", "lolgign", ADMIN_BAN }, { "viptt", "vipct", ADMIN_LEVEL_H }, { "bomjtt", "bomjct", ADMIN_ALL },` GeSHi © Codebox Plus *Telepítés* Fordításhoz ReAPI.inc szükséges! Amxx fájl a plugins mappába, majd a plugin nevét a plugins.ini-be írd be! Sma-t scripting mappába. (nem szükséges) *Kompatibilis:* Amx Mod X 1.8.2(Re) Amx Mod X 1.8.3-dev Belejavíthatnék, de nem fogok. 1-2 helyesírási hibát javítsd kérlek. Megkernek moderatort vagy jovahagyot hogy javitsa a heljes irast mivel nem tudom telorol a gepem sajnos elromlot.. Ha megjavitom vagy vasarolok javitom

Szerző:	siska15 [2018.03.19. 19:06 ]
Hozzászólás témája:	Re: [ReApi] Játékos Modellek
És hogy lehet bele írni hogy a VIP-nek legyen skine illetve az adminak mind2 oldalon modelt?

Szerző:	theglorious [2018.03.19. 19:31 ]
Hozzászólás témája:	Re: [ReApi] Játékos Modellek
siska15 írta: És hogy lehet bele írni hogy a VIP-nek legyen skine illetve az adminak mind2 oldalon modelt? Le van írva (a beállítás rész)

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/