hlmod.hu :: Fegyver Sebesség

hlmod.hu https://hlmod.hu/

Fegyver Sebesség https://hlmod.hu/viewtopic.php?f=101&t=31395	Oldal: 1 / 1

Szerző:

s1mp [ 2022.12.05. 13:23 ]

Hozzászólás témája:

Fegyver Sebesség

Plugin Neve:	Fegyver Sebesség	Plugint készitette:	ConnorMcLeod
Játék:	Counter-Strike	Kategória:	Játékmenet
Eredeti link:	Nincs megadva	Jóváhagyó:	kiki

Plugin készítő: ConnorMcLeod
Plugint fordította: *s1mpla

Leírás:
Ez a bővítmény lehetővé teszi a fegyverek maximális sebességének módosítását, akkor is, ha a játékosnak pajzsa van, vagy zoomolt!

Szükséges Modulok:

Parancsok:
amx_weapon_maxspeed <fegyver neve> <max sebesség> [zoom max sebesség] [pajzs max sebesség]
Fegyverneve : Lista lentebb
Max sebesség : Alapértelmezett MaxSpeed, állítsd 0-ra a bővítmény letiltásához egy adott fegyveren
Zoom Maxspeed : MaxSpeed, ha a fegyveren zoomolt
Shield Maxspeed : MaxSpeed, ha a játékos pajzsot használ

Lista:

► Spoiler mutatása
|---------------------------------------------------------------------|
| Fegyver Neve      | Alap Sebesség |   Zoom Sebesség  |  Pajzs Sebesség |
|---------------------|---------------|---------------|---------------|
| weapon_p228         |        250.0  |               |        180.0  |
| weapon_scout        |        260.0  |        220.0  |               |
| weapon_hegrenade    |        250.0  |               |        180.0  |
| weapon_xm1014       |        240.0  |               |               |
| weapon_c4           |        250.0  |               |               |
| weapon_mac10        |        250.0  |               |               |
| weapon_aug          |        240.0  |               |               |
| weapon_smokegrenade |        250.0  |               |        180.0  |
| weapon_elite        |        250.0  |               |               |
| weapon_fiveseven    |        250.0  |               |        180.0  |
| weapon_ump45        |        250.0  |               |               |
| weapon_sg550        |        210.0  |        150.0  |               |
| weapon_galil        |        240.0  |               |               |
| weapon_famas        |        240.0  |               |               |
| weapon_usp          |        250.0  |               |        180.0  |
| weapon_glock18      |        250.0  |               |        180.0  |
| weapon_awp          |        210.0  |        150.0  |               |
| weapon_mp5navy      |        250.0  |               |               |
| weapon_m249         |        220.0  |               |               |
| weapon_m3           |        230.0  |               |               |
| weapon_m4a1         |        230.0  |               |               |
| weapon_tmp          |        250.0  |               |               |
| weapon_g3sg1        |        210.0  |        150.0  |               |
| weapon_flashbang    |        250.0  |               |        180.0  |
| weapon_deagle       |        250.0  |               |        180.0  |
| weapon_sg552        |        235.0  |        200.0  |               |
| weapon_ak47         |        221.0  |               |               |
| weapon_knife        |        250.0  |               |        180.0  |
| weapon_p90          |        245.0  |               |               |
|---------------------------------------------------------------------|

Példák:

Megjegyzés:
Győződj meg arról, hogy az sv_maxspeed és sv_maxvelocity szerver cvarok a beépülő modul beállításai alapján vannak beállítva.
Ezenkívül módosítanod kell a cl_forwardspeed, cl_backspeed és cl_sidespeed kliens cvarokat, ha 400-nál több maxspeed-et szeretnél.

Ha nem állítod be a zoom max sebességet vagy a pajzs pajzs sebességet akkor az alap max sebességet fogja használni!
Állítsd be, ha nem szeretnéd, hogy a beépülő modul alapértelmezett értéke legyen használatban.

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <hamsandwich>

#define VERSION "0.0.5"
#define PLUGIN "Weapons MaxSpeed"

#define MAX_WEAPONS CSW_P90

#define XO_WEAPON 4
#define m_pPlayer 41
#define m_iId 43

#define XO_PLAYER 5
#define m_iFOV 363
#define OFFSET_SHIELD 510
#define HAS_SHIELD  (1<<24)
#define USES_SHIELD  (1<<16)
const HAS_AND_USES_SHIELD = HAS_SHIELD|USES_SHIELD

#define SHIELD_WEAPONS_BITSUM ((1<<CSW_P228)|(1<<CSW_HEGRENADE)|(1<<CSW_SMOKEGRENADE)|(1<<CSW_FIVESEVEN)|(1<<CSW_USP)|(1<<CSW_GLOCK18)|(1<<CSW_FLASHBANG)|(1<<CSW_DEAGLE)|(1<<CSW_KNIFE))

enum _:MaxSpeedType {
	Float:DefaultMaxSpeed,
	Float:ZoomedMaxSpeed,
	Float:ShieldMaxSpeed
}

new HamHook:g_iHhForwards[MAX_WEAPONS+1]
new Float:g_flMaxSpeed[MAX_WEAPONS+1][MaxSpeedType]

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, "ConnorMcLeod")

register_concmd("amx_weapon_maxspeed", "ConsoleCommand_WeaponSpeed", ADMIN_CFG, "<weapon shortname> <maxspeed> [zoom maxspeed] [shield maxspeed]")
}

public ConsoleCommand_WeaponSpeed(id, lvl, cid)
{
	if( cmd_access(id, lvl, cid, 2) )
	{
		new szWeapon[32] = "weapon_"
		read_argv(1, szWeapon[7], charsmax(szWeapon)-7)

new iId = get_weaponid(szWeapon)

if( iId )
		{
			new iArgs = read_argc()
			if( iArgs == 2 )
			{
				Get_Weapon_State(id, iId, szWeapon)
				return PLUGIN_HANDLED
			}

new szMaxSpeed[5]
			read_argv(2, szMaxSpeed, charsmax(szMaxSpeed))
			g_flMaxSpeed[iId][DefaultMaxSpeed] = floatmax(str_to_float(szMaxSpeed), 0.0)
			if( !g_flMaxSpeed[iId][DefaultMaxSpeed] )
			{
				if( g_iHhForwards[iId] )
				{
					DisableHamForward( g_iHhForwards[iId] )
					Get_Weapon_State(id, iId, szWeapon)
				}
				return PLUGIN_HANDLED
			}

if( iArgs > 3 )
			{
				read_argv(3, szMaxSpeed, charsmax(szMaxSpeed))
				g_flMaxSpeed[iId][ZoomedMaxSpeed] = floatmax(str_to_float(szMaxSpeed), 0.0)
			}
			else
			{
				g_flMaxSpeed[iId][ZoomedMaxSpeed] = 0.0
			}

if( iArgs > 4 && SHIELD_WEAPONS_BITSUM & 1<<iId )
			{
				read_argv(4, szMaxSpeed, charsmax(szMaxSpeed))
				g_flMaxSpeed[iId][ShieldMaxSpeed] = floatmax(str_to_float(szMaxSpeed), 0.0)
			}
			else
			{
				g_flMaxSpeed[iId][ShieldMaxSpeed] = 0.0
			}

if( g_iHhForwards[iId] )
			{
				EnableHamForward( g_iHhForwards[iId] )
			}
			else
			{
				RegisterHam(Ham_CS_Item_GetMaxSpeed, szWeapon, "Item_GetMaxSpeed")
			}
			Get_Weapon_State(id, iId, szWeapon)
		}
	}
	return PLUGIN_HANDLED
}

Get_Weapon_State(id, iId, szWeapon[])
{
	if( !g_flMaxSpeed[iId][DefaultMaxSpeed] )
	{
		console_print(id, "%s A maxspeed az alapértelmezett, a plugin nem aktív ezen a fegyveren!", szWeapon)
	}
	else
	{
		console_print(id, "%s a maximális sebesség a(z) %.1f", szWeapon, g_flMaxSpeed[iId][DefaultMaxSpeed])
		if( g_flMaxSpeed[iId][ZoomedMaxSpeed] )
		{
			console_print(id, "%s A pajzzsal maximális sebesség ezen a fegyveren a(z) %.1f", szWeapon, g_flMaxSpeed[iId][ZoomedMaxSpeed])
		}
		if( g_flMaxSpeed[iId][ShieldMaxSpeed] )
		{
			console_print(id, "%s A zoom-mal maximális sebesség ezen a fegyveren a(z) %.1f", szWeapon, g_flMaxSpeed[iId][ShieldMaxSpeed])
		}
	}
}

public Item_GetMaxSpeed( iWeapon )
{
	new iId = get_pdata_int(iWeapon, m_iId, XO_WEAPON)

// alter m_flWeaponSpeed would be less efficient
	if(	g_flMaxSpeed[iId][ShieldMaxSpeed]
	&&	get_pdata_int(get_pdata_cbase(iWeapon, m_pPlayer, XO_WEAPON), OFFSET_SHIELD, XO_PLAYER) & HAS_AND_USES_SHIELD == HAS_AND_USES_SHIELD	)
	{
		SetHamReturnFloat( g_flMaxSpeed[iId][ShieldMaxSpeed] )
	}
	else if(	g_flMaxSpeed[iId][ZoomedMaxSpeed]
	&&			get_pdata_int(get_pdata_cbase(iWeapon, m_pPlayer, XO_WEAPON), m_iFOV, XO_PLAYER) != 90	)
	{
		SetHamReturnFloat( g_flMaxSpeed[iId][ZoomedMaxSpeed] )
	}
	else
	{
		SetHamReturnFloat( g_flMaxSpeed[iId][DefaultMaxSpeed] )
	}
	return HAM_SUPERCEDE
}

SMA	Letöltés \| Megtekintés
AMXX	Átalakítás AMXX-re*
*A fordítás a aghl.ru oldalon történik.

Oldal: 1 / 1	Minden időpont UTC+02:00 időzóna szerinti
Powered by phpBB® Forum Software © phpBB Limited https://www.phpbb.com/