Regisztrációs Rendszer [Felújított] -hlmod.hu

Megválaszolatlan témák | Aktív témák

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Navigáció

Főmenü

Kezdőlap

Fórum

Kapcsolat

Képfeltöltő Amx Mod X

Letöltések

Pluginok

Fordító (Compiler) SourceMod

Letöltések

Pluginok

Fordító (Compiler) EventScript

Letöltések

Magyar scriptek Pályák

Half-Life

Half-Life 2

Jelenlévő felhasználók

Jelenleg 311 felhasználó van jelen :: 1 regisztrált, 0 rejtett és 310 vendég

A legtöbb felhasználó (2761 fő) 2025.01.09. 20:06-kor tartózkodott itt.

Regisztrált felhasználók: Google [Bot]az elmúlt 5 percben aktív felhasználók alapján

[ Ki van itt ]

Utoljára aktív

Kereső

Regisztrációs Rendszer [Felújított]

Moderátor:Fórum Moderátor

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 1

[3 hozzászólás ]

Nyomtatóbarát verzió |Barát értesítése e-mailben

Előző téma | Következő téma

Szerző

Üzenet

ASDD

Hozzászólás témája: Regisztrációs Rendszer [Felújított]

HozzászólásElküldve:2022.12.04. 17:59

Offline

Csatlakozott:2021.03.16. 10:28
Hozzászólások:49
Megköszönt másnak: 7 alkalommal
Megköszönték neki: 5 alkalommal

Plugin Neve:	Regisztrációs Rendszer [Felújított]	Plugint készitette:	Biel-oGrande
Játék:	Counter-Strike	Kategória:	Technikai/Fejlesztő
Eredeti link:	Nincs megadva	Jóváhagyó:	kiki

Sziasztok!

Hoztam egy felújított Regisztrációs Rendszert amit Biel-oGrande készített!

A plugin segítségével letudjuk védeni a felhasználónkat, más játékosok ellen.
Alapból 2 hibás jelszó beírást enged 3.-nál kitilt (az általunk beállított időre).

Cvarok:

reg_mim_characters "5" — Jelszó minimum karakterszáma.
reg_max_characters "20" — A jelszó maximális karakterszáma.
reg_wrong_passowrd_limit "3" — Próbálkozások bejelentkezéskor.
reg_wrong_passowrd_time_ban "5" — Kitiltás ideje. (Percben)
reg_time_to_log "60"— Rendelkezési idő bejelentkezésre. (Másodpercben)
reg_screenfade "1" — Akik nincsenek bejelentkezve azoknak fekete legyen e képernyerő (1-Igen 0-Nem)

Telepítés:

Szokásos módon + Zip fájlnak megfelelően!

Sma lefordítás:

Probléma lehet:

Akinek nem sikerül lefordítani annak valószínűleg a fordítója nem támogatja azt a include-ot ami szükséges hozzá.

Megoldás:

Zip fájlban lévő include-ot adja hozzá a fordítóhoz és gondmentesen lefordítja!

Képek a pluginról. (Csak telefonnal tudtam fotózni mivel a prntscreent nem támogatta ez miatt offot nem kérek,köszönöm)

https://i.imgur.com/2VQto3B.png

https://i.imgur.com/1iXCAsz.png

https://i.imgur.com/HObZZnM.png

https://i.imgur.com/5vYedmu.png

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <fakemeta>
#if defined _file_vault_included
	#endinput
#endif

#define _file_vault_included

/**
 * FVault was created by Exolent on 8/24/08
 * This vault system uses actual files and no modules
 * It is very flexible and has many features
 * Visit this page for more information: http://forums.alliedmods.net/showthread.php?t=76453
 */

#include <amxmodx>

stock const _vault_dir[] = "addons/amxmodx/data/file_vault";
stock const _temp_vault[] = "fvault_temp.txt";

/** 
 * Retrieves a key name specified by its number
 * 
 * @param vaultname	Vault name to look in
 * @param keynum	Key number within the vault to find key name
 * @param key		String which key name will be copied to
 * @param len		Length of key name
 * @return		Returns 1 on success, 0 on failue.
 */
stock fvault_get_keyname(const vaultname[], const keynum, key[], len)
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	if( !file_exists(filename) )
	{
		return 0;
	}
	
	new vault = fopen(filename, "rt");
	
	new _data[64], _other[3];
	
	new line = -1;
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		
		if( ++line == keynum )
		{
			parse(_data, key, len, _other, sizeof(_other) - 1);
			
			fclose(vault);
			
			return 1;
		}
	}
	
	fclose(vault);
	
	return 0;
}

/** 
 * Retrieves a key number specified by its name
 * 
 * @param vaultname	Vault name to look in
 * @param key		Key name to search for
 * @return		Returns key number on success, -1 on failure
 */
stock fvault_get_keynum(const vaultname[], const key[])
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	if( !file_exists(filename) )
	{
		return -1;
	}
	
	new vault = fopen(filename, "rt");
	
	new _data[70], _key[64], _other[3];
	
	new line = -1;
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		parse(_data, _key, sizeof(_key) - 1, _other, sizeof(_other) - 1);
		
		line++;
		
		if( equal(_key, key) )
		{
			fclose(vault);
			
			return line;
		}
	}
	
	fclose(vault);
	
	return -1;
}

/** 
 * Retrieves data specified by a key
 * 
 * @param vaultname	Vault name to look in
 * @param key		Key name to look for the data
 * @param data		String which data will be copied to
 * @param len		Length of data
 * @param timestamp	The unix time of when the data was last set ( -1 if permanent data, 0 if old fvault version ) ( optional param )
 * @return		Returns 1 on success, 0 on failue.
 */
stock fvault_get_data(const vaultname[], const key[], data[], len, ×tamp=0)
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	if( !file_exists(filename) )
	{
		return 0;
	}
	
	new vault = fopen(filename, "rt");
	
	new _data[512], _key[64], _time[32];
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		parse(_data, _key, sizeof(_key) - 1);
		
		if( equal(_key, key) )
		{
			new _len = strlen(_key) + 4; // + 2 = quotes on key, + 1 = space, + 1 = first quote
			for( new i = copy(data, len, _data[_len]) - 1; i > 0; i-- )
			{
				if( data[i] == '"' ) break;
				
				if( data[i] == ' '
				&& data[i - 1] == '"' )
				{
					data[i - 1] = '^0';
					
					copy(_time, sizeof(_time) - 1, data[i + 1]);
					timestamp = str_to_num(_time);
					break;
				}
			}
			
			fclose(vault);
			
			return 1;
		}
	}
	
	fclose(vault);
	
	copy(data, len, "");
	
	return 0;
}

/** 
 * Sets data of a key with current timestamp
 * 
 * @param vaultname	Vault name to look in
 * @param key		Key name to which data will be set
 * @param data		Data to set to key
 * @return		Does not return a value.
 */
stock fvault_set_data(const vaultname[], const key[], const data[])
{
	_fvault_set_data(vaultname, key, data, get_systime());
}

/** 
 * Sets data of a key permanently (can't be removed with fvault_prune)
 * 
 * @param vaultname	Vault name to look in
 * @param key		Key name to which data will be set
 * @param data		Data to set to key
 * @return		Does not return a value.
 */
stock fvault_pset_data(const vaultname[], const key[], const data[])
{
	_fvault_set_data(vaultname, key, data, -1);
}

_fvault_set_data(const vaultname[], const key[], const data[], const timestamp)
{
	new file = fopen(_temp_vault, "wt");
	
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	new vault = fopen(filename, "rt");
	
	new _data[512], _key[64], _other[3];
	
	new bool:replaced = false;
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		parse(_data, _key, sizeof(_key) - 1, _other, sizeof(_other) - 1);
		
		if( equal(_key, key) && !replaced )
		{
			fprintf(file, "^"%s^" ^"%s^" %i^n", key, data, timestamp);
			
			replaced = true;
		}
		else
		{
			fputs(file, _data);
		}
	}
	
	fclose(file);
	fclose(vault);
	
	if( !replaced )
	{
		file = fopen(filename, "a+");
		fprintf(file, "^"%s^" ^"%s^" %i^n", key, data, timestamp);
		fclose(file);
		
		delete_file(_temp_vault);
	}
	else
	{
		delete_file(filename);
		
		while( !rename_file(_temp_vault, filename, 1) ) { }
	}
}

/** 
 * Removes a key from a vault
 * 
 * @param vaultname	Vault name to look in
 * @param key		Key to remove
 * @return		No return
 */
stock fvault_remove_key(const vaultname[], const key[])
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	if( !file_exists(filename) )
	{
		return;
	}
	
	new file = fopen(_temp_vault, "wt");
	
	new vault = fopen(filename, "rt");
	
	new _data[512], _key[64], _other[3];
	new bool:found_key;
	
	while( !feof(vault) )
	{
		fgets(vault, _data, sizeof(_data) - 1);
		parse(_data, _key, sizeof(_key) - 1, _other, sizeof(_other) - 1);
		
		if( equal(_key, key) )
		{
			found_key = true;
			continue;
		}
		
		fputs(file, _data);
	}
	
	fclose(file);
	fclose(vault);
	
	if( found_key )
	{
		delete_file(filename);
		
		while( !rename_file(_temp_vault, filename, 1) ) { }
	}
	else
	{
		delete_file(_temp_vault);
	}
}

/**
 * Prunes the vault for keys that are within the given timestamps
 * 
 * @param vaultname	Vault name to look in
 * @param start		If timestamp is after this Unix Time (set -1 to prune from very start)
 * @param end		If timestamp is before this Unix Time (set -1 to prune to most time)
 * @return		Returns number of keys pruned
 */
stock fvault_prune(const vaultname[], const start=-1, const end=-1)
{
	if( start == -1 && end == -1 )
	{
		new keys = fvault_size(vaultname);
		if( keys )
		{
			fvault_clear(vaultname);
		}
		
		return keys;
	}
	
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	if( !file_exists(filename) )
	{
		return 0;
	}
	
	new file = fopen(_temp_vault, "wt");
	new vault = fopen(filename, "rt");
	
	new keys;
	
	new data[512], i, _time[32], timestamp;
	while( !feof(vault) )
	{
		fgets(vault, data, sizeof(data) - 1);
		
		if( data[0] )
		{
			_time[0] = 0;
			
			for( i = strlen(data) - 1; i >= 0; i-- )
			{
				if( data[i] == '"' ) break;
				
				if( data[i] == ' ' )
				{
					copy(_time, sizeof(_time) - 1, data[i + 1]);
					break;
				}
			}
			
			timestamp = str_to_num(_time);
			if( timestamp != -1 )
			{
				if( start == -1 && timestamp <= end
				|| end == -1 && timestamp >= start
				|| start <= timestamp <= end )
				{
					keys++;
					continue;
				}
			}
		}
		
		fputs(file, data);
	}
	
	fclose(file);
	fclose(vault);
	
	if( keys )
	{
		delete_file(filename);
		
		while( !rename_file(_temp_vault, filename, 1) ) { }
	}
	else
	{
		delete_file(_temp_vault);
	}
	
	return keys;
}

/**
 * Updates the timestamp on a key located within the vault
 * 
 * @param vaultname	Vault name to look in
 * @param key		Key to update timestamp (if it doesn't exist, a blank value will be set)
 * @param timestamp	Unix Time to set for the key (-1 for current time)
 * @return		Returns 2 on new entry, 1 on success, 0 on failure for the key having a permanent timestamp
 */
stock fvault_touch(const vaultname[], const key[], const timestamp=-1)
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	static new_time;
	if( (new_time = timestamp) == -1 )
	{
		new_time = get_systime();
	}
	
	if( !file_exists(filename) )
	{
		new vault = fopen(filename, "wt");
		fprintf(vault, "^"%s^" ^"^" %i^n", key, new_time);
		fclose(vault);
		return 2;
	}
	
	new file = fopen(_temp_vault, "wt");
	new vault = fopen(filename, "rt");
	
	new bool:updated;
	
	new data[512], _key[64], len, i, _time[32];
	while( !feof(vault) )
	{
		fgets(vault, data, sizeof(data) - 1);
		parse(data, _key, sizeof(_key) - 1);
		
		if( equal(_key, key) )
		{
			_time[0] = 0;
			
			for( i = strlen(data) - 1; i >= 0; i-- )
			{
				if( data[i] == '"' ) break;
				
				if( data[i] == ' ' )
				{
					data[i] = '^0';
					copy(_time, sizeof(_time) - 1, data[i + 1]);
					break;
				}
			}
			
			if( str_to_num(_time) == -1 )
			{
				fclose(file);
				fclose(vault);
				
				delete_file(_temp_vault);
				
				return 0;
			}
			
			fprintf(file, "%s %i^n", data, new_time);
			
			updated = true;
		}
		else
		{
			fputs(file, data);
		}
	}
	
	if( !updated )
	{
		fprintf(file, "^"%s^" ^"^" %i^n", key, new_time);
	}
	
	fclose(file);
	fclose(vault);
	
	delete_file(filename);
	
	while( !rename_file(_temp_vault, filename, 1) ) { }
	
	return (_:(!updated) + 1);
}

/** 
 * Retrieves total keys located within the vault
 * 
 * @param vaultname	Vault name to look in
 * @return		Returns amount of keys in vault
 */
stock fvault_size(const vaultname[])
{
	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	return file_exists(filename) ? file_size(filename, 1) - 1 : 0;
}

/** 
 * Clears all key entries for a vault
 * 
 * @param vaultname	Vault name to erase
 * @return		No return
 */
stock fvault_clear(const vaultname[])
{
 	new filename[128];
	_FormatVaultName(vaultname, filename, sizeof(filename) - 1);
	
	fclose(fopen(filename, "wt"));
}

/** 
 * Retrieves a vault name specified by its number
 * 
 * @param vaultnum	Vault number to find the vault name
 * @param vaultname	String which vault name will be copied to
 * @param len		Length of vault name
 * @return		Returns 1 on success, 0 on failue.
 */
stock fvault_get_vaultname(const vaultnum, vaultname[], len)
{
	if( !dir_exists(_vault_dir) )
	{
		mkdir(_vault_dir);
		return 0;
	}
	
	new filenum;
	
	new dir = open_dir(_vault_dir, vaultname, len);
	
	do
	{
		if( equal(vaultname, ".") || equal(vaultname, "..") )
		{
			continue;
		}
		
		if( filenum == vaultnum )
		{
			close_dir(dir);
			
			replace(vaultname, len, ".txt", "");
			
			return 1;
		}
		
		++filenum;
	}
	while( next_file(dir, vaultname, len) );
	
	close_dir(dir);
	
	copy(vaultname, len, "");
	
	return 0;
}

/** 
 * Retrieves a vault number specified by its name
 * 
 * @param vaultname	Vault name to find the number
 * @return		Returns vault number on success, -1 on failure
 */
stock fvault_get_vaultnum(const vaultname[])
{
	if( !dir_exists(_vault_dir) )
	{
		mkdir(_vault_dir);
		return -1;
	}
	
	new filename[128], filenum;
	
	new dir = open_dir(_vault_dir, filename, sizeof(filename) - 1);
	
	do
	{
		if( equal(filename, ".") || equal(filename, "..") )
		{
			continue;
		}
		
		replace(filename, sizeof(filename) - 1, ".txt", "");
		
		if( equal(filename, vaultname) )
		{
			close_dir(dir);
			
			return filenum;
		}
		
		++filenum;
	}
	while( next_file(dir, filename, sizeof(filename) - 1) );
	
	close_dir(dir);
	
	copy(vaultname, len, "");
	
	return -1;
}

/** 
 * Retrieves total vaults ever created
 * 
 * @return		Returns amount of vaults
 */
stock fvault_total()
{
	if( !dir_exists(_vault_dir) )
	{
		mkdir(_vault_dir);
		return 0;
	}
	
	new vaultname[128], filename[128];
	new dir = open_dir(_vault_dir, vaultname, sizeof(vaultname) - 1);
	
	new filenum;
	do
	{
		if( equal(vaultname, ".") || equal(vaultname, "..") )
		{
			continue;
		}
		
		formatex(filename, sizeof(filename) - 1, "%s/%s", _vault_dir, vaultname);
		if( file_exists(filename) )
		{
			++filenum;
		}
	}
	while( next_file(dir, vaultname, sizeof(vaultname) - 1) );
	
	close_dir(dir);
	
	return filenum;
}

/**
 * Gets all vault keys, data, and timestamps
 * 
 * @param		vaultname - Vault name to look in
 * @param		keys - cellarray holding all of the keys
 * @param		datas - cellarray holding all of the data values
 * @param		timestamps - cellarray holding all of the timestamps
 * 
 * @return		Returns total number of entries in vault
 * 
 * @note		keys needs to be created like this: ArrayCreate(64)
 * 			datas needs to be created like this: ArrayCreate(512)
 * 			timestamps need to be created like this: ArrayCreate()
 */
stock fvault_load(const vaultname[], Array:keys=Invalid_Array, Array:datas=Invalid_Array, Array:timestamps=Invalid_Array)
{
	new filename[128];
	_FormatVaultName(vaultname, filename, 127);
	
	if( !file_exists(filename) )
	{
		return 0;
	}
	
	new vault = fopen(filename, "rt");
	
	new array_size;
	
	new filedata[1024];
	new key[64], data[512], timestamp[32];
	while( !feof(vault) )
	{
		fgets(vault, filedata, 1023);
		
		if( parse(filedata, key, 63, data, 511, timestamp, 31) < 2 )
		{
			continue;
		}
		
		if( keys != Invalid_Array )
		{
			ArrayPushString(keys, key);
		}
		if( datas != Invalid_Array )
		{
			ArrayPushString(datas, data);
		}
		if( timestamps != Invalid_Array )
		{
			ArrayPushCell(timestamps, str_to_num(timestamp));
		}
		
		array_size++;
	}
	
	fclose(vault);
	
	return array_size;
}
 
stock _FormatVaultName(const vaultname[], filename[], len)
{
	static const invalid_chars[][] =
	{
		"/", "\", "*", ":", "?", "^"", "<", ">", "|"
	};
	
	static tempvault[128], i;
	copy(tempvault, sizeof(tempvault) - 1, vaultname);
	
	for( i = 0; i < sizeof(invalid_chars); i++ )
	{
		replace_all(tempvault, sizeof(tempvault) - 1, invalid_chars[i], "");
	}
	
	if( !dir_exists(_vault_dir) )
	{
		mkdir(_vault_dir);
	}
	
	formatex(filename, len, "%s/%s.txt", _vault_dir, tempvault);
}
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1033\\ f0\\ fs16 \n\\ par }
*/

#define PLUGIN "Registration System"
#define VERSION "2022 v3.0"
#define AUTHOR "Biel-oGrande" //

new const g_fvault[ ] = "accounts"

enum _:TOTAL_FORWARDS {
	
	FW_USER_REGISTER,
	FW_USER_LOGGED,
	FW_USER_LOGGED_INVITED,
	FW_USER_ACCOUNT_DELETED
}

new g_Forwards[TOTAL_FORWARDS]
new g_ForwardResult

new g_logged[33], g_registered[33], g_invited[33]

new g_password[33], g_password_again[33]

new g_attempts[33], g_unlock[33], g_deleted_account[33]

new cvar_attempts, cvar_bantime, cvar_logintime, cvar_screenfade, cvar_mim_characters, cvar_max_characters

new g_screenfade

public plugin_init() {
	
	register_plugin(PLUGIN, VERSION, AUTHOR)
	
	register_cvar("registration_system", VERSION, FCVAR_SPONLY | FCVAR_SERVER )
	
	register_clcmd("chooseteam", "message_team")
	register_clcmd("jointeam", "message_team")
	register_clcmd("joinclass", "message_team")
	
	register_forward(FM_ClientUserInfoChanged, "ClientUserInfoChanged")
	register_forward(FM_PlayerPreThink, "PlayerPreThink")
	
	register_clcmd("ENTER_YOUR_PASSWORD","cmd_password")
	register_clcmd("ENTER_YOUR_PASSWORD_AGAIN","cmd_password_again")
	register_clcmd("ENTER_YOUR_PASSWORD_CURRENT","cmd_password_current")
	
	register_clcmd("say", "commands")
	register_clcmd("say_team", "commands")
	
	register_dictionary("registration_system.txt")
	
	cvar_mim_characters = register_cvar("reg_mim_characters", "5")
	cvar_max_characters = register_cvar("reg_max_characters", "20")
	
	cvar_attempts = register_cvar("reg_wrong_passowrd_limit", "3")
	cvar_bantime = register_cvar("reg_wrong_passowrd_time_ban", "5")
	cvar_logintime = register_cvar("reg_time_to_log", "60")
	cvar_screenfade = register_cvar("reg_screenfade", "1")
	
	g_screenfade = get_user_msgid("ScreenFade")
	
	g_Forwards[FW_USER_REGISTER] = CreateMultiForward("reg_user_register", ET_IGNORE, FP_CELL)
	g_Forwards[FW_USER_LOGGED] = CreateMultiForward("reg_user_logged", ET_IGNORE, FP_CELL)
	g_Forwards[FW_USER_LOGGED_INVITED] = CreateMultiForward("reg_user_logged_invited", ET_IGNORE, FP_CELL)
	g_Forwards[FW_USER_ACCOUNT_DELETED] = CreateMultiForward("reg_user_account_deleted", ET_IGNORE, FP_CELL)
}

public plugin_natives() {
	
	register_native("reg_is_user_logged", "native_is_user_logged", 1)
	register_native("reg_is_user_registered", "native_is_user_registered", 1)
	register_native("reg_is_user_invited", "native_is_user_invited", 1)
}

public client_connect(id) {
	
	client_cmd(id, "setinfo ^"_vgui_menus^" ^"1^"")
}

public client_putinserver(id) {
	
	static szName[32], szData[64]
	get_user_name(id, szName, charsmax(szName))
	set_task(get_pcvar_float(cvar_logintime), "login_time", id )
	
	g_unlock[id] = true
	
	if(fvault_get_data(g_fvault, szName, szData, charsmax(szData)))
		g_registered[id] = true
	else
		g_registered[id] = false	
}

public client_disconnect(id) {
	
	remove_task(id)
	g_logged[id] = false
	g_invited[id] = false
	g_unlock[id] = false
}

public message_team(id) {
	
	if(!g_logged[id] && !g_invited[id] && !is_user_bot(id) && !is_user_hltv(id)) {
		
		menu_account(id)
		return PLUGIN_HANDLED
	}
	return PLUGIN_CONTINUE
}

public ClientUserInfoChanged(id) { 
	
	static szOldName[32]
	pev(id, pev_netname, szOldName, charsmax(szOldName))
	
	if(szOldName[0]) {
		
		static const name[] = "name"
		static szNewName[32]
		get_user_info(id, name, szNewName, charsmax(szNewName))
		
		if(!equal(szOldName, szNewName)) {
			
			set_user_info(id, name, szOldName)
			return FMRES_HANDLED
		}
	}
	return FMRES_IGNORED
}

public menu_account(id) {
	
	new szMenu[128], szName[32]
	get_user_name(id, szName, charsmax(szName))
	
	formatex(szMenu, 127, "\r%L^n^n\r\r%L\d: \w[\y%s\w]^n\r%L\d: \w[\y%L\w]", LANG_PLAYER, "MENU_ACCOUNT_TITLE", LANG_PLAYER, "MENU_ACCOUNT_NICK", szName, LANG_PLAYER, "MENU_ACCOUNT_STATUS", 
	LANG_PLAYER, g_invited[id] ? "MENU_ACCOUNT_INVITED" : g_logged[id] ? "MENU_ACCOUNT_LOGGED" : g_registered[id] ? "MENU_ACCOUNT_REGISTERED" : "MENU_ACCOUNT_NOT_REGISTERED")
	
	new Menu = menu_create(szMenu, "handler_menu_account")
	
	formatex(szMenu, 63, "%s%L", g_logged[id] ? "\d" : g_registered[id] ? "\y" : "\d", LANG_PLAYER, "MENU_ACCOUNT_00")
	menu_additem(Menu, szMenu, "1", 0)
	
	formatex(szMenu, 63, "%s%L^n", g_registered[id] ? "\d":"\r", LANG_PLAYER, "MENU_ACCOUNT_01")
	menu_additem(Menu, szMenu, "2", 0)
	
	formatex(szMenu, 63, "%s%L", g_logged[id] ? "\w" : "\d", LANG_PLAYER, "MENU_ACCOUNT_02")
	menu_additem(Menu, szMenu, "3", 0)
	
	formatex(szMenu, 63, "%s%L^n", g_logged[id] ? "\w" :  "\d", LANG_PLAYER, "MENU_ACCOUNT_03")
	menu_additem(Menu, szMenu, "4", 0)
	
	formatex(szMenu, 63, "%s%L", g_registered[id] ? "\d" : g_invited[id] ? "\d" : "\y", LANG_PLAYER, "MENU_ACCOUNT_04")
	menu_additem(Menu, szMenu, "5", 0)
	
	formatex(szMenu, 63, "%L", LANG_PLAYER, "MENU_ACCOUNT_EXIT")
	menu_setprop(Menu, MPROP_EXITNAME, szMenu)
	menu_display(id, Menu, 0)
}

public handler_menu_account(id, menu, item) {
	
	if(item == MENU_EXIT) {
		
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}
	switch(item) {
		
		case 0: login(id)
			case 1: register(id)
			case 2: change(id)	
			case 3: delete_account(id) 
			case 4: invited(id)
		}
	menu_destroy(menu)
	return PLUGIN_HANDLED
}

public login(id) {
	
	if(g_logged[id]) {
		
		menu_account(id)
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "MENU_ACCOUNT_CASE_00_A")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_ACCOUNT_CASE_00_A")
	}
	else if(!g_registered[id]) {
		
		menu_account(id)
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "MENU_ACCOUNT_CASE_00_B")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_ACCOUNT_CASE_00_B")
	}
	else {
		
		client_cmd(id,"messagemode ENTER_YOUR_PASSWORD")
		set_hudmessage(0, 255, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "MENU_ACCOUNT_CASE_00_C")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_ACCOUNT_CASE_00_C")
		g_unlock[id] = false
	}
	return PLUGIN_HANDLED
}

public register(id) {
	
	if(g_registered[id]) {
		
		menu_account(id)
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "MENU_ACCOUNT_CASE_01_A")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_ACCOUNT_CASE_01_A")
	}
	else {
		
		client_cmd(id,"messagemode ENTER_YOUR_PASSWORD")
		set_hudmessage(0, 255, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "MENU_ACCOUNT_CASE_01_B")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_ACCOUNT_CASE_01_B")
		g_unlock[id] = false
	}
	return PLUGIN_HANDLED
}

public change(id) {
	
	if(!g_logged[id]) {
		
		menu_account(id)
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "MENU_ACCOUNT_CASE_02_A")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_ACCOUNT_CASE_02_A")
	}
	else {
		
		client_cmd(id,"messagemode ENTER_YOUR_PASSWORD_CURRENT")
		set_hudmessage(0, 255, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "MENU_ACCOUNT_CASE_02_B")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_ACCOUNT_CASE_02_B")
		g_unlock[id] = false
	}
	return PLUGIN_HANDLED
}

public delete_account(id) {
	
	if(!g_logged[id]) {
		
		menu_account(id)
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "MENU_ACCOUNT_CASE_03_A")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_ACCOUNT_CASE_03_A")
	}
	else {
		
		client_cmd(id,"messagemode ENTER_YOUR_PASSWORD_CURRENT")
		set_hudmessage(0, 255, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "MENU_ACCOUNT_CASE_03_B")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_ACCOUNT_CASE_03_B")
		g_unlock[id] = false
		g_deleted_account[id] = true
	}
	return PLUGIN_HANDLED
}

public invited(id) {
	
	new szName[32]
	get_user_name(id, szName, charsmax(szName))
	
	if(g_registered[id]) {
		
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "MENU_ACCOUNT_CASE_04_A")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_ACCOUNT_CASE_04_A")
		menu_account(id)
	}
	else if(g_invited[id]) {
		
		menu_account(id)
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "MENU_ACCOUNT_CASE_04_B")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_ACCOUNT_CASE_04_B")
	}
	else {
		
		client_cmd(id, "jointeam")
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "MENU_ACCOUNT_CASE_04_C")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_ACCOUNT_CASE_04_C")
		ExecuteForward(g_Forwards[FW_USER_LOGGED_INVITED], g_ForwardResult, id)
		g_invited[id] = true
	}
	return PLUGIN_HANDLED
}

public cmd_password(id) {
	
	if(g_unlock[id]) return PLUGIN_HANDLED
	
	new szName[32], szData[64]
	get_user_name(id, szName, charsmax(szName))
	fvault_get_data(g_fvault, szName, szData, charsmax(szData))		
	
	read_args(g_password[id], 50)
	remove_quotes(g_password[id])
	trim(g_password[id])
	
	g_unlock[id] = true
	
	if(!characters(g_password[id], strlen(g_password[id]))) {
		
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "CMD_PASSWORD_00")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "CMD_PASSWORD_00")
		menu_account(id)
	}
	else if(strlen(g_password[id]) < get_pcvar_num(cvar_mim_characters)) {
		
		menu_account(id)
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "CMD_PASSWORD_01", get_pcvar_num(cvar_mim_characters))
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "CMD_PASSWORD_01", get_pcvar_num(cvar_mim_characters))
	}
	else if(strlen(g_password[id]) > get_pcvar_num(cvar_max_characters)) {
		
		menu_account(id)
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 10.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "CMD_PASSWORD_02",get_pcvar_num( cvar_max_characters))
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "CMD_PASSWORD_02",get_pcvar_num( cvar_max_characters))
	}
	else if(equal(g_password[id], szName[id])) {
		
		menu_account(id)
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 10.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "CMD_PASSWORD_03")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "CMD_PASSWORD_03")
	}
	else if(g_logged[id]) {
		
		if(!equal(szData, g_password[id])) {
			
			client_cmd(id,"messagemode ENTER_YOUR_PASSWORD_AGAIN")
			set_hudmessage(0, 255, 0, 0.02, 0.17, 0, 6.0, 12.0)
			show_hudmessage(id, "%L", LANG_PLAYER, "CMD_PASSWORD_04")
			client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "CMD_PASSWORD_04")
			g_unlock[id] = false
		}
		else {
			
			menu_account(id)
			set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 10.0)
			show_hudmessage(id, "%L", LANG_PLAYER, "CMD_PASSWORD_05")
			client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "CMD_PASSWORD_05")
		}
	}
	else if(!g_registered[id]) {
		
		client_cmd(id,"messagemode ENTER_YOUR_PASSWORD_AGAIN")
		set_hudmessage(0, 255, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "CMD_PASSWORD_06")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "CMD_PASSWORD_06")
		g_unlock[id] = false
	}
	else {
		
		if(equal(szData, g_password[id])) {
			
			remove_task(id)
			client_cmd(id, "jointeam")
			set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
			show_hudmessage(id, "%L", LANG_PLAYER, "CMD_PASSWORD_07")
			client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "CMD_PASSWORD_07")			
			ExecuteForward(g_Forwards[FW_USER_LOGGED], g_ForwardResult, id)
			
			g_logged[id] = true
			g_attempts[id] = 0
		}
		else {
			
			wrong_password(id)
		}
	}
	return PLUGIN_HANDLED
}

public cmd_password_again(id) {
	
	if(g_unlock[id]) return PLUGIN_HANDLED
	
	read_args(g_password_again[id], 50)
	remove_quotes(g_password_again[id])
	trim(g_password_again[id])
	
	g_unlock[id] = true
	
	if(!equal(g_password[id], g_password_again[id])) {
		
		menu_account(id)
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "CMD_PASSOWORD_AGAIN_00")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "CMD_PASSOWORD_AGAIN_00")	
	}
	else if(!g_registered[id]) {
		
		menu_end_register(id)
		set_hudmessage(0, 255, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "CMD_PASSOWORD_AGAIN_01")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "CMD_PASSOWORD_AGAIN_01")	
	}
	else {
		
		menu_change_password(id)
		set_hudmessage(255, 0, 0, 0.02, 0.17, 0, 6.0, 12.0)
		show_hudmessage(id, "%L", LANG_PLAYER, "CMD_PASSOWORD_AGAIN_02")
		client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "CMD_PASSOWORD_AGAIN_02")	
	}
	return PLUGIN_HANDLED
}

public cmd_password_current(id) {
	
	if(g_unlock[id]) return PLUGIN_HANDLED
	
	new szName[32], szData[64]
	get_user_name(id, szName, charsmax(szName))
	fvault_get_data(g_fvault, szName, szData, charsmax(szData))		
	
	read_args(g_password[id], 50)
	remove_quotes(g_password[id])
	trim(g_password[id])
	
	g_unlock[id] = true
	
	if(equal(szData, g_password[id])) {
		
		if(g_deleted_account[id]) {
			
			menu_delete_account(id)
			g_unlock[id] = false
			g_deleted_account[id] = false
		}
		else {
			
			client_cmd(id,"messagemode ENTER_YOUR_PASSWORD")
			set_hudmessage(0, 255, 0, 0.02, 0.17, 0, 6.0, 12.0)
			show_hudmessage(id, "%L", LANG_PLAYER, "CMD_PASSWORD_CURRENT_00")
			client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "CMD_PASSWORD_CURRENT_00")	
			g_unlock[id] = false
		}
	}
	else {
		
		wrong_password(id)
	}
	return PLUGIN_HANDLED
}

public menu_end_register(id) {
	
	new szMenu[128], szName[32]
	get_user_name(id, szName, charsmax(szName))
	
	formatex(szMenu,127, "\r%L^n^n\y%L: \r[\d%s\r]^n\y%L: \r[\d%s\r]", LANG_PLAYER, "MENU_END_REGISTER_TITLE", LANG_PLAYER, "MENU_END_REGISTER_NICK", szName, LANG_PLAYER, "MENU_END_REGISTER_PASSWORD", g_password_again[id])
	
	new Menu = menu_create(szMenu, "handler_menu_end_register")
	
	formatex(szMenu, 63, "%L", LANG_PLAYER, "MENU_END_REGISTER_00")
	menu_additem(Menu, szMenu, "1", 0)
	
	formatex(szMenu, 63, "\r%L^n", LANG_PLAYER, "MENU_END_REGISTER_01")
	menu_additem(Menu, szMenu, "2", 0)
	
	formatex(szMenu, 63, "\y%L", LANG_PLAYER, "MENU_END_REGISTER_02")
	menu_additem(Menu, szMenu, "3", 0)
	
	menu_setprop(Menu, MPROP_EXIT, MEXIT_NEVER)
	menu_display(id, Menu, 0)
}

public handler_menu_end_register(id, menu, item) {
	
	if(item == MENU_EXIT) {
		
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}
	switch(item) {
		
		case 0: end_register(id)
			case 1: register(id)
			case 2: menu_account(id)
		}
	menu_destroy(menu)
	return PLUGIN_HANDLED
}

public end_register(id) {
	
	new szName[32]
	get_user_name(id, szName, charsmax(szName))
	
	fvault_set_data(g_fvault, szName, g_password_again[id])
	
	set_hudmessage(0, 0, 255, 0.02, 0.25, 0, 6.0, 15.0)
	show_hudmessage(id, "%L", LANG_PLAYER, "MENU_END_REGISTER_CASE_00_A")
	client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_END_REGISTER_CASE_00_A")	
	client_print_color(id, "!g%L !t%L: !y[!g %s !y] !t%L: !y[!g %s !y]", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_END_REGISTER_CASE_00_B_NICK", szName, LANG_PLAYER, "MENU_END_REGISTER_CASE_00_B_PASSOWORD", g_password_again[id])
	
	remove_task(id)
	
	ExecuteForward(g_Forwards[FW_USER_REGISTER], g_ForwardResult, id)
	g_registered[id] = true
	g_logged[id] = true
	
	if(g_invited[id]) {
		
		menu_account(id)
		g_invited[id] = false
	}
	else {
		
		client_cmd(id, "jointeam")
	}
}

public menu_change_password(id) {
	
	new szMenu[128], szName[32]
	get_user_name(id, szName, charsmax(szName))
	
	formatex(szMenu, 127, "\r%L^n^n\y%L: \r[\d%s\r]^n\y%L: \r[\d%s\r]", LANG_PLAYER, "MENU_CHANGE_PASSWORD_TITLE", LANG_PLAYER, "MENU_CHANGE_PASSWORD_NICK", szName, LANG_PLAYER, "MENU_CHANGE_PASSWORD_PASSWORD", g_password_again[id])
	
	new Menu = menu_create(szMenu,"handler_menu_change_password")
	
	formatex(szMenu, 63, "%L", LANG_PLAYER, "MENU_CHANGE_PASSWORD_00")
	menu_additem(Menu, szMenu, "1", 0)
	
	formatex(szMenu, 63, "\r%L^n", LANG_PLAYER, "MENU_CHANGE_PASSWORD_01")
	menu_additem(Menu, szMenu, "2", 0)
	
	formatex(szMenu, 63, "\y%L", LANG_PLAYER, "MENU_CHANGE_PASSWORD_02")
	menu_additem(Menu, szMenu, "3", 0)
	
	menu_setprop(Menu, MPROP_EXIT, MEXIT_NEVER)
	menu_display(id, Menu, 0)
}

public handler_menu_change_password(id, menu, item) {
	
	if(item == MENU_EXIT) {
		
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}
	switch(item) {
		
		case 0: replaced_password(id)
			case 1: change(id)
			case 2: menu_account(id)
		}
	menu_destroy(menu)
	return PLUGIN_HANDLED
}

public replaced_password(id) {
	
	new szName[32]
	get_user_name(id, szName, charsmax(szName))
	fvault_set_data(g_fvault, szName, g_password_again[id])
	
	set_hudmessage(0, 0, 255, 0.02, 0.25, 0, 6.0, 15.0)
	show_hudmessage(id, "%L", LANG_PLAYER, "MENU_CHANGE_PASSWORD_CASE_00_A")
	client_print_color(id, "!g%L !t%L", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_CHANGE_PASSWORD_CASE_00_A")	
	client_print_color(id, "!g%L !t%L: !y[!g %s !y]", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "MENU_CHANGE_PASSWORD_CASE_00_B_PASSWORD", g_password_again[id])
	
	g_attempts[id] = 0
}

public menu_delete_account(id) {
	
	new szMenu[128]
	
	formatex(szMenu, 127, "\r%L", LANG_PLAYER, "MENU_DELETED_ACCOUNT_TITLE")
	
	new Menu = menu_create(szMenu,"handler_menu_delete_account")
	
	formatex(szMenu, 63, "%L", LANG_PLAYER, "MENU_DELETED_ACCOUNT_00")
	menu_additem(Menu, szMenu, "1", 0)
	
	formatex(szMenu, 63, "\r%L", LANG_PLAYER, "MENU_DELETED_ACCOUNT_01")
	menu_additem(Menu, szMenu, "2",0)
	
	menu_setprop(Menu, MPROP_EXIT, MEXIT_NEVER)
	menu_display(id, Menu, 0)
}

public handler_menu_delete_account(id, menu, item) {
	
	if(item == MENU_EXIT) {
		
		menu_destroy(menu)
		return PLUGIN_HANDLED
	}
	switch(item) {
		
		case 0: account_deleted(id)
			case 1: menu_account(id)
		}
	menu_destroy(menu)
	return PLUGIN_HANDLED
}

public account_deleted(id) {
	
	new szName[32]
	get_user_name(id, szName, charsmax(szName))
	
	fvault_remove_key(g_fvault, szName)
	
	ExecuteForward(g_Forwards[FW_USER_ACCOUNT_DELETED], g_ForwardResult, id)
	
	client_print(id, print_console, "----------------------------------------")
	client_print(id, print_console, "----- %L -------", LANG_PLAYER, "MENU_DELETED_ACCOUNT_CASE_00")
	client_print(id, print_console, "----------------------------------------")	
	client_cmd(id, "disconnect")
	client_cmd(id, "toggleconsole")	
}

public wrong_password(id) {
	
	g_attempts[id]++
	if(g_attempts[id] >= get_pcvar_num(cvar_attempts)) {
		
		server_cmd("amx_banip #%i %i ^"%L^"", get_user_userid(id), get_pcvar_num(cvar_bantime), LANG_PLAYER, "WRONG_PASSWORD_00", get_pcvar_num(cvar_bantime))
		remove_task(id)
		g_attempts[id] = 0
	}
	else {
		
		menu_account(id)
		set_hudmessage(255, 255, 255, 0.02, 0.25, 0, 6.0, 15.0)
		show_hudmessage(id,"%L [ %d / %d ]", LANG_PLAYER, "WRONG_PASSWORD_01", g_attempts[id], get_pcvar_num(cvar_attempts))
		client_print_color(id, "!g%L !t%L !y[!g %d !y/!g %d !y]", LANG_PLAYER, "REG_PREFIX", LANG_PLAYER, "WRONG_PASSWORD_01", g_attempts[id], get_pcvar_num(cvar_attempts))
	}
}

public login_time(id) {
	
	new szName[32]
	get_user_name(id, szName, charsmax(szName))
	
	if(!g_logged[id] && !g_invited[id] && !is_user_hltv(id) && !is_user_bot(id) ) {
		
		client_print(id, print_console, "----------------------------------------")
		client_print(id, print_console, "%L",LANG_PLAYER, "LOGIN_TIME_00", szName)
		client_print(id, print_console, "%L", LANG_PLAYER, "LOGIN_TIME_01")
		client_print(id, print_console, "%L", LANG_PLAYER, "LOGIN_TIME_02")
		client_print(id, print_console, "%L", LANG_PLAYER, "LOGIN_TIME_04", get_pcvar_num(cvar_logintime))
		client_print(id, print_console, "----------------------------------------")
		client_print_color(0, "!g%L !y%s !t%L !t", LANG_PLAYER, "REG_PREFIX", szName, LANG_PLAYER, "LOGIN_TIME_04")
		client_cmd(id, "disconnect")
		client_cmd(id, "toggleconsole")
	}
}

public PlayerPreThink(id) {
	
	if(!g_logged[id] && !g_invited[id] && !is_user_bot(id) && !is_user_hltv(id) && get_pcvar_num(cvar_screenfade)) {
		
		message_begin(MSG_ONE_UNRELIABLE, g_screenfade, {0,0,0}, id)
		write_short(1<<12)
		write_short(1<<12)
		write_short(0x0000)
		write_byte(0)
		write_byte(0)
		write_byte(0)
		write_byte(255)
		message_end()		
	}
}

public commands(id) {
	
	new text[70], arg1[32], arg2[32], arg3[6]
	read_args(text, sizeof(text) - 1)
	remove_quotes(text)
	arg1[0] = '^0'; arg2[0] = '^0'; arg3[0] = '^0'
	parse(text, arg1, sizeof(arg1) - 1, arg2, sizeof(arg2) - 1, arg3, sizeof(arg3) - 1)
	
	if(equali(arg1, "/", 1) || equali(arg1, ".", 1)) format(arg1, 31, arg1[1])
	
	if(arg3[0]) return PLUGIN_CONTINUE
	
	if(equali(arg1, "registro") || equali(arg1, "register") || equali(arg1, "conta") || equali(arg1, "account")) {
		
		menu_account(id)
	}
	return PLUGIN_CONTINUE
}

public native_is_user_logged(id) {
	
	if(!is_user_connected(id))
		return 0
	
	return g_logged[id]
}

public native_is_user_registered(id) {
	
	if(!is_user_connected(id))
		return 0
	
	return g_registered[id]
}

public native_is_user_invited(id) {
	
	if(!is_user_connected(id))
		return 0
	
	return g_invited[id]
}

bool:characters(const symbol[], len) {
	
	new const valid_chars[][] = {
		
		"0" ,"1" ,"2" ,"3" ,"4" ,"5" ,"6" ,"7" ,"8" ,"9",
		"a", "b", "c", "d", "e", "f", "g", "h", "i", "j",
		"k", "l", "m", "n", "o", "p", "q", "r", "s", "t",
		"u", "v", "w", "x", "y", "z"
	}
	static i, a, valids;
	valids = 0
	
	for(i = 0; i < len; i++) {
		
		for(a = 0; a < sizeof(valid_chars); a++) {
			
			if(symbol[i] == valid_chars[a][0]) {
				
				valids++
				break
			}
		}
	}
	if(valids != len)
		return false
	return true
}

stock client_print_color(const id, const input[], any:...) {
	
	new count = 1, players[32]
	static msg[191]
	vformat(msg, 190, input, 3)
	
	replace_all(msg, 190, "!g", "^4")
	replace_all(msg, 190, "!y", "^1")
	replace_all(msg, 190, "!t", "^3")
	replace_all(msg, 190, "!team2", "^0")
	
	if (id)
		players[0] = id;
	else
		get_players(players, count, "ch")
	
	for (new i = 0; i < count; i++) {
		
		if (is_user_connected(players[i])) {
			
			message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"), _, players[i])
			write_byte(players[i]);
			write_string(msg);
			message_end();
		}
	}
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
Tömörített fájl	Tömörített fájl letöltése
*A fordítás a aghl.ru oldalon történik.

_________________
[steam]MyNameIsTesco[/steam]

Ha tudtam valamiben segíteni köszönd meg:)

A hozzászólást 1 alkalommal szerkesztették, utoljára ASDD 2022.12.04. 18:01-kor.

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

kajlakaki01

Hozzászólás témája: Re: Regisztrációs Rendszer [Felújított]

HozzászólásElküldve:2023.03.01. 06:16

Offline

Csatlakozott:2021.01.08. 18:25
Hozzászólások:273
Megköszönt másnak: 26 alkalommal
Megköszönték neki: 20 alkalommal

ASDD írta:

Szokásos módon + Zip fájlnak megfelelően!

Sma lefordítás:

Probléma lehet:

Akinek nem sikerül lefordítani annak valószínűleg a fordítója nem támogatja azt a include-ot ami szükséges hozzá.

Megoldás:

Zip fájlban lévő include-ot adja hozzá a fordítóhoz és gondmentesen lefordítja!

F12, és C/D:\Program Files (x86)\Steam\userdata\209008089\760\remote\10\screenshots

_________________

FÓRUM

Ők köszönték meg kajlakaki01 nek ezt a hozzászólást: ASDD (2023.06.04. 23:37)

Népszerűség: 2.27%

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

ASDD

Hozzászólás témája: Re: Regisztrációs Rendszer [Felújított]

HozzászólásElküldve:2023.06.04. 23:37

Offline

Csatlakozott:2021.03.16. 10:28
Hozzászólások:49
Megköszönt másnak: 7 alkalommal
Megköszönték neki: 5 alkalommal

kajlakaki01 írta:

ASDD írta:

Szokásos módon + Zip fájlnak megfelelően!

Sma lefordítás:

Probléma lehet:

Akinek nem sikerül lefordítani annak valószínűleg a fordítója nem támogatja azt a include-ot ami szükséges hozzá.

Megoldás:

Zip fájlban lévő include-ot adja hozzá a fordítóhoz és gondmentesen lefordítja!

F12, és C/D:\Program Files (x86)\Steam\userdata\209008089\760\remote\10\screenshots

Szia!

Köszönöm szépen ma is tanultam valamit!

_________________
[steam]MyNameIsTesco[/steam]

Ha tudtam valamiben segíteni köszönd meg:)

Hozzászólás jelentése

Vissza a tetejére

Profil

Hozzászólás az előzmény idézésével

Hozzászólások megjelenítése: Rendezés

Új téma nyitása Hozzászólás a témához

Oldal: 1 / 1

[3 hozzászólás ]

Kezdőlap » Fórum » AMX Mod X » Pluginok » Jóváhagyott pluginok

Ki van itt

Jelenlévő fórumozók: nincs regisztrált felhasználó valamint 6 vendég

Nem nyithatsz témákat ebben a fórumban.
Válaszolhatsz egy témára ebben a fórumban.
Nem szerkesztheted a hozzászólásaidat ebben a fórumban.
Nem törölheted a hozzászólásaidat ebben a fórumban.
Nem küldhetsz csatolmányokat ebben a fórumban.

Ugrás: