hlmod.hu :: FPS Kijelző (Chat)

hlmod.hu https://hlmod.hu/

FPS Kijelző (Chat) https://hlmod.hu/viewtopic.php?f=101&t=31179	Oldal: 1 / 1

Szerző:

Extreme [ 2021.12.02. 10:07 ]

Hozzászólás témája:

FPS Kijelző (Chat)

Plugin Neve:	FPS Kijelző (Chat)	Plugint készitette:	Extreme
Játék:	Counter-Strike	Kategória:	Szórakoztató
Eredeti link:	Nincs megadva	Jóváhagyó:	Dooz

FPS Kijelző
A Plugin lekéri a játékosok FPS-ét és kijelzi chatbe, állítható, hogy csak a lekérő játékosnak jelezze vagy mindenkinek.

Parancs: /fps

Telepítés:
SMA --> cstrike/addons/amxmodx/scripting
AMXX --> cstrike/addons/amxmodx/plugint (Majd a nevét a plugins.ini-be beleírni a configs mappában.)

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
     
#define PLUGIN_NAME        "FPS Kijelzo"
#define PLUGIN_VERSION        "1.0"
#define PLUGIN_AUTHOR        "Extreme"
     
#pragma semicolon        1
     
#define DELAY_COUNT        1.0  
#define DELAY_COMMAND        5.0    //K�sleltet�s a parancs hasz�latai k�z�tt.
#define COLOR            0x04    //Prefix Sz�n: 0x01 Norm�l, 0x04 Z�ld, 0x03 Csapat sz�n.    
#define MAX_PLAYERS        32 + 1
     
    new g_iUserFPS[MAX_PLAYERS];
     
    new g_irFPS;
    new g_irFPSAll;
    new g_irFPSVisual;
    
    new const C_Prefix[] = "FPS"; //Chat Prefix
     
    public plugin_init()
    {
        register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR);
        register_cvar(PLUGIN_NAME, PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY);
       
        g_irFPS        = register_cvar("cfps",        "1");
        g_irFPSAll    = register_cvar("cfpsall",    "1");
        g_irFPSVisual    = register_cvar("cfpsvisual",    "1");
       
        register_forward(FM_PlayerPreThink, "fwdPlayerPreThink");
       
        register_clcmd("say",            "sayHandle");
        register_clcmd("say /fps",        "cmdAboutrFPS");
        register_clcmd("say_team /fps",    "cmdAboutrFPS");
    }
     
    public fwdPlayerPreThink(id)
    {
        if ( !get_pcvar_num(g_irFPS) )
            return FMRES_IGNORED;
       
        static Float:fGameTime, Float:fCountNext[MAX_PLAYERS], iCountFrames[MAX_PLAYERS];
       
        if ( fCountNext[id] >= (fGameTime = get_gametime()) )
        {
            iCountFrames[id]++;
           
            return FMRES_IGNORED;
        }
       
        g_iUserFPS[id]        = iCountFrames[id];
        iCountFrames[id]    = 0;
       
        fCountNext[id]        = fGameTime + DELAY_COUNT;
       
        return FMRES_IGNORED;
    }
     
    public sayHandle(id)
    {
        if ( !get_pcvar_num(g_irFPS) )
            return PLUGIN_CONTINUE;
       
        new szArgs[64];
        read_args(szArgs, charsmax(szArgs));
        remove_quotes(szArgs);
        trim(szArgs);
       
        if ( !szArgs[0] )
            return PLUGIN_HANDLED;
       
        if ( szArgs[0] != '/' )
            return PLUGIN_CONTINUE;
       
       
        //Command
        new szTarget[32];
       
        parse(szArgs,\
        szArgs, charsmax(szArgs),\
        szTarget, charsmax(szTarget));
       
        if ( !equali(szArgs, "/fps", 4) )
            return PLUGIN_CONTINUE;
        //Command
       
       
        //Delay
        new Float:fCommandDelay = DELAY_COMMAND;
       
        static Float:fCommandUsed[MAX_PLAYERS];
       
        if ( fCommandUsed[id] > get_gametime() )
        {
            printMessage(id, id, "^x01Kérlek várj^x04 %.0f^x03 másodpercet^x01 a parancsok között!", fCommandDelay);
            return PLUGIN_HANDLED;
        }
        //Delay
       
       
        //Display
        trim(szTarget);
       
        if ( !szTarget[0] )
            fCommandUsed[id] = displayFPS(id, id, fCommandDelay);
        else {
            new targetId = cmd_target(id, szTarget, 2);
           
            if ( targetId )
                fCommandUsed[id] = displayFPS(id, targetId, fCommandDelay);
            else {
                printMessage(id, id, "Nem található vagy túl sok játékos található ezzel a névvel: ^x04 %s", szTarget);
                return PLUGIN_HANDLED;
            }
        }
        //Display
       
       
        return get_pcvar_num(g_irFPSVisual) ? PLUGIN_CONTINUE : PLUGIN_HANDLED;
    }
     
    Float:displayFPS(id, targetId, Float:fCommandDelay)  
    {
        new szName[32];
        get_user_name(targetId, szName, charsmax(szName));
       
        new szMsg[192];
        formatex(szMsg, charsmax(szMsg), "^x03%s^x01 FPS-e:^x04 %d", szName, g_iUserFPS[targetId]);
       
        printMessage(id, get_pcvar_num(g_irFPSAll) ? 0 : id, szMsg);
       
        return get_gametime() + fCommandDelay;
    }
     
    printMessage(id, targetId, const sMsg[], any:...)
    {
        new szMessage[192];
       
        vformat(szMessage, charsmax(szMessage), sMsg, 4);
        format(szMessage, charsmax(szMessage), "%c[%s] %s", COLOR, C_Prefix, szMessage);
       
        static iSayText;
       
        if ( !iSayText )
            iSayText = get_user_msgid("SayText");
       
        message_begin(targetId ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, iSayText, {0, 0, 0}, targetId);
        write_byte(id);
        write_string(szMessage);
        message_end();
    }
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1038\\ f0\\ fs16 \n\\ par }
*/

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Szerző:	~Shediboii [ 2021.12.15. 11:57 ]
Hozzászólás témája:	Re: FPS Kijelző (Chat)
#define PLUGIN_NAME "FPS.Meter" #define PLUGIN_VERSION "1.0" #define PLUGIN_AUTHOR "raggy" Eredeti készítő, mikor jár már le az, hogyha nem te írtál valamit, nem írod át az authort? Eredeti link: https://forum.csduragi.com/post313023.html#p313023

Szerző:	regener [ 2021.12.15. 17:31 ]
Hozzászólás témája:	Re: FPS Kijelző (Chat)
Az SMA másolgatását sem értem miért emelik ki a telepítésnél A pluginT mappában meg nem fog menni Mondjuk egy 20 éves játéknál az fps mérést sem értem, de ez +1 felesleges opció a sok mellé...

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/