[CSO] Flying Guillotine

Megválaszolatlan témák | Aktív témák

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Navigáció

Főmenü

Kezdőlap

Fórum

Kapcsolat

Képfeltöltő Amx Mod X

Letöltések

Pluginok

Fordító (Compiler) SourceMod

Letöltések

Pluginok

Fordító (Compiler) EventScript

Letöltések

Magyar scriptek Pályák

Half-Life

Half-Life 2

Jelenlévő felhasználók

Jelenleg 154 felhasználó van jelen :: 1 regisztrált, 0 rejtett és 153 vendég

A legtöbb felhasználó (1565 fő) 2020.11.21. 11:26-kor tartózkodott itt.

Regisztrált felhasználók: Bing [Bot] az elmúlt 5 percben aktív felhasználók alapján

[ Ki van itt ]

Utoljára aktív

Kereső

[CSO] Flying Guillotine

Moderátor: Fórum Moderátor

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 1

[ 2 hozzászólás ]

Nyomtatóbarát verzió | Barát értesítése e-mailben

Előző téma | Következő téma

Szerző

Üzenet

Dooz

Hozzászólás témája: [CSO] Flying Guillotine

HozzászólásElküldve: 2018.06.05. 22:53

Offline

Csatlakozott: 2016.02.10. 12:46
Hozzászólások: 429
Megköszönt másnak: 61 alkalommal
Megköszönték neki: 157 alkalommal

Plugin Neve:	[CSO] Flying Guillotine	Plugint készitette:	Dias Pendragon
Játék:	Counter-Strike	Kategória:	Technikai/Fejlesztő
Eredeti link:	Nincs megadva	Jóváhagyó:	JohanCorn

Flying Guillotine

Kép

Leírás:
A Flying Guillotine egy fegyver, amelyet zombiek megölésére fejlesztettek ki.
Egy lövedéket lő ki, amely az ellenség testén átmegy, majd bizonyos távolság után visszatér a tulajdonosához.
Ha a lövedék nem tud visszatéri (akadály van elötte), akkor megsemmisül.
Különleges képessége abban rejlik, hogy ha az ellenség fejét eltalálja a lövedék, akkor ez bizonyos ideig folyamatosan követni, illetve sebezni fogja.

Használat:
A Flying Guillotine-t a /get_guillotine paranccsal tudod előhívni, amelyet a chat-be kell beírni.

Beállítások:
guillotine_damage 35 //A fegyver alap sebzése.
guillotine_ammo 10 //Lövedékek mennyisége.
guillotine_max_radius 700.0 //Maximális távolság, amelyre egy lövedék elrepülhet.
guillotine_fly_speed 1000.0 //A lövedék sebessége.
guillotine_knockback 300.0 //A lövedék visszaütése.
guillotine_damage_delay 0.2 //Az időtartam, amennyi el kell teljen 2 sebzés között, miután eltalálta az ellenség fejét a lövedék.
guillotine_hittime 5.0 //Az időtartam, amennyi ideig a lövedék követni, illetve sebezni fogja az ellenséget
guillotine_unlimited_ammo 0 //Végtelen lövedék [0 - Kikapcsolva | 1 - Bekapcsolva]

Egyéb tudnivalók:
Ha Zombie Plague 5.0 módhoz szeretnéd használni akkor töröld 10. sorban a "//" jelet a #define USE_FOR_ZOMBIE elejéröl.
Ezt követően nem fog müködni a /get_guillotine parancs.
A fegyver árát a 83. sorban tudod módosítani: #define Item_Price 20

Telepítés:
A .zip tartalmát csak húzd bele egyszerűen a cstrike mappába.

Fontos!
Ha bármiféle problémát tapasztalsz a fegyver használata során, akkor megkérlek jelezd azt a komment szekcióba vagy privát üzenetbe.

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <fakemeta_util>
#include <hamsandwich>
#include <cstrike>
#include <xs>
#include <fun>

#define USE_FOR_ZOMBIE 
//Ha Zombie Plague módhoz szeretnéd használni akkor töröld a "//" jelet a "#define" elejéröl

#if defined USE_FOR_ZOMBIE
#if defined _zp50_items_included
  #endinput
#endif
#define _zp50_items_included

#if defined _zp50_core_included
  #endinput
#endif
#define _zp50_core_included

#if defined _zp50_core_const_included
  #endinput
#endif
#define _zp50_core_const_included

#define ZP_VERSION_STR_LONG "5.0.5"
#define ZP_VERSION_STRING "5.0.5"
#define ZP_VERSION_NUM 505

#if AMXX_VERSION_NUM >= 175
	#pragma reqlib zp50_core
	#if !defined AMXMODX_NOAUTOLOAD
		#pragma loadlib zp50_core
	#endif
#else
	#pragma library zp50_core
#endif

native zp_core_is_zombie(id)
native zp_core_is_first_zombie(id)
native zp_core_is_last_zombie(id)
native zp_core_is_last_human(id)
native zp_core_get_zombie_count()
native zp_core_get_human_count()
native zp_core_infect(id, attacker = 0)
native zp_core_cure(id, attacker = 0)
native zp_core_force_infect(id)
native zp_core_force_cure(id)
native zp_core_respawn_as_zombie(id, zombie = true)
forward zp_fw_core_infect(id, attacker)
forward zp_fw_core_infect_post(id, attacker)
forward zp_fw_core_cure(id, attacker)
forward zp_fw_core_cure_post(id, attacker)
forward zp_fw_core_infect_pre(id, attacker)
forward zp_fw_core_cure_pre(id, attacker)
forward zp_fw_core_last_zombie(id)
forward zp_fw_core_last_human(id)
forward zp_fw_core_spawn_post(id)

#if defined _zp50_items_const_included
  #endinput
#endif
#define _zp50_items_const_included

#define ZP_INVALID_ITEM -1

#define ZP_ITEM_AVAILABLE 0
#define ZP_ITEM_NOT_AVAILABLE 1
#define ZP_ITEM_DONT_SHOW 2

#if AMXX_VERSION_NUM >= 175
	#pragma reqlib zp50_items
	#if !defined AMXMODX_NOAUTOLOAD
		#pragma loadlib zp50_items
	#endif
#else
	#pragma library zp50_items
#endif

native zp_items_register(const name[], cost)
native zp_items_get_id(const real_name[])
native zp_items_get_name(itemid, name[], len)
native zp_items_get_real_name(itemid, real_name[], len)
native zp_items_get_cost(itemid)
native zp_items_show_menu(id)
native zp_items_force_buy(id, itemid, ignorecost = false)
native zp_items_menu_text_add(const text[])
forward zp_fw_items_select_pre(id, itemid, ignorecost)
forward zp_fw_items_select_post(id, itemid, ignorecost)

#if defined _zp50_class_survivor_included
  #endinput
#endif
#define _zp50_class_survivor_included

#if defined _zp50_class_human_included
  #endinput
#endif
#define _zp50_class_human_included

#if defined _zp50_core_included
  #endinput
#endif
#define _zp50_core_included

#if defined _zp50_core_const_included
  #endinput
#endif
#define _zp50_core_const_included

#define ZP_VERSION_STR_LONG "5.0.5"
#define ZP_VERSION_STRING "5.0.5"
#define ZP_VERSION_NUM 505

#if AMXX_VERSION_NUM >= 175
	#pragma reqlib zp50_core
	#if !defined AMXMODX_NOAUTOLOAD
		#pragma loadlib zp50_core
	#endif
#else
	#pragma library zp50_core
#endif

#if defined _zp50_class_human_const_inc
  #endinput
#endif
#define _zp50_class_human_const_inc

#define ZP_INVALID_HUMAN_CLASS -1
#define ZP_CLASS_AVAILABLE 0
#define ZP_CLASS_NOT_AVAILABLE 1
#define ZP_CLASS_DONT_SHOW 2

#if AMXX_VERSION_NUM >= 175
	#pragma reqlib zp50_class_human
	#if !defined AMXMODX_NOAUTOLOAD
		#pragma loadlib zp50_class_human
	#endif
#else
	#pragma library zp50_class_human
#endif

native zp_class_human_get_current(id)
native zp_class_human_get_next(id)
native zp_class_human_set_next(id, classid)
native zp_class_human_register(const name[], const description[], health, Float:speed, Float:gravity)
native zp_class_human_register_model(classid, const model[])
native zp_class_human_get_id(const real_name[])
native zp_class_human_get_name(classid, name[], len)
native zp_class_human_get_real_name(classid, real_name[], len)
native zp_class_human_get_desc(classid, description[], len)
native zp_class_human_get_count()
native zp_class_human_show_menu(id)
native zp_class_human_menu_text_add(const text[])
forward zp_fw_class_human_select_pre(id, classid)

#if AMXX_VERSION_NUM >= 175
	#pragma reqlib zp50_class_survivor
	#if !defined AMXMODX_NOAUTOLOAD
		#pragma loadlib zp50_class_survivor
	#endif
#else
	#pragma library zp50_class_survivor
#endif

native zp_class_survivor_get(id)
native zp_class_survivor_set(id)
native zp_class_survivor_get_count()

#endif

#define PLUGIN "[CSO] Guillotine"
#define VERSION "1.0"
#define AUTHOR "Dias Pendragon"
#define MODIFIED/FIXED "Dooz"

#define MODEL_V "models/v_guillotine.mdl"
#define MODEL_P "models/p_guillotine.mdl"
#define MODEL_W "models/w_guillotine.mdl"

#define MODEL_S "models/guillotine_projectile.mdl"
#define MODEL_GIB "models/gibs_guilotine.mdl"

new const Weapon_Sounds[7][] =
{
	"weapons/guillotine_catch2.wav",
	"weapons/guillotine_draw.wav",
	"weapons/guillotine_draw_empty.wav",
	"weapons/guillotine_explode.wav",
	"weapons/guillotine_red.wav",
	"weapons/guillotine-1.wav",
	"weapons/guillotine_wall.wav"
}

new const Weapon_Resources[4][] = 
{
	"sprites/weapon_guillotine.txt",
	"sprites/640hud13_2.spr",
	"sprites/640hud120_2.spr",
	"sprites/guillotine_lost.spr"
}

enum
{
	ANIM_IDLE = 0, // 1.96
	ANIM_IDLE_EMPTY, // 1.96
	ANIM_SHOOT, // 0.67
	ANIM_DRAW, // 1.13
	ANIM_DRAW_EMPTY, // 1.13
	ANIM_EXPECT, // 1.96
	ANIM_EXPECT_FX, // 1.96
	ANIM_CATCH, // 0.967
	ANIM_LOST // 1.3
}

#define TASK_RESET 14220151

const m_iLastHitGroup = 75

// MACROS
#define Get_BitVar(%1,%2) (%1 & (1 << (%2 & 31)))
#define Set_BitVar(%1,%2) %1 |= (1 << (%2 & 31))
#define UnSet_BitVar(%1,%2) %1 &= ~(1 << (%2 & 31))

const pev_eteam = pev_iuser1
const pev_return = pev_iuser2
const pev_extra = pev_iuser3

new g_Cvars[8], g_Had_Guillotine, g_InTempingAttack, g_CanShoot, g_Hit, g_Ammo[33], g_MyGuillotine[33], Float:g_DamageTimeA[33], Float:g_DamageTimeB[33]
new g_ExpSprID, g_GibModelID, g_MaxPlayers;

// Safety
new g_IsConnected, g_IsAlive, g_PlayerWeapon[33]

#if defined USE_FOR_ZOMBIE
new g_Item;
#define Item_Price 20
#endif

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	#if defined USE_FOR_ZOMBIE
		g_Item = zp_items_register("Flying Guillotine", Item_Price);
	#else
		register_clcmd("say /get_guillotine", "Get_Guillotine")
	#endif 
	
	register_clcmd("weapon_guillotine", "HookWeapon")
	
	g_Cvars[0] = register_cvar("guillotine_damage", "35");
	g_Cvars[1] = register_cvar("guillotine_ammo", "10");
	g_Cvars[2] = register_cvar("guillotine_max_radius", "700.0");
	g_Cvars[3] = register_cvar("guillotine_fly_speed", "1000.0");
	g_Cvars[4] = register_cvar("guillotine_knockback", "300.0");
	g_Cvars[5] = register_cvar("guillotine_damage_delay", "0.2");
	g_Cvars[6] = register_cvar("guillotine_hittime", "5.0");
	g_Cvars[7] = register_cvar("guillotine_unlimited_ammo", "0");
	
	register_forward(FM_UpdateClientData, "fw_UpdateClientData_Post", 1)
	register_forward(FM_CmdStart, "fw_CmdStart")
	register_forward(FM_SetModel, "fw_SetModel")	
	register_forward(FM_EmitSound, "fw_EmitSound")
	register_forward(FM_TraceLine, "fw_TraceLine")
	register_forward(FM_TraceHull, "fw_TraceHull")
	
	register_touch("guillotine", "*", "fw_Guillotine_Touch")
	register_think("guillotine", "fw_Guillotine_Think")
	
	register_logevent("Event_Round_Start", 2, "1=Round_Start")  
	register_event("CurWeapon", "Event_CurWeapon", "be", "1=1")
	
	RegisterHam(Ham_Item_Deploy, "weapon_m249", "fw_Item_Deploy_Post", 1)	
	RegisterHam(Ham_Item_AddToPlayer, "weapon_m249", "fw_Item_AddToPlayer_Post", 1)
	RegisterHam(Ham_Weapon_WeaponIdle, "weapon_m249", "fw_Weapon_WeaponIdle_Post", 1)

register_message(get_user_msgid("DeathMsg"), "message_DeathMsg");
	
	g_MaxPlayers = get_maxplayers();
	Register_SafetyFunc();
}

public plugin_precache()
{
	precache_model(MODEL_V)
	precache_model(MODEL_P)
	precache_model(MODEL_W)
	
	precache_model(MODEL_S)
	g_GibModelID = precache_model(MODEL_GIB)
	
	for(new i = 0; i < sizeof(Weapon_Sounds); i++)
		precache_sound(Weapon_Sounds[i])
	for(new i = 0; i < sizeof(Weapon_Resources); i++)
	{
		if(!i) precache_generic(Weapon_Resources[i])
		else if(i == 3) g_ExpSprID = precache_model(Weapon_Resources[i])
		else precache_model(Weapon_Resources[i])
	}
}

public client_putinserver(id)
	Safety_Connected(id)

public client_disconnect(id)
	Safety_Disconnected(id)

public Event_Round_Start(){
	static Classname[64];
	for(new id = 1; id < g_MaxPlayers; ++id){
		if(!is_connected(id) || !pev_valid(g_MyGuillotine[id]))
			continue;
			
		pev(g_MyGuillotine[id], pev_classname, Classname, 63)
		
		if(equal(Classname, "guillotine"))
			remove_entity(g_MyGuillotine[id])
	}
}

#if defined USE_FOR_ZOMBIE
public zp_fw_items_select_pre(id, itemid, ignorecost){

if(itemid == g_Item){
        if(zp_core_is_zombie(id) || zp_class_survivor_get(id))
            return ZP_ITEM_DONT_SHOW;
    }
	
    return ZP_ITEM_AVAILABLE;
}  
 
public zp_fw_items_select_post(id, itemid, ignorecost){

if (itemid == g_Item)
		Get_Guillotine(id)

return ZP_ITEM_AVAILABLE;
}
#endif

public Get_Guillotine(id)
{
	Drop_Weapon(id, 1)
	
	Set_BitVar(g_Had_Guillotine, id)
	Set_BitVar(g_CanShoot, id)
	UnSet_BitVar(g_InTempingAttack, id)
	UnSet_BitVar(g_Hit, id)
	
	g_Ammo[id] = get_pcvar_num(g_Cvars[1])
	g_MyGuillotine[id] = 0
	
	give_item(id, "weapon_m249")
	update_ammo(id, -1, g_Ammo[id])
}

public Remove_Guillotine(id)
{
	UnSet_BitVar(g_Had_Guillotine, id)
	UnSet_BitVar(g_CanShoot, id)
	UnSet_BitVar(g_InTempingAttack, id)
	UnSet_BitVar(g_Hit, id)

g_Ammo[id] = 0
}

public message_DeathMsg(msg_id, msg_dest, id)
{
	static szTruncatedWeapon[33], iAttacker, iVictim;
	get_msg_arg_string(4, szTruncatedWeapon, charsmax(szTruncatedWeapon))
 
	iAttacker = get_msg_arg_int(1);
	iVictim = get_msg_arg_int(2);
 
	if(!is_user_connected(iAttacker) || iAttacker == iVictim)
		return PLUGIN_CONTINUE;
 
	if(equal(szTruncatedWeapon, "knife") && get_user_weapon(iAttacker) == CSW_M249)
		if(Get_BitVar(g_Had_Guillotine, iAttacker))
			set_msg_arg_string(4, "Flying Guillotine");
 
	return PLUGIN_CONTINUE;
}

public HookWeapon(id)
{
	engclient_cmd(id, "weapon_m249")
	return PLUGIN_HANDLED
}

public Event_CurWeapon(id)
{
	if(!is_alive(id))
		return
		
	static CSWID; CSWID = read_data(2)
	if(CSWID == CSW_M249 && Get_BitVar(g_Had_Guillotine, id))
		update_ammo(id, -1, g_Ammo[id])
}

public update_ammo(id, Ammo, BpAmmo)
{
	message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("CurWeapon"), _, id)
	write_byte(1)
	write_byte(CSW_M249)
	write_byte(Ammo)
	message_end()
	
	message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("AmmoX"), _, id)
	write_byte(10)
	write_byte(BpAmmo)
	message_end()
	
	cs_set_user_bpammo(id, CSW_M249, BpAmmo)
}

public client_PostThink(id)
{
	if(!is_alive(id))
		return
		
	if(get_player_weapon(id) != CSW_M249 || !Get_BitVar(g_Had_Guillotine, id))
		return
	
	if(!Get_BitVar(g_CanShoot, id) && !pev_valid(g_MyGuillotine[id]))
	{
		// Reset Player
		Set_PlayerNextAttack(id, 1.0)
		Set_WeaponIdleTime(id, CSW_M249, 1.0)
		
		Set_WeaponAnim(id, ANIM_LOST)
		Set_BitVar(g_CanShoot, id)
		UnSet_BitVar(g_Hit, id)
		
		set_task(0.95, "Reset_Guillotine", id+TASK_RESET)
	}
}

public fw_UpdateClientData_Post(id, sendweapons, cd_handle)
{
	if(!is_alive(id))
		return FMRES_IGNORED
	if(get_player_weapon(id) != CSW_M249 || !Get_BitVar(g_Had_Guillotine, id))
		return FMRES_IGNORED
	
	set_cd(cd_handle, CD_flNextAttack, get_gametime() + 0.001) 
	
	return FMRES_HANDLED
}

public fw_CmdStart(id, uc_handle, seed)
{
	if(!is_alive(id))
		return FMRES_IGNORED
	if(get_player_weapon(id) != CSW_M249 || !Get_BitVar(g_Had_Guillotine, id))
		return FMRES_IGNORED
	
	static CurButton; CurButton = get_uc(uc_handle, UC_Buttons)
	
	if(CurButton & IN_ATTACK)
	{
		CurButton &= ~IN_ATTACK
		set_uc(uc_handle, UC_Buttons, CurButton)
		
		HandleShot_Guillotine(id)
	}
	
	return FMRES_HANDLED
}

public fw_SetModel(entity, model[])
{
	if(!pev_valid(entity))
		return FMRES_IGNORED
	
	static Classname[32]
	pev(entity, pev_classname, Classname, sizeof(Classname))
	
	if(!equal(Classname, "weaponbox"))
		return FMRES_IGNORED
	
	static iOwner
	iOwner = pev(entity, pev_owner)
	
	if(equal(model, "models/w_m249.mdl"))
	{
		static weapon; weapon = find_ent_by_owner(-1, "weapon_m249", entity)
		
		if(!pev_valid(weapon))
			return FMRES_IGNORED;
		
		if(Get_BitVar(g_Had_Guillotine, iOwner))
		{
			set_pev(weapon, pev_impulse, 1422015)
			set_pev(weapon, pev_iuser4, g_Ammo[iOwner])
			
			engfunc(EngFunc_SetModel, entity, MODEL_W)
			
			Remove_Guillotine(iOwner)
			
			return FMRES_SUPERCEDE
		}
	}

return FMRES_IGNORED;
}

public fw_EmitSound(id, channel, const sample[], Float:volume, Float:attn, flags, pitch)
{
	if(!is_connected(id))
		return FMRES_IGNORED
	if(!Get_BitVar(g_InTempingAttack, id))
		return FMRES_IGNORED
		
	if(sample[8] == 'k' && sample[9] == 'n' && sample[10] == 'i')
	{
		if(sample[14] == 's' && sample[15] == 'l' && sample[16] == 'a')
			return FMRES_SUPERCEDE
		if (sample[14] == 'h' && sample[15] == 'i' && sample[16] == 't')
		{
			if (sample[17] == 'w')  return FMRES_SUPERCEDE
			else  return FMRES_SUPERCEDE
		}
		if (sample[14] == 's' && sample[15] == 't' && sample[16] == 'a')
			return FMRES_SUPERCEDE;
	}
	
	return FMRES_IGNORED
}

public fw_TraceLine(Float:vector_start[3], Float:vector_end[3], ignored_monster, id, handle)
{
	if(!is_alive(id))
		return FMRES_IGNORED	
	if(!Get_BitVar(g_InTempingAttack, id))
		return FMRES_IGNORED
	
	static Float:vecStart[3], Float:vecEnd[3], Float:v_angle[3], Float:v_forward[3], Float:view_ofs[3], Float:fOrigin[3]
	
	pev(id, pev_origin, fOrigin)
	pev(id, pev_view_ofs, view_ofs)
	xs_vec_add(fOrigin, view_ofs, vecStart)
	pev(id, pev_v_angle, v_angle)
	
	engfunc(EngFunc_MakeVectors, v_angle)
	get_global_vector(GL_v_forward, v_forward)

xs_vec_mul_scalar(v_forward, 0.0, v_forward)
	xs_vec_add(vecStart, v_forward, vecEnd)
	
	engfunc(EngFunc_TraceLine, vecStart, vecEnd, ignored_monster, id, handle)
	
	return FMRES_SUPERCEDE
}

public fw_TraceHull(Float:vector_start[3], Float:vector_end[3], ignored_monster, hull, id, handle)
{
	if(!is_alive(id))
		return FMRES_IGNORED	
	if(!Get_BitVar(g_InTempingAttack, id))
		return FMRES_IGNORED
	
	static Float:vecStart[3], Float:vecEnd[3], Float:v_angle[3], Float:v_forward[3], Float:view_ofs[3], Float:fOrigin[3]
	
	pev(id, pev_origin, fOrigin)
	pev(id, pev_view_ofs, view_ofs)
	xs_vec_add(fOrigin, view_ofs, vecStart)
	pev(id, pev_v_angle, v_angle)
	
	engfunc(EngFunc_MakeVectors, v_angle)
	get_global_vector(GL_v_forward, v_forward)
	
	xs_vec_mul_scalar(v_forward, 0.0, v_forward)
	xs_vec_add(vecStart, v_forward, vecEnd)
	
	engfunc(EngFunc_TraceHull, vecStart, vecEnd, ignored_monster, hull, id, handle)
	
	return FMRES_SUPERCEDE
}

public fw_Guillotine_Touch(Ent, Touched)
{
	if(!pev_valid(Ent))
		return
		
	static id; id = pev(Ent, pev_owner)
	if(!is_alive(id))
	{
		Guillotine_Broken(Ent)
		return
	}
		
	if(is_connected(Touched))
	{ // Touch Human
		if(!is_alive(Touched))
			return
		if(Get_BitVar(g_Hit, id))
			return
		if(Touched == id)
			return
		if(!get_pcvar_num(get_cvar_pointer("mp_friendlyfire")))
		{
			if(cs_get_user_team(Touched) == cs_get_user_team(id))
				return
		}
				
		static Float:HeadOrigin[3], Float:HeadAngles[3];
		engfunc(EngFunc_GetBonePosition, Touched, 8, HeadOrigin, HeadAngles);		
				
		static Float:EntOrigin[3]; pev(Ent, pev_origin, EntOrigin)
		
		if(get_distance_f(EntOrigin, HeadOrigin) <= 16.0)
		{
			if(!pev(Ent, pev_return))
			{
				// Set
				Set_BitVar(g_Hit, id)
				Set_WeaponAnim(id, ANIM_EXPECT_FX)
				
				set_pev(Ent, pev_enemy, Touched)
				set_pev(Ent, pev_return, 1)
				set_pev(Ent, pev_movetype, MOVETYPE_FOLLOW)
				set_pev(Ent, pev_velocity, {0.0, 0.0, 0.0})
				set_pev(Ent, pev_fuser1, get_gametime() + get_pcvar_float(g_Cvars[6]))
				
				// Animation
				set_pev(Ent, pev_animtime, get_gametime())
				set_pev(Ent, pev_framerate, 5.0)
				set_pev(Ent, pev_sequence, 1)
			} else {
				if(get_gametime() - get_pcvar_float(g_Cvars[5]) > g_DamageTimeA[id])
				{	
					ExecuteHamB(Ham_TakeDamage, Touched, fm_get_user_weapon_entity(id, CSW_KNIFE), id, get_pcvar_float(g_Cvars[0]), DMG_SLASH)
					g_DamageTimeA[id] = get_gametime()
				}
			}
		} else {
			if(get_gametime() - get_pcvar_float(g_Cvars[5]) > g_DamageTimeA[id])
			{	
				ExecuteHamB(Ham_TakeDamage, Touched, fm_get_user_weapon_entity(id, CSW_KNIFE), id, get_pcvar_float(g_Cvars[0]), DMG_SLASH)
				
				// Knockback
				static Float:OriginA[3]; pev(id, pev_origin, OriginA)
				static Float:Origin[3]; pev(Touched, pev_origin, Origin)
				static Float:Velocity[3]; Get_SpeedVector(OriginA, Origin, get_pcvar_float(g_Cvars[4]), Velocity)
			
				set_pev(Touched, pev_velocity, Velocity)
				
				g_DamageTimeA[id] = get_gametime()
			}
		}	
	} else { // Touch Wall
		if(!pev(Ent, pev_return))
		{
			set_pev(Ent, pev_velocity, {0.0, 0.0, 0.0})
			
			set_pev(Ent, pev_return, 1)
			emit_sound(Ent, CHAN_BODY, Weapon_Sounds[6], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
			
			// Reset Angles
			static Float:Angles[3]
			pev(id, pev_v_angle, Angles)
			
			Angles[0] *= -1.0
			set_pev(Ent, pev_angles, Angles)
			
			// Check Damage
			static Float:TakeDamage; pev(Touched, pev_takedamage, TakeDamage)
			if(TakeDamage == DAMAGE_YES) ExecuteHamB(Ham_TakeDamage, Touched, fm_get_user_weapon_entity(id, CSW_KNIFE), id, get_pcvar_float(g_Cvars[0]), DMG_SLASH)
		} else {
			static Classname[32];
			pev(Touched, pev_classname, Classname, 31)
			
			if(!Get_BitVar(g_Hit, id) && !equal(Classname, "weaponbox")) Guillotine_Broken(Ent)
			return
		}
	}
}

public fw_Guillotine_Think(Ent)
{
	if(!pev_valid(Ent))
		return
		
	static id; id = pev(Ent, pev_owner)
	if(!is_alive(id))
	{
		Guillotine_Broken(Ent)
		return
	}
	if(!Get_BitVar(g_Had_Guillotine, id))
	{
		Guillotine_Broken(Ent)
		return
	}
	
	static Float:LiveTime
	pev(Ent, pev_fuser2, LiveTime)
			
	if(get_gametime() >= LiveTime)
	{
		Guillotine_Broken(Ent)
		return
	}
	
	if(pev(Ent, pev_return)) // Returning to the owner
	{
		static Target; Target = pev(Ent, pev_enemy)
		if(!is_alive(Target))
		{
			UnSet_BitVar(g_Hit, id)
			
			if(pev(Ent, pev_sequence) != 0) set_pev(Ent, pev_sequence, 0)
			if(pev(Ent, pev_movetype) != MOVETYPE_FLY) set_pev(Ent, pev_movetype, MOVETYPE_FLY)
			set_pev(Ent, pev_aiment, 0)
			
			if(entity_range(Ent, id) > 100.0)
			{
				static Float:Origin[3]; pev(id, pev_origin, Origin)
				Hook_The_Fucking_Ent(Ent, Origin, get_pcvar_float(g_Cvars[3]))
			} else {
				Guillotine_Catch(id, Ent)
				return
			}
		} else {
			static Float:fTimeRemove
			pev(Ent, pev_fuser1, fTimeRemove)
			
			if(get_gametime() >= fTimeRemove)
			{
				set_pev(Ent, pev_enemy, 0)
			} else {
				static Float:HeadOrigin[3], Float:HeadAngles[3];
				engfunc(EngFunc_GetBonePosition, Target, 8, HeadOrigin, HeadAngles);
				
				static Float:Velocity[3];
				pev(Ent, pev_velocity, Velocity)

set_pev(Ent, pev_velocity, {0.0, 0.0, 0.0})
				set_pev(Ent, pev_angles, HeadAngles)
				
				static Float:EnemyOrigin[3]; pev(Target, pev_origin, EnemyOrigin)
				if(get_distance_f(EnemyOrigin, HeadOrigin) <= 24.0) engfunc(EngFunc_SetOrigin, Ent, HeadOrigin)
				else engfunc(EngFunc_SetOrigin, Ent, EnemyOrigin)
	
				if(get_gametime() - get_pcvar_float(g_Cvars[5]) > g_DamageTimeB[id])
				{	
					// Animation
					if(!pev(Ent, pev_sequence))
					{
						set_pev(Ent, pev_animtime, get_gametime())
						set_pev(Ent, pev_framerate, 5.0)
						set_pev(Ent, pev_sequence, 1)
					}

set_pdata_int(Target, m_iLastHitGroup, HIT_HEAD, 5)
					ExecuteHamB(Ham_TakeDamage, Target, fm_get_user_weapon_entity(id, CSW_KNIFE), id, get_pcvar_float(g_Cvars[0]), DMG_SLASH)
		
					g_DamageTimeB[id] = get_gametime()
				}
				
				// Knockback
				static Float:OriginA[3]; pev(id, pev_origin, OriginA)
				static Float:Origin[3]; pev(Target, pev_origin, Origin)
				static Float:VelocityA[3]; Get_SpeedVector(OriginA, Origin, get_pcvar_float(g_Cvars[4]) / 5.0, VelocityA)
			
				set_pev(Target, pev_velocity, VelocityA)
			}
		}
	} else {
		if(entity_range(Ent, id) >= get_pcvar_float(g_Cvars[2]))
		{
			set_pev(Ent, pev_velocity, {0.0, 0.0, 0.0})
			set_pev(Ent, pev_return, 1)
		}
	}
	
	set_pev(Ent, pev_nextthink, get_gametime() + 0.05)
}

public Guillotine_Broken(Ent)
{
	static Float:Origin[3];
	
	emit_sound(Ent, CHAN_BODY, Weapon_Sounds[3], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
	pev(Ent, pev_origin, Origin)
	
	remove_entity(Ent)

// Effect
	message_begin(MSG_BROADCAST ,SVC_TEMPENTITY)
	write_byte(TE_EXPLOSION)
	engfunc(EngFunc_WriteCoord, Origin[0])
	engfunc(EngFunc_WriteCoord, Origin[1])
	engfunc(EngFunc_WriteCoord, Origin[2])
	write_short(g_ExpSprID)	// sprite index
	write_byte(5)	// scale in 0.1's
	write_byte(30)	// framerate
	write_byte(TE_EXPLFLAG_NOSOUND)	// flags
	message_end()
	
	message_begin(MSG_BROADCAST,SVC_TEMPENTITY);
	write_byte(TE_BREAKMODEL)
	engfunc(EngFunc_WriteCoord, Origin[0])
	engfunc(EngFunc_WriteCoord, Origin[1])
	engfunc(EngFunc_WriteCoord, Origin[2])
	write_coord(64); // size x
	write_coord(64); // size y
	write_coord(64); // size z
	write_coord(random_num(-64,64)); // velocity x
	write_coord(random_num(-64,64)); // velocity y
	write_coord(25); // velocity z
	write_byte(10); // random velocity
	write_short(g_GibModelID); // model index that you want to break
	write_byte(32); // count
	write_byte(25); // life
	write_byte(0x01); // flags: BREAK_GLASS
	message_end();  	
}

public Reset_Guillotine(id)
{
	id -= TASK_RESET
	
	if(!is_alive(id))
		return
	if(!Get_BitVar(g_Had_Guillotine, id))
		return
	Set_BitVar(g_CanShoot, id)
	if(get_player_weapon(id) != CSW_M249)
		return
	
	Set_PlayerNextAttack(id, 0.75)
	Set_WeaponIdleTime(id, CSW_M249, 0.75)
	
	if(g_Ammo[id]) 
	{	
		Set_WeaponAnim(id, ANIM_DRAW)
		PlaySound(id, Weapon_Sounds[0])
	}
}

public Guillotine_Catch(id, Ent)
{
	// Remove Entity
	remove_entity(Ent)
	g_MyGuillotine[id] = -1
	
	// Reset Player
	if(get_player_weapon(id) == CSW_M249 && Get_BitVar(g_Had_Guillotine, id))
	{
		if(!get_pcvar_num(g_Cvars[7]))
			g_Ammo[id] = min(g_Ammo[id] + 1, get_pcvar_num(g_Cvars[0]))
		
		update_ammo(id, -1, g_Ammo[id])
		
		Create_FakeAttack(id)
		
		Set_PlayerNextAttack(id, 1.0)
		Set_WeaponIdleTime(id, CSW_M249, 1.0)
		
		Set_WeaponAnim(id, ANIM_CATCH)
		Set_BitVar(g_CanShoot, id)
		UnSet_BitVar(g_Hit, id)

emit_sound(id, CHAN_WEAPON, Weapon_Sounds[0], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
	} else {
		emit_sound(id, CHAN_WEAPON, Weapon_Sounds[3], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
		Set_BitVar(g_CanShoot, id)
		UnSet_BitVar(g_Hit, id)
	}
}

public fw_Item_Deploy_Post(Ent)
{
	if(pev_valid(Ent) != 2)
		return
	static Id; Id = get_pdata_cbase(Ent, 41, 4)
	if(get_pdata_cbase(Id, 373) != Ent)
		return
	if(!Get_BitVar(g_Had_Guillotine, Id))
		return
	
	set_pev(Id, pev_viewmodel2, MODEL_V)
	set_pev(Id, pev_weaponmodel2, MODEL_P)
	
	static Valid; Valid = pev_valid(g_MyGuillotine[Id])
	if(g_Ammo[Id]) 
	{	
		Set_WeaponAnim(Id, ANIM_DRAW)
		if(!Valid) PlaySound(Id, Weapon_Sounds[0])
	} else Set_WeaponAnim(Id, ANIM_DRAW_EMPTY)
	
	if(!Valid) Set_BitVar(g_CanShoot, Id)
	else Set_WeaponAnim(Id, ANIM_DRAW_EMPTY)
		
	set_pdata_string(Id, (492) * 4, "grenade", -1 , 20)
}

public fw_Item_AddToPlayer_Post(Ent, id)
{
	if(!pev_valid(Ent))
		return HAM_IGNORED
		
	if(pev(Ent, pev_impulse) == 1422015)
	{
		Set_BitVar(g_Had_Guillotine, id)
		Set_BitVar(g_CanShoot, id)
		
		set_pev(Ent, pev_impulse, 0)
		g_Ammo[id] = pev(Ent, pev_iuser4)
	}
	
	message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("WeaponList"), _, id)
	write_string(Get_BitVar(g_Had_Guillotine, id) ? "weapon_guillotine" : "weapon_m249")
	write_byte(3)
	write_byte(200)
	write_byte(-1)
	write_byte(-1)
	write_byte(0)
	write_byte(4)
	write_byte(CSW_M249)
	write_byte(0)
	message_end()			
	
	return HAM_HANDLED	
}

public fw_Weapon_WeaponIdle_Post(iEnt)
{
	if(pev_valid(iEnt) != 2)
		return
	static Id; Id = get_pdata_cbase(iEnt, 41, 4)
	
	if(!Get_BitVar(g_Had_Guillotine, Id))
		return
		
	if(get_pdata_float(iEnt, 48, 4) <= 0.25)
	{
		if(g_Ammo[Id]) 
		{	
			if(Get_BitVar(g_CanShoot, Id)) Set_WeaponAnim(Id, ANIM_IDLE)
			else {
				if(Get_BitVar(g_Hit, Id)) Set_WeaponAnim(Id, ANIM_EXPECT_FX)
				else Set_WeaponAnim(Id, ANIM_EXPECT)
			}
		} else Set_WeaponAnim(Id, ANIM_IDLE_EMPTY)
		
		set_pdata_float(iEnt, 48, 20.0, 4)
	}	
}

public HandleShot_Guillotine(id)
{
	if(get_pdata_float(id, 83, 5) > 0.0)
		return
	if(g_Ammo[id] <= 0)
		return
	if(!Get_BitVar(g_CanShoot, id))
		return
		
	static Ent; Ent = fm_get_user_weapon_entity(id, CSW_M249)
	if(!pev_valid(Ent)) return		
	
	UnSet_BitVar(g_CanShoot, id)
	Create_FakeAttack(id)
	
	Set_WeaponAnim(id, ANIM_SHOOT)
	emit_sound(id, CHAN_WEAPON, Weapon_Sounds[5], VOL_NORM, ATTN_NORM, 0, PITCH_NORM)
	
	Create_Guillotine(id)

Set_PlayerNextAttack(id, 0.5)
	Set_WeaponIdleTime(id, CSW_M249, 0.5)
	
	if(!get_pcvar_num(g_Cvars[7]))
		g_Ammo[id]--
	
	update_ammo(id, -1, g_Ammo[id])
}

public Create_Guillotine(id)
{
	new iEnt = create_entity("info_target")
	
	static Float:Origin[3], Float:TargetOrigin[3], Float:Velocity[3], Float:Angles[3]
	
	get_weapon_attachment(id, Origin, 0.0)
	Origin[2] -= 10.0
	get_position(id, 1024.0, 0.0, 0.0, TargetOrigin)
	
	pev(id, pev_v_angle, Angles)
	Angles[0] *= -1.0
	
	// set info for ent
	set_pev(iEnt, pev_movetype, MOVETYPE_FLY)
	entity_set_string(iEnt, EV_SZ_classname, "guillotine")
	engfunc(EngFunc_SetModel, iEnt, MODEL_S)
	
	set_pev(iEnt, pev_mins, Float:{-1.0, -1.0, -1.0})
	set_pev(iEnt, pev_maxs, Float:{1.0, 1.0, 1.0})
	set_pev(iEnt, pev_origin, Origin)
	set_pev(iEnt, pev_angles, Angles)
	set_pev(iEnt, pev_gravity, 0.01)
	set_pev(iEnt, pev_solid, SOLID_TRIGGER)
	set_pev(iEnt, pev_owner, id)	
	set_pev(iEnt, pev_eteam, get_user_team(id))
	set_pev(iEnt, pev_return, 0)
	set_pev(iEnt, pev_extra, 0)
	set_pev(iEnt, pev_enemy, 0)
	set_pev(iEnt, pev_fuser2, get_gametime() + 8.0)
	
	get_speed_vector(Origin, TargetOrigin, get_pcvar_float(g_Cvars[3]), Velocity)
	set_pev(iEnt, pev_velocity, Velocity)	
	
	set_pev(iEnt, pev_nextthink, get_gametime() + 0.1)
	
	g_MyGuillotine[id] = iEnt
	
	// Animation
	set_pev(iEnt, pev_animtime, get_gametime())
	set_pev(iEnt, pev_framerate, 2.0)
	set_pev(iEnt, pev_sequence, 0)
}

public Create_FakeAttack(id)
{
	static Ent; Ent = fm_get_user_weapon_entity(id, CSW_KNIFE)
	if(!pev_valid(Ent)) return
	
	Set_BitVar(g_InTempingAttack, id)
	ExecuteHamB(Ham_Weapon_PrimaryAttack, Ent)
	
	// Set Real Attack Anim
	static iAnimDesired,  szAnimation[64]

formatex(szAnimation, charsmax(szAnimation), (pev(id, pev_flags) & FL_DUCKING) ? "crouch_shoot_%s" : "ref_shoot_%s", "knife")
	if((iAnimDesired = lookup_sequence(id, szAnimation)) == -1)
		iAnimDesired = 0
	
	set_pev(id, pev_sequence, iAnimDesired)
	UnSet_BitVar(g_InTempingAttack, id)
}

stock Set_WeaponIdleTime(id, WeaponId ,Float:TimeIdle)
{
	static entwpn; entwpn = fm_get_user_weapon_entity(id, WeaponId)
	if(!pev_valid(entwpn)) 
		return
		
	set_pdata_float(entwpn, 46, TimeIdle, 4)
	set_pdata_float(entwpn, 47, TimeIdle, 4)
	set_pdata_float(entwpn, 48, TimeIdle + 0.5, 4)
}

stock Set_PlayerNextAttack(id, Float:nexttime)
{
	set_pdata_float(id, 83, nexttime, 5)
}

stock Set_WeaponAnim(id, anim)
{
	set_pev(id, pev_weaponanim, anim)
	
	message_begin(MSG_ONE_UNRELIABLE, SVC_WEAPONANIM, {0, 0, 0}, id)
	write_byte(anim)
	write_byte(pev(id, pev_body))
	message_end()
}

stock get_weapon_attachment(id, Float:output[3], Float:fDis = 40.0)
{ 
	static Float:vfEnd[3], viEnd[3] 
	get_user_origin(id, viEnd, 3)  
	IVecFVec(viEnd, vfEnd) 
	
	static Float:fOrigin[3], Float:fAngle[3]
	
	pev(id, pev_origin, fOrigin) 
	pev(id, pev_view_ofs, fAngle)
	
	xs_vec_add(fOrigin, fAngle, fOrigin) 
	
	static Float:fAttack[3]
	
	xs_vec_sub(vfEnd, fOrigin, fAttack)
	xs_vec_sub(vfEnd, fOrigin, fAttack) 
	
	static Float:fRate
	
	fRate = fDis / vector_length(fAttack)
	xs_vec_mul_scalar(fAttack, fRate, fAttack)
	
	xs_vec_add(fOrigin, fAttack, output)
}

stock get_position(id,Float:forw, Float:right, Float:up, Float:vStart[])
{
	new Float:vOrigin[3], Float:vAngle[3], Float:vForward[3], Float:vRight[3], Float:vUp[3]
	
	pev(id, pev_origin, vOrigin)
	pev(id, pev_view_ofs,vUp) //for player
	xs_vec_add(vOrigin,vUp,vOrigin)
	pev(id, pev_v_angle, vAngle) // if normal entity ,use pev_angles
	
	angle_vector(vAngle,ANGLEVECTOR_FORWARD,vForward) //or use EngFunc_AngleVectors
	angle_vector(vAngle,ANGLEVECTOR_RIGHT,vRight)
	angle_vector(vAngle,ANGLEVECTOR_UP,vUp)
	
	vStart[0] = vOrigin[0] + vForward[0] * forw + vRight[0] * right + vUp[0] * up
	vStart[1] = vOrigin[1] + vForward[1] * forw + vRight[1] * right + vUp[1] * up
	vStart[2] = vOrigin[2] + vForward[2] * forw + vRight[2] * right + vUp[2] * up
}

stock get_speed_vector(const Float:origin1[3],const Float:origin2[3],Float:speed, Float:new_velocity[3])
{
	new_velocity[0] = origin2[0] - origin1[0]
	new_velocity[1] = origin2[1] - origin1[1]
	new_velocity[2] = origin2[2] - origin1[2]
	new Float:num = floatsqroot(speed*speed / (new_velocity[0]*new_velocity[0] + new_velocity[1]*new_velocity[1] + new_velocity[2]*new_velocity[2]))
	new_velocity[0] *= num
	new_velocity[1] *= num
	new_velocity[2] *= num
	
	return 1;
}

stock Hook_The_Fucking_Ent(ent, Float:TargetOrigin[3], Float:Speed)
{
	static Float:fl_Velocity[3], Float:EntOrigin[3], Float:distance_f, Float:fl_Time
	
	pev(ent, pev_origin, EntOrigin)
	
	distance_f = get_distance_f(EntOrigin, TargetOrigin)
	fl_Time = distance_f / Speed
		
	pev(ent, pev_velocity, fl_Velocity)
		
	fl_Velocity[0] = (TargetOrigin[0] - EntOrigin[0]) / fl_Time
	fl_Velocity[1] = (TargetOrigin[1] - EntOrigin[1]) / fl_Time
	fl_Velocity[2] = (TargetOrigin[2] - EntOrigin[2]) / fl_Time

set_pev(ent, pev_velocity, fl_Velocity)
}

stock PlaySound(id, const sound[])
{
	if(equal(sound[strlen(sound)-4], ".mp3")) client_cmd(id, "mp3 play ^"sound/%s^"", sound)
	else client_cmd(id, "spk ^"%s^"", sound)
}

stock Get_SpeedVector(const Float:origin1[3],const Float:origin2[3],Float:speed, Float:new_velocity[3])
{
	new_velocity[0] = origin2[0] - origin1[0]
	new_velocity[1] = origin2[1] - origin1[1]
	new_velocity[2] = origin2[2] - origin1[2]
	new Float:num = floatsqroot(speed*speed / (new_velocity[0]*new_velocity[0] + new_velocity[1]*new_velocity[1] + new_velocity[2]*new_velocity[2]))
	new_velocity[0] *= num
	new_velocity[1] *= num
	new_velocity[2] *= num
	
	return 1;
}

stock Drop_Weapon(id, slot)
{
	if(!(1 <= slot <= 2))
		return 0;
 
	static iCount; iCount = 0;
	static iEntity; iEntity = get_pdata_cbase(id, (367 + slot), 5);
 
	if(iEntity > 0)
	{
		static iNext;
		static szWeaponName[32];
 
		do {
			iNext = get_pdata_cbase(iEntity, 42, 4);
 
			if(get_weaponname(cs_get_weapon_id(iEntity), szWeaponName, charsmax(szWeaponName)))
			{  
				engclient_cmd(id, "drop", szWeaponName);
				iCount++;
			}
		}
 
		while(( iEntity = iNext) > 0);
	}
 
	return iCount;
}

/* ===============================
------------- SAFETY -------------
=================================*/
public Register_SafetyFunc()
{
	register_event("CurWeapon", "Safety_CurWeapon", "be", "1=1")
	
	RegisterHam(Ham_Spawn, "player", "fw_Safety_Spawn_Post", 1)
	RegisterHam(Ham_Killed, "player", "fw_Safety_Killed_Post", 1)
}

public Safety_Connected(id)
{
	Set_BitVar(g_IsConnected, id)
	UnSet_BitVar(g_IsAlive, id)
	
	g_PlayerWeapon[id] = 0
}

public Safety_Disconnected(id)
{
	UnSet_BitVar(g_IsConnected, id)
	UnSet_BitVar(g_IsAlive, id)
	
	g_PlayerWeapon[id] = 0
}

public Safety_CurWeapon(id)
{
	if(!is_alive(id))
		return
		
	static CSW; CSW = read_data(2)
	if(g_PlayerWeapon[id] != CSW) g_PlayerWeapon[id] = CSW
}

public fw_Safety_Spawn_Post(id)
{
	if(!is_user_alive(id))
		return
		
	Set_BitVar(g_IsAlive, id)
}

public fw_Safety_Killed_Post(id)
{
	UnSet_BitVar(g_IsAlive, id)
}

public is_alive(id)
{
	if(!(1 <= id <= 32))
		return 0
	if(!Get_BitVar(g_IsConnected, id))
		return 0
	if(!Get_BitVar(g_IsAlive, id)) 
		return 0
	
	return 1
}

public is_connected(id)
{
	if(!(1 <= id <= 32))
		return 0
	if(!Get_BitVar(g_IsConnected, id))
		return 0
	
	return 1
}

public get_player_weapon(id)
{
	if(!is_alive(id))
		return 0
	
	return g_PlayerWeapon[id]
}

/* ===============================
--------- End of SAFETY ----------
=================================*/

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

A hozzászólást 3 alkalommal szerkesztették, utoljára Dooz 2018.06.05. 22:57-kor.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

rericsi8

Hozzászólás témája: Re: [CSO] Flying Guillotine

HozzászólásElküldve: 2018.06.21. 22:25

Offline

Csatlakozott: 2011.09.26. 20:33
Hozzászólások: 2105
Megköszönt másnak: 28 alkalommal
Megköszönték neki: 33 alkalommal

https://en.wikipedia.org/wiki/Flying_guillotine

"Lövedéknek" nem igazán hívnám de jó.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Hozzászólások megjelenítése: Rendezés

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 1

[ 2 hozzászólás ]

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 11 vendég

Nem nyithatsz témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Ugrás:

hlmod.hu

[CSO] Flying Guillotine

Ki van itt