hlmod.hu :: OciXCrom Egyszerű Demo felvevö

hlmod.hu https://hlmod.hu/

OciXCrom Egyszerű Demo felvevö https://hlmod.hu/viewtopic.php?f=101&t=30299	Oldal: 1 / 1

Szerző:

ROL_MESTER [ 2020.03.01. 10:24 ]

Hozzászólás témája:

OciXCrom Egyszerű Demo felvevö

Plugin Neve:	OciXCrom Egyszerű Demo felvevö	Plugint készitette:	OciXCrom
Játék:	Counter-Strike	Kategória:	Admin parancsok
Eredeti link:	Megnézem	Jóváhagyó:	Dooz

☄ Leírás

Egy egyszerű beépülő modul a demók automatikus rögzítéséhez színes üzenetekkel.

CVAR lista:
- dem_delay "15.0"> - A szerverre való csatlakozás után ennyi másodperccel később induljon a felvétel.
- dem_msg_delay "0.1"> - A chat üzenetek megjelenítésének késleltetése a felvétel elkezdése után.
- dem_name "CRX Auto Demo" - A demo fájl neve.
- dem_message "!g[!tDemo RecordeR!g] !nA felvétel elkezdődött a !gcstrike !nmappádba: !t<name>" - Az első üzenet.
- dem_message2 "!g[!tDemo RecordeR!g] !nA Demo felvétel elkezdési ideje: !t<time>" - A második üzenet.
- dem_time_format "% X" - A megjelenített idő formátuma (további részletek itt)

Színek és beállítások:
Az üzenetek színezésének letőségei a CromChat-re alapozva működnek.
Az üzenetekhez hozzáadható információk:
- <name> = demo neve
- <time> = felvételi idő kezdete

☄ Telepités

cromchat.inc -> be másolod az include mapába
Az .sma lefordítása után kapott .amxx-et feltöltöd a plugins mappába.
Ezután hozzáadod a plugins.ini-hez a crx_demorecorder.amxx-et.

#include <amxmodx>

#define CC_COLORS_TYPE CC_COLORS_SHORT
#include <cromchat>

#define PLUGIN_VERSION "2.0"
#define MAX_MESSAGE_LENGTH 192
#define MAX_DEMO_NAME_LENGTH 64
#define MAX_TIME_LENGTH 32
#define DEMO_MESSAGES 2
#define REPLACER_SYMBOL "_"

#define ARG_NAME "<name>"
#define ARG_NAME_FULL "<name>.dem"
#define ARG_TIME "<time>"

new const g_szSymbols[][] = { " ", ":", ".", "*", "/", "|", "\", "?", ">", "<" }

enum _:Cvars
{
	dem_delay,
	dem_msg_delay,
	dem_name,
	dem_message,
	dem_message2,
	dem_time_format
}

enum _:CvarValues
{
	Float:cv_dem_delay,
	Float:cv_dem_msg_delay,
	cv_dem_name[MAX_DEMO_NAME_LENGTH],
	cv_dem_message[MAX_MESSAGE_LENGTH],
	cv_dem_message2[MAX_MESSAGE_LENGTH],
	cv_dem_time_format[MAX_TIME_LENGTH]
}

new g_eCvars[Cvars], g_eCvarValues[CvarValues]

public plugin_init()
{
	register_plugin("Simple Demo Recorder", PLUGIN_VERSION, "OciXCrom")
	register_cvar("CRXDemoRecorder", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	
	g_eCvars[dem_delay] = register_cvar("dem_delay", "15.0") //Néhány másodperc után jelentkezzen be a kiszolgálóra a bemutató rögzítésének megkezdéséhez.
	g_eCvars[dem_msg_delay] = register_cvar("dem_msg_delay", "0.1") //A bemutató néhány másodperces felvétele után a csevegési üzenetek elküldésre kerülnek.
	g_eCvars[dem_name] = register_cvar("dem_name", "CRX Auto Demo") //Demó neve
	g_eCvars[dem_message] = register_cvar("dem_message", "!g[!tPrefix!g] !nMost felvesszük hogyan játszol, !gcstrike !nmappában található: !t<name>") //Első üzenet.
	g_eCvars[dem_message2] = register_cvar("dem_message2", "!g[!tPrefix!g] !nDemo felvétele elkezdödőtt: !t<time>") //Második üzenet
	g_eCvars[dem_time_format] = register_cvar("dem_time_format", "%X") //Az idő megjelenítésének módja
}

public plugin_cfg()
{
	g_eCvarValues[cv_dem_delay] = _:get_pcvar_float(g_eCvars[dem_delay])
	g_eCvarValues[cv_dem_msg_delay] = _:get_pcvar_float(g_eCvars[dem_msg_delay])
	get_pcvar_string(g_eCvars[dem_name], g_eCvarValues[cv_dem_name], charsmax(g_eCvarValues[cv_dem_name]))
	get_pcvar_string(g_eCvars[dem_message], g_eCvarValues[cv_dem_message], charsmax(g_eCvarValues[cv_dem_message]))
	get_pcvar_string(g_eCvars[dem_message2], g_eCvarValues[cv_dem_message2], charsmax(g_eCvarValues[cv_dem_message2]))
	get_pcvar_string(g_eCvars[dem_time_format], g_eCvarValues[cv_dem_time_format], charsmax(g_eCvarValues[cv_dem_time_format]))
	
	for(new i; i < sizeof(g_szSymbols); i++)
		replace_all(g_eCvarValues[cv_dem_name], charsmax(g_eCvarValues[cv_dem_name]), g_szSymbols[i], REPLACER_SYMBOL)
		
	add(g_eCvarValues[cv_dem_name], charsmax(g_eCvarValues[cv_dem_name]), ".dem")
}

public client_putinserver(id)
	set_task(g_eCvarValues[cv_dem_delay], "StartRecording", id)

public StartRecording(id)
{
	if(!is_user_connected(id))
		return
	
	client_cmd(id, "stop; record ^"%s^"", g_eCvarValues[cv_dem_name])
	set_task(g_eCvarValues[cv_dem_msg_delay], "SendMessages", id)
}

public SendMessages(id)
{
	if(!is_user_connected(id))
		return
		
	new szMessage[DEMO_MESSAGES][MAX_MESSAGE_LENGTH]
	copy(szMessage[0], charsmax(szMessage[]), g_eCvarValues[cv_dem_message])
	copy(szMessage[1], charsmax(szMessage[]), g_eCvarValues[cv_dem_message2])
	
	for(new i; i < DEMO_MESSAGES; i++)
	{
		apply_replacements(szMessage[i], charsmax(szMessage[]))
		CC_SendMessage(id, szMessage[i])
	}
}

apply_replacements(szMessage[], const iLen)
{
	replace_all(szMessage, iLen, ARG_NAME, g_eCvarValues[cv_dem_name])
	
	if(contain(szMessage, ARG_TIME) != -1)
	{
		new szTime[MAX_TIME_LENGTH]
		get_time(g_eCvarValues[cv_dem_time_format], szTime, charsmax(szTime))
		replace_all(szMessage, iLen, ARG_TIME, szTime)
	}
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

Szerző:	ultraibolya [ 2020.03.01. 10:34 ]
Hozzászólás témája:	Re: OciXCrom Egyszerű Demo felvevö
Cromchat include a tömörített fájlban van? Azt kérlek linkeld a leírásba,vagy a fájlba csatold.

Szerző:	ROL_MESTER [ 2020.03.01. 10:36 ]
Hozzászólás témája:	Re: OciXCrom Egyszerű Demo felvevö
ultraibolya írta: Cromchat include a tömörített fájlban van? Azt kérlek linkeld a leírásba,vagy a fájlba csatold. Szia minden a tömörített fájba meg található!

Szerző:	regener [ 2020.03.01. 13:20 ]
Hozzászólás témája:	Re: OciXCrom Egyszerű Demo felvevö
A Gooogle fordítós szövegeket ne rakjuk már ki légyszives, egy CVAR-t pedig lehagytál a színezésen felül. CVAR lista: - dem_delay "15.0"> - A szerverre való csatlakozás után ennyi másodperccel később induljon a felvétel. - dem_msg_delay "0.1"> - A chat üzenetek megjelenítésének késleltetése a felvétel elkezdése után. - dem_name "CRX Auto Demo" - A demo fájl neve. - dem_message "!g[!tDemo RecordeR!g] !nA felvétel elkezdődött a !gcstrike !nmappádba: !t<name>" - Az első üzenet. - dem_message2 "!g[!tDemo RecordeR!g] !nA Demo felvétel elkezdési ideje: !t<time>" - A második üzenet. - dem_time_format "% X" - A megjelenített idő formátuma (további részletek itt) Színek és beállítások: Az üzenetek színezésének letőségei a CromChat-re alapozva működnek. Az üzenetekhez hozzáadható információk: - <name> = demo neve - <time> = felvételi idő kezdete Eredeti link pedig: https://amxx-bg.info/viewtopic.php?f=32&t=61

Szerző:	ROL_MESTER [ 2020.03.01. 13:32 ]
Hozzászólás témája:	Re: OciXCrom Egyszerű Demo felvevö
regener írta: A Gooogle fordítós szövegeket ne rakjuk már ki légyszives, egy CVAR-t pedig lehagytál a színezésen felül. CVAR lista: - dem_delay "15.0"> - A szerverre való csatlakozás után ennyi másodperccel később induljon a felvétel. - dem_msg_delay "0.1"> - A chat üzenetek megjelenítésének késleltetése a felvétel elkezdése után. - dem_name "CRX Auto Demo" - A demo fájl neve. - dem_message "!g[!tDemo RecordeR!g] !nA felvétel elkezdődött a !gcstrike !nmappádba: !t<name>" - Az első üzenet. - dem_message2 "!g[!tDemo RecordeR!g] !nA Demo felvétel elkezdési ideje: !t<time>" - A második üzenet. - dem_time_format "% X" - A megjelenített idő formátuma (további részletek itt) Színek és beállítások: Az üzenetek színezésének letőségei a CromChat-re alapozva működnek. Az üzenetekhez hozzáadható információk: - <name> = demo neve - <time> = felvételi idő kezdete Eredeti link pedig: https://amxx-bg.info/viewtopic.php?f=32&t=61 Bocsi de elég nehez orosz nyelvröl magyara forditani hogy pontos legyen de javitom a leírást

Szerző:	Dooz [ 2020.06.11. 18:22 ]
Hozzászólás témája:	Re: OciXCrom Egyszerű Demo felvevö
A 3. sorban a #define CC_COLORS_TYPE CC_COLORS_CUSTOM le kellett cserélni a következőre #define CC_COLORS_TYPE CC_COLORS_SHORT, mivel te nem a megfelelő színkódokat használtad a dem_message, illetve dem_message2 cvar-nál. Forráskódot frissítettem.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/